src/CMakeLists.txt

   1
   2 configure_file(config-baloo.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-baloo.h)
   3
   4 configure_file(config-dolphin.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-dolphin.h)
   5
   6 add_definitions(
   7     -DTRANSLATION_DOMAIN=\"dolphin\"
   8     -DQT_USE_FAST_CONCATENATION
   9     -DQT_USE_FAST_OPERATOR_PLUS
  10 )
  11 remove_definitions(
  12     -DQT_NO_CAST_FROM_BYTEARRAY
  13     -DQT_NO_URL_CAST_FROM_STRING
  14     -DQT_NO_SIGNALS_SLOTS_KEYWORDS
  15     -DQT_NO_CAST_FROM_ASCII
  16     -DQT_NO_CAST_TO_ASCII
  17 )
  18
  19 ##########################################
  20
  21 set(dolphinvcs_LIB_SRCS
  22     views/versioncontrol/kversioncontrolplugin.cpp
  23 )
  24
  25 add_library(dolphinvcs ${dolphinvcs_LIB_SRCS})
  26
  27 generate_export_header(dolphinvcs BASE_NAME dolphin)
  28
  29 target_link_libraries(
  30     dolphinvcs PUBLIC
  31     Qt5::Widgets
  32 )
  33
  34 set_target_properties(dolphinvcs PROPERTIES
  35     VERSION ${DOLPHINVCS_VERSION_STRING}
  36     SOVERSION ${DOLPHINVCS_SOVERSION}
  37     EXPORT_NAME DolphinVcs
  38 )
  39
  40 ecm_generate_headers(dolphinvcs_LIB_HEADERS
  41     HEADER_NAMES
  42     KVersionControlPlugin
  43
  44     RELATIVE "views/versioncontrol"
  45     REQUIRED_HEADERS dolphinvcs_LIB_HEADERS
  46 )
  47
  48 install(TARGETS dolphinvcs EXPORT DolphinVcsTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
  49
  50 install(FILES views/versioncontrol/fileviewversioncontrolplugin.desktop DESTINATION ${KDE_INSTALL_KSERVICETYPES5DIR})
  51 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphin_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
  52 install(FILES ${dolphinvcs_LIB_HEADERS} DESTINATION "${KDE_INSTALL_INCLUDEDIR}/Dolphin" COMPONENT Devel)
  53
  54 ########### next target ###############
  55
  56 set(dolphinprivate_LIB_SRCS
  57     kitemviews/kfileitemlistview.cpp
  58     kitemviews/kfileitemlistwidget.cpp
  59     kitemviews/kfileitemmodel.cpp
  60     kitemviews/kfileitemmodelrolesupdater.cpp
  61     kitemviews/kitemlistcontainer.cpp
  62     kitemviews/kitemlistcontroller.cpp
  63     kitemviews/kitemlistgroupheader.cpp
  64     kitemviews/kitemlistheader.cpp
  65     kitemviews/kitemlistselectionmanager.cpp
  66     kitemviews/kitemliststyleoption.cpp
  67     kitemviews/kitemlistview.cpp
  68     kitemviews/kitemlistviewaccessible.cpp
  69     kitemviews/kitemlistwidget.cpp
  70     kitemviews/kitemmodelbase.cpp
  71     kitemviews/kitemset.cpp
  72     kitemviews/kstandarditem.cpp
  73     kitemviews/kstandarditemlistgroupheader.cpp
  74     kitemviews/kstandarditemlistwidget.cpp
  75     kitemviews/kstandarditemlistview.cpp
  76     kitemviews/kstandarditemmodel.cpp
  77     kitemviews/private/kdirectorycontentscounter.cpp
  78     kitemviews/private/kdirectorycontentscounterworker.cpp
  79     kitemviews/private/kfileitemclipboard.cpp
  80     kitemviews/private/kfileitemmodeldirlister.cpp
  81     kitemviews/private/kfileitemmodelfilter.cpp
  82     kitemviews/private/kitemlistheaderwidget.cpp
  83     kitemviews/private/kitemlistkeyboardsearchmanager.cpp
  84     kitemviews/private/kitemlistroleeditor.cpp
  85     kitemviews/private/kitemlistrubberband.cpp
  86     kitemviews/private/kitemlistselectiontoggle.cpp
  87     kitemviews/private/kitemlistsizehintresolver.cpp
  88     kitemviews/private/kitemlistsmoothscroller.cpp
  89     kitemviews/private/kitemlistviewanimation.cpp
  90     kitemviews/private/kitemlistviewlayouter.cpp
  91     kitemviews/private/kpixmapmodifier.cpp
  92     settings/additionalinfodialog.cpp
  93     settings/applyviewpropsjob.cpp
  94     settings/viewmodes/viewmodesettings.cpp
  95     settings/viewpropertiesdialog.cpp
  96     settings/viewpropsprogressinfo.cpp
  97     views/dolphinfileitemlistwidget.cpp
  98     views/dolphinitemlistview.cpp
  99     views/dolphinnewfilemenuobserver.cpp
 100     views/dolphinremoteencoding.cpp
 101     views/dolphinview.cpp
 102     views/dolphinviewactionhandler.cpp
 103     views/draganddrophelper.cpp
 104     views/renamedialog.cpp
 105     views/tooltips/filemetadatatooltip.cpp
 106     views/tooltips/tooltipmanager.cpp
 107     views/versioncontrol/updateitemstatesthread.cpp
 108     views/versioncontrol/versioncontrolobserver.cpp
 109     views/viewmodecontroller.cpp
 110     views/viewproperties.cpp
 111     views/zoomlevelinfo.cpp
 112     dolphinremoveaction.cpp
 113     dolphinnewfilemenu.cpp
 114     dolphindebug.cpp
 115 )
 116
 117 if(HAVE_BALOO)
 118     set(dolphinprivate_LIB_SRCS
 119         ${dolphinprivate_LIB_SRCS}
 120         kitemviews/private/kbaloorolesprovider.cpp
 121     )
 122 endif()
 123
 124 kconfig_add_kcfg_files(dolphinprivate_LIB_SRCS GENERATE_MOC
 125     settings/dolphin_compactmodesettings.kcfgc
 126     settings/dolphin_directoryviewpropertysettings.kcfgc
 127     settings/dolphin_detailsmodesettings.kcfgc
 128     settings/dolphin_iconsmodesettings.kcfgc
 129     settings/dolphin_generalsettings.kcfgc
 130     settings/dolphin_versioncontrolsettings.kcfgc
 131 )
 132
 133 add_library(dolphinprivate ${dolphinprivate_LIB_SRCS})
 134
 135 target_link_libraries(
 136     dolphinprivate PUBLIC
 137     dolphinvcs
 138     Qt5::Gui
 139     KF5::Crash
 140     KF5::I18n
 141     KF5::IconThemes
 142     KF5::KIOCore
 143     KF5::KIOWidgets
 144     KF5::KIOFileWidgets
 145     KF5::Completion
 146     KF5::TextWidgets
 147     KF5::WindowSystem
 148     KF5::ConfigCore
 149     KF5::NewStuff
 150     KF5::Parts
 151 )
 152
 153 if(HAVE_BALOO)
 154     target_link_libraries(
 155         dolphinprivate PUBLIC
 156         KF5::FileMetaData
 157         KF5::Baloo
 158         KF5::BalooWidgets
 159     )
 160 else()
 161     target_link_libraries(
 162         dolphinprivate PUBLIC
 163         KF5::KDELibs4Support # for KFileMetaDataWidget
 164     )
 165 endif()
 166
 167 set_target_properties(dolphinprivate PROPERTIES
 168     VERSION ${DOLPHINPRIVATE_VERSION_STRING}
 169     SOVERSION ${DOLPHINPRIVATE_SOVERSION}
 170 )
 171
 172 install(TARGETS dolphinprivate ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} LIBRARY NAMELINK_SKIP)
 173
 174 ##########################################
 175
 176 set(dolphinpart_SRCS
 177    dolphinpart.cpp
 178    dolphinpart_ext.cpp
 179    dolphindebug.cpp
 180 )
 181
 182 add_library(dolphinpart MODULE ${dolphinpart_SRCS})
 183
 184 target_link_libraries(dolphinpart
 185     dolphinprivate
 186 )
 187
 188 install(TARGETS dolphinpart DESTINATION ${KDE_INSTALL_PLUGINDIR})
 189
 190 install(FILES dolphinpart.rc DESTINATION ${KDE_INSTALL_KXMLGUI5DIR}/dolphinpart)
 191 install(FILES dolphinpart.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR})
 192
 193 ##########################################
 194
 195 set(dolphin_SRCS
 196     dolphindockwidget.cpp
 197     dolphinmainwindow.cpp
 198     dolphinviewcontainer.cpp
 199     dolphincontextmenu.cpp
 200     dolphintabbar.cpp
 201     dolphinrecenttabsmenu.cpp
 202     dolphintabpage.cpp
 203     dolphintabwidget.cpp
 204     filterbar/filterbar.cpp
 205     main.cpp
 206     panels/information/filemetadataconfigurationdialog.cpp
 207     panels/information/informationpanel.cpp
 208     panels/information/informationpanelcontent.cpp
 209     panels/information/pixmapviewer.cpp
 210     panels/information/phononwidget.cpp
 211     panels/places/placespanel.cpp
 212     panels/places/placesitem.cpp
 213     panels/places/placesitemeditdialog.cpp
 214     panels/places/placesitemlistgroupheader.cpp
 215     panels/places/placesitemlistwidget.cpp
 216     panels/places/placesitemmodel.cpp
 217     panels/places/placesitemsignalhandler.cpp
 218     panels/places/placesview.cpp
 219     panels/panel.cpp
 220     panels/folders/foldersitemlistwidget.cpp
 221     panels/folders/treeviewcontextmenu.cpp
 222     panels/folders/folderspanel.cpp
 223     search/dolphinfacetswidget.cpp
 224     search/dolphinsearchbox.cpp
 225     settings/general/behaviorsettingspage.cpp
 226     settings/general/configurepreviewplugindialog.cpp
 227     settings/general/confirmationssettingspage.cpp
 228     settings/general/generalsettingspage.cpp
 229     settings/general/previewssettingspage.cpp
 230     settings/general/statusbarsettingspage.cpp
 231     settings/dolphinsettingsdialog.cpp
 232     settings/navigation/navigationsettingspage.cpp
 233     settings/services/servicessettingspage.cpp
 234     settings/settingspagebase.cpp
 235     settings/serviceitemdelegate.cpp
 236     settings/servicemodel.cpp
 237     settings/startup/startupsettingspage.cpp
 238     settings/trash/trashsettingspage.cpp
 239     settings/viewmodes/dolphinfontrequester.cpp
 240     settings/viewmodes/viewsettingspage.cpp
 241     settings/viewmodes/viewmodesettings.cpp
 242     settings/viewmodes/viewsettingstab.cpp
 243     statusbar/dolphinstatusbar.cpp
 244     statusbar/mountpointobserver.cpp
 245     statusbar/mountpointobservercache.cpp
 246     statusbar/spaceinfoobserver.cpp
 247     statusbar/statusbarspaceinfo.cpp
 248     views/zoomlevelinfo.cpp
 249     dolphindebug.cpp
 250     dbusinterface.cpp
 251     global.cpp
 252 )
 253
 254 kconfig_add_kcfg_files(dolphin_SRCS GENERATE_MOC
 255     panels/folders/dolphin_folderspanelsettings.kcfgc
 256     panels/information/dolphin_informationpanelsettings.kcfgc
 257     panels/places/dolphin_placespanelsettings.kcfgc
 258     settings/dolphin_compactmodesettings.kcfgc
 259     settings/dolphin_detailsmodesettings.kcfgc
 260     settings/dolphin_generalsettings.kcfgc
 261     settings/dolphin_iconsmodesettings.kcfgc
 262     search/dolphin_searchsettings.kcfgc
 263     settings/dolphin_versioncontrolsettings.kcfgc
 264 )
 265
 266 if(NOT WIN32)
 267    set(dolphin_SRCS ${dolphin_SRCS} panels/terminal/terminalpanel.cpp)
 268 endif()
 269
 270 # TODO Does anything replace kde4_add_app_icon ?
 271 #kde4_add_app_icon(dolphin_SRCS "${KDE4_ICON_INSTALL_DIR}/oxygen/*/apps/system-file-manager.png")
 272
 273 kf5_add_kdeinit_executable(dolphin ${dolphin_SRCS})
 274
 275 target_include_directories(kdeinit_dolphin PRIVATE ${PHONON_INCLUDES})
 276
 277 target_link_libraries(kdeinit_dolphin
 278     dolphinprivate
 279     KF5::Parts
 280     KF5::KCMUtils
 281     KF5::Solid
 282     KF5::CoreAddons
 283     KF5::DBusAddons
 284     KF5::Bookmarks
 285     KF5::Notifications
 286     Phonon::phonon4qt5
 287 )
 288
 289 if (KF5Activities_FOUND)
 290     target_link_libraries(
 291         kdeinit_dolphin
 292         KF5::Activities
 293     )
 294 endif()
 295
 296 include(DbusInterfaceMacros)
 297
 298 generate_and_install_dbus_interface(
 299     kdeinit_dolphin
 300     dbusinterface.h
 301     org.freedesktop.FileManager1.xml
 302     OPTIONS -a
 303 )
 304
 305 install(TARGETS kdeinit_dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 306 install(TARGETS dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 307
 308 ##########################################
 309
 310 set(kcm_dolphinviewmodes_PART_SRCS
 311     settings/kcm/kcmdolphinviewmodes.cpp
 312     settings/viewmodes/dolphinfontrequester.cpp
 313     settings/viewmodes/viewmodesettings.cpp
 314     settings/viewmodes/viewsettingstab.cpp
 315     views/zoomlevelinfo.cpp)
 316
 317 set(kcm_dolphinnavigation_PART_SRCS
 318     settings/kcm/kcmdolphinnavigation.cpp
 319     settings/navigation/navigationsettingspage.cpp
 320     settings/settingspagebase.cpp)
 321
 322 set(kcm_dolphinservices_PART_SRCS
 323     settings/kcm/kcmdolphinservices.cpp
 324     settings/services/servicessettingspage.cpp
 325     settings/settingspagebase.cpp
 326     settings/serviceitemdelegate.cpp
 327     settings/servicemodel.cpp)
 328
 329 set(kcm_dolphingeneral_PART_SRCS
 330     settings/kcm/kcmdolphingeneral.cpp
 331     settings/general/behaviorsettingspage.cpp
 332     settings/general/previewssettingspage.cpp
 333     settings/general/configurepreviewplugindialog.cpp
 334     settings/general/confirmationssettingspage.cpp
 335     settings/settingspagebase.cpp
 336     settings/serviceitemdelegate.cpp
 337     settings/servicemodel.cpp)
 338
 339 kconfig_add_kcfg_files(kcm_dolphinviewmodes_PART_SRCS
 340     settings/dolphin_compactmodesettings.kcfgc
 341     settings/dolphin_directoryviewpropertysettings.kcfgc
 342     settings/dolphin_detailsmodesettings.kcfgc
 343     settings/dolphin_iconsmodesettings.kcfgc
 344     settings/dolphin_generalsettings.kcfgc
 345     settings/dolphin_versioncontrolsettings.kcfgc
 346 )
 347
 348 kconfig_add_kcfg_files(kcm_dolphinnavigation_PART_SRCS
 349     settings/dolphin_generalsettings.kcfgc)
 350
 351 kconfig_add_kcfg_files(kcm_dolphinservices_PART_SRCS
 352     settings/dolphin_generalsettings.kcfgc
 353     settings/dolphin_versioncontrolsettings.kcfgc)
 354
 355 kconfig_add_kcfg_files(kcm_dolphingeneral_PART_SRCS
 356     settings/dolphin_generalsettings.kcfgc)
 357
 358 add_library(kcm_dolphinviewmodes MODULE ${kcm_dolphinviewmodes_PART_SRCS})
 359 add_library(kcm_dolphinnavigation MODULE ${kcm_dolphinnavigation_PART_SRCS})
 360 add_library(kcm_dolphinservices MODULE ${kcm_dolphinservices_PART_SRCS})
 361 add_library(kcm_dolphingeneral MODULE ${kcm_dolphingeneral_PART_SRCS})
 362
 363 target_link_libraries(kcm_dolphinviewmodes dolphinprivate)
 364 target_link_libraries(kcm_dolphinnavigation dolphinprivate)
 365 target_link_libraries(kcm_dolphinservices dolphinprivate)
 366 target_link_libraries(kcm_dolphingeneral dolphinprivate)
 367
 368 install(TARGETS kcm_dolphinviewmodes DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 369 install(TARGETS kcm_dolphinnavigation DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 370 install(TARGETS kcm_dolphinservices DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 371 install(TARGETS kcm_dolphingeneral DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 372
 373 ########### install files ###############
 374
 375 install( PROGRAMS org.kde.dolphin.desktop DESTINATION ${KDE_INSTALL_APPDIR} )
 376 install( FILES settings/dolphin_directoryviewpropertysettings.kcfg
 377                settings/dolphin_generalsettings.kcfg
 378                settings/dolphin_compactmodesettings.kcfg
 379                settings/dolphin_iconsmodesettings.kcfg
 380                settings/dolphin_detailsmodesettings.kcfg
 381                settings/dolphin_versioncontrolsettings.kcfg
 382          DESTINATION ${KDE_INSTALL_KCFGDIR} )
 383 install( FILES dolphinui.rc DESTINATION ${KDE_INSTALL_KXMLGUI5DIR}/dolphin )
 384 install( FILES org.kde.dolphin.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR} )
 385 install( FILES settings/kcm/kcmdolphinviewmodes.desktop DESTINATION
 386 ${KDE_INSTALL_KSERVICES5DIR} )
 387 install( FILES settings/kcm/kcmdolphinnavigation.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 388 install( FILES settings/kcm/kcmdolphinservices.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 389 install( FILES settings/kcm/kcmdolphingeneral.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 390 install( FILES settings/services/servicemenu.knsrc DESTINATION ${KDE_INSTALL_CONFDIR} )
 391 install( PROGRAMS settings/services/servicemenuinstallation DESTINATION ${KDE_INSTALL_BINDIR} )
 392 install( PROGRAMS settings/services/servicemenudeinstallation DESTINATION ${KDE_INSTALL_BINDIR} )
 393
 394 if(BUILD_TESTING)
 395     find_package(Qt5Test ${QT_MIN_VERSION} CONFIG REQUIRED)
 396     add_subdirectory(tests)
 397 endif()