src/CMakeLists.txt

   1 include(ECMAddAppIcon)
   2
   3 configure_file(config-dolphin.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-dolphin.h)
   4
   5 add_definitions(
   6     -DTRANSLATION_DOMAIN=\"dolphin\"
   7 )
   8 remove_definitions(
   9     -DQT_NO_CAST_FROM_BYTEARRAY
  10     -DQT_NO_CAST_FROM_ASCII
  11     -DQT_NO_CAST_TO_ASCII
  12 )
  13
  14 ##########################################
  15
  16 add_library(dolphinvcs SHARED)
  17
  18 target_sources(dolphinvcs PRIVATE
  19     views/versioncontrol/kversioncontrolplugin.cpp
  20 )
  21
  22 generate_export_header(dolphinvcs BASE_NAME dolphinvcs)
  23
  24 target_link_libraries(
  25     dolphinvcs PUBLIC
  26     Qt${QT_MAJOR_VERSION}::Widgets
  27 )
  28
  29 set_target_properties(dolphinvcs PROPERTIES
  30     VERSION ${DOLPHINVCS_VERSION}
  31     SOVERSION ${DOLPHINVCS_SOVERSION}
  32     EXPORT_NAME DolphinVcs
  33 )
  34
  35 ecm_generate_headers(dolphinvcs_LIB_HEADERS
  36     HEADER_NAMES
  37     KVersionControlPlugin
  38
  39     RELATIVE "views/versioncontrol"
  40     REQUIRED_HEADERS dolphinvcs_LIB_HEADERS
  41 )
  42 target_include_directories(dolphinvcs INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR}>")
  43
  44 install(TARGETS dolphinvcs EXPORT DolphinVcsTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
  45
  46 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphinvcs_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
  47 install(FILES ${dolphinvcs_LIB_HEADERS} DESTINATION "${KDE_INSTALL_INCLUDEDIR}/Dolphin" COMPONENT Devel)
  48
  49 ########### next target ###############
  50
  51 add_library(dolphinprivate SHARED)
  52
  53 target_sources(dolphinprivate PRIVATE
  54     kitemviews/kfileitemlistview.cpp
  55     kitemviews/kfileitemlistwidget.cpp
  56     kitemviews/kfileitemlisttostring.cpp
  57     kitemviews/kfileitemmodel.cpp
  58     kitemviews/kfileitemmodelrolesupdater.cpp
  59     kitemviews/kitemlistcontainer.cpp
  60     kitemviews/kitemlistcontroller.cpp
  61     kitemviews/kitemlistgroupheader.cpp
  62     kitemviews/kitemlistheader.cpp
  63     kitemviews/kitemlistselectionmanager.cpp
  64     kitemviews/kitemliststyleoption.cpp
  65     kitemviews/kitemlistview.cpp
  66     kitemviews/kitemlistviewaccessible.cpp
  67     kitemviews/kitemlistwidget.cpp
  68     kitemviews/kitemmodelbase.cpp
  69     kitemviews/kitemset.cpp
  70     kitemviews/kstandarditemlistgroupheader.cpp
  71     kitemviews/kstandarditemlistwidget.cpp
  72     kitemviews/kstandarditemlistview.cpp
  73     kitemviews/private/kdirectorycontentscounter.cpp
  74     kitemviews/private/kdirectorycontentscounterworker.cpp
  75     kitemviews/private/kfileitemclipboard.cpp
  76     kitemviews/private/kfileitemmodelfilter.cpp
  77     kitemviews/private/kitemlistheaderwidget.cpp
  78     kitemviews/private/kitemlistkeyboardsearchmanager.cpp
  79     kitemviews/private/kitemlistroleeditor.cpp
  80     kitemviews/private/kitemlistrubberband.cpp
  81     kitemviews/private/kitemlistselectiontoggle.cpp
  82     kitemviews/private/kitemlistsizehintresolver.cpp
  83     kitemviews/private/kitemlistsmoothscroller.cpp
  84     kitemviews/private/kitemlistviewanimation.cpp
  85     kitemviews/private/kitemlistviewlayouter.cpp
  86     kitemviews/private/kpixmapmodifier.cpp
  87     settings/applyviewpropsjob.cpp
  88     settings/viewmodes/viewmodesettings.cpp
  89     settings/viewpropertiesdialog.cpp
  90     settings/viewpropsprogressinfo.cpp
  91     selectionmode/actiontexthelper.cpp
  92     views/dolphinfileitemlistwidget.cpp
  93     views/dolphinitemlistview.cpp
  94     views/dolphinnewfilemenuobserver.cpp
  95     views/dolphinremoteencoding.cpp
  96     views/dolphinview.cpp
  97     views/dolphinviewactionhandler.cpp
  98     views/draganddrophelper.cpp
  99     views/versioncontrol/updateitemstatesthread.cpp
 100     views/versioncontrol/versioncontrolobserver.cpp
 101     views/viewmodecontroller.cpp
 102     views/viewproperties.cpp
 103     views/zoomlevelinfo.cpp
 104     dolphinremoveaction.cpp
 105     middleclickactioneventfilter.cpp
 106     dolphinnewfilemenu.cpp
 107
 108     kitemviews/kfileitemlistview.h
 109     kitemviews/kfileitemlistwidget.h
 110     kitemviews/kfileitemlisttostring.h
 111     kitemviews/kfileitemmodel.h
 112     kitemviews/kfileitemmodelrolesupdater.h
 113     kitemviews/kitemlistcontainer.h
 114     kitemviews/kitemlistcontroller.h
 115     kitemviews/kitemlistgroupheader.h
 116     kitemviews/kitemlistheader.h
 117     kitemviews/kitemlistselectionmanager.h
 118     kitemviews/kitemliststyleoption.h
 119     kitemviews/kitemlistview.h
 120     kitemviews/kitemlistviewaccessible.h
 121     kitemviews/kitemlistwidget.h
 122     kitemviews/kitemmodelbase.h
 123     kitemviews/kitemset.h
 124     kitemviews/kstandarditemlistgroupheader.h
 125     kitemviews/kstandarditemlistwidget.h
 126     kitemviews/kstandarditemlistview.h
 127     kitemviews/private/kdirectorycontentscounter.h
 128     kitemviews/private/kdirectorycontentscounterworker.h
 129     kitemviews/private/kfileitemclipboard.h
 130     kitemviews/private/kfileitemmodelfilter.h
 131     kitemviews/private/kitemlistheaderwidget.h
 132     kitemviews/private/kitemlistkeyboardsearchmanager.h
 133     kitemviews/private/kitemlistroleeditor.h
 134     kitemviews/private/kitemlistrubberband.h
 135     kitemviews/private/kitemlistselectiontoggle.h
 136     kitemviews/private/kitemlistsizehintresolver.h
 137     kitemviews/private/kitemlistsmoothscroller.h
 138     kitemviews/private/kitemlistviewanimation.h
 139     kitemviews/private/kitemlistviewlayouter.h
 140     kitemviews/private/kpixmapmodifier.h
 141     settings/applyviewpropsjob.h
 142     settings/viewmodes/viewmodesettings.h
 143     settings/viewpropertiesdialog.h
 144     settings/viewpropsprogressinfo.h
 145     selectionmode/actiontexthelper.h
 146     views/dolphinfileitemlistwidget.h
 147     views/dolphinitemlistview.h
 148     views/dolphinnewfilemenuobserver.h
 149     views/dolphinremoteencoding.h
 150     views/dolphinview.h
 151     views/dolphinviewactionhandler.h
 152     views/draganddrophelper.h
 153     views/versioncontrol/updateitemstatesthread.h
 154     views/versioncontrol/versioncontrolobserver.h
 155     views/viewmodecontroller.h
 156     views/viewproperties.h
 157     views/zoomlevelinfo.h
 158     dolphinremoveaction.h
 159     middleclickactioneventfilter.h
 160     dolphinnewfilemenu.h
 161 )
 162
 163 ecm_qt_declare_logging_category(dolphinprivate
 164     HEADER dolphindebug.h
 165     IDENTIFIER DolphinDebug
 166     CATEGORY_NAME org.kde.dolphin
 167     DESCRIPTION "dolphin"
 168     EXPORT DOLPHIN
 169 )
 170
 171 if(HAVE_BALOO)
 172     target_sources(dolphinprivate PRIVATE
 173         views/tooltips/dolphinfilemetadatawidget.cpp
 174         views/tooltips/tooltipmanager.cpp
 175         kitemviews/private/kbaloorolesprovider.cpp
 176         views/tooltips/dolphinfilemetadatawidget.h
 177         views/tooltips/tooltipmanager.h
 178         kitemviews/private/kbaloorolesprovider.h
 179     )
 180 endif()
 181
 182 kconfig_add_kcfg_files(dolphinprivate
 183     settings/dolphin_compactmodesettings.kcfgc
 184     settings/dolphin_directoryviewpropertysettings.kcfgc
 185     settings/dolphin_detailsmodesettings.kcfgc
 186     settings/dolphin_iconsmodesettings.kcfgc
 187     settings/dolphin_contentdisplaysettings.kcfgc
 188     settings/dolphin_generalsettings.kcfgc
 189     settings/dolphin_contextmenusettings.kcfgc
 190     settings/dolphin_versioncontrolsettings.kcfgc
 191 )
 192
 193 generate_export_header(dolphinprivate BASE_NAME dolphin)
 194
 195 target_link_libraries(
 196     dolphinprivate PUBLIC
 197     dolphinvcs
 198     Qt${QT_MAJOR_VERSION}::Concurrent
 199     Qt${QT_MAJOR_VERSION}::Gui
 200     KF6::I18n
 201     KF6::IconThemes
 202     KF6::KIOCore
 203     KF6::KIOWidgets
 204     KF6::KIOFileWidgets
 205     KF6::Completion
 206     KF6::TextWidgets
 207     KF6::ConfigCore
 208     KF6::NewStuffWidgets    # KNSWidgets::Button
 209     KF6::Parts
 210     KF6::WindowSystem
 211     KF6::WidgetsAddons
 212     KF6::Codecs
 213     KF6::KCMUtils
 214
 215     KF6::MoreTools
 216
 217     ${FTS_LIB}
 218 )
 219
 220 if(HAVE_BALOO)
 221     target_link_libraries(
 222         dolphinprivate PUBLIC
 223         KF6::FileMetaData
 224         KF6::Baloo
 225         KF6::BalooWidgets
 226     )
 227 endif()
 228
 229 set_target_properties(dolphinprivate PROPERTIES
 230     VERSION ${DOLPHINPRIVATE_VERSION}
 231     SOVERSION ${DOLPHINPRIVATE_SOVERSION}
 232 )
 233
 234 install(TARGETS dolphinprivate ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} LIBRARY NAMELINK_SKIP)
 235 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphin_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
 236
 237 ##########################################
 238 configure_file(dolphinpart.json.in ${CMAKE_CURRENT_BINARY_DIR}/dolphinpart.json @ONLY)
 239
 240 add_library(dolphinpart MODULE)
 241
 242 target_sources(dolphinpart PRIVATE
 243     dolphinpart.cpp
 244     dolphinpart_ext.cpp
 245     dolphindebug.cpp
 246     dolphinpart.h
 247     dolphinpart_ext.h
 248     dolphindebug.h
 249
 250     dolphinpart.qrc
 251 )
 252
 253 target_link_libraries(dolphinpart
 254     dolphinprivate
 255 )
 256
 257 install(TARGETS dolphinpart DESTINATION ${KDE_INSTALL_PLUGINDIR}/kf${QT_MAJOR_VERSION}/parts)
 258 install(FILES dolphinpartactions.desktop DESTINATION "${KDE_INSTALL_DATADIR}/dolphin/")
 259
 260 ##########################################
 261
 262 add_library(dolphinstatic STATIC)
 263
 264 target_sources(dolphinstatic PRIVATE
 265     dolphinbookmarkhandler.cpp
 266     dolphindockwidget.cpp
 267     dolphinmainwindow.cpp
 268     dolphinviewcontainer.cpp
 269     dolphincontextmenu.cpp
 270     dolphinnavigatorswidgetaction.cpp
 271     dolphintabbar.cpp
 272     dolphinplacesmodelsingleton.cpp
 273     dolphinrecenttabsmenu.cpp
 274     dolphintabpage.cpp
 275     dolphintabwidget.cpp
 276     dolphinurlnavigator.cpp
 277     dolphinurlnavigatorscontroller.cpp
 278     trash/dolphintrash.cpp
 279     filterbar/filterbar.cpp
 280     kitemviews/kfileitemlisttostring.cpp
 281     panels/places/placespanel.cpp
 282     panels/panel.cpp
 283     panels/folders/foldersitemlistwidget.cpp
 284     panels/folders/treeviewcontextmenu.cpp
 285     panels/folders/folderspanel.cpp
 286     panels/terminal/terminalpanel.cpp
 287     search/dolphinfacetswidget.cpp
 288     search/dolphinquery.cpp
 289     search/dolphinsearchbox.cpp
 290     selectionmode/actiontexthelper.cpp
 291     selectionmode/actionwithwidget.cpp
 292     selectionmode/backgroundcolorhelper.cpp
 293     selectionmode/bottombar.cpp
 294     selectionmode/bottombarcontentscontainer.cpp
 295     selectionmode/topbar.cpp
 296     settings/general/behaviorsettingspage.cpp
 297     settings/general/confirmationssettingspage.cpp
 298     settings/general/generalsettingspage.cpp
 299     settings/general/previewssettingspage.cpp
 300     settings/general/statusbarsettingspage.cpp
 301     settings/dolphinsettingsdialog.cpp
 302     settings/navigation/navigationsettingspage.cpp
 303     settings/contextmenu/contextmenusettingspage.cpp
 304     settings/settingspagebase.cpp
 305     settings/servicemodel.cpp
 306     settings/startup/startupsettingspage.cpp
 307     settings/trash/trashsettingspage.cpp
 308     settings/viewmodes/dolphinfontrequester.cpp
 309     settings/viewmodes/viewsettingspage.cpp
 310     settings/viewmodes/viewmodesettings.cpp
 311     settings/viewmodes/viewsettingstab.cpp
 312     settings/viewmodes/contentdisplaytab.cpp
 313     statusbar/dolphinstatusbar.cpp
 314     statusbar/mountpointobserver.cpp
 315     statusbar/mountpointobservercache.cpp
 316     statusbar/spaceinfoobserver.cpp
 317     statusbar/statusbarspaceinfo.cpp
 318     views/zoomlevelinfo.cpp
 319     dolphindebug.cpp
 320     global.cpp
 321     dolphin.qrc
 322
 323     dolphinbookmarkhandler.h
 324     dolphindockwidget.h
 325     dolphinmainwindow.h
 326     dolphinviewcontainer.h
 327     dolphincontextmenu.h
 328     dolphinnavigatorswidgetaction.h
 329     dolphintabbar.h
 330     dolphinplacesmodelsingleton.h
 331     dolphinrecenttabsmenu.h
 332     dolphintabpage.h
 333     dolphintabwidget.h
 334     dolphinurlnavigator.h
 335     dolphinurlnavigatorscontroller.h
 336     trash/dolphintrash.h
 337     filterbar/filterbar.h
 338     kitemviews/kfileitemlisttostring.h
 339     panels/places/placespanel.h
 340     panels/panel.h
 341     panels/folders/foldersitemlistwidget.h
 342     panels/folders/treeviewcontextmenu.h
 343     panels/folders/folderspanel.h
 344     panels/terminal/terminalpanel.h
 345     search/dolphinfacetswidget.h
 346     search/dolphinquery.h
 347     search/dolphinsearchbox.h
 348     selectionmode/actiontexthelper.h
 349     selectionmode/actionwithwidget.h
 350     selectionmode/backgroundcolorhelper.h
 351     selectionmode/bottombar.h
 352     selectionmode/bottombarcontentscontainer.h
 353     selectionmode/topbar.h
 354     settings/general/behaviorsettingspage.h
 355     settings/general/confirmationssettingspage.h
 356     settings/general/generalsettingspage.h
 357     settings/general/previewssettingspage.h
 358     settings/general/statusbarsettingspage.h
 359     settings/dolphinsettingsdialog.h
 360     settings/navigation/navigationsettingspage.h
 361     settings/contextmenu/contextmenusettingspage.h
 362     settings/settingspagebase.h
 363     settings/servicemodel.h
 364     settings/startup/startupsettingspage.h
 365     settings/trash/trashsettingspage.h
 366     settings/viewmodes/dolphinfontrequester.h
 367     settings/viewmodes/viewsettingspage.h
 368     settings/viewmodes/viewmodesettings.h
 369     settings/viewmodes/viewsettingstab.h
 370     settings/viewmodes/contentdisplaytab.h
 371     statusbar/dolphinstatusbar.h
 372     statusbar/mountpointobserver.h
 373     statusbar/mountpointobservercache.h
 374     statusbar/spaceinfoobserver.h
 375     statusbar/statusbarspaceinfo.h
 376     views/zoomlevelinfo.h
 377     dolphindebug.h
 378     global.h
 379 )
 380
 381 if(HAVE_BALOO)
 382     target_sources(dolphinstatic PRIVATE
 383         panels/information/informationpanel.cpp
 384         panels/information/informationpanelcontent.cpp
 385         panels/information/pixmapviewer.cpp
 386         panels/information/phononwidget.cpp
 387         panels/information/informationpanel.h
 388         panels/information/informationpanelcontent.h
 389         panels/information/pixmapviewer.h
 390         panels/information/phononwidget.h
 391     )
 392 endif()
 393
 394 if(HAVE_KUSERFEEDBACK)
 395     target_sources(dolphinstatic PRIVATE
 396         userfeedback/dolphinfeedbackprovider.cpp
 397         userfeedback/settingsdatasource.cpp
 398         userfeedback/placesdatasource.cpp
 399         settings/userfeedback/userfeedbacksettingspage.cpp
 400         userfeedback/dolphinfeedbackprovider.h
 401         userfeedback/settingsdatasource.h
 402         userfeedback/placesdatasource.h
 403         settings/userfeedback/userfeedbacksettingspage.h
 404     )
 405 endif()
 406
 407 kconfig_add_kcfg_files(dolphinstatic
 408     panels/folders/dolphin_folderspanelsettings.kcfgc
 409     panels/information/dolphin_informationpanelsettings.kcfgc
 410     panels/places/dolphin_placespanelsettings.kcfgc
 411     settings/dolphin_compactmodesettings.kcfgc
 412     settings/dolphin_detailsmodesettings.kcfgc
 413     settings/dolphin_contextmenusettings.kcfgc
 414     settings/dolphin_iconsmodesettings.kcfgc
 415     settings/dolphin_contentdisplaysettings.kcfgc
 416     search/dolphin_searchsettings.kcfgc
 417     settings/dolphin_versioncontrolsettings.kcfgc
 418 )
 419 kconfig_add_kcfg_files(dolphinstatic GENERATE_MOC
 420     settings/dolphin_generalsettings.kcfgc
 421 )
 422
 423 qt_generate_dbus_interface(${CMAKE_CURRENT_SOURCE_DIR}/dolphinmainwindow.h org.kde.DolphinMainWindow.xml)
 424 qt_add_dbus_adaptor(dolphin_dbus_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindow.h DolphinMainWindow)
 425 qt_add_dbus_interface(dolphin_dbus_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindowinterface)
 426 qt_add_dbus_interface(dolphin_dbus_SRCS panels/terminal/org.kde.KIOFuse.VFS.xml kiofuse_interface)
 427
 428 target_sources(dolphinstatic PRIVATE
 429     ${dolphin_dbus_SRCS}
 430 )
 431
 432 target_include_directories(dolphinstatic SYSTEM PRIVATE ${PHONON_INCLUDES})
 433 target_link_libraries(dolphinstatic
 434     dolphinprivate
 435     KF6::CoreAddons
 436     KF6::KCMUtils
 437     KF6::DBusAddons
 438     KF6::Notifications
 439     Phonon::phonon4qt${QT_MAJOR_VERSION}
 440 )
 441
 442 if (HAVE_KACTIVITIES)
 443     target_link_libraries(
 444         dolphinstatic
 445         KF6::Activities
 446     )
 447 endif()
 448
 449 if (HAVE_KUSERFEEDBACK)
 450     target_link_libraries(
 451         dolphinstatic
 452         KUserFeedbackCoreQt6
 453         KUserFeedbackWidgetsQt6
 454     )
 455 endif()
 456
 457 add_executable(dolphin)
 458
 459 target_sources(dolphin PRIVATE
 460     dbusinterface.cpp
 461     dbusinterface.h
 462     main.cpp
 463 )
 464
 465 if(FLATPAK)
 466     target_compile_definitions(dolphin PRIVATE FLATPAK)
 467 endif()
 468
 469 # Sets the icon on Windows and OSX
 470 file(GLOB ICONS_SRCS "${CMAKE_CURRENT_SOURCE_DIR}/icons/*system-file-manager.png")
 471 ecm_add_app_icon(dolphin ICONS ${ICONS_SRCS})
 472
 473 target_link_libraries(dolphin
 474     PRIVATE
 475     dolphinprivate
 476     dolphinstatic
 477     KF6::Crash
 478 )
 479
 480 if (HAVE_X11)
 481     if (QT_MAJOR_VERSION STREQUAL "5")
 482         target_link_libraries(dolphin PRIVATE Qt{QT_MAJOR_VERSION}::X11Extras)
 483     else()
 484         target_link_libraries(dolphin PRIVATE Qt::GuiPrivate)
 485     endif()
 486 endif()
 487
 488 include(DbusInterfaceMacros)
 489
 490 generate_and_install_dbus_interface(
 491     dolphin
 492     dbusinterface.h
 493     org.freedesktop.FileManager1.xml
 494     OPTIONS -a
 495 )
 496
 497 install(TARGETS dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 498
 499 ##########################################
 500
 501 if(NOT WIN32)
 502     # The settings are still accessible from the hamburger menu
 503     add_library(kcm_dolphinviewmodes MODULE)
 504     add_library(kcm_dolphinnavigation MODULE)
 505     add_library(kcm_dolphingeneral MODULE)
 506
 507     target_sources(kcm_dolphinviewmodes PRIVATE
 508         settings/kcm/kcmdolphinviewmodes.cpp
 509         settings/viewmodes/dolphinfontrequester.cpp
 510         settings/viewmodes/viewmodesettings.cpp
 511         settings/viewmodes/viewsettingstab.cpp
 512         views/zoomlevelinfo.cpp
 513         settings/kcm/kcmdolphinviewmodes.h
 514         settings/viewmodes/dolphinfontrequester.h
 515         settings/viewmodes/viewmodesettings.h
 516         settings/viewmodes/viewsettingstab.h
 517         views/zoomlevelinfo.h)
 518
 519     target_sources(kcm_dolphinnavigation PRIVATE
 520         settings/kcm/kcmdolphinnavigation.cpp
 521         settings/navigation/navigationsettingspage.cpp
 522         settings/settingspagebase.cpp
 523         settings/kcm/kcmdolphinnavigation.h
 524         settings/navigation/navigationsettingspage.h
 525         settings/settingspagebase.h
 526     )
 527
 528     target_sources(kcm_dolphingeneral PRIVATE
 529         settings/kcm/kcmdolphingeneral.cpp
 530         settings/general/behaviorsettingspage.cpp
 531         settings/general/previewssettingspage.cpp
 532         settings/general/confirmationssettingspage.cpp
 533         settings/settingspagebase.cpp
 534         settings/servicemodel.cpp
 535         settings/kcm/kcmdolphingeneral.h
 536         settings/general/behaviorsettingspage.h
 537         settings/general/previewssettingspage.h
 538         settings/general/confirmationssettingspage.h
 539         settings/settingspagebase.h
 540         settings/servicemodel.h
 541     )
 542
 543     kconfig_add_kcfg_files(kcm_dolphinviewmodes
 544         settings/dolphin_compactmodesettings.kcfgc
 545         settings/dolphin_directoryviewpropertysettings.kcfgc
 546         settings/dolphin_detailsmodesettings.kcfgc
 547         settings/dolphin_iconsmodesettings.kcfgc
 548         settings/dolphin_contentdisplaysettings.kcfgc
 549         settings/dolphin_generalsettings.kcfgc
 550         settings/dolphin_versioncontrolsettings.kcfgc
 551     )
 552
 553     kconfig_add_kcfg_files(kcm_dolphinnavigation
 554         settings/dolphin_generalsettings.kcfgc)
 555
 556     kconfig_add_kcfg_files(kcm_dolphingeneral
 557         settings/dolphin_generalsettings.kcfgc)
 558
 559     target_link_libraries(kcm_dolphinviewmodes dolphinprivate)
 560     target_link_libraries(kcm_dolphinnavigation dolphinprivate)
 561     target_link_libraries(kcm_dolphingeneral dolphinprivate)
 562
 563     install( FILES org.kde.dolphin.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR} )
 564
 565     install(TARGETS kcm_dolphinviewmodes DESTINATION ${KDE_INSTALL_PLUGINDIR}/dolphin/kcms )
 566     install(TARGETS kcm_dolphinnavigation DESTINATION ${KDE_INSTALL_PLUGINDIR}/dolphin/kcms )
 567     install(TARGETS kcm_dolphingeneral DESTINATION ${KDE_INSTALL_PLUGINDIR}/dolphin/kcms )
 568 endif()
 569
 570 if(NOT WIN32)
 571     add_subdirectory(settings/contextmenu/servicemenuinstaller)
 572     install( FILES settings/contextmenu/servicemenu.knsrc DESTINATION ${KDE_INSTALL_KNSRCDIR} )
 573 endif()
 574
 575 ########### install files ###############
 576
 577 install( PROGRAMS org.kde.dolphin.desktop DESTINATION ${KDE_INSTALL_APPDIR} )
 578
 579 install( DIRECTORY DESTINATION "${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel" )
 580
 581 install(
 582     CODE "execute_process(COMMAND \"${CMAKE_COMMAND}\" -E create_symlink \"${KDE_INSTALL_FULL_APPDIR}/org.kde.dolphin.desktop\" \"\$ENV{DESTDIR}${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel/org.kde.dolphin.desktop\")"
 583 )
 584
 585 install( FILES settings/dolphin_directoryviewpropertysettings.kcfg
 586                settings/dolphin_generalsettings.kcfg
 587                settings/dolphin_contextmenusettings.kcfg
 588                settings/dolphin_compactmodesettings.kcfg
 589                settings/dolphin_iconsmodesettings.kcfg
 590                settings/dolphin_detailsmodesettings.kcfg
 591                settings/dolphin_contentdisplaysettings.kcfg
 592                settings/dolphin_versioncontrolsettings.kcfg
 593          DESTINATION ${KDE_INSTALL_KCFGDIR} )
 594
 595 install( FILES settings/dolphin_detailsmodesettings.upd
 596          DESTINATION ${KDE_INSTALL_KCONFUPDATEDIR} )
 597
 598 if(BUILD_TESTING)
 599     add_subdirectory(tests)
 600 endif()