src/CMakeLists.txt

   1 include(ECMAddAppIcon)
   2
   3 configure_file(config-baloo.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-baloo.h)
   4
   5 configure_file(config-kactivities.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-kactivities.h)
   6
   7 configure_file(config-terminal.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-terminal.h)
   8
   9 add_definitions(
  10     -DTRANSLATION_DOMAIN=\"dolphin\"
  11 )
  12 remove_definitions(
  13     -DQT_NO_CAST_FROM_BYTEARRAY
  14     -DQT_NO_SIGNALS_SLOTS_KEYWORDS
  15     -DQT_NO_CAST_FROM_ASCII
  16     -DQT_NO_CAST_TO_ASCII
  17 )
  18
  19 ##########################################
  20
  21 set(dolphinvcs_LIB_SRCS
  22     views/versioncontrol/kversioncontrolplugin.cpp
  23 )
  24
  25 add_library(dolphinvcs ${dolphinvcs_LIB_SRCS})
  26 generate_export_header(dolphinvcs BASE_NAME dolphinvcs)
  27
  28 target_link_libraries(
  29     dolphinvcs PUBLIC
  30     Qt5::Widgets
  31 )
  32
  33 set_target_properties(dolphinvcs PROPERTIES
  34     VERSION ${DOLPHINVCS_VERSION_STRING}
  35     SOVERSION ${DOLPHINVCS_SOVERSION}
  36     EXPORT_NAME DolphinVcs
  37 )
  38
  39 ecm_generate_headers(dolphinvcs_LIB_HEADERS
  40     HEADER_NAMES
  41     KVersionControlPlugin
  42
  43     RELATIVE "views/versioncontrol"
  44     REQUIRED_HEADERS dolphinvcs_LIB_HEADERS
  45 )
  46
  47 install(TARGETS dolphinvcs EXPORT DolphinVcsTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
  48
  49 install(FILES views/versioncontrol/fileviewversioncontrolplugin.desktop DESTINATION ${KDE_INSTALL_KSERVICETYPES5DIR})
  50 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphinvcs_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
  51 install(FILES ${dolphinvcs_LIB_HEADERS} DESTINATION "${KDE_INSTALL_INCLUDEDIR}/Dolphin" COMPONENT Devel)
  52
  53 ########### next target ###############
  54
  55 set(dolphinprivate_LIB_SRCS
  56     kitemviews/kfileitemlistview.cpp
  57     kitemviews/kfileitemlistwidget.cpp
  58     kitemviews/kfileitemmodel.cpp
  59     kitemviews/kfileitemmodelrolesupdater.cpp
  60     kitemviews/kitemlistcontainer.cpp
  61     kitemviews/kitemlistcontroller.cpp
  62     kitemviews/kitemlistgroupheader.cpp
  63     kitemviews/kitemlistheader.cpp
  64     kitemviews/kitemlistselectionmanager.cpp
  65     kitemviews/kitemliststyleoption.cpp
  66     kitemviews/kitemlistview.cpp
  67     kitemviews/kitemlistviewaccessible.cpp
  68     kitemviews/kitemlistwidget.cpp
  69     kitemviews/kitemmodelbase.cpp
  70     kitemviews/kitemset.cpp
  71     kitemviews/kstandarditem.cpp
  72     kitemviews/kstandarditemlistgroupheader.cpp
  73     kitemviews/kstandarditemlistwidget.cpp
  74     kitemviews/kstandarditemlistview.cpp
  75     kitemviews/kstandarditemmodel.cpp
  76     kitemviews/private/kdirectorycontentscounter.cpp
  77     kitemviews/private/kdirectorycontentscounterworker.cpp
  78     kitemviews/private/kfileitemclipboard.cpp
  79     kitemviews/private/kfileitemmodeldirlister.cpp
  80     kitemviews/private/kfileitemmodelfilter.cpp
  81     kitemviews/private/kitemlistheaderwidget.cpp
  82     kitemviews/private/kitemlistkeyboardsearchmanager.cpp
  83     kitemviews/private/kitemlistroleeditor.cpp
  84     kitemviews/private/kitemlistrubberband.cpp
  85     kitemviews/private/kitemlistselectiontoggle.cpp
  86     kitemviews/private/kitemlistsizehintresolver.cpp
  87     kitemviews/private/kitemlistsmoothscroller.cpp
  88     kitemviews/private/kitemlistviewanimation.cpp
  89     kitemviews/private/kitemlistviewlayouter.cpp
  90     kitemviews/private/kpixmapmodifier.cpp
  91     settings/applyviewpropsjob.cpp
  92     settings/viewmodes/viewmodesettings.cpp
  93     settings/viewpropertiesdialog.cpp
  94     settings/viewpropsprogressinfo.cpp
  95     views/dolphinfileitemlistwidget.cpp
  96     views/dolphinitemlistview.cpp
  97     views/dolphinnewfilemenuobserver.cpp
  98     views/dolphinremoteencoding.cpp
  99     views/dolphinview.cpp
 100     views/dolphinviewactionhandler.cpp
 101     views/draganddrophelper.cpp
 102     views/renamedialog.cpp
 103     views/versioncontrol/updateitemstatesthread.cpp
 104     views/versioncontrol/versioncontrolobserver.cpp
 105     views/viewmodecontroller.cpp
 106     views/viewproperties.cpp
 107     views/zoomlevelinfo.cpp
 108     dolphinremoveaction.cpp
 109     middleclickactioneventfilter.cpp
 110     dolphinnewfilemenu.cpp
 111 )
 112
 113 ecm_qt_declare_logging_category(dolphinprivate_LIB_SRCS HEADER dolphindebug.h IDENTIFIER DolphinDebug CATEGORY_NAME org.kde.dolphin)
 114
 115 if(HAVE_BALOO)
 116     set(dolphinprivate_LIB_SRCS
 117         ${dolphinprivate_LIB_SRCS}
 118         views/tooltips/dolphinfilemetadatawidget.cpp
 119         views/tooltips/tooltipmanager.cpp
 120         kitemviews/private/kbaloorolesprovider.cpp
 121     )
 122 endif()
 123
 124 kconfig_add_kcfg_files(dolphinprivate_LIB_SRCS GENERATE_MOC
 125     settings/dolphin_compactmodesettings.kcfgc
 126     settings/dolphin_directoryviewpropertysettings.kcfgc
 127     settings/dolphin_detailsmodesettings.kcfgc
 128     settings/dolphin_iconsmodesettings.kcfgc
 129     settings/dolphin_generalsettings.kcfgc
 130     settings/dolphin_versioncontrolsettings.kcfgc
 131 )
 132
 133 add_library(dolphinprivate ${dolphinprivate_LIB_SRCS})
 134 generate_export_header(dolphinprivate BASE_NAME dolphin)
 135
 136 target_link_libraries(
 137     dolphinprivate PUBLIC
 138     dolphinvcs
 139     Qt5::Concurrent
 140     Qt5::Gui
 141     KF5::I18n
 142     KF5::IconThemes
 143     KF5::KIOCore
 144     KF5::KIOWidgets
 145     KF5::KIOFileWidgets
 146     KF5::Completion
 147     KF5::TextWidgets
 148     KF5::ConfigCore
 149     KF5::NewStuff
 150     KF5::Parts
 151     KF5::WindowSystem
 152 )
 153
 154 if(HAVE_BALOO)
 155     target_link_libraries(
 156         dolphinprivate PUBLIC
 157         KF5::FileMetaData
 158         KF5::Baloo
 159         KF5::BalooWidgets
 160     )
 161 endif()
 162
 163 set_target_properties(dolphinprivate PROPERTIES
 164     VERSION ${DOLPHINPRIVATE_VERSION_STRING}
 165     SOVERSION ${DOLPHINPRIVATE_SOVERSION}
 166 )
 167
 168 install(TARGETS dolphinprivate ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} LIBRARY NAMELINK_SKIP)
 169 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphin_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
 170
 171 ##########################################
 172
 173 set(dolphinpart_SRCS
 174    dolphinpart.cpp
 175    dolphinpart_ext.cpp
 176    dolphindebug.cpp
 177 )
 178
 179 qt5_add_resources(dolphinpart_SRCS dolphinpart.qrc)
 180
 181 add_library(dolphinpart MODULE ${dolphinpart_SRCS})
 182
 183 target_link_libraries(dolphinpart
 184     dolphinprivate
 185 )
 186
 187 install(TARGETS dolphinpart DESTINATION ${KDE_INSTALL_PLUGINDIR})
 188
 189 install(FILES dolphinpart.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR})
 190
 191 ##########################################
 192
 193 set(dolphinstatic_SRCS
 194     dolphinbookmarkhandler.cpp
 195     dolphindockwidget.cpp
 196     dolphinmainwindow.cpp
 197     dolphinviewcontainer.cpp
 198     dolphincontextmenu.cpp
 199     dolphintabbar.cpp
 200     dolphinplacesmodelsingleton.cpp
 201     dolphinrecenttabsmenu.cpp
 202     dolphintabpage.cpp
 203     dolphintabwidget.cpp
 204     trash/dolphintrash.cpp
 205     filterbar/filterbar.cpp
 206     panels/places/placespanel.cpp
 207     panels/places/placesitem.cpp
 208     panels/places/placesitemlistgroupheader.cpp
 209     panels/places/placesitemlistwidget.cpp
 210     panels/places/placesitemmodel.cpp
 211     panels/places/placesitemsignalhandler.cpp
 212     panels/places/placesview.cpp
 213     panels/panel.cpp
 214     panels/folders/foldersitemlistwidget.cpp
 215     panels/folders/treeviewcontextmenu.cpp
 216     panels/folders/folderspanel.cpp
 217     panels/terminal/terminalpanel.cpp
 218     search/dolphinfacetswidget.cpp
 219     search/dolphinsearchbox.cpp
 220     settings/general/behaviorsettingspage.cpp
 221     settings/general/configurepreviewplugindialog.cpp
 222     settings/general/confirmationssettingspage.cpp
 223     settings/general/generalsettingspage.cpp
 224     settings/general/previewssettingspage.cpp
 225     settings/general/statusbarsettingspage.cpp
 226     settings/dolphinsettingsdialog.cpp
 227     settings/navigation/navigationsettingspage.cpp
 228     settings/services/servicessettingspage.cpp
 229     settings/settingspagebase.cpp
 230     settings/serviceitemdelegate.cpp
 231     settings/servicemodel.cpp
 232     settings/startup/startupsettingspage.cpp
 233     settings/trash/trashsettingspage.cpp
 234     settings/viewmodes/dolphinfontrequester.cpp
 235     settings/viewmodes/viewsettingspage.cpp
 236     settings/viewmodes/viewmodesettings.cpp
 237     settings/viewmodes/viewsettingstab.cpp
 238     statusbar/dolphinstatusbar.cpp
 239     statusbar/mountpointobserver.cpp
 240     statusbar/mountpointobservercache.cpp
 241     statusbar/spaceinfoobserver.cpp
 242     statusbar/statusbarspaceinfo.cpp
 243     views/zoomlevelinfo.cpp
 244     dolphindebug.cpp
 245     global.cpp
 246 )
 247
 248 if(HAVE_BALOO)
 249     set(dolphinstatic_SRCS
 250         ${dolphinstatic_SRCS}
 251         panels/information/informationpanel.cpp
 252         panels/information/informationpanelcontent.cpp
 253         panels/information/pixmapviewer.cpp
 254         panels/information/phononwidget.cpp
 255     )
 256 endif()
 257
 258 kconfig_add_kcfg_files(dolphinstatic_SRCS GENERATE_MOC
 259     panels/folders/dolphin_folderspanelsettings.kcfgc
 260     panels/information/dolphin_informationpanelsettings.kcfgc
 261     panels/places/dolphin_placespanelsettings.kcfgc
 262     settings/dolphin_compactmodesettings.kcfgc
 263     settings/dolphin_detailsmodesettings.kcfgc
 264     settings/dolphin_generalsettings.kcfgc
 265     settings/dolphin_iconsmodesettings.kcfgc
 266     search/dolphin_searchsettings.kcfgc
 267     settings/dolphin_versioncontrolsettings.kcfgc
 268 )
 269
 270 qt5_add_resources(dolphinstatic_SRCS dolphin.qrc)
 271
 272 add_library(dolphinstatic STATIC ${dolphinstatic_SRCS})
 273
 274 target_include_directories(dolphinstatic SYSTEM PRIVATE ${PHONON_INCLUDES})
 275 target_link_libraries(dolphinstatic
 276     dolphinprivate
 277     KF5::KCMUtils
 278     KF5::DBusAddons
 279     KF5::Notifications
 280     Phonon::phonon4qt5
 281 )
 282
 283 if (HAVE_KACTIVITIES)
 284     target_link_libraries(
 285         dolphinstatic
 286         KF5::Activities
 287     )
 288 endif()
 289
 290 set(dolphin_SRCS
 291     dbusinterface.cpp
 292     main.cpp
 293 )
 294
 295 # Sets the icon on Windows and OSX
 296 file(GLOB ICONS_SRCS "${CMAKE_CURRENT_SOURCE_DIR}/icons/*system-file-manager.png")
 297 ecm_add_app_icon(dolphin_SRCS ICONS ${ICONS_SRCS})
 298
 299 kf5_add_kdeinit_executable(dolphin ${dolphin_SRCS})
 300
 301
 302 target_link_libraries(kdeinit_dolphin PRIVATE
 303     dolphinstatic
 304     dolphinprivate
 305     KF5::Crash
 306 )
 307
 308 include(DbusInterfaceMacros)
 309
 310 generate_and_install_dbus_interface(
 311     kdeinit_dolphin
 312     dbusinterface.h
 313     org.freedesktop.FileManager1.xml
 314     OPTIONS -a
 315 )
 316
 317 install(TARGETS kdeinit_dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 318 install(TARGETS dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 319
 320 ##########################################
 321
 322 set(kcm_dolphinviewmodes_PART_SRCS
 323     settings/kcm/kcmdolphinviewmodes.cpp
 324     settings/viewmodes/dolphinfontrequester.cpp
 325     settings/viewmodes/viewmodesettings.cpp
 326     settings/viewmodes/viewsettingstab.cpp
 327     views/zoomlevelinfo.cpp)
 328
 329 set(kcm_dolphinnavigation_PART_SRCS
 330     settings/kcm/kcmdolphinnavigation.cpp
 331     settings/navigation/navigationsettingspage.cpp
 332     settings/settingspagebase.cpp)
 333
 334 set(kcm_dolphinservices_PART_SRCS
 335     settings/kcm/kcmdolphinservices.cpp
 336     settings/services/servicessettingspage.cpp
 337     settings/settingspagebase.cpp
 338     settings/serviceitemdelegate.cpp
 339     settings/servicemodel.cpp)
 340
 341 set(kcm_dolphingeneral_PART_SRCS
 342     settings/kcm/kcmdolphingeneral.cpp
 343     settings/general/behaviorsettingspage.cpp
 344     settings/general/previewssettingspage.cpp
 345     settings/general/configurepreviewplugindialog.cpp
 346     settings/general/confirmationssettingspage.cpp
 347     settings/settingspagebase.cpp
 348     settings/serviceitemdelegate.cpp
 349     settings/servicemodel.cpp)
 350
 351 kconfig_add_kcfg_files(kcm_dolphinviewmodes_PART_SRCS
 352     settings/dolphin_compactmodesettings.kcfgc
 353     settings/dolphin_directoryviewpropertysettings.kcfgc
 354     settings/dolphin_detailsmodesettings.kcfgc
 355     settings/dolphin_iconsmodesettings.kcfgc
 356     settings/dolphin_generalsettings.kcfgc
 357     settings/dolphin_versioncontrolsettings.kcfgc
 358 )
 359
 360 kconfig_add_kcfg_files(kcm_dolphinnavigation_PART_SRCS
 361     settings/dolphin_generalsettings.kcfgc)
 362
 363 kconfig_add_kcfg_files(kcm_dolphinservices_PART_SRCS
 364     settings/dolphin_generalsettings.kcfgc
 365     settings/dolphin_versioncontrolsettings.kcfgc)
 366
 367 kconfig_add_kcfg_files(kcm_dolphingeneral_PART_SRCS
 368     settings/dolphin_generalsettings.kcfgc)
 369
 370 add_library(kcm_dolphinviewmodes MODULE ${kcm_dolphinviewmodes_PART_SRCS})
 371 add_library(kcm_dolphinnavigation MODULE ${kcm_dolphinnavigation_PART_SRCS})
 372 add_library(kcm_dolphinservices MODULE ${kcm_dolphinservices_PART_SRCS})
 373 add_library(kcm_dolphingeneral MODULE ${kcm_dolphingeneral_PART_SRCS})
 374
 375 target_link_libraries(kcm_dolphinviewmodes dolphinprivate)
 376 target_link_libraries(kcm_dolphinnavigation dolphinprivate)
 377 target_link_libraries(kcm_dolphinservices dolphinprivate)
 378 target_link_libraries(kcm_dolphingeneral dolphinprivate)
 379
 380 install(TARGETS kcm_dolphinviewmodes DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 381 install(TARGETS kcm_dolphinnavigation DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 382 install(TARGETS kcm_dolphinservices DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 383 install(TARGETS kcm_dolphingeneral DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 384
 385 ########### install files ###############
 386
 387 install( PROGRAMS org.kde.dolphin.desktop DESTINATION ${KDE_INSTALL_APPDIR} )
 388
 389 install( DIRECTORY DESTINATION "${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel" )
 390
 391 install(
 392     CODE "execute_process(COMMAND \"${CMAKE_COMMAND}\" -E create_symlink \"${KDE_INSTALL_FULL_APPDIR}/org.kde.dolphin.desktop\" \"\$ENV{DESTDIR}${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel/org.kde.dolphin.desktop\")"
 393 )
 394
 395 install( FILES settings/dolphin_directoryviewpropertysettings.kcfg
 396                settings/dolphin_generalsettings.kcfg
 397                settings/dolphin_compactmodesettings.kcfg
 398                settings/dolphin_iconsmodesettings.kcfg
 399                settings/dolphin_detailsmodesettings.kcfg
 400                settings/dolphin_versioncontrolsettings.kcfg
 401          DESTINATION ${KDE_INSTALL_KCFGDIR} )
 402 install( FILES org.kde.dolphin.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR} )
 403 install( FILES settings/kcm/kcmdolphinviewmodes.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 404 install( FILES settings/kcm/kcmdolphinnavigation.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 405 install( FILES settings/kcm/kcmdolphinservices.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 406 install( FILES settings/kcm/kcmdolphingeneral.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 407 install( FILES settings/services/servicemenu.knsrc DESTINATION ${KDE_INSTALL_CONFDIR} )
 408 install( PROGRAMS settings/services/servicemenuinstallation DESTINATION ${KDE_INSTALL_BINDIR} )
 409 install( PROGRAMS settings/services/servicemenudeinstallation DESTINATION ${KDE_INSTALL_BINDIR} )
 410
 411 if(BUILD_TESTING)
 412     find_package(Qt5Test ${QT_MIN_VERSION} CONFIG REQUIRED)
 413     add_subdirectory(tests)
 414 endif()