src/CMakeLists.txt

   1 include(ECMAddAppIcon)
   2
   3 configure_file(config-dolphin.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-dolphin.h)
   4
   5 add_definitions(
   6     -DTRANSLATION_DOMAIN=\"dolphin\"
   7 )
   8 remove_definitions(
   9     -DQT_NO_CAST_FROM_BYTEARRAY
  10     -DQT_NO_CAST_FROM_ASCII
  11     -DQT_NO_CAST_TO_ASCII
  12 )
  13
  14 ##########################################
  15
  16 add_library(dolphinvcs SHARED)
  17
  18 target_sources(dolphinvcs PRIVATE
  19     views/versioncontrol/kversioncontrolplugin.cpp
  20 )
  21
  22 generate_export_header(dolphinvcs BASE_NAME dolphinvcs)
  23
  24 target_link_libraries(
  25     dolphinvcs PUBLIC
  26     Qt6::Widgets
  27 )
  28
  29 set_target_properties(dolphinvcs PROPERTIES
  30     VERSION ${DOLPHINVCS_VERSION}
  31     SOVERSION ${DOLPHINVCS_SOVERSION}
  32     EXPORT_NAME DolphinVcs
  33 )
  34
  35 ecm_generate_headers(dolphinvcs_LIB_HEADERS
  36     HEADER_NAMES
  37     KVersionControlPlugin
  38
  39     RELATIVE "views/versioncontrol"
  40     REQUIRED_HEADERS dolphinvcs_LIB_HEADERS
  41 )
  42 target_include_directories(dolphinvcs INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR}>")
  43
  44 install(TARGETS dolphinvcs EXPORT DolphinVcsTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
  45
  46 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphinvcs_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
  47 install(FILES ${dolphinvcs_LIB_HEADERS} DESTINATION "${KDE_INSTALL_INCLUDEDIR}/Dolphin" COMPONENT Devel)
  48
  49 ########### next target ###############
  50
  51 add_library(dolphinprivate SHARED)
  52
  53 target_sources(dolphinprivate PRIVATE
  54     kitemviews/kfileitemlistview.cpp
  55     kitemviews/kfileitemlistwidget.cpp
  56     kitemviews/kfileitemlisttostring.cpp
  57     kitemviews/kfileitemmodel.cpp
  58     kitemviews/kfileitemmodelrolesupdater.cpp
  59     kitemviews/kitemlistcontainer.cpp
  60     kitemviews/kitemlistcontroller.cpp
  61     kitemviews/kitemlistgroupheader.cpp
  62     kitemviews/kitemlistheader.cpp
  63     kitemviews/kitemlistselectionmanager.cpp
  64     kitemviews/kitemliststyleoption.cpp
  65     kitemviews/kitemlistview.cpp
  66     kitemviews/kitemlistviewaccessible.cpp
  67     kitemviews/kitemlistwidget.cpp
  68     kitemviews/kitemmodelbase.cpp
  69     kitemviews/kitemset.cpp
  70     kitemviews/kstandarditemlistgroupheader.cpp
  71     kitemviews/kstandarditemlistwidget.cpp
  72     kitemviews/kstandarditemlistview.cpp
  73     kitemviews/private/kdirectorycontentscounter.cpp
  74     kitemviews/private/kdirectorycontentscounterworker.cpp
  75     kitemviews/private/kfileitemclipboard.cpp
  76     kitemviews/private/kfileitemmodelfilter.cpp
  77     kitemviews/private/kitemlistheaderwidget.cpp
  78     kitemviews/private/kitemlistkeyboardsearchmanager.cpp
  79     kitemviews/private/kitemlistroleeditor.cpp
  80     kitemviews/private/kitemlistrubberband.cpp
  81     kitemviews/private/kitemlistselectiontoggle.cpp
  82     kitemviews/private/kitemlistsizehintresolver.cpp
  83     kitemviews/private/kitemlistsmoothscroller.cpp
  84     kitemviews/private/kitemlistviewanimation.cpp
  85     kitemviews/private/kitemlistviewlayouter.cpp
  86     kitemviews/private/kitemviewsutils.cpp
  87     kitemviews/private/kpixmapmodifier.cpp
  88     settings/applyviewpropsjob.cpp
  89     settings/viewmodes/viewmodesettings.cpp
  90     settings/viewpropertiesdialog.cpp
  91     settings/viewpropsprogressinfo.cpp
  92     selectionmode/actiontexthelper.cpp
  93     views/dolphinfileitemlistwidget.cpp
  94     views/dolphinitemlistview.cpp
  95     views/dolphinnewfilemenuobserver.cpp
  96     views/dolphinremoteencoding.cpp
  97     views/dolphinview.cpp
  98     views/dolphinviewactionhandler.cpp
  99     views/draganddrophelper.cpp
 100     views/versioncontrol/updateitemstatesthread.cpp
 101     views/versioncontrol/versioncontrolobserver.cpp
 102     views/viewmodecontroller.cpp
 103     views/viewproperties.cpp
 104     views/zoomlevelinfo.cpp
 105     dolphinremoveaction.cpp
 106     middleclickactioneventfilter.cpp
 107     dolphinnewfilemenu.cpp
 108
 109     kitemviews/kfileitemlistview.h
 110     kitemviews/kfileitemlistwidget.h
 111     kitemviews/kfileitemlisttostring.h
 112     kitemviews/kfileitemmodel.h
 113     kitemviews/kfileitemmodelrolesupdater.h
 114     kitemviews/kitemlistcontainer.h
 115     kitemviews/kitemlistcontroller.h
 116     kitemviews/kitemlistgroupheader.h
 117     kitemviews/kitemlistheader.h
 118     kitemviews/kitemlistselectionmanager.h
 119     kitemviews/kitemliststyleoption.h
 120     kitemviews/kitemlistview.h
 121     kitemviews/kitemlistviewaccessible.h
 122     kitemviews/kitemlistwidget.h
 123     kitemviews/kitemmodelbase.h
 124     kitemviews/kitemset.h
 125     kitemviews/kstandarditemlistgroupheader.h
 126     kitemviews/kstandarditemlistwidget.h
 127     kitemviews/kstandarditemlistview.h
 128     kitemviews/private/kdirectorycontentscounter.h
 129     kitemviews/private/kdirectorycontentscounterworker.h
 130     kitemviews/private/kfileitemclipboard.h
 131     kitemviews/private/kfileitemmodelfilter.h
 132     kitemviews/private/kitemlistheaderwidget.h
 133     kitemviews/private/kitemlistkeyboardsearchmanager.h
 134     kitemviews/private/kitemlistroleeditor.h
 135     kitemviews/private/kitemlistrubberband.h
 136     kitemviews/private/kitemlistselectiontoggle.h
 137     kitemviews/private/kitemlistsizehintresolver.h
 138     kitemviews/private/kitemlistsmoothscroller.h
 139     kitemviews/private/kitemlistviewanimation.h
 140     kitemviews/private/kitemlistviewlayouter.h
 141     kitemviews/private/kpixmapmodifier.h
 142     settings/applyviewpropsjob.h
 143     settings/viewmodes/viewmodesettings.h
 144     settings/viewpropertiesdialog.h
 145     settings/viewpropsprogressinfo.h
 146     selectionmode/actiontexthelper.h
 147     views/dolphinfileitemlistwidget.h
 148     views/dolphinitemlistview.h
 149     views/dolphinnewfilemenuobserver.h
 150     views/dolphinremoteencoding.h
 151     views/dolphinview.h
 152     views/dolphinviewactionhandler.h
 153     views/draganddrophelper.h
 154     views/versioncontrol/updateitemstatesthread.h
 155     views/versioncontrol/versioncontrolobserver.h
 156     views/viewmodecontroller.h
 157     views/viewproperties.h
 158     views/zoomlevelinfo.h
 159     dolphinremoveaction.h
 160     middleclickactioneventfilter.h
 161     dolphinnewfilemenu.h
 162 )
 163
 164 ecm_qt_declare_logging_category(dolphinprivate
 165     HEADER dolphindebug.h
 166     IDENTIFIER DolphinDebug
 167     CATEGORY_NAME org.kde.dolphin
 168     DESCRIPTION "dolphin"
 169     EXPORT DOLPHIN
 170 )
 171
 172 if(HAVE_BALOO)
 173     target_sources(dolphinprivate PRIVATE
 174         views/tooltips/dolphinfilemetadatawidget.cpp
 175         views/tooltips/tooltipmanager.cpp
 176         kitemviews/private/kbaloorolesprovider.cpp
 177         views/tooltips/dolphinfilemetadatawidget.h
 178         views/tooltips/tooltipmanager.h
 179         kitemviews/private/kbaloorolesprovider.h
 180     )
 181 endif()
 182
 183 kconfig_add_kcfg_files(dolphinprivate
 184     settings/dolphin_compactmodesettings.kcfgc
 185     settings/dolphin_directoryviewpropertysettings.kcfgc
 186     settings/dolphin_detailsmodesettings.kcfgc
 187     settings/dolphin_iconsmodesettings.kcfgc
 188     settings/dolphin_contentdisplaysettings.kcfgc
 189     settings/dolphin_generalsettings.kcfgc
 190     settings/dolphin_contextmenusettings.kcfgc
 191     settings/dolphin_versioncontrolsettings.kcfgc
 192 )
 193
 194 generate_export_header(dolphinprivate BASE_NAME dolphin)
 195
 196 target_link_libraries(
 197     dolphinprivate PUBLIC
 198     dolphinvcs
 199     Qt6::Concurrent
 200     Qt6::Gui
 201     KF6::I18n
 202     KF6::IconThemes
 203     KF6::KIOCore
 204     KF6::KIOWidgets
 205     KF6::KIOFileWidgets
 206     KF6::Completion
 207     KF6::TextWidgets
 208     KF6::ConfigCore
 209     KF6::NewStuffWidgets    # KNSWidgets::Button
 210     KF6::Parts
 211     KF6::WindowSystem
 212     KF6::WidgetsAddons
 213     KF6::Codecs
 214     KF6::KCMUtils
 215
 216     ${FTS_LIB}
 217 )
 218
 219 if(HAVE_BALOO)
 220     target_link_libraries(
 221         dolphinprivate PUBLIC
 222         KF6::FileMetaData
 223         KF6::Baloo
 224         KF6::BalooWidgets
 225     )
 226 endif()
 227
 228 set_target_properties(dolphinprivate PROPERTIES
 229     VERSION ${DOLPHINPRIVATE_VERSION}
 230     SOVERSION ${DOLPHINPRIVATE_SOVERSION}
 231 )
 232
 233 install(TARGETS dolphinprivate ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} LIBRARY NAMELINK_SKIP)
 234 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphin_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
 235
 236 ##########################################
 237 configure_file(dolphinpart.json.in ${CMAKE_CURRENT_BINARY_DIR}/dolphinpart.json @ONLY)
 238
 239 add_library(dolphinpart MODULE)
 240
 241 target_sources(dolphinpart PRIVATE
 242     dolphinpart.cpp
 243     dolphinpart_ext.cpp
 244     dolphindebug.cpp
 245     dolphinpart.h
 246     dolphinpart_ext.h
 247     dolphindebug.h
 248
 249     dolphinpart.qrc
 250 )
 251
 252 target_link_libraries(dolphinpart
 253     dolphinprivate
 254 )
 255
 256 install(TARGETS dolphinpart DESTINATION ${KDE_INSTALL_PLUGINDIR}/kf6/parts)
 257 install(FILES dolphinpartactions.desktop DESTINATION "${KDE_INSTALL_DATADIR}/dolphin/")
 258
 259 ##########################################
 260
 261 add_library(dolphinstatic STATIC)
 262
 263 target_sources(dolphinstatic PRIVATE
 264     animatedheightwidget.cpp
 265     dolphinbookmarkhandler.cpp
 266     dolphindockwidget.cpp
 267     dolphinmainwindow.cpp
 268     dolphinviewcontainer.cpp
 269     dolphincontextmenu.cpp
 270     dolphinnavigatorswidgetaction.cpp
 271     dolphintabbar.cpp
 272     dolphinplacesmodelsingleton.cpp
 273     dolphinrecenttabsmenu.cpp
 274     dolphintabpage.cpp
 275     dolphintabwidget.cpp
 276     dolphinurlnavigator.cpp
 277     dolphinurlnavigatorscontroller.cpp
 278     trash/dolphintrash.cpp
 279     filterbar/filterbar.cpp
 280     kitemviews/kfileitemlisttostring.cpp
 281     panels/places/placespanel.cpp
 282     panels/panel.cpp
 283     panels/folders/foldersitemlistwidget.cpp
 284     panels/folders/treeviewcontextmenu.cpp
 285     panels/folders/folderspanel.cpp
 286     panels/terminal/terminalpanel.cpp
 287     search/dolphinfacetswidget.cpp
 288     search/dolphinquery.cpp
 289     search/dolphinsearchbox.cpp
 290     selectionmode/actiontexthelper.cpp
 291     selectionmode/actionwithwidget.cpp
 292     selectionmode/backgroundcolorhelper.cpp
 293     selectionmode/bottombar.cpp
 294     selectionmode/bottombarcontentscontainer.cpp
 295     selectionmode/topbar.cpp
 296     settings/interface/folderstabssettingspage.cpp
 297     settings/interface/statusandlocationbarssettingspage.cpp
 298     settings/interface/confirmationssettingspage.cpp
 299     settings/interface/interfacesettingspage.cpp
 300     settings/interface/previewssettingspage.cpp
 301     settings/dolphinsettingsdialog.cpp
 302     settings/contextmenu/contextmenusettingspage.cpp
 303     settings/settingspagebase.cpp
 304     settings/servicemodel.cpp
 305     settings/trash/trashsettingspage.cpp
 306     settings/viewmodes/dolphinfontrequester.cpp
 307     settings/viewmodes/viewsettingspage.cpp
 308     settings/viewmodes/viewmodesettings.cpp
 309     settings/viewmodes/viewsettingstab.cpp
 310     settings/viewmodes/contentdisplaytab.cpp
 311     settings/viewmodes/generalviewsettingspage.cpp
 312     statusbar/dolphinstatusbar.cpp
 313     statusbar/mountpointobserver.cpp
 314     statusbar/mountpointobservercache.cpp
 315     statusbar/spaceinfoobserver.cpp
 316     statusbar/statusbarspaceinfo.cpp
 317     views/zoomlevelinfo.cpp
 318     dolphindebug.cpp
 319     global.cpp
 320     dolphin.qrc
 321
 322     animatedheightwidget.h
 323     dolphinbookmarkhandler.h
 324     dolphindockwidget.h
 325     dolphinmainwindow.h
 326     dolphinviewcontainer.h
 327     dolphincontextmenu.h
 328     dolphinnavigatorswidgetaction.h
 329     dolphintabbar.h
 330     dolphinplacesmodelsingleton.h
 331     dolphinrecenttabsmenu.h
 332     dolphintabpage.h
 333     dolphintabwidget.h
 334     dolphinurlnavigator.h
 335     dolphinurlnavigatorscontroller.h
 336     trash/dolphintrash.h
 337     filterbar/filterbar.h
 338     kitemviews/kfileitemlisttostring.h
 339     panels/places/placespanel.h
 340     panels/panel.h
 341     panels/folders/foldersitemlistwidget.h
 342     panels/folders/treeviewcontextmenu.h
 343     panels/folders/folderspanel.h
 344     panels/terminal/terminalpanel.h
 345     search/dolphinfacetswidget.h
 346     search/dolphinquery.h
 347     search/dolphinsearchbox.h
 348     selectionmode/actiontexthelper.h
 349     selectionmode/actionwithwidget.h
 350     selectionmode/backgroundcolorhelper.h
 351     selectionmode/bottombar.h
 352     selectionmode/bottombarcontentscontainer.h
 353     selectionmode/topbar.h
 354     settings/interface/folderstabssettingspage.h
 355     settings/interface/statusandlocationbarssettingspage.h
 356     settings/interface/confirmationssettingspage.h
 357     settings/interface/interfacesettingspage.h
 358     settings/interface/previewssettingspage.h
 359     settings/dolphinsettingsdialog.h
 360     settings/contextmenu/contextmenusettingspage.h
 361     settings/settingspagebase.h
 362     settings/servicemodel.h
 363     settings/trash/trashsettingspage.h
 364     settings/viewmodes/dolphinfontrequester.h
 365     settings/viewmodes/viewsettingspage.h
 366     settings/viewmodes/viewmodesettings.h
 367     settings/viewmodes/viewsettingstab.h
 368     settings/viewmodes/contentdisplaytab.h
 369     settings/viewmodes/generalviewsettingspage.h
 370     statusbar/dolphinstatusbar.h
 371     statusbar/mountpointobserver.h
 372     statusbar/mountpointobservercache.h
 373     statusbar/spaceinfoobserver.h
 374     statusbar/statusbarspaceinfo.h
 375     views/zoomlevelinfo.h
 376     dolphindebug.h
 377     global.h
 378 )
 379
 380 if(HAVE_BALOO)
 381     target_sources(dolphinstatic PRIVATE
 382         panels/information/informationpanel.cpp
 383         panels/information/informationpanelcontent.cpp
 384         panels/information/pixmapviewer.cpp
 385         panels/information/phononwidget.cpp
 386         settings/interface/panelsettingspage.cpp
 387         panels/information/informationpanel.h
 388         panels/information/informationpanelcontent.h
 389         panels/information/pixmapviewer.h
 390         panels/information/phononwidget.h
 391         settings/interface/panelsettingspage.h
 392     )
 393
 394     kconfig_add_kcfg_files(dolphinstatic
 395         panels/information/dolphin_informationpanelsettings.kcfgc
 396     )
 397
 398 endif()
 399
 400 if(HAVE_KUSERFEEDBACK)
 401     target_sources(dolphinstatic PRIVATE
 402         userfeedback/dolphinfeedbackprovider.cpp
 403         userfeedback/settingsdatasource.cpp
 404         userfeedback/placesdatasource.cpp
 405         settings/userfeedback/userfeedbacksettingspage.cpp
 406         userfeedback/dolphinfeedbackprovider.h
 407         userfeedback/settingsdatasource.h
 408         userfeedback/placesdatasource.h
 409         settings/userfeedback/userfeedbacksettingspage.h
 410     )
 411 endif()
 412
 413 kconfig_add_kcfg_files(dolphinstatic
 414     panels/folders/dolphin_folderspanelsettings.kcfgc
 415     panels/places/dolphin_placespanelsettings.kcfgc
 416     settings/dolphin_compactmodesettings.kcfgc
 417     settings/dolphin_detailsmodesettings.kcfgc
 418     settings/dolphin_contextmenusettings.kcfgc
 419     settings/dolphin_iconsmodesettings.kcfgc
 420     settings/dolphin_contentdisplaysettings.kcfgc
 421     search/dolphin_searchsettings.kcfgc
 422     settings/dolphin_versioncontrolsettings.kcfgc
 423 )
 424 kconfig_add_kcfg_files(dolphinstatic GENERATE_MOC
 425     settings/dolphin_generalsettings.kcfgc
 426 )
 427
 428 qt_generate_dbus_interface(${CMAKE_CURRENT_SOURCE_DIR}/dolphinmainwindow.h org.kde.DolphinMainWindow.xml)
 429 qt_add_dbus_adaptor(dolphin_dbus_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindow.h DolphinMainWindow)
 430 qt_add_dbus_interface(dolphin_dbus_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindowinterface)
 431 qt_add_dbus_interface(dolphin_dbus_SRCS panels/terminal/org.kde.KIOFuse.VFS.xml kiofuse_interface)
 432
 433 target_sources(dolphinstatic PRIVATE
 434     ${dolphin_dbus_SRCS}
 435 )
 436
 437 target_include_directories(dolphinstatic SYSTEM PRIVATE ${PHONON_INCLUDES})
 438 target_link_libraries(dolphinstatic
 439     dolphinprivate
 440     KF6::CoreAddons
 441     KF6::KCMUtils
 442     KF6::DBusAddons
 443     KF6::Notifications
 444     KF6::BookmarksWidgets
 445     Phonon::phonon4qt6
 446 )
 447
 448 if (HAVE_PLASMA_ACTIVITIES)
 449     target_link_libraries(
 450         dolphinstatic
 451         Plasma::Activities
 452     )
 453 endif()
 454
 455 if (HAVE_KUSERFEEDBACK)
 456     target_link_libraries(
 457         dolphinstatic
 458         KF6::UserFeedbackCore
 459         KF6::UserFeedbackWidgets
 460     )
 461 endif()
 462
 463 add_executable(dolphin)
 464
 465 target_sources(dolphin PRIVATE
 466     dbusinterface.cpp
 467     dbusinterface.h
 468     main.cpp
 469 )
 470
 471 if(FLATPAK)
 472     target_compile_definitions(dolphin PRIVATE FLATPAK)
 473 endif()
 474
 475 # Install the icons on macOS and Windows
 476 ecm_add_app_icon(dolphin
 477     ICONS
 478         icons/128-apps-org.kde.dolphin.png
 479         icons/16-apps-org.kde.dolphin.png
 480         icons/22-apps-org.kde.dolphin.png
 481         icons/32-apps-org.kde.dolphin.png
 482         icons/48-apps-org.kde.dolphin.png
 483         icons/64-apps-org.kde.dolphin.png
 484     DESTINATION
 485         ${KDE_INSTALL_ICONDIR}
 486     THEME
 487         hicolor
 488 )
 489
 490 install(FILES icons/org.kde.dolphin.svg DESTINATION ${KDE_INSTALL_ICONDIR}/hicolor/scalable/apps)
 491
 492 target_link_libraries(dolphin
 493     PRIVATE
 494     dolphinprivate
 495     dolphinstatic
 496     KF6::Crash
 497 )
 498
 499 if (HAVE_X11)
 500     target_link_libraries(dolphin PRIVATE Qt::GuiPrivate)
 501 endif()
 502
 503 include(DbusInterfaceMacros)
 504
 505 generate_and_install_dbus_interface(
 506     dolphin
 507     dbusinterface.h
 508     org.freedesktop.FileManager1.xml
 509     OPTIONS -a
 510 )
 511
 512 install(TARGETS dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 513
 514 ##########################################
 515
 516 if(NOT WIN32)
 517     # The settings are still accessible from the hamburger menu
 518     add_library(kcm_dolphinviewmodes MODULE)
 519     add_library(kcm_dolphingeneral MODULE)
 520
 521     target_sources(kcm_dolphinviewmodes PRIVATE
 522         settings/kcm/kcmdolphinviewmodes.cpp
 523         settings/viewmodes/dolphinfontrequester.cpp
 524         settings/viewmodes/viewmodesettings.cpp
 525         settings/viewmodes/viewsettingstab.cpp
 526         settings/settingspagebase.cpp
 527         views/zoomlevelinfo.cpp
 528         settings/kcm/kcmdolphinviewmodes.h
 529         settings/viewmodes/dolphinfontrequester.h
 530         settings/viewmodes/viewmodesettings.h
 531         settings/viewmodes/viewsettingstab.h
 532         views/zoomlevelinfo.h)
 533
 534     target_sources(kcm_dolphingeneral PRIVATE
 535         settings/kcm/kcmdolphingeneral.cpp
 536         settings/interface/folderstabssettingspage.cpp
 537         settings/interface/statusandlocationbarssettingspage.cpp
 538         settings/interface/previewssettingspage.cpp
 539         settings/interface/confirmationssettingspage.cpp
 540         settings/settingspagebase.cpp
 541         settings/servicemodel.cpp
 542         dolphin_generalsettings.cpp
 543         dolphindebug.cpp
 544         dolphinmainwindowinterface.cpp
 545         views/viewproperties.cpp
 546         dolphin_directoryviewpropertysettings.cpp
 547         global.cpp
 548         settings/kcm/kcmdolphingeneral.h
 549         settings/interface/folderstabssettingspage.h
 550         settings/interface/statusandlocationbarssettingspage.h
 551         settings/interface/previewssettingspage.h
 552         settings/interface/confirmationssettingspage.h
 553         settings/settingspagebase.h
 554         settings/servicemodel.h
 555         dolphin_generalsettings.h
 556         dolphindebug.h
 557         dolphinmainwindowinterface.h
 558         views/viewproperties.h
 559         dolphin_directoryviewpropertysettings.h
 560         global.h
 561     )
 562
 563     kconfig_add_kcfg_files(kcm_dolphinviewmodes
 564         settings/dolphin_compactmodesettings.kcfgc
 565         settings/dolphin_directoryviewpropertysettings.kcfgc
 566         settings/dolphin_detailsmodesettings.kcfgc
 567         settings/dolphin_iconsmodesettings.kcfgc
 568         settings/dolphin_contentdisplaysettings.kcfgc
 569         settings/dolphin_generalsettings.kcfgc
 570         settings/dolphin_versioncontrolsettings.kcfgc
 571     )
 572
 573     kconfig_add_kcfg_files(kcm_dolphingeneral
 574         settings/dolphin_generalsettings.kcfgc)
 575
 576     target_link_libraries(kcm_dolphinviewmodes dolphinprivate)
 577     target_link_libraries(kcm_dolphingeneral dolphinprivate)
 578
 579     install( FILES org.kde.dolphin.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR} )
 580
 581     install(TARGETS kcm_dolphinviewmodes DESTINATION ${KDE_INSTALL_PLUGINDIR}/dolphin/kcms )
 582     install(TARGETS kcm_dolphingeneral DESTINATION ${KDE_INSTALL_PLUGINDIR}/dolphin/kcms )
 583 endif()
 584
 585 if(NOT WIN32)
 586     add_subdirectory(settings/contextmenu/servicemenuinstaller)
 587     install( FILES settings/contextmenu/servicemenu.knsrc DESTINATION ${KDE_INSTALL_KNSRCDIR} )
 588 endif()
 589
 590 ########### install files ###############
 591
 592 install( PROGRAMS org.kde.dolphin.desktop DESTINATION ${KDE_INSTALL_APPDIR} )
 593
 594 install( DIRECTORY DESTINATION "${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel" )
 595
 596 install(
 597     CODE "execute_process(COMMAND \"${CMAKE_COMMAND}\" -E create_symlink \"${KDE_INSTALL_FULL_APPDIR}/org.kde.dolphin.desktop\" \"\$ENV{DESTDIR}${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel/org.kde.dolphin.desktop\")"
 598 )
 599
 600 install( FILES settings/dolphin_directoryviewpropertysettings.kcfg
 601                settings/dolphin_generalsettings.kcfg
 602                settings/dolphin_contextmenusettings.kcfg
 603                settings/dolphin_compactmodesettings.kcfg
 604                settings/dolphin_iconsmodesettings.kcfg
 605                settings/dolphin_detailsmodesettings.kcfg
 606                settings/dolphin_contentdisplaysettings.kcfg
 607                settings/dolphin_versioncontrolsettings.kcfg
 608          DESTINATION ${KDE_INSTALL_KCFGDIR} )
 609
 610 install( FILES settings/dolphin_detailsmodesettings.upd
 611                settings/dolphin_directorysizemode.upd
 612                settings/dolphin_directorysizemode.py
 613          DESTINATION ${KDE_INSTALL_KCONFUPDATEDIR} )
 614
 615 if(BUILD_TESTING)
 616     add_subdirectory(tests)
 617 endif()