src/CMakeLists.txt

   1 include(ECMAddAppIcon)
   2
   3 configure_file(config-dolphin.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-dolphin.h)
   4
   5 add_definitions(
   6     -DTRANSLATION_DOMAIN=\"dolphin\"
   7 )
   8 remove_definitions(
   9     -DQT_NO_CAST_FROM_BYTEARRAY
  10     -DQT_NO_CAST_FROM_ASCII
  11     -DQT_NO_CAST_TO_ASCII
  12 )
  13
  14 ##########################################
  15
  16 add_library(dolphinvcs SHARED)
  17
  18 target_sources(dolphinvcs PRIVATE
  19     views/versioncontrol/kversioncontrolplugin.cpp
  20 )
  21
  22 generate_export_header(dolphinvcs BASE_NAME dolphinvcs)
  23
  24 target_link_libraries(
  25     dolphinvcs PUBLIC
  26     Qt${QT_MAJOR_VERSION}::Widgets
  27 )
  28
  29 set_target_properties(dolphinvcs PROPERTIES
  30     VERSION ${DOLPHINVCS_VERSION}
  31     SOVERSION ${DOLPHINVCS_SOVERSION}
  32     EXPORT_NAME DolphinVcs
  33 )
  34
  35 ecm_generate_headers(dolphinvcs_LIB_HEADERS
  36     HEADER_NAMES
  37     KVersionControlPlugin
  38
  39     RELATIVE "views/versioncontrol"
  40     REQUIRED_HEADERS dolphinvcs_LIB_HEADERS
  41 )
  42 target_include_directories(dolphinvcs INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR}>")
  43
  44 install(TARGETS dolphinvcs EXPORT DolphinVcsTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
  45
  46 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphinvcs_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
  47 install(FILES ${dolphinvcs_LIB_HEADERS} DESTINATION "${KDE_INSTALL_INCLUDEDIR}/Dolphin" COMPONENT Devel)
  48
  49 ########### next target ###############
  50
  51 add_library(dolphinprivate SHARED)
  52
  53 target_sources(dolphinprivate PRIVATE
  54     kitemviews/kfileitemlistview.cpp
  55     kitemviews/kfileitemlistwidget.cpp
  56     kitemviews/kfileitemlisttostring.cpp
  57     kitemviews/kfileitemmodel.cpp
  58     kitemviews/kfileitemmodelrolesupdater.cpp
  59     kitemviews/kitemlistcontainer.cpp
  60     kitemviews/kitemlistcontroller.cpp
  61     kitemviews/kitemlistgroupheader.cpp
  62     kitemviews/kitemlistheader.cpp
  63     kitemviews/kitemlistselectionmanager.cpp
  64     kitemviews/kitemliststyleoption.cpp
  65     kitemviews/kitemlistview.cpp
  66     kitemviews/kitemlistviewaccessible.cpp
  67     kitemviews/kitemlistwidget.cpp
  68     kitemviews/kitemmodelbase.cpp
  69     kitemviews/kitemset.cpp
  70     kitemviews/kstandarditemlistgroupheader.cpp
  71     kitemviews/kstandarditemlistwidget.cpp
  72     kitemviews/kstandarditemlistview.cpp
  73     kitemviews/private/kdirectorycontentscounter.cpp
  74     kitemviews/private/kdirectorycontentscounterworker.cpp
  75     kitemviews/private/kfileitemclipboard.cpp
  76     kitemviews/private/kfileitemmodelfilter.cpp
  77     kitemviews/private/kitemlistheaderwidget.cpp
  78     kitemviews/private/kitemlistkeyboardsearchmanager.cpp
  79     kitemviews/private/kitemlistroleeditor.cpp
  80     kitemviews/private/kitemlistrubberband.cpp
  81     kitemviews/private/kitemlistselectiontoggle.cpp
  82     kitemviews/private/kitemlistsizehintresolver.cpp
  83     kitemviews/private/kitemlistsmoothscroller.cpp
  84     kitemviews/private/kitemlistviewanimation.cpp
  85     kitemviews/private/kitemlistviewlayouter.cpp
  86     kitemviews/private/kpixmapmodifier.cpp
  87     settings/applyviewpropsjob.cpp
  88     settings/viewmodes/viewmodesettings.cpp
  89     settings/viewpropertiesdialog.cpp
  90     settings/viewpropsprogressinfo.cpp
  91     selectionmode/actiontexthelper.cpp
  92     views/dolphinfileitemlistwidget.cpp
  93     views/dolphinitemlistview.cpp
  94     views/dolphinnewfilemenuobserver.cpp
  95     views/dolphinremoteencoding.cpp
  96     views/dolphinview.cpp
  97     views/dolphinviewactionhandler.cpp
  98     views/draganddrophelper.cpp
  99     views/versioncontrol/updateitemstatesthread.cpp
 100     views/versioncontrol/versioncontrolobserver.cpp
 101     views/viewmodecontroller.cpp
 102     views/viewproperties.cpp
 103     views/zoomlevelinfo.cpp
 104     dolphinremoveaction.cpp
 105     middleclickactioneventfilter.cpp
 106     dolphinnewfilemenu.cpp
 107
 108     kitemviews/kfileitemlistview.h
 109     kitemviews/kfileitemlistwidget.h
 110     kitemviews/kfileitemlisttostring.h
 111     kitemviews/kfileitemmodel.h
 112     kitemviews/kfileitemmodelrolesupdater.h
 113     kitemviews/kitemlistcontainer.h
 114     kitemviews/kitemlistcontroller.h
 115     kitemviews/kitemlistgroupheader.h
 116     kitemviews/kitemlistheader.h
 117     kitemviews/kitemlistselectionmanager.h
 118     kitemviews/kitemliststyleoption.h
 119     kitemviews/kitemlistview.h
 120     kitemviews/kitemlistviewaccessible.h
 121     kitemviews/kitemlistwidget.h
 122     kitemviews/kitemmodelbase.h
 123     kitemviews/kitemset.h
 124     kitemviews/kstandarditemlistgroupheader.h
 125     kitemviews/kstandarditemlistwidget.h
 126     kitemviews/kstandarditemlistview.h
 127     kitemviews/private/kdirectorycontentscounter.h
 128     kitemviews/private/kdirectorycontentscounterworker.h
 129     kitemviews/private/kfileitemclipboard.h
 130     kitemviews/private/kfileitemmodelfilter.h
 131     kitemviews/private/kitemlistheaderwidget.h
 132     kitemviews/private/kitemlistkeyboardsearchmanager.h
 133     kitemviews/private/kitemlistroleeditor.h
 134     kitemviews/private/kitemlistrubberband.h
 135     kitemviews/private/kitemlistselectiontoggle.h
 136     kitemviews/private/kitemlistsizehintresolver.h
 137     kitemviews/private/kitemlistsmoothscroller.h
 138     kitemviews/private/kitemlistviewanimation.h
 139     kitemviews/private/kitemlistviewlayouter.h
 140     kitemviews/private/kpixmapmodifier.h
 141     settings/applyviewpropsjob.h
 142     settings/viewmodes/viewmodesettings.h
 143     settings/viewpropertiesdialog.h
 144     settings/viewpropsprogressinfo.h
 145     selectionmode/actiontexthelper.h
 146     views/dolphinfileitemlistwidget.h
 147     views/dolphinitemlistview.h
 148     views/dolphinnewfilemenuobserver.h
 149     views/dolphinremoteencoding.h
 150     views/dolphinview.h
 151     views/dolphinviewactionhandler.h
 152     views/draganddrophelper.h
 153     views/versioncontrol/updateitemstatesthread.h
 154     views/versioncontrol/versioncontrolobserver.h
 155     views/viewmodecontroller.h
 156     views/viewproperties.h
 157     views/zoomlevelinfo.h
 158     dolphinremoveaction.h
 159     middleclickactioneventfilter.h
 160     dolphinnewfilemenu.h
 161 )
 162
 163 ecm_qt_declare_logging_category(dolphinprivate
 164     HEADER dolphindebug.h
 165     IDENTIFIER DolphinDebug
 166     CATEGORY_NAME org.kde.dolphin
 167     DESCRIPTION "dolphin"
 168     EXPORT DOLPHIN
 169 )
 170
 171 if(HAVE_BALOO)
 172     target_sources(dolphinprivate PRIVATE
 173         views/tooltips/dolphinfilemetadatawidget.cpp
 174         views/tooltips/tooltipmanager.cpp
 175         kitemviews/private/kbaloorolesprovider.cpp
 176         views/tooltips/dolphinfilemetadatawidget.h
 177         views/tooltips/tooltipmanager.h
 178         kitemviews/private/kbaloorolesprovider.h
 179     )
 180 endif()
 181
 182 kconfig_add_kcfg_files(dolphinprivate
 183     settings/dolphin_compactmodesettings.kcfgc
 184     settings/dolphin_directoryviewpropertysettings.kcfgc
 185     settings/dolphin_detailsmodesettings.kcfgc
 186     settings/dolphin_iconsmodesettings.kcfgc
 187     settings/dolphin_contentdisplaysettings.kcfgc
 188     settings/dolphin_generalsettings.kcfgc
 189     settings/dolphin_contextmenusettings.kcfgc
 190     settings/dolphin_versioncontrolsettings.kcfgc
 191 )
 192
 193 generate_export_header(dolphinprivate BASE_NAME dolphin)
 194
 195 target_link_libraries(
 196     dolphinprivate PUBLIC
 197     dolphinvcs
 198     Qt${QT_MAJOR_VERSION}::Concurrent
 199     Qt${QT_MAJOR_VERSION}::Gui
 200     KF6::I18n
 201     KF6::IconThemes
 202     KF6::KIOCore
 203     KF6::KIOWidgets
 204     KF6::KIOFileWidgets
 205     KF6::Completion
 206     KF6::TextWidgets
 207     KF6::ConfigCore
 208     KF6::NewStuffWidgets    # KNSWidgets::Button
 209     KF6::Parts
 210     KF6::WindowSystem
 211     KF6::WidgetsAddons
 212     KF6::Codecs
 213     KF6::KCMUtils
 214
 215     KF6::MoreTools
 216 )
 217
 218 if(HAVE_BALOO)
 219     target_link_libraries(
 220         dolphinprivate PUBLIC
 221         KF6::FileMetaData
 222         KF6::Baloo
 223         KF6::BalooWidgets
 224     )
 225 endif()
 226
 227 set_target_properties(dolphinprivate PROPERTIES
 228     VERSION ${DOLPHINPRIVATE_VERSION}
 229     SOVERSION ${DOLPHINPRIVATE_SOVERSION}
 230 )
 231
 232 install(TARGETS dolphinprivate ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} LIBRARY NAMELINK_SKIP)
 233 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphin_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
 234
 235 ##########################################
 236 configure_file(dolphinpart.json.in ${CMAKE_CURRENT_BINARY_DIR}/dolphinpart.json @ONLY)
 237
 238 add_library(dolphinpart MODULE)
 239
 240 target_sources(dolphinpart PRIVATE
 241     dolphinpart.cpp
 242     dolphinpart_ext.cpp
 243     dolphindebug.cpp
 244     dolphinpart.h
 245     dolphinpart_ext.h
 246     dolphindebug.h
 247
 248     dolphinpart.qrc
 249 )
 250
 251 target_link_libraries(dolphinpart
 252     dolphinprivate
 253 )
 254
 255 install(TARGETS dolphinpart DESTINATION ${KDE_INSTALL_PLUGINDIR}/kf${QT_MAJOR_VERSION}/parts)
 256 install(FILES dolphinpartactions.desktop DESTINATION "${KDE_INSTALL_DATADIR}/dolphin/")
 257
 258 ##########################################
 259
 260 add_library(dolphinstatic STATIC)
 261
 262 target_sources(dolphinstatic PRIVATE
 263     dolphinbookmarkhandler.cpp
 264     dolphindockwidget.cpp
 265     dolphinmainwindow.cpp
 266     dolphinviewcontainer.cpp
 267     dolphincontextmenu.cpp
 268     dolphinnavigatorswidgetaction.cpp
 269     dolphintabbar.cpp
 270     dolphinplacesmodelsingleton.cpp
 271     dolphinrecenttabsmenu.cpp
 272     dolphintabpage.cpp
 273     dolphintabwidget.cpp
 274     dolphinurlnavigator.cpp
 275     dolphinurlnavigatorscontroller.cpp
 276     trash/dolphintrash.cpp
 277     filterbar/filterbar.cpp
 278     kitemviews/kfileitemlisttostring.cpp
 279     panels/places/placespanel.cpp
 280     panels/panel.cpp
 281     panels/folders/foldersitemlistwidget.cpp
 282     panels/folders/treeviewcontextmenu.cpp
 283     panels/folders/folderspanel.cpp
 284     panels/terminal/terminalpanel.cpp
 285     search/dolphinfacetswidget.cpp
 286     search/dolphinquery.cpp
 287     search/dolphinsearchbox.cpp
 288     selectionmode/actiontexthelper.cpp
 289     selectionmode/actionwithwidget.cpp
 290     selectionmode/backgroundcolorhelper.cpp
 291     selectionmode/bottombar.cpp
 292     selectionmode/bottombarcontentscontainer.cpp
 293     selectionmode/topbar.cpp
 294     settings/general/behaviorsettingspage.cpp
 295     settings/general/confirmationssettingspage.cpp
 296     settings/general/generalsettingspage.cpp
 297     settings/general/previewssettingspage.cpp
 298     settings/general/statusbarsettingspage.cpp
 299     settings/dolphinsettingsdialog.cpp
 300     settings/navigation/navigationsettingspage.cpp
 301     settings/contextmenu/contextmenusettingspage.cpp
 302     settings/settingspagebase.cpp
 303     settings/servicemodel.cpp
 304     settings/startup/startupsettingspage.cpp
 305     settings/trash/trashsettingspage.cpp
 306     settings/viewmodes/dolphinfontrequester.cpp
 307     settings/viewmodes/viewsettingspage.cpp
 308     settings/viewmodes/viewmodesettings.cpp
 309     settings/viewmodes/viewsettingstab.cpp
 310     settings/viewmodes/contentdisplaytab.cpp
 311     statusbar/dolphinstatusbar.cpp
 312     statusbar/mountpointobserver.cpp
 313     statusbar/mountpointobservercache.cpp
 314     statusbar/spaceinfoobserver.cpp
 315     statusbar/statusbarspaceinfo.cpp
 316     views/zoomlevelinfo.cpp
 317     dolphindebug.cpp
 318     global.cpp
 319     dolphin.qrc
 320
 321     dolphinbookmarkhandler.h
 322     dolphindockwidget.h
 323     dolphinmainwindow.h
 324     dolphinviewcontainer.h
 325     dolphincontextmenu.h
 326     dolphinnavigatorswidgetaction.h
 327     dolphintabbar.h
 328     dolphinplacesmodelsingleton.h
 329     dolphinrecenttabsmenu.h
 330     dolphintabpage.h
 331     dolphintabwidget.h
 332     dolphinurlnavigator.h
 333     dolphinurlnavigatorscontroller.h
 334     trash/dolphintrash.h
 335     filterbar/filterbar.h
 336     kitemviews/kfileitemlisttostring.h
 337     panels/places/placespanel.h
 338     panels/panel.h
 339     panels/folders/foldersitemlistwidget.h
 340     panels/folders/treeviewcontextmenu.h
 341     panels/folders/folderspanel.h
 342     panels/terminal/terminalpanel.h
 343     search/dolphinfacetswidget.h
 344     search/dolphinquery.h
 345     search/dolphinsearchbox.h
 346     selectionmode/actiontexthelper.h
 347     selectionmode/actionwithwidget.h
 348     selectionmode/backgroundcolorhelper.h
 349     selectionmode/bottombar.h
 350     selectionmode/bottombarcontentscontainer.h
 351     selectionmode/topbar.h
 352     settings/general/behaviorsettingspage.h
 353     settings/general/confirmationssettingspage.h
 354     settings/general/generalsettingspage.h
 355     settings/general/previewssettingspage.h
 356     settings/general/statusbarsettingspage.h
 357     settings/dolphinsettingsdialog.h
 358     settings/navigation/navigationsettingspage.h
 359     settings/contextmenu/contextmenusettingspage.h
 360     settings/settingspagebase.h
 361     settings/servicemodel.h
 362     settings/startup/startupsettingspage.h
 363     settings/trash/trashsettingspage.h
 364     settings/viewmodes/dolphinfontrequester.h
 365     settings/viewmodes/viewsettingspage.h
 366     settings/viewmodes/viewmodesettings.h
 367     settings/viewmodes/viewsettingstab.h
 368     settings/viewmodes/contentdisplaytab.h
 369     statusbar/dolphinstatusbar.h
 370     statusbar/mountpointobserver.h
 371     statusbar/mountpointobservercache.h
 372     statusbar/spaceinfoobserver.h
 373     statusbar/statusbarspaceinfo.h
 374     views/zoomlevelinfo.h
 375     dolphindebug.h
 376     global.h
 377 )
 378
 379 if(HAVE_BALOO)
 380     target_sources(dolphinstatic PRIVATE
 381         panels/information/informationpanel.cpp
 382         panels/information/informationpanelcontent.cpp
 383         panels/information/pixmapviewer.cpp
 384         panels/information/phononwidget.cpp
 385         panels/information/informationpanel.h
 386         panels/information/informationpanelcontent.h
 387         panels/information/pixmapviewer.h
 388         panels/information/phononwidget.h
 389     )
 390 endif()
 391
 392 if(HAVE_KUSERFEEDBACK)
 393     target_sources(dolphinstatic PRIVATE
 394         userfeedback/dolphinfeedbackprovider.cpp
 395         userfeedback/settingsdatasource.cpp
 396         userfeedback/placesdatasource.cpp
 397         settings/userfeedback/userfeedbacksettingspage.cpp
 398         userfeedback/dolphinfeedbackprovider.h
 399         userfeedback/settingsdatasource.h
 400         userfeedback/placesdatasource.h
 401         settings/userfeedback/userfeedbacksettingspage.h
 402     )
 403 endif()
 404
 405 kconfig_add_kcfg_files(dolphinstatic
 406     panels/folders/dolphin_folderspanelsettings.kcfgc
 407     panels/information/dolphin_informationpanelsettings.kcfgc
 408     panels/places/dolphin_placespanelsettings.kcfgc
 409     settings/dolphin_compactmodesettings.kcfgc
 410     settings/dolphin_detailsmodesettings.kcfgc
 411     settings/dolphin_contextmenusettings.kcfgc
 412     settings/dolphin_iconsmodesettings.kcfgc
 413     settings/dolphin_contentdisplaysettings.kcfgc
 414     search/dolphin_searchsettings.kcfgc
 415     settings/dolphin_versioncontrolsettings.kcfgc
 416 )
 417 kconfig_add_kcfg_files(dolphinstatic GENERATE_MOC
 418     settings/dolphin_generalsettings.kcfgc
 419 )
 420
 421 qt_generate_dbus_interface(${CMAKE_CURRENT_SOURCE_DIR}/dolphinmainwindow.h org.kde.DolphinMainWindow.xml)
 422 qt_add_dbus_adaptor(dolphin_dbus_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindow.h DolphinMainWindow)
 423 qt_add_dbus_interface(dolphin_dbus_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindowinterface)
 424 qt_add_dbus_interface(dolphin_dbus_SRCS panels/terminal/org.kde.KIOFuse.VFS.xml kiofuse_interface)
 425
 426 target_sources(dolphinstatic PRIVATE
 427     ${dolphin_dbus_SRCS}
 428 )
 429
 430 target_include_directories(dolphinstatic SYSTEM PRIVATE ${PHONON_INCLUDES})
 431 target_link_libraries(dolphinstatic
 432     dolphinprivate
 433     KF6::CoreAddons
 434     KF6::KCMUtils
 435     KF6::DBusAddons
 436     KF6::Notifications
 437     Phonon::phonon4qt${QT_MAJOR_VERSION}
 438 )
 439
 440 if (HAVE_KACTIVITIES)
 441     target_link_libraries(
 442         dolphinstatic
 443         KF6::Activities
 444     )
 445 endif()
 446
 447 if (HAVE_KUSERFEEDBACK)
 448     target_link_libraries(
 449         dolphinstatic
 450         KUserFeedbackCoreQt6
 451         KUserFeedbackWidgetsQt6
 452     )
 453 endif()
 454
 455 add_executable(dolphin)
 456
 457 target_sources(dolphin PRIVATE
 458     dbusinterface.cpp
 459     dbusinterface.h
 460     main.cpp
 461 )
 462
 463 if(FLATPAK)
 464     target_compile_definitions(dolphin PRIVATE FLATPAK)
 465 endif()
 466
 467 # Sets the icon on Windows and OSX
 468 file(GLOB ICONS_SRCS "${CMAKE_CURRENT_SOURCE_DIR}/icons/*system-file-manager.png")
 469 ecm_add_app_icon(dolphin ICONS ${ICONS_SRCS})
 470
 471 target_link_libraries(dolphin
 472     PRIVATE
 473     dolphinprivate
 474     dolphinstatic
 475     KF6::Crash
 476 )
 477
 478 if (HAVE_X11)
 479     if (QT_MAJOR_VERSION STREQUAL "5")
 480         target_link_libraries(dolphin PRIVATE Qt{QT_MAJOR_VERSION}::X11Extras)
 481     else()
 482         target_link_libraries(dolphin PRIVATE Qt::GuiPrivate)
 483     endif()
 484 endif()
 485
 486 include(DbusInterfaceMacros)
 487
 488 generate_and_install_dbus_interface(
 489     dolphin
 490     dbusinterface.h
 491     org.freedesktop.FileManager1.xml
 492     OPTIONS -a
 493 )
 494
 495 install(TARGETS dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 496
 497 ##########################################
 498
 499 if(NOT WIN32)
 500     # The settings are still accessible from the hamburger menu
 501     add_library(kcm_dolphinviewmodes MODULE)
 502     add_library(kcm_dolphinnavigation MODULE)
 503     add_library(kcm_dolphingeneral MODULE)
 504
 505     target_sources(kcm_dolphinviewmodes PRIVATE
 506         settings/kcm/kcmdolphinviewmodes.cpp
 507         settings/viewmodes/dolphinfontrequester.cpp
 508         settings/viewmodes/viewmodesettings.cpp
 509         settings/viewmodes/viewsettingstab.cpp
 510         views/zoomlevelinfo.cpp
 511         settings/kcm/kcmdolphinviewmodes.h
 512         settings/viewmodes/dolphinfontrequester.h
 513         settings/viewmodes/viewmodesettings.h
 514         settings/viewmodes/viewsettingstab.h
 515         views/zoomlevelinfo.h)
 516
 517     target_sources(kcm_dolphinnavigation PRIVATE
 518         settings/kcm/kcmdolphinnavigation.cpp
 519         settings/navigation/navigationsettingspage.cpp
 520         settings/settingspagebase.cpp
 521         settings/kcm/kcmdolphinnavigation.h
 522         settings/navigation/navigationsettingspage.h
 523         settings/settingspagebase.h
 524     )
 525
 526     target_sources(kcm_dolphingeneral PRIVATE
 527         settings/kcm/kcmdolphingeneral.cpp
 528         settings/general/behaviorsettingspage.cpp
 529         settings/general/previewssettingspage.cpp
 530         settings/general/confirmationssettingspage.cpp
 531         settings/settingspagebase.cpp
 532         settings/servicemodel.cpp
 533         settings/kcm/kcmdolphingeneral.h
 534         settings/general/behaviorsettingspage.h
 535         settings/general/previewssettingspage.h
 536         settings/general/confirmationssettingspage.h
 537         settings/settingspagebase.h
 538         settings/servicemodel.h
 539     )
 540
 541     kconfig_add_kcfg_files(kcm_dolphinviewmodes
 542         settings/dolphin_compactmodesettings.kcfgc
 543         settings/dolphin_directoryviewpropertysettings.kcfgc
 544         settings/dolphin_detailsmodesettings.kcfgc
 545         settings/dolphin_iconsmodesettings.kcfgc
 546         settings/dolphin_contentdisplaysettings.kcfgc
 547         settings/dolphin_generalsettings.kcfgc
 548         settings/dolphin_versioncontrolsettings.kcfgc
 549     )
 550
 551     kconfig_add_kcfg_files(kcm_dolphinnavigation
 552         settings/dolphin_generalsettings.kcfgc)
 553
 554     kconfig_add_kcfg_files(kcm_dolphingeneral
 555         settings/dolphin_generalsettings.kcfgc)
 556
 557     target_link_libraries(kcm_dolphinviewmodes dolphinprivate)
 558     target_link_libraries(kcm_dolphinnavigation dolphinprivate)
 559     target_link_libraries(kcm_dolphingeneral dolphinprivate)
 560
 561     install( FILES org.kde.dolphin.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR} )
 562
 563     install(TARGETS kcm_dolphinviewmodes DESTINATION ${KDE_INSTALL_PLUGINDIR}/dolphin/kcms )
 564     install(TARGETS kcm_dolphinnavigation DESTINATION ${KDE_INSTALL_PLUGINDIR}/dolphin/kcms )
 565     install(TARGETS kcm_dolphingeneral DESTINATION ${KDE_INSTALL_PLUGINDIR}/dolphin/kcms )
 566 endif()
 567
 568 if(NOT WIN32)
 569     add_subdirectory(settings/contextmenu/servicemenuinstaller)
 570     install( FILES settings/contextmenu/servicemenu.knsrc DESTINATION ${KDE_INSTALL_KNSRCDIR} )
 571 endif()
 572
 573 ########### install files ###############
 574
 575 install( PROGRAMS org.kde.dolphin.desktop DESTINATION ${KDE_INSTALL_APPDIR} )
 576
 577 install( DIRECTORY DESTINATION "${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel" )
 578
 579 install(
 580     CODE "execute_process(COMMAND \"${CMAKE_COMMAND}\" -E create_symlink \"${KDE_INSTALL_FULL_APPDIR}/org.kde.dolphin.desktop\" \"\$ENV{DESTDIR}${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel/org.kde.dolphin.desktop\")"
 581 )
 582
 583 install( FILES settings/dolphin_directoryviewpropertysettings.kcfg
 584                settings/dolphin_generalsettings.kcfg
 585                settings/dolphin_contextmenusettings.kcfg
 586                settings/dolphin_compactmodesettings.kcfg
 587                settings/dolphin_iconsmodesettings.kcfg
 588                settings/dolphin_detailsmodesettings.kcfg
 589                settings/dolphin_contentdisplaysettings.kcfg
 590                settings/dolphin_versioncontrolsettings.kcfg
 591          DESTINATION ${KDE_INSTALL_KCFGDIR} )
 592
 593 install( FILES settings/dolphin_detailsmodesettings.upd
 594          DESTINATION ${KDE_INSTALL_KCONFUPDATEDIR} )
 595
 596 if(BUILD_TESTING)
 597     add_subdirectory(tests)
 598 endif()