CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.0)
   2
   3 # KDE Application Version, managed by release script
   4 set (KDE_APPLICATIONS_VERSION_MAJOR "17")
   5 set (KDE_APPLICATIONS_VERSION_MINOR "11")
   6 set (KDE_APPLICATIONS_VERSION_MICRO "70")
   7 set (KDE_APPLICATIONS_VERSION "${KDE_APPLICATIONS_VERSION_MAJOR}.${KDE_APPLICATIONS_VERSION_MINOR}.${KDE_APPLICATIONS_VERSION_MICRO}")
   8 project(Dolphin VERSION ${KDE_APPLICATIONS_VERSION})
   9
  10 set(QT_MIN_VERSION "5.5.0")
  11 set(KF5_MIN_VERSION "5.30.0")
  12 set(ECM_MIN_VERSION "1.6.0")
  13
  14 # ECM setup
  15 find_package(ECM ${ECM_MIN_VERSION} CONFIG REQUIRED)
  16 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH} ${CMAKE_SOURCE_DIR}/cmake)
  17
  18 include(ECMSetupVersion)
  19 include(ECMGenerateHeaders)
  20 include(ECMPackageConfigHelpers)
  21 include(GenerateExportHeader)
  22 include(FeatureSummary)
  23 include(KDEInstallDirs)
  24 include(KDECMakeSettings)
  25 include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
  26
  27 ecm_setup_version(${KDE_APPLICATIONS_VERSION} VARIABLE_PREFIX DOLPHIN
  28                   VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/src/dolphin_version.h"
  29 )
  30
  31 ecm_setup_version("5.0.0" VARIABLE_PREFIX DOLPHINVCS
  32                   VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/dolphinvcs_version.h"
  33                   PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/DolphinVcsConfigVersion.cmake"
  34                   SOVERSION 5
  35 )
  36
  37 ecm_setup_version("5.0.0" VARIABLE_PREFIX DOLPHINPRIVATE
  38                   SOVERSION 5
  39 )
  40
  41 find_package(Qt5 ${QT_MIN_VERSION} CONFIG REQUIRED COMPONENTS
  42     Core
  43     Concurrent
  44     Widgets
  45     Gui
  46     DBus
  47 )
  48
  49 find_package(KF5 ${KF5_MIN_VERSION} REQUIRED COMPONENTS
  50     DocTools
  51     Init
  52     KCMUtils
  53     NewStuff
  54     CoreAddons
  55     I18n
  56     DBusAddons
  57     Bookmarks
  58     Config
  59     KIO
  60     Parts
  61     Solid
  62     IconThemes
  63     Completion
  64     TextWidgets
  65     Notifications
  66     Crash
  67 )
  68 find_package(KF5 ${KF5_MIN_VERSION} OPTIONAL_COMPONENTS
  69     Activities
  70 )
  71
  72 find_package(Phonon4Qt5 CONFIG REQUIRED)
  73
  74 find_package(KF5Baloo 4.97)
  75 set_package_properties(KF5Baloo PROPERTIES DESCRIPTION "Baloo Core libraries"
  76                        URL "http://www.kde.org"
  77                        TYPE OPTIONAL
  78                        PURPOSE "For adding desktop-wide search and tagging support to dolphin"
  79                       )
  80
  81 find_package(KF5BalooWidgets 4.97)
  82 set_package_properties(KF5BalooWidgets PROPERTIES DESCRIPTION "Baloos Widgets"
  83                        URL "http://www.kde.org"
  84                        TYPE OPTIONAL
  85                       )
  86
  87 find_package(KF5FileMetaData 5.19.0)
  88 set_package_properties(KF5FileMetaData PROPERTIES
  89                        URL "https://projects.kde.org/kfilemetadata"
  90                        TYPE OPTIONAL
  91                        PURPOSE "For accessing file metadata labels"
  92                       )
  93
  94 if (KF5Baloo_FOUND AND KF5BalooWidgets_FOUND AND KF5FileMetaData_FOUND)
  95     message(STATUS "Baloo packages are found")
  96     set(HAVE_BALOO TRUE)
  97 else()
  98     find_package(KF5 ${KF5_MIN_VERSION} REQUIRED COMPONENTS
  99         KDELibs4Support # for KFileMetaDataWidget
 100     )
 101 endif()
 102
 103 add_definitions(-DQT_NO_URL_CAST_FROM_STRING)
 104
 105 add_subdirectory(src)
 106 add_subdirectory(doc)
 107
 108 # CMake files
 109 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/DolphinVcs")
 110
 111 ecm_configure_package_config_file(
 112     "${CMAKE_CURRENT_SOURCE_DIR}/DolphinVcsConfig.cmake.in"
 113     "${CMAKE_CURRENT_BINARY_DIR}/DolphinVcsConfig.cmake"
 114     INSTALL_DESTINATION ${CMAKECONFIG_INSTALL_DIR}
 115 )
 116
 117 install(FILES
 118     "${CMAKE_CURRENT_BINARY_DIR}/DolphinVcsConfig.cmake"
 119     "${CMAKE_CURRENT_BINARY_DIR}/DolphinVcsConfigVersion.cmake"
 120     DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
 121     COMPONENT Devel
 122 )
 123
 124 install(EXPORT DolphinVcsTargets
 125     DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
 126     FILE DolphinVcsTargets.cmake
 127 )
 128
 129 install(FILES
 130     "${CMAKE_CURRENT_BINARY_DIR}/dolphinvcs_version.h"
 131     DESTINATION "${KDE_INSTALL_INCLUDEDIR}/Dolphin"
 132     COMPONENT Devel
 133 )
 134
 135 configure_file(org.kde.dolphin.FileManager1.service.in
 136                ${CMAKE_CURRENT_BINARY_DIR}/org.kde.dolphin.FileManager1.service)
 137 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/org.kde.dolphin.FileManager1.service
 138         DESTINATION ${DBUS_SERVICES_INSTALL_DIR})
 139
 140 feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)
 141