src/CMakeLists.txt

   1 include(ECMAddAppIcon)
   2
   3 configure_file(config-dolphin.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-dolphin.h)
   4
   5 add_definitions(
   6     -DTRANSLATION_DOMAIN=\"dolphin\"
   7 )
   8 remove_definitions(
   9     -DQT_NO_CAST_FROM_BYTEARRAY
  10     -DQT_NO_CAST_FROM_ASCII
  11     -DQT_NO_CAST_TO_ASCII
  12 )
  13
  14 ##########################################
  15
  16 add_library(dolphinvcs SHARED)
  17
  18 target_sources(dolphinvcs PRIVATE
  19     views/versioncontrol/kversioncontrolplugin.cpp
  20 )
  21
  22 generate_export_header(dolphinvcs BASE_NAME dolphinvcs)
  23
  24 target_link_libraries(
  25     dolphinvcs PUBLIC
  26     Qt6::Widgets
  27 )
  28
  29 set_target_properties(dolphinvcs PROPERTIES
  30     VERSION ${DOLPHINVCS_VERSION}
  31     SOVERSION ${DOLPHINVCS_SOVERSION}
  32     EXPORT_NAME DolphinVcs
  33 )
  34
  35 ecm_generate_headers(dolphinvcs_LIB_HEADERS
  36     HEADER_NAMES
  37     KVersionControlPlugin
  38
  39     RELATIVE "views/versioncontrol"
  40     REQUIRED_HEADERS dolphinvcs_LIB_HEADERS
  41 )
  42 target_include_directories(dolphinvcs INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR}>")
  43
  44 install(TARGETS dolphinvcs EXPORT DolphinVcsTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
  45
  46 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphinvcs_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
  47 install(FILES ${dolphinvcs_LIB_HEADERS} DESTINATION "${KDE_INSTALL_INCLUDEDIR}/Dolphin" COMPONENT Devel)
  48
  49 ########### next target ###############
  50
  51 add_library(dolphinprivate SHARED)
  52
  53 target_sources(dolphinprivate PRIVATE
  54     kitemviews/kfileitemlistview.cpp
  55     kitemviews/kfileitemlistwidget.cpp
  56     kitemviews/kfileitemlisttostring.cpp
  57     kitemviews/kfileitemmodel.cpp
  58     kitemviews/kfileitemmodelrolesupdater.cpp
  59     kitemviews/kitemlistcontainer.cpp
  60     kitemviews/kitemlistcontroller.cpp
  61     kitemviews/kitemlistgroupheader.cpp
  62     kitemviews/kitemlistheader.cpp
  63     kitemviews/kitemlistselectionmanager.cpp
  64     kitemviews/kitemliststyleoption.cpp
  65     kitemviews/kitemlistview.cpp
  66     kitemviews/kitemlistviewaccessible.cpp
  67     kitemviews/kitemlistwidget.cpp
  68     kitemviews/kitemmodelbase.cpp
  69     kitemviews/kitemset.cpp
  70     kitemviews/kstandarditemlistgroupheader.cpp
  71     kitemviews/kstandarditemlistwidget.cpp
  72     kitemviews/kstandarditemlistview.cpp
  73     kitemviews/private/kdirectorycontentscounter.cpp
  74     kitemviews/private/kdirectorycontentscounterworker.cpp
  75     kitemviews/private/kfileitemclipboard.cpp
  76     kitemviews/private/kfileitemmodelfilter.cpp
  77     kitemviews/private/kitemlistheaderwidget.cpp
  78     kitemviews/private/kitemlistkeyboardsearchmanager.cpp
  79     kitemviews/private/kitemlistroleeditor.cpp
  80     kitemviews/private/kitemlistrubberband.cpp
  81     kitemviews/private/kitemlistselectiontoggle.cpp
  82     kitemviews/private/kitemlistsizehintresolver.cpp
  83     kitemviews/private/kitemlistsmoothscroller.cpp
  84     kitemviews/private/kitemlistviewanimation.cpp
  85     kitemviews/private/kitemlistviewlayouter.cpp
  86     kitemviews/private/kpixmapmodifier.cpp
  87     settings/applyviewpropsjob.cpp
  88     settings/viewmodes/viewmodesettings.cpp
  89     settings/viewpropertiesdialog.cpp
  90     settings/viewpropsprogressinfo.cpp
  91     selectionmode/actiontexthelper.cpp
  92     views/dolphinfileitemlistwidget.cpp
  93     views/dolphinitemlistview.cpp
  94     views/dolphinnewfilemenuobserver.cpp
  95     views/dolphinremoteencoding.cpp
  96     views/dolphinview.cpp
  97     views/dolphinviewactionhandler.cpp
  98     views/draganddrophelper.cpp
  99     views/versioncontrol/updateitemstatesthread.cpp
 100     views/versioncontrol/versioncontrolobserver.cpp
 101     views/viewmodecontroller.cpp
 102     views/viewproperties.cpp
 103     views/zoomlevelinfo.cpp
 104     dolphinremoveaction.cpp
 105     middleclickactioneventfilter.cpp
 106     dolphinnewfilemenu.cpp
 107
 108     kitemviews/kfileitemlistview.h
 109     kitemviews/kfileitemlistwidget.h
 110     kitemviews/kfileitemlisttostring.h
 111     kitemviews/kfileitemmodel.h
 112     kitemviews/kfileitemmodelrolesupdater.h
 113     kitemviews/kitemlistcontainer.h
 114     kitemviews/kitemlistcontroller.h
 115     kitemviews/kitemlistgroupheader.h
 116     kitemviews/kitemlistheader.h
 117     kitemviews/kitemlistselectionmanager.h
 118     kitemviews/kitemliststyleoption.h
 119     kitemviews/kitemlistview.h
 120     kitemviews/kitemlistviewaccessible.h
 121     kitemviews/kitemlistwidget.h
 122     kitemviews/kitemmodelbase.h
 123     kitemviews/kitemset.h
 124     kitemviews/kstandarditemlistgroupheader.h
 125     kitemviews/kstandarditemlistwidget.h
 126     kitemviews/kstandarditemlistview.h
 127     kitemviews/private/kdirectorycontentscounter.h
 128     kitemviews/private/kdirectorycontentscounterworker.h
 129     kitemviews/private/kfileitemclipboard.h
 130     kitemviews/private/kfileitemmodelfilter.h
 131     kitemviews/private/kitemlistheaderwidget.h
 132     kitemviews/private/kitemlistkeyboardsearchmanager.h
 133     kitemviews/private/kitemlistroleeditor.h
 134     kitemviews/private/kitemlistrubberband.h
 135     kitemviews/private/kitemlistselectiontoggle.h
 136     kitemviews/private/kitemlistsizehintresolver.h
 137     kitemviews/private/kitemlistsmoothscroller.h
 138     kitemviews/private/kitemlistviewanimation.h
 139     kitemviews/private/kitemlistviewlayouter.h
 140     kitemviews/private/kpixmapmodifier.h
 141     settings/applyviewpropsjob.h
 142     settings/viewmodes/viewmodesettings.h
 143     settings/viewpropertiesdialog.h
 144     settings/viewpropsprogressinfo.h
 145     selectionmode/actiontexthelper.h
 146     views/dolphinfileitemlistwidget.h
 147     views/dolphinitemlistview.h
 148     views/dolphinnewfilemenuobserver.h
 149     views/dolphinremoteencoding.h
 150     views/dolphinview.h
 151     views/dolphinviewactionhandler.h
 152     views/draganddrophelper.h
 153     views/versioncontrol/updateitemstatesthread.h
 154     views/versioncontrol/versioncontrolobserver.h
 155     views/viewmodecontroller.h
 156     views/viewproperties.h
 157     views/zoomlevelinfo.h
 158     dolphinremoveaction.h
 159     middleclickactioneventfilter.h
 160     dolphinnewfilemenu.h
 161 )
 162
 163 ecm_qt_declare_logging_category(dolphinprivate
 164     HEADER dolphindebug.h
 165     IDENTIFIER DolphinDebug
 166     CATEGORY_NAME org.kde.dolphin
 167     DESCRIPTION "dolphin"
 168     EXPORT DOLPHIN
 169 )
 170
 171 if(HAVE_BALOO)
 172     target_sources(dolphinprivate PRIVATE
 173         views/tooltips/dolphinfilemetadatawidget.cpp
 174         views/tooltips/tooltipmanager.cpp
 175         kitemviews/private/kbaloorolesprovider.cpp
 176         views/tooltips/dolphinfilemetadatawidget.h
 177         views/tooltips/tooltipmanager.h
 178         kitemviews/private/kbaloorolesprovider.h
 179     )
 180 endif()
 181
 182 kconfig_add_kcfg_files(dolphinprivate
 183     settings/dolphin_compactmodesettings.kcfgc
 184     settings/dolphin_directoryviewpropertysettings.kcfgc
 185     settings/dolphin_detailsmodesettings.kcfgc
 186     settings/dolphin_iconsmodesettings.kcfgc
 187     settings/dolphin_contentdisplaysettings.kcfgc
 188     settings/dolphin_generalsettings.kcfgc
 189     settings/dolphin_contextmenusettings.kcfgc
 190     settings/dolphin_versioncontrolsettings.kcfgc
 191 )
 192
 193 generate_export_header(dolphinprivate BASE_NAME dolphin)
 194
 195 target_link_libraries(
 196     dolphinprivate PUBLIC
 197     dolphinvcs
 198     Qt6::Concurrent
 199     Qt6::Gui
 200     KF6::I18n
 201     KF6::IconThemes
 202     KF6::KIOCore
 203     KF6::KIOWidgets
 204     KF6::KIOFileWidgets
 205     KF6::Completion
 206     KF6::TextWidgets
 207     KF6::ConfigCore
 208     KF6::NewStuffWidgets    # KNSWidgets::Button
 209     KF6::Parts
 210     KF6::WindowSystem
 211     KF6::WidgetsAddons
 212     KF6::Codecs
 213     KF6::KCMUtils
 214
 215     ${FTS_LIB}
 216 )
 217
 218 if(HAVE_BALOO)
 219     target_link_libraries(
 220         dolphinprivate PUBLIC
 221         KF6::FileMetaData
 222         KF6::Baloo
 223         KF6::BalooWidgets
 224     )
 225 endif()
 226
 227 set_target_properties(dolphinprivate PROPERTIES
 228     VERSION ${DOLPHINPRIVATE_VERSION}
 229     SOVERSION ${DOLPHINPRIVATE_SOVERSION}
 230 )
 231
 232 install(TARGETS dolphinprivate ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} LIBRARY NAMELINK_SKIP)
 233 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphin_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
 234
 235 ##########################################
 236 configure_file(dolphinpart.json.in ${CMAKE_CURRENT_BINARY_DIR}/dolphinpart.json @ONLY)
 237
 238 add_library(dolphinpart MODULE)
 239
 240 target_sources(dolphinpart PRIVATE
 241     dolphinpart.cpp
 242     dolphinpart_ext.cpp
 243     dolphindebug.cpp
 244     dolphinpart.h
 245     dolphinpart_ext.h
 246     dolphindebug.h
 247
 248     dolphinpart.qrc
 249 )
 250
 251 target_link_libraries(dolphinpart
 252     dolphinprivate
 253 )
 254
 255 install(TARGETS dolphinpart DESTINATION ${KDE_INSTALL_PLUGINDIR}/kf6/parts)
 256 install(FILES dolphinpartactions.desktop DESTINATION "${KDE_INSTALL_DATADIR}/dolphin/")
 257
 258 ##########################################
 259
 260 add_library(dolphinstatic STATIC)
 261
 262 target_sources(dolphinstatic PRIVATE
 263     dolphinbookmarkhandler.cpp
 264     dolphindockwidget.cpp
 265     dolphinmainwindow.cpp
 266     dolphinviewcontainer.cpp
 267     dolphincontextmenu.cpp
 268     dolphinnavigatorswidgetaction.cpp
 269     dolphintabbar.cpp
 270     dolphinplacesmodelsingleton.cpp
 271     dolphinrecenttabsmenu.cpp
 272     dolphintabpage.cpp
 273     dolphintabwidget.cpp
 274     dolphinurlnavigator.cpp
 275     dolphinurlnavigatorscontroller.cpp
 276     trash/dolphintrash.cpp
 277     filterbar/filterbar.cpp
 278     kitemviews/kfileitemlisttostring.cpp
 279     panels/places/placespanel.cpp
 280     panels/panel.cpp
 281     panels/folders/foldersitemlistwidget.cpp
 282     panels/folders/treeviewcontextmenu.cpp
 283     panels/folders/folderspanel.cpp
 284     panels/terminal/terminalpanel.cpp
 285     search/dolphinfacetswidget.cpp
 286     search/dolphinquery.cpp
 287     search/dolphinsearchbox.cpp
 288     selectionmode/actiontexthelper.cpp
 289     selectionmode/actionwithwidget.cpp
 290     selectionmode/backgroundcolorhelper.cpp
 291     selectionmode/bottombar.cpp
 292     selectionmode/bottombarcontentscontainer.cpp
 293     selectionmode/topbar.cpp
 294     settings/interface/folderstabssettingspage.cpp
 295     settings/interface/statusandlocationbarssettingspage.cpp
 296     settings/interface/confirmationssettingspage.cpp
 297     settings/interface/interfacesettingspage.cpp
 298     settings/interface/previewssettingspage.cpp
 299     settings/dolphinsettingsdialog.cpp
 300     settings/contextmenu/contextmenusettingspage.cpp
 301     settings/settingspagebase.cpp
 302     settings/servicemodel.cpp
 303     settings/trash/trashsettingspage.cpp
 304     settings/viewmodes/dolphinfontrequester.cpp
 305     settings/viewmodes/viewsettingspage.cpp
 306     settings/viewmodes/viewmodesettings.cpp
 307     settings/viewmodes/viewsettingstab.cpp
 308     settings/viewmodes/contentdisplaytab.cpp
 309     settings/viewmodes/generalviewsettingspage.cpp
 310     statusbar/dolphinstatusbar.cpp
 311     statusbar/mountpointobserver.cpp
 312     statusbar/mountpointobservercache.cpp
 313     statusbar/spaceinfoobserver.cpp
 314     statusbar/statusbarspaceinfo.cpp
 315     views/zoomlevelinfo.cpp
 316     dolphindebug.cpp
 317     global.cpp
 318     dolphin.qrc
 319
 320     dolphinbookmarkhandler.h
 321     dolphindockwidget.h
 322     dolphinmainwindow.h
 323     dolphinviewcontainer.h
 324     dolphincontextmenu.h
 325     dolphinnavigatorswidgetaction.h
 326     dolphintabbar.h
 327     dolphinplacesmodelsingleton.h
 328     dolphinrecenttabsmenu.h
 329     dolphintabpage.h
 330     dolphintabwidget.h
 331     dolphinurlnavigator.h
 332     dolphinurlnavigatorscontroller.h
 333     trash/dolphintrash.h
 334     filterbar/filterbar.h
 335     kitemviews/kfileitemlisttostring.h
 336     panels/places/placespanel.h
 337     panels/panel.h
 338     panels/folders/foldersitemlistwidget.h
 339     panels/folders/treeviewcontextmenu.h
 340     panels/folders/folderspanel.h
 341     panels/terminal/terminalpanel.h
 342     search/dolphinfacetswidget.h
 343     search/dolphinquery.h
 344     search/dolphinsearchbox.h
 345     selectionmode/actiontexthelper.h
 346     selectionmode/actionwithwidget.h
 347     selectionmode/backgroundcolorhelper.h
 348     selectionmode/bottombar.h
 349     selectionmode/bottombarcontentscontainer.h
 350     selectionmode/topbar.h
 351     settings/interface/folderstabssettingspage.h
 352     settings/interface/statusandlocationbarssettingspage.h
 353     settings/interface/confirmationssettingspage.h
 354     settings/interface/interfacesettingspage.h
 355     settings/interface/previewssettingspage.h
 356     settings/dolphinsettingsdialog.h
 357     settings/contextmenu/contextmenusettingspage.h
 358     settings/settingspagebase.h
 359     settings/servicemodel.h
 360     settings/trash/trashsettingspage.h
 361     settings/viewmodes/dolphinfontrequester.h
 362     settings/viewmodes/viewsettingspage.h
 363     settings/viewmodes/viewmodesettings.h
 364     settings/viewmodes/viewsettingstab.h
 365     settings/viewmodes/contentdisplaytab.h
 366     settings/viewmodes/generalviewsettingspage.h
 367     statusbar/dolphinstatusbar.h
 368     statusbar/mountpointobserver.h
 369     statusbar/mountpointobservercache.h
 370     statusbar/spaceinfoobserver.h
 371     statusbar/statusbarspaceinfo.h
 372     views/zoomlevelinfo.h
 373     dolphindebug.h
 374     global.h
 375 )
 376
 377 if(HAVE_BALOO)
 378     target_sources(dolphinstatic PRIVATE
 379         panels/information/informationpanel.cpp
 380         panels/information/informationpanelcontent.cpp
 381         panels/information/pixmapviewer.cpp
 382         panels/information/phononwidget.cpp
 383         panels/information/informationpanel.h
 384         panels/information/informationpanelcontent.h
 385         panels/information/pixmapviewer.h
 386         panels/information/phononwidget.h
 387     )
 388 endif()
 389
 390 if(HAVE_KUSERFEEDBACK)
 391     target_sources(dolphinstatic PRIVATE
 392         userfeedback/dolphinfeedbackprovider.cpp
 393         userfeedback/settingsdatasource.cpp
 394         userfeedback/placesdatasource.cpp
 395         settings/userfeedback/userfeedbacksettingspage.cpp
 396         userfeedback/dolphinfeedbackprovider.h
 397         userfeedback/settingsdatasource.h
 398         userfeedback/placesdatasource.h
 399         settings/userfeedback/userfeedbacksettingspage.h
 400     )
 401 endif()
 402
 403 kconfig_add_kcfg_files(dolphinstatic
 404     panels/folders/dolphin_folderspanelsettings.kcfgc
 405     panels/information/dolphin_informationpanelsettings.kcfgc
 406     panels/places/dolphin_placespanelsettings.kcfgc
 407     settings/dolphin_compactmodesettings.kcfgc
 408     settings/dolphin_detailsmodesettings.kcfgc
 409     settings/dolphin_contextmenusettings.kcfgc
 410     settings/dolphin_iconsmodesettings.kcfgc
 411     settings/dolphin_contentdisplaysettings.kcfgc
 412     search/dolphin_searchsettings.kcfgc
 413     settings/dolphin_versioncontrolsettings.kcfgc
 414 )
 415 kconfig_add_kcfg_files(dolphinstatic GENERATE_MOC
 416     settings/dolphin_generalsettings.kcfgc
 417 )
 418
 419 qt_generate_dbus_interface(${CMAKE_CURRENT_SOURCE_DIR}/dolphinmainwindow.h org.kde.DolphinMainWindow.xml)
 420 qt_add_dbus_adaptor(dolphin_dbus_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindow.h DolphinMainWindow)
 421 qt_add_dbus_interface(dolphin_dbus_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindowinterface)
 422 qt_add_dbus_interface(dolphin_dbus_SRCS panels/terminal/org.kde.KIOFuse.VFS.xml kiofuse_interface)
 423
 424 target_sources(dolphinstatic PRIVATE
 425     ${dolphin_dbus_SRCS}
 426 )
 427
 428 target_include_directories(dolphinstatic SYSTEM PRIVATE ${PHONON_INCLUDES})
 429 target_link_libraries(dolphinstatic
 430     dolphinprivate
 431     KF6::CoreAddons
 432     KF6::KCMUtils
 433     KF6::DBusAddons
 434     KF6::Notifications
 435     KF6::BookmarksWidgets
 436     Phonon::phonon4qt6
 437 )
 438
 439 if (HAVE_KACTIVITIES)
 440     target_link_libraries(
 441         dolphinstatic
 442         KF6::Activities
 443     )
 444 endif()
 445
 446 if (HAVE_KUSERFEEDBACK)
 447     target_link_libraries(
 448         dolphinstatic
 449         KUserFeedbackCoreQt6
 450         KUserFeedbackWidgetsQt6
 451     )
 452 endif()
 453
 454 add_executable(dolphin)
 455
 456 target_sources(dolphin PRIVATE
 457     dbusinterface.cpp
 458     dbusinterface.h
 459     main.cpp
 460 )
 461
 462 if(FLATPAK)
 463     target_compile_definitions(dolphin PRIVATE FLATPAK)
 464 endif()
 465
 466 # Sets the icon on Windows and OSX
 467 file(GLOB ICONS_SRCS "${CMAKE_CURRENT_SOURCE_DIR}/icons/*system-file-manager.png")
 468 ecm_add_app_icon(dolphin ICONS ${ICONS_SRCS})
 469
 470 target_link_libraries(dolphin
 471     PRIVATE
 472     dolphinprivate
 473     dolphinstatic
 474     KF6::Crash
 475 )
 476
 477 if (HAVE_X11)
 478     target_link_libraries(dolphin PRIVATE Qt::GuiPrivate)
 479 endif()
 480
 481 include(DbusInterfaceMacros)
 482
 483 generate_and_install_dbus_interface(
 484     dolphin
 485     dbusinterface.h
 486     org.freedesktop.FileManager1.xml
 487     OPTIONS -a
 488 )
 489
 490 install(TARGETS dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 491
 492 ##########################################
 493
 494 if(NOT WIN32)
 495     # The settings are still accessible from the hamburger menu
 496     add_library(kcm_dolphinviewmodes MODULE)
 497     add_library(kcm_dolphingeneral MODULE)
 498
 499     target_sources(kcm_dolphinviewmodes PRIVATE
 500         settings/kcm/kcmdolphinviewmodes.cpp
 501         settings/viewmodes/dolphinfontrequester.cpp
 502         settings/viewmodes/viewmodesettings.cpp
 503         settings/viewmodes/viewsettingstab.cpp
 504         settings/settingspagebase.cpp
 505         views/zoomlevelinfo.cpp
 506         settings/kcm/kcmdolphinviewmodes.h
 507         settings/viewmodes/dolphinfontrequester.h
 508         settings/viewmodes/viewmodesettings.h
 509         settings/viewmodes/viewsettingstab.h
 510         views/zoomlevelinfo.h)
 511
 512     target_sources(kcm_dolphingeneral PRIVATE
 513         settings/kcm/kcmdolphingeneral.cpp
 514         settings/interface/folderstabssettingspage.cpp
 515         settings/interface/statusandlocationbarssettingspage.cpp
 516         settings/interface/previewssettingspage.cpp
 517         settings/interface/confirmationssettingspage.cpp
 518         settings/settingspagebase.cpp
 519         settings/servicemodel.cpp
 520         dolphin_generalsettings.cpp
 521         dolphindebug.cpp
 522         dolphinmainwindowinterface.cpp
 523         views/viewproperties.cpp
 524         dolphin_directoryviewpropertysettings.cpp
 525         global.cpp
 526         settings/kcm/kcmdolphingeneral.h
 527         settings/interface/folderstabssettingspage.h
 528         settings/interface/statusandlocationbarssettingspage.h
 529         settings/interface/previewssettingspage.h
 530         settings/interface/confirmationssettingspage.h
 531         settings/settingspagebase.h
 532         settings/servicemodel.h
 533         dolphin_generalsettings.h
 534         dolphindebug.h
 535         dolphinmainwindowinterface.h
 536         views/viewproperties.h
 537         dolphin_directoryviewpropertysettings.h
 538         global.h
 539     )
 540
 541     kconfig_add_kcfg_files(kcm_dolphinviewmodes
 542         settings/dolphin_compactmodesettings.kcfgc
 543         settings/dolphin_directoryviewpropertysettings.kcfgc
 544         settings/dolphin_detailsmodesettings.kcfgc
 545         settings/dolphin_iconsmodesettings.kcfgc
 546         settings/dolphin_contentdisplaysettings.kcfgc
 547         settings/dolphin_generalsettings.kcfgc
 548         settings/dolphin_versioncontrolsettings.kcfgc
 549     )
 550
 551     kconfig_add_kcfg_files(kcm_dolphingeneral
 552         settings/dolphin_generalsettings.kcfgc)
 553
 554     target_link_libraries(kcm_dolphinviewmodes dolphinprivate)
 555     target_link_libraries(kcm_dolphingeneral dolphinprivate)
 556
 557     install( FILES org.kde.dolphin.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR} )
 558
 559     install(TARGETS kcm_dolphinviewmodes DESTINATION ${KDE_INSTALL_PLUGINDIR}/dolphin/kcms )
 560     install(TARGETS kcm_dolphingeneral DESTINATION ${KDE_INSTALL_PLUGINDIR}/dolphin/kcms )
 561 endif()
 562
 563 if(NOT WIN32)
 564     add_subdirectory(settings/contextmenu/servicemenuinstaller)
 565     install( FILES settings/contextmenu/servicemenu.knsrc DESTINATION ${KDE_INSTALL_KNSRCDIR} )
 566 endif()
 567
 568 ########### install files ###############
 569
 570 install( PROGRAMS org.kde.dolphin.desktop DESTINATION ${KDE_INSTALL_APPDIR} )
 571
 572 install( DIRECTORY DESTINATION "${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel" )
 573
 574 install(
 575     CODE "execute_process(COMMAND \"${CMAKE_COMMAND}\" -E create_symlink \"${KDE_INSTALL_FULL_APPDIR}/org.kde.dolphin.desktop\" \"\$ENV{DESTDIR}${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel/org.kde.dolphin.desktop\")"
 576 )
 577
 578 install( FILES settings/dolphin_directoryviewpropertysettings.kcfg
 579                settings/dolphin_generalsettings.kcfg
 580                settings/dolphin_contextmenusettings.kcfg
 581                settings/dolphin_compactmodesettings.kcfg
 582                settings/dolphin_iconsmodesettings.kcfg
 583                settings/dolphin_detailsmodesettings.kcfg
 584                settings/dolphin_contentdisplaysettings.kcfg
 585                settings/dolphin_versioncontrolsettings.kcfg
 586          DESTINATION ${KDE_INSTALL_KCFGDIR} )
 587
 588 install( FILES settings/dolphin_detailsmodesettings.upd
 589          DESTINATION ${KDE_INSTALL_KCONFUPDATEDIR} )
 590
 591 if(BUILD_TESTING)
 592     add_subdirectory(tests)
 593 endif()