src/CMakeLists.txt

   1 include(ECMAddAppIcon)
   2
   3 configure_file(config-baloo.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-baloo.h)
   4
   5 configure_file(config-kactivities.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-kactivities.h)
   6
   7 configure_file(config-packagekit.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-packagekit.h)
   8
   9 configure_file(config-terminal.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-terminal.h)
  10
  11 add_definitions(
  12     -DTRANSLATION_DOMAIN=\"dolphin\"
  13 )
  14 remove_definitions(
  15     -DQT_NO_CAST_FROM_BYTEARRAY
  16     -DQT_NO_SIGNALS_SLOTS_KEYWORDS
  17     -DQT_NO_CAST_FROM_ASCII
  18     -DQT_NO_CAST_TO_ASCII
  19 )
  20
  21 ##########################################
  22
  23 set(dolphinvcs_LIB_SRCS
  24     views/versioncontrol/kversioncontrolplugin.cpp
  25 )
  26
  27 add_library(dolphinvcs ${dolphinvcs_LIB_SRCS})
  28 generate_export_header(dolphinvcs BASE_NAME dolphinvcs)
  29
  30 target_link_libraries(
  31     dolphinvcs PUBLIC
  32     Qt5::Widgets
  33 )
  34
  35 set_target_properties(dolphinvcs PROPERTIES
  36     VERSION ${DOLPHINVCS_VERSION_STRING}
  37     SOVERSION ${DOLPHINVCS_SOVERSION}
  38     EXPORT_NAME DolphinVcs
  39 )
  40
  41 ecm_generate_headers(dolphinvcs_LIB_HEADERS
  42     HEADER_NAMES
  43     KVersionControlPlugin
  44
  45     RELATIVE "views/versioncontrol"
  46     REQUIRED_HEADERS dolphinvcs_LIB_HEADERS
  47 )
  48
  49 install(TARGETS dolphinvcs EXPORT DolphinVcsTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
  50
  51 install(FILES views/versioncontrol/fileviewversioncontrolplugin.desktop DESTINATION ${KDE_INSTALL_KSERVICETYPES5DIR})
  52 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphinvcs_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
  53 install(FILES ${dolphinvcs_LIB_HEADERS} DESTINATION "${KDE_INSTALL_INCLUDEDIR}/Dolphin" COMPONENT Devel)
  54
  55 ########### next target ###############
  56
  57 set(dolphinprivate_LIB_SRCS
  58     kitemviews/kfileitemlistview.cpp
  59     kitemviews/kfileitemlistwidget.cpp
  60     kitemviews/kfileitemmodel.cpp
  61     kitemviews/kfileitemmodelrolesupdater.cpp
  62     kitemviews/kitemlistcontainer.cpp
  63     kitemviews/kitemlistcontroller.cpp
  64     kitemviews/kitemlistgroupheader.cpp
  65     kitemviews/kitemlistheader.cpp
  66     kitemviews/kitemlistselectionmanager.cpp
  67     kitemviews/kitemliststyleoption.cpp
  68     kitemviews/kitemlistview.cpp
  69     kitemviews/kitemlistviewaccessible.cpp
  70     kitemviews/kitemlistwidget.cpp
  71     kitemviews/kitemmodelbase.cpp
  72     kitemviews/kitemset.cpp
  73     kitemviews/kstandarditem.cpp
  74     kitemviews/kstandarditemlistgroupheader.cpp
  75     kitemviews/kstandarditemlistwidget.cpp
  76     kitemviews/kstandarditemlistview.cpp
  77     kitemviews/kstandarditemmodel.cpp
  78     kitemviews/private/kdirectorycontentscounter.cpp
  79     kitemviews/private/kdirectorycontentscounterworker.cpp
  80     kitemviews/private/kfileitemclipboard.cpp
  81     kitemviews/private/kfileitemmodeldirlister.cpp
  82     kitemviews/private/kfileitemmodelfilter.cpp
  83     kitemviews/private/kitemlistheaderwidget.cpp
  84     kitemviews/private/kitemlistkeyboardsearchmanager.cpp
  85     kitemviews/private/kitemlistroleeditor.cpp
  86     kitemviews/private/kitemlistrubberband.cpp
  87     kitemviews/private/kitemlistselectiontoggle.cpp
  88     kitemviews/private/kitemlistsizehintresolver.cpp
  89     kitemviews/private/kitemlistsmoothscroller.cpp
  90     kitemviews/private/kitemlistviewanimation.cpp
  91     kitemviews/private/kitemlistviewlayouter.cpp
  92     kitemviews/private/kpixmapmodifier.cpp
  93     settings/applyviewpropsjob.cpp
  94     settings/viewmodes/viewmodesettings.cpp
  95     settings/viewpropertiesdialog.cpp
  96     settings/viewpropsprogressinfo.cpp
  97     views/dolphinfileitemlistwidget.cpp
  98     views/dolphinitemlistview.cpp
  99     views/dolphinnewfilemenuobserver.cpp
 100     views/dolphinremoteencoding.cpp
 101     views/dolphinview.cpp
 102     views/dolphinviewactionhandler.cpp
 103     views/draganddrophelper.cpp
 104     views/versioncontrol/updateitemstatesthread.cpp
 105     views/versioncontrol/versioncontrolobserver.cpp
 106     views/viewmodecontroller.cpp
 107     views/viewproperties.cpp
 108     views/zoomlevelinfo.cpp
 109     dolphinremoveaction.cpp
 110     middleclickactioneventfilter.cpp
 111     dolphinnewfilemenu.cpp
 112 )
 113
 114 ecm_qt_declare_logging_category(dolphinprivate_LIB_SRCS HEADER dolphindebug.h IDENTIFIER DolphinDebug CATEGORY_NAME org.kde.dolphin)
 115
 116 if(HAVE_BALOO)
 117     set(dolphinprivate_LIB_SRCS
 118         ${dolphinprivate_LIB_SRCS}
 119         views/tooltips/dolphinfilemetadatawidget.cpp
 120         views/tooltips/tooltipmanager.cpp
 121         kitemviews/private/kbaloorolesprovider.cpp
 122     )
 123 endif()
 124
 125 kconfig_add_kcfg_files(dolphinprivate_LIB_SRCS GENERATE_MOC
 126     settings/dolphin_compactmodesettings.kcfgc
 127     settings/dolphin_directoryviewpropertysettings.kcfgc
 128     settings/dolphin_detailsmodesettings.kcfgc
 129     settings/dolphin_iconsmodesettings.kcfgc
 130     settings/dolphin_generalsettings.kcfgc
 131     settings/dolphin_versioncontrolsettings.kcfgc
 132 )
 133
 134 add_library(dolphinprivate ${dolphinprivate_LIB_SRCS})
 135 generate_export_header(dolphinprivate BASE_NAME dolphin)
 136
 137 target_link_libraries(
 138     dolphinprivate PUBLIC
 139     dolphinvcs
 140     Qt5::Concurrent
 141     Qt5::Gui
 142     KF5::I18n
 143     KF5::IconThemes
 144     KF5::KIOCore
 145     KF5::KIOWidgets
 146     KF5::KIOFileWidgets
 147     KF5::Completion
 148     KF5::TextWidgets
 149     KF5::ConfigCore
 150     KF5::NewStuff
 151     KF5::Parts
 152     KF5::WindowSystem
 153 )
 154
 155 if(HAVE_BALOO)
 156     target_link_libraries(
 157         dolphinprivate PUBLIC
 158         KF5::FileMetaData
 159         KF5::Baloo
 160         KF5::BalooWidgets
 161     )
 162 endif()
 163
 164 set_target_properties(dolphinprivate PROPERTIES
 165     VERSION ${DOLPHINPRIVATE_VERSION_STRING}
 166     SOVERSION ${DOLPHINPRIVATE_SOVERSION}
 167 )
 168
 169 install(TARGETS dolphinprivate ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} LIBRARY NAMELINK_SKIP)
 170 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphin_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
 171
 172 ##########################################
 173
 174 set(dolphinpart_SRCS
 175    dolphinpart.cpp
 176    dolphinpart_ext.cpp
 177    dolphindebug.cpp
 178 )
 179
 180 qt5_add_resources(dolphinpart_SRCS dolphinpart.qrc)
 181
 182 add_library(dolphinpart MODULE ${dolphinpart_SRCS})
 183
 184 target_link_libraries(dolphinpart
 185     dolphinprivate
 186 )
 187
 188 install(TARGETS dolphinpart DESTINATION ${KDE_INSTALL_PLUGINDIR})
 189
 190 install(FILES dolphinpart.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR})
 191
 192 ##########################################
 193
 194 set(dolphinstatic_SRCS
 195     dolphinbookmarkhandler.cpp
 196     dolphindockwidget.cpp
 197     dolphinmainwindow.cpp
 198     dolphinviewcontainer.cpp
 199     dolphincontextmenu.cpp
 200     dolphintabbar.cpp
 201     dolphinplacesmodelsingleton.cpp
 202     dolphinrecenttabsmenu.cpp
 203     dolphintabpage.cpp
 204     dolphintabwidget.cpp
 205     trash/dolphintrash.cpp
 206     filterbar/filterbar.cpp
 207     panels/places/placespanel.cpp
 208     panels/places/placesitem.cpp
 209     panels/places/placesitemlistgroupheader.cpp
 210     panels/places/placesitemlistwidget.cpp
 211     panels/places/placesitemmodel.cpp
 212     panels/places/placesitemsignalhandler.cpp
 213     panels/places/placesview.cpp
 214     panels/panel.cpp
 215     panels/folders/foldersitemlistwidget.cpp
 216     panels/folders/treeviewcontextmenu.cpp
 217     panels/folders/folderspanel.cpp
 218     panels/terminal/terminalpanel.cpp
 219     search/dolphinfacetswidget.cpp
 220     search/dolphinquery.cpp
 221     search/dolphinsearchbox.cpp
 222     settings/general/behaviorsettingspage.cpp
 223     settings/general/configurepreviewplugindialog.cpp
 224     settings/general/confirmationssettingspage.cpp
 225     settings/general/generalsettingspage.cpp
 226     settings/general/previewssettingspage.cpp
 227     settings/general/statusbarsettingspage.cpp
 228     settings/dolphinsettingsdialog.cpp
 229     settings/navigation/navigationsettingspage.cpp
 230     settings/services/servicessettingspage.cpp
 231     settings/settingspagebase.cpp
 232     settings/serviceitemdelegate.cpp
 233     settings/servicemodel.cpp
 234     settings/startup/startupsettingspage.cpp
 235     settings/trash/trashsettingspage.cpp
 236     settings/viewmodes/dolphinfontrequester.cpp
 237     settings/viewmodes/viewsettingspage.cpp
 238     settings/viewmodes/viewmodesettings.cpp
 239     settings/viewmodes/viewsettingstab.cpp
 240     statusbar/dolphinstatusbar.cpp
 241     statusbar/mountpointobserver.cpp
 242     statusbar/mountpointobservercache.cpp
 243     statusbar/spaceinfoobserver.cpp
 244     statusbar/statusbarspaceinfo.cpp
 245     views/zoomlevelinfo.cpp
 246     dolphindebug.cpp
 247     global.cpp
 248 )
 249
 250 if(HAVE_BALOO)
 251     set(dolphinstatic_SRCS
 252         ${dolphinstatic_SRCS}
 253         panels/information/informationpanel.cpp
 254         panels/information/informationpanelcontent.cpp
 255         panels/information/pixmapviewer.cpp
 256         panels/information/phononwidget.cpp
 257     )
 258 endif()
 259
 260 kconfig_add_kcfg_files(dolphinstatic_SRCS GENERATE_MOC
 261     panels/folders/dolphin_folderspanelsettings.kcfgc
 262     panels/information/dolphin_informationpanelsettings.kcfgc
 263     panels/places/dolphin_placespanelsettings.kcfgc
 264     settings/dolphin_compactmodesettings.kcfgc
 265     settings/dolphin_detailsmodesettings.kcfgc
 266     settings/dolphin_generalsettings.kcfgc
 267     settings/dolphin_iconsmodesettings.kcfgc
 268     search/dolphin_searchsettings.kcfgc
 269     settings/dolphin_versioncontrolsettings.kcfgc
 270 )
 271
 272 qt5_add_resources(dolphinstatic_SRCS dolphin.qrc)
 273
 274 qt5_generate_dbus_interface(${CMAKE_CURRENT_SOURCE_DIR}/dolphinmainwindow.h org.kde.DolphinMainWindow.xml)
 275 qt5_add_dbus_adaptor(dolphinstatic_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindow.h DolphinMainWindow)
 276 qt5_add_dbus_interface(dolphinstatic_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindowinterface)
 277 qt5_add_dbus_interface(dolphinstatic_SRCS panels/terminal/org.kde.KIOFuse.VFS.xml kiofuse_interface)
 278
 279 add_library(dolphinstatic STATIC ${dolphinstatic_SRCS})
 280
 281 target_include_directories(dolphinstatic SYSTEM PRIVATE ${PHONON_INCLUDES})
 282 target_link_libraries(dolphinstatic
 283     dolphinprivate
 284     KF5::CoreAddons
 285     KF5::KCMUtils
 286     KF5::DBusAddons
 287     KF5::Notifications
 288     Phonon::phonon4qt5
 289 )
 290
 291 if (HAVE_KACTIVITIES)
 292     target_link_libraries(
 293         dolphinstatic
 294         KF5::Activities
 295     )
 296 endif()
 297
 298 set(dolphin_SRCS
 299     dbusinterface.cpp
 300     main.cpp
 301 )
 302
 303 # Sets the icon on Windows and OSX
 304 file(GLOB ICONS_SRCS "${CMAKE_CURRENT_SOURCE_DIR}/icons/*system-file-manager.png")
 305 ecm_add_app_icon(dolphin_SRCS ICONS ${ICONS_SRCS})
 306
 307 kf5_add_kdeinit_executable(dolphin ${dolphin_SRCS})
 308
 309
 310 target_link_libraries(kdeinit_dolphin PUBLIC
 311     dolphinprivate
 312     PRIVATE
 313     dolphinstatic
 314     KF5::Crash
 315 )
 316
 317 include(DbusInterfaceMacros)
 318
 319 generate_and_install_dbus_interface(
 320     kdeinit_dolphin
 321     dbusinterface.h
 322     org.freedesktop.FileManager1.xml
 323     OPTIONS -a
 324 )
 325
 326 install(TARGETS kdeinit_dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 327 install(TARGETS dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 328
 329 ##########################################
 330
 331 set(kcm_dolphinviewmodes_PART_SRCS
 332     settings/kcm/kcmdolphinviewmodes.cpp
 333     settings/viewmodes/dolphinfontrequester.cpp
 334     settings/viewmodes/viewmodesettings.cpp
 335     settings/viewmodes/viewsettingstab.cpp
 336     views/zoomlevelinfo.cpp)
 337
 338 set(kcm_dolphinnavigation_PART_SRCS
 339     settings/kcm/kcmdolphinnavigation.cpp
 340     settings/navigation/navigationsettingspage.cpp
 341     settings/settingspagebase.cpp)
 342
 343 set(kcm_dolphinservices_PART_SRCS
 344     settings/kcm/kcmdolphinservices.cpp
 345     settings/services/servicessettingspage.cpp
 346     settings/settingspagebase.cpp
 347     settings/serviceitemdelegate.cpp
 348     settings/servicemodel.cpp)
 349
 350 set(kcm_dolphingeneral_PART_SRCS
 351     settings/kcm/kcmdolphingeneral.cpp
 352     settings/general/behaviorsettingspage.cpp
 353     settings/general/previewssettingspage.cpp
 354     settings/general/configurepreviewplugindialog.cpp
 355     settings/general/confirmationssettingspage.cpp
 356     settings/settingspagebase.cpp
 357     settings/serviceitemdelegate.cpp
 358     settings/servicemodel.cpp)
 359
 360 kconfig_add_kcfg_files(kcm_dolphinviewmodes_PART_SRCS
 361     settings/dolphin_compactmodesettings.kcfgc
 362     settings/dolphin_directoryviewpropertysettings.kcfgc
 363     settings/dolphin_detailsmodesettings.kcfgc
 364     settings/dolphin_iconsmodesettings.kcfgc
 365     settings/dolphin_generalsettings.kcfgc
 366     settings/dolphin_versioncontrolsettings.kcfgc
 367 )
 368
 369 kconfig_add_kcfg_files(kcm_dolphinnavigation_PART_SRCS
 370     settings/dolphin_generalsettings.kcfgc)
 371
 372 kconfig_add_kcfg_files(kcm_dolphinservices_PART_SRCS
 373     settings/dolphin_generalsettings.kcfgc
 374     settings/dolphin_versioncontrolsettings.kcfgc)
 375
 376 kconfig_add_kcfg_files(kcm_dolphingeneral_PART_SRCS
 377     settings/dolphin_generalsettings.kcfgc)
 378
 379 add_library(kcm_dolphinviewmodes MODULE ${kcm_dolphinviewmodes_PART_SRCS})
 380 add_library(kcm_dolphinnavigation MODULE ${kcm_dolphinnavigation_PART_SRCS})
 381 add_library(kcm_dolphinservices MODULE ${kcm_dolphinservices_PART_SRCS})
 382 add_library(kcm_dolphingeneral MODULE ${kcm_dolphingeneral_PART_SRCS})
 383
 384 target_link_libraries(kcm_dolphinviewmodes dolphinprivate)
 385 target_link_libraries(kcm_dolphinnavigation dolphinprivate)
 386 target_link_libraries(kcm_dolphinservices dolphinprivate)
 387 target_link_libraries(kcm_dolphingeneral dolphinprivate)
 388
 389 install(TARGETS kcm_dolphinviewmodes DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 390 install(TARGETS kcm_dolphinnavigation DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 391 install(TARGETS kcm_dolphinservices DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 392 install(TARGETS kcm_dolphingeneral DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 393
 394 add_subdirectory(settings/services/servicemenuinstaller)
 395
 396 ########### install files ###############
 397
 398 install( PROGRAMS org.kde.dolphin.desktop DESTINATION ${KDE_INSTALL_APPDIR} )
 399
 400 install( DIRECTORY DESTINATION "${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel" )
 401
 402 install(
 403     CODE "execute_process(COMMAND \"${CMAKE_COMMAND}\" -E create_symlink \"${KDE_INSTALL_FULL_APPDIR}/org.kde.dolphin.desktop\" \"\$ENV{DESTDIR}${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel/org.kde.dolphin.desktop\")"
 404 )
 405
 406 install( FILES settings/dolphin_directoryviewpropertysettings.kcfg
 407                settings/dolphin_generalsettings.kcfg
 408                settings/dolphin_compactmodesettings.kcfg
 409                settings/dolphin_iconsmodesettings.kcfg
 410                settings/dolphin_detailsmodesettings.kcfg
 411                settings/dolphin_versioncontrolsettings.kcfg
 412          DESTINATION ${KDE_INSTALL_KCFGDIR} )
 413 install( FILES org.kde.dolphin.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR} )
 414 install( FILES settings/kcm/kcmdolphinviewmodes.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 415 install( FILES settings/kcm/kcmdolphinnavigation.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 416 install( FILES settings/kcm/kcmdolphinservices.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 417 install( FILES settings/kcm/kcmdolphingeneral.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 418 install( FILES settings/services/servicemenu.knsrc DESTINATION ${KDE_INSTALL_KNSRCDIR} )
 419
 420 if(BUILD_TESTING)
 421     find_package(Qt5Test ${QT_MIN_VERSION} CONFIG REQUIRED)
 422     add_subdirectory(tests)
 423 endif()