src/CMakeLists.txt

   1 include(ECMAddAppIcon)
   2
   3 configure_file(config-dolphin.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-dolphin.h)
   4
   5 add_definitions(
   6     -DTRANSLATION_DOMAIN=\"dolphin\"
   7 )
   8 remove_definitions(
   9     -DQT_NO_CAST_FROM_BYTEARRAY
  10     -DQT_NO_CAST_FROM_ASCII
  11     -DQT_NO_CAST_TO_ASCII
  12 )
  13
  14 ##########################################
  15
  16 add_library(dolphinvcs SHARED)
  17
  18 target_sources(dolphinvcs PRIVATE
  19     views/versioncontrol/kversioncontrolplugin.cpp
  20 )
  21
  22 generate_export_header(dolphinvcs BASE_NAME dolphinvcs)
  23
  24 target_link_libraries(
  25     dolphinvcs PUBLIC
  26     Qt${QT_MAJOR_VERSION}::Widgets
  27 )
  28
  29 set_target_properties(dolphinvcs PROPERTIES
  30     VERSION ${DOLPHINVCS_VERSION}
  31     SOVERSION ${DOLPHINVCS_SOVERSION}
  32     EXPORT_NAME DolphinVcs
  33 )
  34
  35 ecm_generate_headers(dolphinvcs_LIB_HEADERS
  36     HEADER_NAMES
  37     KVersionControlPlugin
  38
  39     RELATIVE "views/versioncontrol"
  40     REQUIRED_HEADERS dolphinvcs_LIB_HEADERS
  41 )
  42
  43 install(TARGETS dolphinvcs EXPORT DolphinVcsTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
  44
  45 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphinvcs_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
  46 install(FILES ${dolphinvcs_LIB_HEADERS} DESTINATION "${KDE_INSTALL_INCLUDEDIR}/Dolphin" COMPONENT Devel)
  47
  48 ########### next target ###############
  49
  50 add_library(dolphinprivate SHARED)
  51
  52 target_sources(dolphinprivate PRIVATE
  53     kitemviews/kfileitemlistview.cpp
  54     kitemviews/kfileitemlistwidget.cpp
  55     kitemviews/kfileitemlisttostring.cpp
  56     kitemviews/kfileitemmodel.cpp
  57     kitemviews/kfileitemmodelrolesupdater.cpp
  58     kitemviews/kitemlistcontainer.cpp
  59     kitemviews/kitemlistcontroller.cpp
  60     kitemviews/kitemlistgroupheader.cpp
  61     kitemviews/kitemlistheader.cpp
  62     kitemviews/kitemlistselectionmanager.cpp
  63     kitemviews/kitemliststyleoption.cpp
  64     kitemviews/kitemlistview.cpp
  65     kitemviews/kitemlistviewaccessible.cpp
  66     kitemviews/kitemlistwidget.cpp
  67     kitemviews/kitemmodelbase.cpp
  68     kitemviews/kitemset.cpp
  69     kitemviews/kstandarditemlistgroupheader.cpp
  70     kitemviews/kstandarditemlistwidget.cpp
  71     kitemviews/kstandarditemlistview.cpp
  72     kitemviews/private/kdirectorycontentscounter.cpp
  73     kitemviews/private/kdirectorycontentscounterworker.cpp
  74     kitemviews/private/kfileitemclipboard.cpp
  75     kitemviews/private/kfileitemmodelfilter.cpp
  76     kitemviews/private/kitemlistheaderwidget.cpp
  77     kitemviews/private/kitemlistkeyboardsearchmanager.cpp
  78     kitemviews/private/kitemlistroleeditor.cpp
  79     kitemviews/private/kitemlistrubberband.cpp
  80     kitemviews/private/kitemlistselectiontoggle.cpp
  81     kitemviews/private/kitemlistsizehintresolver.cpp
  82     kitemviews/private/kitemlistsmoothscroller.cpp
  83     kitemviews/private/kitemlistviewanimation.cpp
  84     kitemviews/private/kitemlistviewlayouter.cpp
  85     kitemviews/private/kpixmapmodifier.cpp
  86     settings/applyviewpropsjob.cpp
  87     settings/viewmodes/viewmodesettings.cpp
  88     settings/viewpropertiesdialog.cpp
  89     settings/viewpropsprogressinfo.cpp
  90     selectionmode/actiontexthelper.cpp
  91     views/dolphinfileitemlistwidget.cpp
  92     views/dolphinitemlistview.cpp
  93     views/dolphinnewfilemenuobserver.cpp
  94     views/dolphinremoteencoding.cpp
  95     views/dolphinview.cpp
  96     views/dolphinviewactionhandler.cpp
  97     views/draganddrophelper.cpp
  98     views/versioncontrol/updateitemstatesthread.cpp
  99     views/versioncontrol/versioncontrolobserver.cpp
 100     views/viewmodecontroller.cpp
 101     views/viewproperties.cpp
 102     views/zoomlevelinfo.cpp
 103     dolphinremoveaction.cpp
 104     middleclickactioneventfilter.cpp
 105     dolphinnewfilemenu.cpp
 106
 107     kitemviews/kfileitemlistview.h
 108     kitemviews/kfileitemlistwidget.h
 109     kitemviews/kfileitemlisttostring.h
 110     kitemviews/kfileitemmodel.h
 111     kitemviews/kfileitemmodelrolesupdater.h
 112     kitemviews/kitemlistcontainer.h
 113     kitemviews/kitemlistcontroller.h
 114     kitemviews/kitemlistgroupheader.h
 115     kitemviews/kitemlistheader.h
 116     kitemviews/kitemlistselectionmanager.h
 117     kitemviews/kitemliststyleoption.h
 118     kitemviews/kitemlistview.h
 119     kitemviews/kitemlistviewaccessible.h
 120     kitemviews/kitemlistwidget.h
 121     kitemviews/kitemmodelbase.h
 122     kitemviews/kitemset.h
 123     kitemviews/kstandarditemlistgroupheader.h
 124     kitemviews/kstandarditemlistwidget.h
 125     kitemviews/kstandarditemlistview.h
 126     kitemviews/private/kdirectorycontentscounter.h
 127     kitemviews/private/kdirectorycontentscounterworker.h
 128     kitemviews/private/kfileitemclipboard.h
 129     kitemviews/private/kfileitemmodelfilter.h
 130     kitemviews/private/kitemlistheaderwidget.h
 131     kitemviews/private/kitemlistkeyboardsearchmanager.h
 132     kitemviews/private/kitemlistroleeditor.h
 133     kitemviews/private/kitemlistrubberband.h
 134     kitemviews/private/kitemlistselectiontoggle.h
 135     kitemviews/private/kitemlistsizehintresolver.h
 136     kitemviews/private/kitemlistsmoothscroller.h
 137     kitemviews/private/kitemlistviewanimation.h
 138     kitemviews/private/kitemlistviewlayouter.h
 139     kitemviews/private/kpixmapmodifier.h
 140     settings/applyviewpropsjob.h
 141     settings/viewmodes/viewmodesettings.h
 142     settings/viewpropertiesdialog.h
 143     settings/viewpropsprogressinfo.h
 144     selectionmode/actiontexthelper.h
 145     views/dolphinfileitemlistwidget.h
 146     views/dolphinitemlistview.h
 147     views/dolphinnewfilemenuobserver.h
 148     views/dolphinremoteencoding.h
 149     views/dolphinview.h
 150     views/dolphinviewactionhandler.h
 151     views/draganddrophelper.h
 152     views/versioncontrol/updateitemstatesthread.h
 153     views/versioncontrol/versioncontrolobserver.h
 154     views/viewmodecontroller.h
 155     views/viewproperties.h
 156     views/zoomlevelinfo.h
 157     dolphinremoveaction.h
 158     middleclickactioneventfilter.h
 159     dolphinnewfilemenu.h
 160 )
 161
 162 ecm_qt_declare_logging_category(dolphinprivate
 163     HEADER dolphindebug.h
 164     IDENTIFIER DolphinDebug
 165     CATEGORY_NAME org.kde.dolphin
 166     DESCRIPTION "dolphin"
 167     EXPORT DOLPHIN
 168 )
 169
 170 if(HAVE_BALOO)
 171     target_sources(dolphinprivate PRIVATE
 172         views/tooltips/dolphinfilemetadatawidget.cpp
 173         views/tooltips/tooltipmanager.cpp
 174         kitemviews/private/kbaloorolesprovider.cpp
 175         views/tooltips/dolphinfilemetadatawidget.h
 176         views/tooltips/tooltipmanager.h
 177         kitemviews/private/kbaloorolesprovider.h
 178     )
 179 endif()
 180
 181 kconfig_add_kcfg_files(dolphinprivate
 182     settings/dolphin_compactmodesettings.kcfgc
 183     settings/dolphin_directoryviewpropertysettings.kcfgc
 184     settings/dolphin_detailsmodesettings.kcfgc
 185     settings/dolphin_iconsmodesettings.kcfgc
 186     settings/dolphin_contentdisplaysettings.kcfgc
 187     settings/dolphin_generalsettings.kcfgc
 188     settings/dolphin_contextmenusettings.kcfgc
 189     settings/dolphin_versioncontrolsettings.kcfgc
 190 )
 191
 192 generate_export_header(dolphinprivate BASE_NAME dolphin)
 193
 194 target_link_libraries(
 195     dolphinprivate PUBLIC
 196     dolphinvcs
 197     Qt${QT_MAJOR_VERSION}::Concurrent
 198     Qt${QT_MAJOR_VERSION}::Gui
 199     KF5::I18n
 200     KF5::IconThemes
 201     KF5::KIOCore
 202     KF5::KIOWidgets
 203     KF5::KIOFileWidgets
 204     KF5::Completion
 205     KF5::TextWidgets
 206     KF5::ConfigCore
 207     KF5::NewStuff
 208     KF5::NewStuffWidgets    # KNSWidgets::Button
 209     KF5::Parts
 210     KF5::WindowSystem
 211     KF5::WidgetsAddons
 212     KF5::Codecs
 213 )
 214
 215 if(HAVE_BALOO)
 216     target_link_libraries(
 217         dolphinprivate PUBLIC
 218         KF5::FileMetaData
 219         KF5::Baloo
 220         KF5::BalooWidgets
 221     )
 222 endif()
 223
 224 set_target_properties(dolphinprivate PROPERTIES
 225     VERSION ${DOLPHINPRIVATE_VERSION}
 226     SOVERSION ${DOLPHINPRIVATE_SOVERSION}
 227 )
 228
 229 install(TARGETS dolphinprivate ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} LIBRARY NAMELINK_SKIP)
 230 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphin_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
 231
 232 ##########################################
 233 configure_file(dolphinpart.json.in ${CMAKE_CURRENT_BINARY_DIR}/dolphinpart.json @ONLY)
 234
 235 add_library(dolphinpart MODULE)
 236
 237 target_sources(dolphinpart PRIVATE
 238     dolphinpart.cpp
 239     dolphinpart_ext.cpp
 240     dolphindebug.cpp
 241     dolphinpart.h
 242     dolphinpart_ext.h
 243     dolphindebug.h
 244
 245     dolphinpart.qrc
 246 )
 247
 248 target_link_libraries(dolphinpart
 249     dolphinprivate
 250 )
 251
 252 install(TARGETS dolphinpart DESTINATION ${KDE_INSTALL_PLUGINDIR}/kf${QT_MAJOR_VERSION}/parts)
 253 install(FILES dolphinpartactions.desktop DESTINATION "${KDE_INSTALL_DATADIR}/dolphin/")
 254
 255 ##########################################
 256
 257 add_library(dolphinstatic STATIC)
 258
 259 target_sources(dolphinstatic PRIVATE
 260     dolphinbookmarkhandler.cpp
 261     dolphindockwidget.cpp
 262     dolphinmainwindow.cpp
 263     dolphinviewcontainer.cpp
 264     dolphincontextmenu.cpp
 265     dolphinnavigatorswidgetaction.cpp
 266     dolphintabbar.cpp
 267     dolphinplacesmodelsingleton.cpp
 268     dolphinrecenttabsmenu.cpp
 269     dolphintabpage.cpp
 270     dolphintabwidget.cpp
 271     dolphinurlnavigator.cpp
 272     dolphinurlnavigatorscontroller.cpp
 273     trash/dolphintrash.cpp
 274     filterbar/filterbar.cpp
 275     kitemviews/kfileitemlisttostring.cpp
 276     panels/places/placespanel.cpp
 277     panels/panel.cpp
 278     panels/folders/foldersitemlistwidget.cpp
 279     panels/folders/treeviewcontextmenu.cpp
 280     panels/folders/folderspanel.cpp
 281     panels/terminal/terminalpanel.cpp
 282     search/dolphinfacetswidget.cpp
 283     search/dolphinquery.cpp
 284     search/dolphinsearchbox.cpp
 285     selectionmode/actiontexthelper.cpp
 286     selectionmode/actionwithwidget.cpp
 287     selectionmode/backgroundcolorhelper.cpp
 288     selectionmode/bottombar.cpp
 289     selectionmode/bottombarcontentscontainer.cpp
 290     selectionmode/topbar.cpp
 291     settings/general/behaviorsettingspage.cpp
 292     settings/general/configurepreviewplugindialog.cpp
 293     settings/general/confirmationssettingspage.cpp
 294     settings/general/generalsettingspage.cpp
 295     settings/general/previewssettingspage.cpp
 296     settings/general/statusbarsettingspage.cpp
 297     settings/dolphinsettingsdialog.cpp
 298     settings/navigation/navigationsettingspage.cpp
 299     settings/contextmenu/contextmenusettingspage.cpp
 300     settings/settingspagebase.cpp
 301     settings/serviceitemdelegate.cpp
 302     settings/servicemodel.cpp
 303     settings/startup/startupsettingspage.cpp
 304     settings/trash/trashsettingspage.cpp
 305     settings/viewmodes/dolphinfontrequester.cpp
 306     settings/viewmodes/viewsettingspage.cpp
 307     settings/viewmodes/viewmodesettings.cpp
 308     settings/viewmodes/viewsettingstab.cpp
 309     settings/viewmodes/contentdisplaytab.cpp
 310     statusbar/dolphinstatusbar.cpp
 311     statusbar/mountpointobserver.cpp
 312     statusbar/mountpointobservercache.cpp
 313     statusbar/spaceinfoobserver.cpp
 314     statusbar/statusbarspaceinfo.cpp
 315     views/zoomlevelinfo.cpp
 316     dolphindebug.cpp
 317     global.cpp
 318     dolphin.qrc
 319
 320     dolphinbookmarkhandler.h
 321     dolphindockwidget.h
 322     dolphinmainwindow.h
 323     dolphinviewcontainer.h
 324     dolphincontextmenu.h
 325     dolphinnavigatorswidgetaction.h
 326     dolphintabbar.h
 327     dolphinplacesmodelsingleton.h
 328     dolphinrecenttabsmenu.h
 329     dolphintabpage.h
 330     dolphintabwidget.h
 331     dolphinurlnavigator.h
 332     dolphinurlnavigatorscontroller.h
 333     trash/dolphintrash.h
 334     filterbar/filterbar.h
 335     kitemviews/kfileitemlisttostring.h
 336     panels/places/placespanel.h
 337     panels/panel.h
 338     panels/folders/foldersitemlistwidget.h
 339     panels/folders/treeviewcontextmenu.h
 340     panels/folders/folderspanel.h
 341     panels/terminal/terminalpanel.h
 342     search/dolphinfacetswidget.h
 343     search/dolphinquery.h
 344     search/dolphinsearchbox.h
 345     selectionmode/actiontexthelper.h
 346     selectionmode/actionwithwidget.h
 347     selectionmode/backgroundcolorhelper.h
 348     selectionmode/bottombar.h
 349     selectionmode/bottombarcontentscontainer.h
 350     selectionmode/topbar.h
 351     settings/general/behaviorsettingspage.h
 352     settings/general/configurepreviewplugindialog.h
 353     settings/general/confirmationssettingspage.h
 354     settings/general/generalsettingspage.h
 355     settings/general/previewssettingspage.h
 356     settings/general/statusbarsettingspage.h
 357     settings/dolphinsettingsdialog.h
 358     settings/navigation/navigationsettingspage.h
 359     settings/contextmenu/contextmenusettingspage.h
 360     settings/settingspagebase.h
 361     settings/serviceitemdelegate.h
 362     settings/servicemodel.h
 363     settings/startup/startupsettingspage.h
 364     settings/trash/trashsettingspage.h
 365     settings/viewmodes/dolphinfontrequester.h
 366     settings/viewmodes/viewsettingspage.h
 367     settings/viewmodes/viewmodesettings.h
 368     settings/viewmodes/viewsettingstab.h
 369     settings/viewmodes/contentdisplaytab.h
 370     statusbar/dolphinstatusbar.h
 371     statusbar/mountpointobserver.h
 372     statusbar/mountpointobservercache.h
 373     statusbar/spaceinfoobserver.h
 374     statusbar/statusbarspaceinfo.h
 375     views/zoomlevelinfo.h
 376     dolphindebug.h
 377     global.h
 378 )
 379
 380 if(HAVE_BALOO)
 381     target_sources(dolphinstatic PRIVATE
 382         panels/information/informationpanel.cpp
 383         panels/information/informationpanelcontent.cpp
 384         panels/information/pixmapviewer.cpp
 385         panels/information/phononwidget.cpp
 386         panels/information/informationpanel.h
 387         panels/information/informationpanelcontent.h
 388         panels/information/pixmapviewer.h
 389         panels/information/phononwidget.h
 390     )
 391 endif()
 392
 393 if(HAVE_KUSERFEEDBACK)
 394     target_sources(dolphinstatic PRIVATE
 395         userfeedback/dolphinfeedbackprovider.cpp
 396         userfeedback/settingsdatasource.cpp
 397         userfeedback/placesdatasource.cpp
 398         settings/userfeedback/userfeedbacksettingspage.cpp
 399         userfeedback/dolphinfeedbackprovider.h
 400         userfeedback/settingsdatasource.h
 401         userfeedback/placesdatasource.h
 402         settings/userfeedback/userfeedbacksettingspage.h
 403     )
 404 endif()
 405
 406 kconfig_add_kcfg_files(dolphinstatic
 407     panels/folders/dolphin_folderspanelsettings.kcfgc
 408     panels/information/dolphin_informationpanelsettings.kcfgc
 409     panels/places/dolphin_placespanelsettings.kcfgc
 410     settings/dolphin_compactmodesettings.kcfgc
 411     settings/dolphin_detailsmodesettings.kcfgc
 412     settings/dolphin_contextmenusettings.kcfgc
 413     settings/dolphin_iconsmodesettings.kcfgc
 414     settings/dolphin_contentdisplaysettings.kcfgc
 415     search/dolphin_searchsettings.kcfgc
 416     settings/dolphin_versioncontrolsettings.kcfgc
 417 )
 418 kconfig_add_kcfg_files(dolphinstatic GENERATE_MOC
 419     settings/dolphin_generalsettings.kcfgc
 420 )
 421
 422 qt_generate_dbus_interface(${CMAKE_CURRENT_SOURCE_DIR}/dolphinmainwindow.h org.kde.DolphinMainWindow.xml)
 423 qt_add_dbus_adaptor(dolphin_dbus_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindow.h DolphinMainWindow)
 424 qt_add_dbus_interface(dolphin_dbus_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindowinterface)
 425 qt_add_dbus_interface(dolphin_dbus_SRCS panels/terminal/org.kde.KIOFuse.VFS.xml kiofuse_interface)
 426
 427 target_sources(dolphinstatic PRIVATE
 428     ${dolphin_dbus_SRCS}
 429 )
 430
 431 target_include_directories(dolphinstatic SYSTEM PRIVATE ${PHONON_INCLUDES})
 432 target_link_libraries(dolphinstatic
 433     dolphinprivate
 434     KF5::CoreAddons
 435     KF5::KCMUtils
 436     KF5::DBusAddons
 437     KF5::Notifications
 438     Phonon::phonon4qt${QT_MAJOR_VERSION}
 439 )
 440
 441 if (HAVE_KACTIVITIES)
 442     target_link_libraries(
 443         dolphinstatic
 444         KF5::Activities
 445     )
 446 endif()
 447
 448 if (HAVE_KUSERFEEDBACK)
 449     target_link_libraries(
 450         dolphinstatic
 451         KUserFeedbackCore
 452         KUserFeedbackWidgets
 453     )
 454 endif()
 455
 456 add_executable(dolphin)
 457
 458 target_sources(dolphin PRIVATE
 459     dbusinterface.cpp
 460     dbusinterface.h
 461     main.cpp
 462 )
 463
 464 if(FLATPAK)
 465     target_compile_definitions(dolphin PRIVATE FLATPAK)
 466 endif()
 467
 468 # Sets the icon on Windows and OSX
 469 file(GLOB ICONS_SRCS "${CMAKE_CURRENT_SOURCE_DIR}/icons/*system-file-manager.png")
 470 ecm_add_app_icon(dolphin ICONS ${ICONS_SRCS})
 471
 472 target_link_libraries(dolphin
 473     PRIVATE
 474     dolphinprivate
 475     dolphinstatic
 476     KF5::Crash
 477 )
 478
 479 if (HAVE_X11)
 480     if (QT_MAJOR_VERSION STREQUAL "5")
 481         target_link_libraries(dolphin PRIVATE Qt5::X11Extras)
 482     else()
 483         target_link_libraries(dolphin PRIVATE Qt::GuiPrivate)
 484     endif()
 485 endif()
 486
 487 include(DbusInterfaceMacros)
 488
 489 generate_and_install_dbus_interface(
 490     dolphin
 491     dbusinterface.h
 492     org.freedesktop.FileManager1.xml
 493     OPTIONS -a
 494 )
 495
 496 install(TARGETS dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 497
 498 ##########################################
 499
 500 if(NOT WIN32)
 501     # The settings are still accessible from the hamburger menu
 502     add_library(kcm_dolphinviewmodes MODULE)
 503     add_library(kcm_dolphinnavigation MODULE)
 504     add_library(kcm_dolphingeneral MODULE)
 505
 506     target_sources(kcm_dolphinviewmodes PRIVATE
 507         settings/kcm/kcmdolphinviewmodes.cpp
 508         settings/viewmodes/dolphinfontrequester.cpp
 509         settings/viewmodes/viewmodesettings.cpp
 510         settings/viewmodes/viewsettingstab.cpp
 511         views/zoomlevelinfo.cpp
 512         settings/kcm/kcmdolphinviewmodes.h
 513         settings/viewmodes/dolphinfontrequester.h
 514         settings/viewmodes/viewmodesettings.h
 515         settings/viewmodes/viewsettingstab.h
 516         views/zoomlevelinfo.h)
 517
 518     target_sources(kcm_dolphinnavigation PRIVATE
 519         settings/kcm/kcmdolphinnavigation.cpp
 520         settings/navigation/navigationsettingspage.cpp
 521         settings/settingspagebase.cpp
 522         settings/kcm/kcmdolphinnavigation.h
 523         settings/navigation/navigationsettingspage.h
 524         settings/settingspagebase.h
 525     )
 526
 527     target_sources(kcm_dolphingeneral PRIVATE
 528         settings/kcm/kcmdolphingeneral.cpp
 529         settings/general/behaviorsettingspage.cpp
 530         settings/general/previewssettingspage.cpp
 531         settings/general/configurepreviewplugindialog.cpp
 532         settings/general/confirmationssettingspage.cpp
 533         settings/settingspagebase.cpp
 534         settings/serviceitemdelegate.cpp
 535         settings/servicemodel.cpp
 536         settings/kcm/kcmdolphingeneral.h
 537         settings/general/behaviorsettingspage.h
 538         settings/general/previewssettingspage.h
 539         settings/general/configurepreviewplugindialog.h
 540         settings/general/confirmationssettingspage.h
 541         settings/settingspagebase.h
 542         settings/serviceitemdelegate.h
 543         settings/servicemodel.h
 544     )
 545
 546     kconfig_add_kcfg_files(kcm_dolphinviewmodes
 547         settings/dolphin_compactmodesettings.kcfgc
 548         settings/dolphin_directoryviewpropertysettings.kcfgc
 549         settings/dolphin_detailsmodesettings.kcfgc
 550         settings/dolphin_iconsmodesettings.kcfgc
 551         settings/dolphin_contentdisplaysettings.kcfgc
 552         settings/dolphin_generalsettings.kcfgc
 553         settings/dolphin_versioncontrolsettings.kcfgc
 554     )
 555
 556     kconfig_add_kcfg_files(kcm_dolphinnavigation
 557         settings/dolphin_generalsettings.kcfgc)
 558
 559     kconfig_add_kcfg_files(kcm_dolphingeneral
 560         settings/dolphin_generalsettings.kcfgc)
 561
 562     target_link_libraries(kcm_dolphinviewmodes dolphinprivate)
 563     target_link_libraries(kcm_dolphinnavigation dolphinprivate)
 564     target_link_libraries(kcm_dolphingeneral dolphinprivate)
 565
 566     install( FILES org.kde.dolphin.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR} )
 567
 568     install(TARGETS kcm_dolphinviewmodes DESTINATION ${KDE_INSTALL_PLUGINDIR}/dolphin/kcms )
 569     install(TARGETS kcm_dolphinnavigation DESTINATION ${KDE_INSTALL_PLUGINDIR}/dolphin/kcms )
 570     install(TARGETS kcm_dolphingeneral DESTINATION ${KDE_INSTALL_PLUGINDIR}/dolphin/kcms )
 571 endif()
 572
 573 if(NOT WIN32)
 574     add_subdirectory(settings/contextmenu/servicemenuinstaller)
 575     install( FILES settings/contextmenu/servicemenu.knsrc DESTINATION ${KDE_INSTALL_KNSRCDIR} )
 576 endif()
 577
 578 ########### install files ###############
 579
 580 install( PROGRAMS org.kde.dolphin.desktop DESTINATION ${KDE_INSTALL_APPDIR} )
 581
 582 install( DIRECTORY DESTINATION "${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel" )
 583
 584 install(
 585     CODE "execute_process(COMMAND \"${CMAKE_COMMAND}\" -E create_symlink \"${KDE_INSTALL_FULL_APPDIR}/org.kde.dolphin.desktop\" \"\$ENV{DESTDIR}${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel/org.kde.dolphin.desktop\")"
 586 )
 587
 588 install( FILES settings/dolphin_directoryviewpropertysettings.kcfg
 589                settings/dolphin_generalsettings.kcfg
 590                settings/dolphin_contextmenusettings.kcfg
 591                settings/dolphin_compactmodesettings.kcfg
 592                settings/dolphin_iconsmodesettings.kcfg
 593                settings/dolphin_detailsmodesettings.kcfg
 594                settings/dolphin_contentdisplaysettings.kcfg
 595                settings/dolphin_versioncontrolsettings.kcfg
 596          DESTINATION ${KDE_INSTALL_KCFGDIR} )
 597
 598 install( FILES settings/dolphin_detailsmodesettings.upd
 599          DESTINATION ${KDE_INSTALL_KCONFUPDATEDIR} )
 600
 601 if(BUILD_TESTING)
 602     add_subdirectory(tests)
 603 endif()