src/CMakeLists.txt

   1 include(ECMAddAppIcon)
   2
   3 configure_file(config-dolphin.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-dolphin.h)
   4
   5 add_definitions(
   6     -DTRANSLATION_DOMAIN=\"dolphin\"
   7 )
   8 remove_definitions(
   9     -DQT_NO_CAST_FROM_BYTEARRAY
  10     -DQT_NO_CAST_FROM_ASCII
  11     -DQT_NO_CAST_TO_ASCII
  12 )
  13
  14 ##########################################
  15
  16 add_library(dolphinvcs SHARED)
  17
  18 target_sources(dolphinvcs PRIVATE
  19     views/versioncontrol/kversioncontrolplugin.cpp
  20 )
  21
  22 generate_export_header(dolphinvcs BASE_NAME dolphinvcs)
  23
  24 target_link_libraries(
  25     dolphinvcs PUBLIC
  26     Qt${QT_MAJOR_VERSION}::Widgets
  27 )
  28
  29 set_target_properties(dolphinvcs PROPERTIES
  30     VERSION ${DOLPHINVCS_VERSION}
  31     SOVERSION ${DOLPHINVCS_SOVERSION}
  32     EXPORT_NAME DolphinVcs
  33 )
  34
  35 ecm_generate_headers(dolphinvcs_LIB_HEADERS
  36     HEADER_NAMES
  37     KVersionControlPlugin
  38
  39     RELATIVE "views/versioncontrol"
  40     REQUIRED_HEADERS dolphinvcs_LIB_HEADERS
  41 )
  42
  43 install(TARGETS dolphinvcs EXPORT DolphinVcsTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
  44
  45 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphinvcs_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
  46 install(FILES ${dolphinvcs_LIB_HEADERS} DESTINATION "${KDE_INSTALL_INCLUDEDIR}/Dolphin" COMPONENT Devel)
  47
  48 ########### next target ###############
  49
  50 add_library(dolphinprivate SHARED)
  51
  52 target_sources(dolphinprivate PRIVATE
  53     kitemviews/kfileitemlistview.cpp
  54     kitemviews/kfileitemlistwidget.cpp
  55     kitemviews/kfileitemlisttostring.cpp
  56     kitemviews/kfileitemmodel.cpp
  57     kitemviews/kfileitemmodelrolesupdater.cpp
  58     kitemviews/kitemlistcontainer.cpp
  59     kitemviews/kitemlistcontroller.cpp
  60     kitemviews/kitemlistgroupheader.cpp
  61     kitemviews/kitemlistheader.cpp
  62     kitemviews/kitemlistselectionmanager.cpp
  63     kitemviews/kitemliststyleoption.cpp
  64     kitemviews/kitemlistview.cpp
  65     kitemviews/kitemlistviewaccessible.cpp
  66     kitemviews/kitemlistwidget.cpp
  67     kitemviews/kitemmodelbase.cpp
  68     kitemviews/kitemset.cpp
  69     kitemviews/kstandarditemlistgroupheader.cpp
  70     kitemviews/kstandarditemlistwidget.cpp
  71     kitemviews/kstandarditemlistview.cpp
  72     kitemviews/private/kdirectorycontentscounter.cpp
  73     kitemviews/private/kdirectorycontentscounterworker.cpp
  74     kitemviews/private/kfileitemclipboard.cpp
  75     kitemviews/private/kfileitemmodelfilter.cpp
  76     kitemviews/private/kitemlistheaderwidget.cpp
  77     kitemviews/private/kitemlistkeyboardsearchmanager.cpp
  78     kitemviews/private/kitemlistroleeditor.cpp
  79     kitemviews/private/kitemlistrubberband.cpp
  80     kitemviews/private/kitemlistselectiontoggle.cpp
  81     kitemviews/private/kitemlistsizehintresolver.cpp
  82     kitemviews/private/kitemlistsmoothscroller.cpp
  83     kitemviews/private/kitemlistviewanimation.cpp
  84     kitemviews/private/kitemlistviewlayouter.cpp
  85     kitemviews/private/kpixmapmodifier.cpp
  86     settings/applyviewpropsjob.cpp
  87     settings/viewmodes/viewmodesettings.cpp
  88     settings/viewpropertiesdialog.cpp
  89     settings/viewpropsprogressinfo.cpp
  90     views/dolphinfileitemlistwidget.cpp
  91     views/dolphinitemlistview.cpp
  92     views/dolphinnewfilemenuobserver.cpp
  93     views/dolphinremoteencoding.cpp
  94     views/dolphinview.cpp
  95     views/dolphinviewactionhandler.cpp
  96     views/draganddrophelper.cpp
  97     views/versioncontrol/updateitemstatesthread.cpp
  98     views/versioncontrol/versioncontrolobserver.cpp
  99     views/viewmodecontroller.cpp
 100     views/viewproperties.cpp
 101     views/zoomlevelinfo.cpp
 102     dolphinremoveaction.cpp
 103     middleclickactioneventfilter.cpp
 104     dolphinnewfilemenu.cpp
 105 )
 106
 107 ecm_qt_declare_logging_category(dolphinprivate
 108     HEADER dolphindebug.h
 109     IDENTIFIER DolphinDebug
 110     CATEGORY_NAME org.kde.dolphin
 111     DESCRIPTION "dolphin"
 112     EXPORT DOLPHIN
 113 )
 114
 115 if(HAVE_BALOO)
 116     target_sources(dolphinprivate PRIVATE
 117         views/tooltips/dolphinfilemetadatawidget.cpp
 118         views/tooltips/tooltipmanager.cpp
 119         kitemviews/private/kbaloorolesprovider.cpp
 120     )
 121 endif()
 122
 123 kconfig_add_kcfg_files(dolphinprivate
 124     settings/dolphin_compactmodesettings.kcfgc
 125     settings/dolphin_directoryviewpropertysettings.kcfgc
 126     settings/dolphin_detailsmodesettings.kcfgc
 127     settings/dolphin_iconsmodesettings.kcfgc
 128     settings/dolphin_generalsettings.kcfgc
 129     settings/dolphin_contextmenusettings.kcfgc
 130     settings/dolphin_versioncontrolsettings.kcfgc
 131 )
 132
 133 generate_export_header(dolphinprivate BASE_NAME dolphin)
 134
 135 target_link_libraries(
 136     dolphinprivate PUBLIC
 137     dolphinvcs
 138     Qt${QT_MAJOR_VERSION}::Concurrent
 139     Qt${QT_MAJOR_VERSION}::Gui
 140     KF5::I18n
 141     KF5::IconThemes
 142     KF5::KIOCore
 143     KF5::KIOWidgets
 144     KF5::KIOFileWidgets
 145     KF5::Completion
 146     KF5::TextWidgets
 147     KF5::ConfigCore
 148     KF5::NewStuff
 149     KF5::NewStuffWidgets    # KNSWidgets::Button
 150     KF5::Parts
 151     KF5::WindowSystem
 152     KF5::WidgetsAddons
 153 )
 154
 155 if(HAVE_BALOO)
 156     target_link_libraries(
 157         dolphinprivate PUBLIC
 158         KF5::FileMetaData
 159         KF5::Baloo
 160         KF5::BalooWidgets
 161     )
 162 endif()
 163
 164 set_target_properties(dolphinprivate PROPERTIES
 165     VERSION ${DOLPHINPRIVATE_VERSION}
 166     SOVERSION ${DOLPHINPRIVATE_SOVERSION}
 167 )
 168
 169 install(TARGETS dolphinprivate ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} LIBRARY NAMELINK_SKIP)
 170 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphin_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
 171
 172 ##########################################
 173 configure_file(dolphinpart.json.in ${CMAKE_CURRENT_BINARY_DIR}/dolphinpart.json @ONLY)
 174
 175 add_library(dolphinpart MODULE)
 176
 177 target_sources(dolphinpart PRIVATE
 178     dolphinpart.cpp
 179     dolphinpart_ext.cpp
 180     dolphindebug.cpp
 181
 182     dolphinpart.qrc
 183 )
 184
 185 target_link_libraries(dolphinpart
 186     dolphinprivate
 187 )
 188
 189 install(TARGETS dolphinpart DESTINATION ${KDE_INSTALL_PLUGINDIR}/kf${QT_MAJOR_VERSION}/parts)
 190 install(FILES dolphinpartactions.desktop DESTINATION "${KDE_INSTALL_DATADIR}/dolphin/")
 191
 192 ##########################################
 193
 194 add_library(dolphinstatic STATIC)
 195
 196 target_sources(dolphinstatic PRIVATE
 197     dolphinbookmarkhandler.cpp
 198     dolphindockwidget.cpp
 199     dolphinmainwindow.cpp
 200     dolphinviewcontainer.cpp
 201     dolphincontextmenu.cpp
 202     dolphinnavigatorswidgetaction.cpp
 203     dolphintabbar.cpp
 204     dolphinplacesmodelsingleton.cpp
 205     dolphinrecenttabsmenu.cpp
 206     dolphintabpage.cpp
 207     dolphintabwidget.cpp
 208     dolphinurlnavigator.cpp
 209     dolphinurlnavigatorscontroller.cpp
 210     trash/dolphintrash.cpp
 211     filterbar/filterbar.cpp
 212     kitemviews/kfileitemlisttostring.cpp
 213     panels/places/placespanel.cpp
 214     panels/panel.cpp
 215     panels/folders/foldersitemlistwidget.cpp
 216     panels/folders/treeviewcontextmenu.cpp
 217     panels/folders/folderspanel.cpp
 218     panels/terminal/terminalpanel.cpp
 219     search/dolphinfacetswidget.cpp
 220     search/dolphinquery.cpp
 221     search/dolphinsearchbox.cpp
 222     selectionmode/actionwithwidget.cpp
 223     selectionmode/backgroundcolorhelper.cpp
 224     selectionmode/selectionmodebottombar.cpp
 225     selectionmode/selectionmodetopbar.cpp
 226     settings/general/behaviorsettingspage.cpp
 227     settings/general/configurepreviewplugindialog.cpp
 228     settings/general/confirmationssettingspage.cpp
 229     settings/general/generalsettingspage.cpp
 230     settings/general/previewssettingspage.cpp
 231     settings/general/statusbarsettingspage.cpp
 232     settings/dolphinsettingsdialog.cpp
 233     settings/navigation/navigationsettingspage.cpp
 234     settings/contextmenu/contextmenusettingspage.cpp
 235     settings/settingspagebase.cpp
 236     settings/serviceitemdelegate.cpp
 237     settings/servicemodel.cpp
 238     settings/startup/startupsettingspage.cpp
 239     settings/trash/trashsettingspage.cpp
 240     settings/viewmodes/dolphinfontrequester.cpp
 241     settings/viewmodes/viewsettingspage.cpp
 242     settings/viewmodes/viewmodesettings.cpp
 243     settings/viewmodes/viewsettingstab.cpp
 244     statusbar/dolphinstatusbar.cpp
 245     statusbar/mountpointobserver.cpp
 246     statusbar/mountpointobservercache.cpp
 247     statusbar/spaceinfoobserver.cpp
 248     statusbar/statusbarspaceinfo.cpp
 249     views/zoomlevelinfo.cpp
 250     dolphindebug.cpp
 251     global.cpp
 252     dolphin.qrc
 253 )
 254
 255 if(HAVE_BALOO)
 256     target_sources(dolphinstatic PRIVATE
 257         panels/information/informationpanel.cpp
 258         panels/information/informationpanelcontent.cpp
 259         panels/information/pixmapviewer.cpp
 260         panels/information/phononwidget.cpp
 261     )
 262 endif()
 263
 264 if(HAVE_KUSERFEEDBACK)
 265     target_sources(dolphinstatic PRIVATE
 266         userfeedback/dolphinfeedbackprovider.cpp
 267         userfeedback/settingsdatasource.cpp
 268         userfeedback/placesdatasource.cpp
 269         settings/userfeedback/userfeedbacksettingspage.cpp
 270     )
 271 endif()
 272
 273 kconfig_add_kcfg_files(dolphinstatic
 274     panels/folders/dolphin_folderspanelsettings.kcfgc
 275     panels/information/dolphin_informationpanelsettings.kcfgc
 276     panels/places/dolphin_placespanelsettings.kcfgc
 277     settings/dolphin_compactmodesettings.kcfgc
 278     settings/dolphin_detailsmodesettings.kcfgc
 279     settings/dolphin_contextmenusettings.kcfgc
 280     settings/dolphin_iconsmodesettings.kcfgc
 281     search/dolphin_searchsettings.kcfgc
 282     settings/dolphin_versioncontrolsettings.kcfgc
 283 )
 284 kconfig_add_kcfg_files(dolphinstatic GENERATE_MOC
 285     settings/dolphin_generalsettings.kcfgc
 286 )
 287
 288 qt_generate_dbus_interface(${CMAKE_CURRENT_SOURCE_DIR}/dolphinmainwindow.h org.kde.DolphinMainWindow.xml)
 289 qt_add_dbus_adaptor(dolphin_dbus_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindow.h DolphinMainWindow)
 290 qt_add_dbus_interface(dolphin_dbus_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindowinterface)
 291 qt_add_dbus_interface(dolphin_dbus_SRCS panels/terminal/org.kde.KIOFuse.VFS.xml kiofuse_interface)
 292
 293 target_sources(dolphinstatic PRIVATE
 294     ${dolphin_dbus_SRCS}
 295 )
 296
 297 target_include_directories(dolphinstatic SYSTEM PRIVATE ${PHONON_INCLUDES})
 298 target_link_libraries(dolphinstatic
 299     dolphinprivate
 300     KF5::CoreAddons
 301     KF5::KCMUtils
 302     KF5::DBusAddons
 303     KF5::Notifications
 304     Phonon::phonon4qt${QT_MAJOR_VERSION}
 305 )
 306
 307 if (HAVE_KACTIVITIES)
 308     target_link_libraries(
 309         dolphinstatic
 310         KF5::Activities
 311     )
 312 endif()
 313
 314 if (HAVE_KUSERFEEDBACK)
 315     target_link_libraries(
 316         dolphinstatic
 317         KUserFeedbackCore
 318         KUserFeedbackWidgets
 319     )
 320 endif()
 321
 322 add_executable(dolphin)
 323
 324 target_sources(dolphin PRIVATE
 325     dbusinterface.cpp
 326     main.cpp
 327 )
 328
 329 if(FLATPAK)
 330     target_compile_definitions(dolphin PRIVATE FLATPAK)
 331 endif()
 332
 333 # Sets the icon on Windows and OSX
 334 file(GLOB ICONS_SRCS "${CMAKE_CURRENT_SOURCE_DIR}/icons/*system-file-manager.png")
 335 ecm_add_app_icon(dolphin ICONS ${ICONS_SRCS})
 336
 337 target_link_libraries(dolphin
 338     PRIVATE
 339     dolphinprivate
 340     dolphinstatic
 341     KF5::Crash
 342 )
 343
 344 include(DbusInterfaceMacros)
 345
 346 generate_and_install_dbus_interface(
 347     dolphin
 348     dbusinterface.h
 349     org.freedesktop.FileManager1.xml
 350     OPTIONS -a
 351 )
 352
 353 install(TARGETS dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 354
 355 ##########################################
 356
 357 if(NOT WIN32)
 358     # The settings are still accessible from the hamburger menu
 359     add_library(kcm_dolphinviewmodes MODULE)
 360     add_library(kcm_dolphinnavigation MODULE)
 361     add_library(kcm_dolphingeneral MODULE)
 362
 363     target_sources(kcm_dolphinviewmodes PRIVATE
 364         settings/kcm/kcmdolphinviewmodes.cpp
 365         settings/viewmodes/dolphinfontrequester.cpp
 366         settings/viewmodes/viewmodesettings.cpp
 367         settings/viewmodes/viewsettingstab.cpp
 368         views/zoomlevelinfo.cpp)
 369
 370     target_sources(kcm_dolphinnavigation PRIVATE
 371         settings/kcm/kcmdolphinnavigation.cpp
 372         settings/navigation/navigationsettingspage.cpp
 373         settings/settingspagebase.cpp)
 374
 375     target_sources(kcm_dolphingeneral PRIVATE
 376         settings/kcm/kcmdolphingeneral.cpp
 377         settings/general/behaviorsettingspage.cpp
 378         settings/general/previewssettingspage.cpp
 379         settings/general/configurepreviewplugindialog.cpp
 380         settings/general/confirmationssettingspage.cpp
 381         settings/settingspagebase.cpp
 382         settings/serviceitemdelegate.cpp
 383         settings/servicemodel.cpp)
 384
 385     kconfig_add_kcfg_files(kcm_dolphinviewmodes
 386         settings/dolphin_compactmodesettings.kcfgc
 387         settings/dolphin_directoryviewpropertysettings.kcfgc
 388         settings/dolphin_detailsmodesettings.kcfgc
 389         settings/dolphin_iconsmodesettings.kcfgc
 390         settings/dolphin_generalsettings.kcfgc
 391         settings/dolphin_versioncontrolsettings.kcfgc
 392     )
 393
 394     kconfig_add_kcfg_files(kcm_dolphinnavigation
 395         settings/dolphin_generalsettings.kcfgc)
 396
 397     kconfig_add_kcfg_files(kcm_dolphingeneral
 398         settings/dolphin_generalsettings.kcfgc)
 399
 400     target_link_libraries(kcm_dolphinviewmodes dolphinprivate)
 401     target_link_libraries(kcm_dolphinnavigation dolphinprivate)
 402     target_link_libraries(kcm_dolphingeneral dolphinprivate)
 403
 404     install( FILES org.kde.dolphin.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR} )
 405
 406     install(TARGETS kcm_dolphinviewmodes DESTINATION ${KDE_INSTALL_PLUGINDIR}/dolphin/kcms )
 407     install(TARGETS kcm_dolphinnavigation DESTINATION ${KDE_INSTALL_PLUGINDIR}/dolphin/kcms )
 408     install(TARGETS kcm_dolphingeneral DESTINATION ${KDE_INSTALL_PLUGINDIR}/dolphin/kcms )
 409 endif()
 410
 411 if(NOT WIN32)
 412     add_subdirectory(settings/contextmenu/servicemenuinstaller)
 413     install( FILES settings/contextmenu/servicemenu.knsrc DESTINATION ${KDE_INSTALL_KNSRCDIR} )
 414 endif()
 415
 416 ########### install files ###############
 417
 418 install( PROGRAMS org.kde.dolphin.desktop DESTINATION ${KDE_INSTALL_APPDIR} )
 419
 420 install( DIRECTORY DESTINATION "${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel" )
 421
 422 install(
 423     CODE "execute_process(COMMAND \"${CMAKE_COMMAND}\" -E create_symlink \"${KDE_INSTALL_FULL_APPDIR}/org.kde.dolphin.desktop\" \"\$ENV{DESTDIR}${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel/org.kde.dolphin.desktop\")"
 424 )
 425
 426 install( FILES settings/dolphin_directoryviewpropertysettings.kcfg
 427                settings/dolphin_generalsettings.kcfg
 428                settings/dolphin_contextmenusettings.kcfg
 429                settings/dolphin_compactmodesettings.kcfg
 430                settings/dolphin_iconsmodesettings.kcfg
 431                settings/dolphin_detailsmodesettings.kcfg
 432                settings/dolphin_versioncontrolsettings.kcfg
 433          DESTINATION ${KDE_INSTALL_KCFGDIR} )
 434
 435 install( FILES settings/dolphin_detailsmodesettings.upd
 436          DESTINATION ${KDE_INSTALL_KCONFUPDATEDIR} )
 437
 438 if(BUILD_TESTING)
 439     add_subdirectory(tests)
 440 endif()