src/CMakeLists.txt

   1 include(ECMAddAppIcon)
   2
   3 configure_file(config-baloo.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-baloo.h)
   4
   5 configure_file(config-dolphin.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-dolphin.h)
   6
   7 add_definitions(
   8     -DTRANSLATION_DOMAIN=\"dolphin\"
   9     -DQT_USE_FAST_CONCATENATION
  10     -DQT_USE_FAST_OPERATOR_PLUS
  11 )
  12 remove_definitions(
  13     -DQT_NO_CAST_FROM_BYTEARRAY
  14     -DQT_NO_URL_CAST_FROM_STRING
  15     -DQT_NO_SIGNALS_SLOTS_KEYWORDS
  16     -DQT_NO_CAST_FROM_ASCII
  17     -DQT_NO_CAST_TO_ASCII
  18 )
  19
  20 ##########################################
  21
  22 set(dolphinvcs_LIB_SRCS
  23     views/versioncontrol/kversioncontrolplugin.cpp
  24 )
  25
  26 add_library(dolphinvcs ${dolphinvcs_LIB_SRCS})
  27 generate_export_header(dolphinvcs BASE_NAME dolphinvcs)
  28
  29 target_link_libraries(
  30     dolphinvcs PUBLIC
  31     Qt5::Widgets
  32 )
  33
  34 set_target_properties(dolphinvcs PROPERTIES
  35     VERSION ${DOLPHINVCS_VERSION_STRING}
  36     SOVERSION ${DOLPHINVCS_SOVERSION}
  37     EXPORT_NAME DolphinVcs
  38 )
  39
  40 ecm_generate_headers(dolphinvcs_LIB_HEADERS
  41     HEADER_NAMES
  42     KVersionControlPlugin
  43
  44     RELATIVE "views/versioncontrol"
  45     REQUIRED_HEADERS dolphinvcs_LIB_HEADERS
  46 )
  47
  48 install(TARGETS dolphinvcs EXPORT DolphinVcsTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
  49
  50 install(FILES views/versioncontrol/fileviewversioncontrolplugin.desktop DESTINATION ${KDE_INSTALL_KSERVICETYPES5DIR})
  51 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphinvcs_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
  52 install(FILES ${dolphinvcs_LIB_HEADERS} DESTINATION "${KDE_INSTALL_INCLUDEDIR}/Dolphin" COMPONENT Devel)
  53
  54 ########### next target ###############
  55
  56 set(dolphinprivate_LIB_SRCS
  57     kitemviews/kfileitemlistview.cpp
  58     kitemviews/kfileitemlistwidget.cpp
  59     kitemviews/kfileitemmodel.cpp
  60     kitemviews/kfileitemmodelrolesupdater.cpp
  61     kitemviews/kitemlistcontainer.cpp
  62     kitemviews/kitemlistcontroller.cpp
  63     kitemviews/kitemlistgroupheader.cpp
  64     kitemviews/kitemlistheader.cpp
  65     kitemviews/kitemlistselectionmanager.cpp
  66     kitemviews/kitemliststyleoption.cpp
  67     kitemviews/kitemlistview.cpp
  68     kitemviews/kitemlistviewaccessible.cpp
  69     kitemviews/kitemlistwidget.cpp
  70     kitemviews/kitemmodelbase.cpp
  71     kitemviews/kitemset.cpp
  72     kitemviews/kstandarditem.cpp
  73     kitemviews/kstandarditemlistgroupheader.cpp
  74     kitemviews/kstandarditemlistwidget.cpp
  75     kitemviews/kstandarditemlistview.cpp
  76     kitemviews/kstandarditemmodel.cpp
  77     kitemviews/private/kdirectorycontentscounter.cpp
  78     kitemviews/private/kdirectorycontentscounterworker.cpp
  79     kitemviews/private/kfileitemclipboard.cpp
  80     kitemviews/private/kfileitemmodeldirlister.cpp
  81     kitemviews/private/kfileitemmodelfilter.cpp
  82     kitemviews/private/kitemlistheaderwidget.cpp
  83     kitemviews/private/kitemlistkeyboardsearchmanager.cpp
  84     kitemviews/private/kitemlistroleeditor.cpp
  85     kitemviews/private/kitemlistrubberband.cpp
  86     kitemviews/private/kitemlistselectiontoggle.cpp
  87     kitemviews/private/kitemlistsizehintresolver.cpp
  88     kitemviews/private/kitemlistsmoothscroller.cpp
  89     kitemviews/private/kitemlistviewanimation.cpp
  90     kitemviews/private/kitemlistviewlayouter.cpp
  91     kitemviews/private/kpixmapmodifier.cpp
  92     settings/additionalinfodialog.cpp
  93     settings/applyviewpropsjob.cpp
  94     settings/viewmodes/viewmodesettings.cpp
  95     settings/viewpropertiesdialog.cpp
  96     settings/viewpropsprogressinfo.cpp
  97     views/dolphinfileitemlistwidget.cpp
  98     views/dolphinitemlistview.cpp
  99     views/dolphinnewfilemenuobserver.cpp
 100     views/dolphinremoteencoding.cpp
 101     views/dolphinview.cpp
 102     views/dolphinviewactionhandler.cpp
 103     views/draganddrophelper.cpp
 104     views/renamedialog.cpp
 105     views/tooltips/dolphinfilemetadatawidget.cpp
 106     views/tooltips/tooltipmanager.cpp
 107     views/versioncontrol/updateitemstatesthread.cpp
 108     views/versioncontrol/versioncontrolobserver.cpp
 109     views/viewmodecontroller.cpp
 110     views/viewproperties.cpp
 111     views/zoomlevelinfo.cpp
 112     dolphinremoveaction.cpp
 113     dolphinnewfilemenu.cpp
 114     dolphindebug.cpp
 115 )
 116
 117 if(HAVE_BALOO)
 118     set(dolphinprivate_LIB_SRCS
 119         ${dolphinprivate_LIB_SRCS}
 120         kitemviews/private/kbaloorolesprovider.cpp
 121     )
 122 endif()
 123
 124 kconfig_add_kcfg_files(dolphinprivate_LIB_SRCS GENERATE_MOC
 125     settings/dolphin_compactmodesettings.kcfgc
 126     settings/dolphin_directoryviewpropertysettings.kcfgc
 127     settings/dolphin_detailsmodesettings.kcfgc
 128     settings/dolphin_iconsmodesettings.kcfgc
 129     settings/dolphin_generalsettings.kcfgc
 130     settings/dolphin_versioncontrolsettings.kcfgc
 131 )
 132
 133 add_library(dolphinprivate ${dolphinprivate_LIB_SRCS})
 134 generate_export_header(dolphinprivate BASE_NAME dolphin)
 135
 136 target_link_libraries(
 137     dolphinprivate PUBLIC
 138     dolphinvcs
 139     Qt5::Gui
 140     KF5::Crash
 141     KF5::I18n
 142     KF5::IconThemes
 143     KF5::KIOCore
 144     KF5::KIOWidgets
 145     KF5::KIOFileWidgets
 146     KF5::Completion
 147     KF5::TextWidgets
 148     KF5::ConfigCore
 149     KF5::NewStuff
 150     KF5::Parts
 151 )
 152
 153 if(HAVE_BALOO)
 154     target_link_libraries(
 155         dolphinprivate PUBLIC
 156         KF5::FileMetaData
 157         KF5::Baloo
 158         KF5::BalooWidgets
 159     )
 160 else()
 161     target_link_libraries(
 162         dolphinprivate PUBLIC
 163         KF5::KDELibs4Support # for KFileMetaDataWidget
 164     )
 165 endif()
 166
 167 set_target_properties(dolphinprivate PROPERTIES
 168     VERSION ${DOLPHINPRIVATE_VERSION_STRING}
 169     SOVERSION ${DOLPHINPRIVATE_SOVERSION}
 170 )
 171
 172 install(TARGETS dolphinprivate ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} LIBRARY NAMELINK_SKIP)
 173 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphin_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
 174
 175 ##########################################
 176
 177 set(dolphinpart_SRCS
 178    dolphinpart.cpp
 179    dolphinpart_ext.cpp
 180    dolphindebug.cpp
 181 )
 182
 183 add_library(dolphinpart MODULE ${dolphinpart_SRCS})
 184
 185 target_link_libraries(dolphinpart
 186     dolphinprivate
 187 )
 188
 189 install(TARGETS dolphinpart DESTINATION ${KDE_INSTALL_PLUGINDIR})
 190
 191 install(FILES dolphinpart.rc DESTINATION ${KDE_INSTALL_KXMLGUI5DIR}/dolphinpart)
 192 install(FILES dolphinpart.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR})
 193
 194 ##########################################
 195
 196 set(dolphin_SRCS
 197     dolphindockwidget.cpp
 198     dolphinmainwindow.cpp
 199     dolphinviewcontainer.cpp
 200     dolphincontextmenu.cpp
 201     dolphintabbar.cpp
 202     dolphinrecenttabsmenu.cpp
 203     dolphintabpage.cpp
 204     dolphintabwidget.cpp
 205     filterbar/filterbar.cpp
 206     main.cpp
 207     panels/information/filemetadataconfigurationdialog.cpp
 208     panels/information/informationpanel.cpp
 209     panels/information/informationpanelcontent.cpp
 210     panels/information/pixmapviewer.cpp
 211     panels/information/phononwidget.cpp
 212     panels/places/placespanel.cpp
 213     panels/places/placesitem.cpp
 214     panels/places/placesitemeditdialog.cpp
 215     panels/places/placesitemlistgroupheader.cpp
 216     panels/places/placesitemlistwidget.cpp
 217     panels/places/placesitemmodel.cpp
 218     panels/places/placesitemsignalhandler.cpp
 219     panels/places/placesview.cpp
 220     panels/panel.cpp
 221     panels/folders/foldersitemlistwidget.cpp
 222     panels/folders/treeviewcontextmenu.cpp
 223     panels/folders/folderspanel.cpp
 224     search/dolphinfacetswidget.cpp
 225     search/dolphinsearchbox.cpp
 226     settings/general/behaviorsettingspage.cpp
 227     settings/general/configurepreviewplugindialog.cpp
 228     settings/general/confirmationssettingspage.cpp
 229     settings/general/generalsettingspage.cpp
 230     settings/general/previewssettingspage.cpp
 231     settings/general/statusbarsettingspage.cpp
 232     settings/dolphinsettingsdialog.cpp
 233     settings/navigation/navigationsettingspage.cpp
 234     settings/services/servicessettingspage.cpp
 235     settings/settingspagebase.cpp
 236     settings/serviceitemdelegate.cpp
 237     settings/servicemodel.cpp
 238     settings/startup/startupsettingspage.cpp
 239     settings/trash/trashsettingspage.cpp
 240     settings/viewmodes/dolphinfontrequester.cpp
 241     settings/viewmodes/viewsettingspage.cpp
 242     settings/viewmodes/viewmodesettings.cpp
 243     settings/viewmodes/viewsettingstab.cpp
 244     statusbar/dolphinstatusbar.cpp
 245     statusbar/mountpointobserver.cpp
 246     statusbar/mountpointobservercache.cpp
 247     statusbar/spaceinfoobserver.cpp
 248     statusbar/statusbarspaceinfo.cpp
 249     views/zoomlevelinfo.cpp
 250     dolphindebug.cpp
 251     dbusinterface.cpp
 252     global.cpp
 253 )
 254
 255 kconfig_add_kcfg_files(dolphin_SRCS GENERATE_MOC
 256     panels/folders/dolphin_folderspanelsettings.kcfgc
 257     panels/information/dolphin_informationpanelsettings.kcfgc
 258     panels/places/dolphin_placespanelsettings.kcfgc
 259     settings/dolphin_compactmodesettings.kcfgc
 260     settings/dolphin_detailsmodesettings.kcfgc
 261     settings/dolphin_generalsettings.kcfgc
 262     settings/dolphin_iconsmodesettings.kcfgc
 263     search/dolphin_searchsettings.kcfgc
 264     settings/dolphin_versioncontrolsettings.kcfgc
 265 )
 266
 267 if(NOT WIN32)
 268    set(dolphin_SRCS ${dolphin_SRCS} panels/terminal/terminalpanel.cpp)
 269 endif()
 270
 271 # Sets the icon on Windows and OSX
 272 file(GLOB ICONS_SRCS "${CMAKE_CURRENT_SOURCE_DIR}/icons/*system-file-manager.png")
 273 ecm_add_app_icon(dolphin_SRCS ICONS ${ICONS_SRCS})
 274
 275 kf5_add_kdeinit_executable(dolphin ${dolphin_SRCS})
 276
 277 target_include_directories(kdeinit_dolphin PRIVATE ${PHONON_INCLUDES})
 278
 279 target_link_libraries(kdeinit_dolphin
 280     dolphinprivate
 281     KF5::Parts
 282     KF5::KCMUtils
 283     KF5::Solid
 284     KF5::CoreAddons
 285     KF5::DBusAddons
 286     KF5::Bookmarks
 287     KF5::Notifications
 288     Phonon::phonon4qt5
 289 )
 290
 291 if (KF5Activities_FOUND)
 292     target_link_libraries(
 293         kdeinit_dolphin
 294         KF5::Activities
 295     )
 296 endif()
 297
 298 include(DbusInterfaceMacros)
 299
 300 generate_and_install_dbus_interface(
 301     kdeinit_dolphin
 302     dbusinterface.h
 303     org.freedesktop.FileManager1.xml
 304     OPTIONS -a
 305 )
 306
 307 install(TARGETS kdeinit_dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 308 install(TARGETS dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 309
 310 ##########################################
 311
 312 set(kcm_dolphinviewmodes_PART_SRCS
 313     settings/kcm/kcmdolphinviewmodes.cpp
 314     settings/viewmodes/dolphinfontrequester.cpp
 315     settings/viewmodes/viewmodesettings.cpp
 316     settings/viewmodes/viewsettingstab.cpp
 317     views/zoomlevelinfo.cpp)
 318
 319 set(kcm_dolphinnavigation_PART_SRCS
 320     settings/kcm/kcmdolphinnavigation.cpp
 321     settings/navigation/navigationsettingspage.cpp
 322     settings/settingspagebase.cpp)
 323
 324 set(kcm_dolphinservices_PART_SRCS
 325     settings/kcm/kcmdolphinservices.cpp
 326     settings/services/servicessettingspage.cpp
 327     settings/settingspagebase.cpp
 328     settings/serviceitemdelegate.cpp
 329     settings/servicemodel.cpp)
 330
 331 set(kcm_dolphingeneral_PART_SRCS
 332     settings/kcm/kcmdolphingeneral.cpp
 333     settings/general/behaviorsettingspage.cpp
 334     settings/general/previewssettingspage.cpp
 335     settings/general/configurepreviewplugindialog.cpp
 336     settings/general/confirmationssettingspage.cpp
 337     settings/settingspagebase.cpp
 338     settings/serviceitemdelegate.cpp
 339     settings/servicemodel.cpp)
 340
 341 kconfig_add_kcfg_files(kcm_dolphinviewmodes_PART_SRCS
 342     settings/dolphin_compactmodesettings.kcfgc
 343     settings/dolphin_directoryviewpropertysettings.kcfgc
 344     settings/dolphin_detailsmodesettings.kcfgc
 345     settings/dolphin_iconsmodesettings.kcfgc
 346     settings/dolphin_generalsettings.kcfgc
 347     settings/dolphin_versioncontrolsettings.kcfgc
 348 )
 349
 350 kconfig_add_kcfg_files(kcm_dolphinnavigation_PART_SRCS
 351     settings/dolphin_generalsettings.kcfgc)
 352
 353 kconfig_add_kcfg_files(kcm_dolphinservices_PART_SRCS
 354     settings/dolphin_generalsettings.kcfgc
 355     settings/dolphin_versioncontrolsettings.kcfgc)
 356
 357 kconfig_add_kcfg_files(kcm_dolphingeneral_PART_SRCS
 358     settings/dolphin_generalsettings.kcfgc)
 359
 360 add_library(kcm_dolphinviewmodes MODULE ${kcm_dolphinviewmodes_PART_SRCS})
 361 add_library(kcm_dolphinnavigation MODULE ${kcm_dolphinnavigation_PART_SRCS})
 362 add_library(kcm_dolphinservices MODULE ${kcm_dolphinservices_PART_SRCS})
 363 add_library(kcm_dolphingeneral MODULE ${kcm_dolphingeneral_PART_SRCS})
 364
 365 target_link_libraries(kcm_dolphinviewmodes dolphinprivate)
 366 target_link_libraries(kcm_dolphinnavigation dolphinprivate)
 367 target_link_libraries(kcm_dolphinservices dolphinprivate)
 368 target_link_libraries(kcm_dolphingeneral dolphinprivate)
 369
 370 install(TARGETS kcm_dolphinviewmodes DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 371 install(TARGETS kcm_dolphinnavigation DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 372 install(TARGETS kcm_dolphinservices DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 373 install(TARGETS kcm_dolphingeneral DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 374
 375 ########### install files ###############
 376
 377 install( PROGRAMS org.kde.dolphin.desktop DESTINATION ${KDE_INSTALL_APPDIR} )
 378 install( FILES settings/dolphin_directoryviewpropertysettings.kcfg
 379                settings/dolphin_generalsettings.kcfg
 380                settings/dolphin_compactmodesettings.kcfg
 381                settings/dolphin_iconsmodesettings.kcfg
 382                settings/dolphin_detailsmodesettings.kcfg
 383                settings/dolphin_versioncontrolsettings.kcfg
 384          DESTINATION ${KDE_INSTALL_KCFGDIR} )
 385 install( FILES dolphinui.rc DESTINATION ${KDE_INSTALL_KXMLGUI5DIR}/dolphin )
 386 install( FILES org.kde.dolphin.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR} )
 387 install( FILES settings/kcm/kcmdolphinviewmodes.desktop DESTINATION
 388 ${KDE_INSTALL_KSERVICES5DIR} )
 389 install( FILES settings/kcm/kcmdolphinnavigation.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 390 install( FILES settings/kcm/kcmdolphinservices.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 391 install( FILES settings/kcm/kcmdolphingeneral.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 392 install( FILES settings/services/servicemenu.knsrc DESTINATION ${KDE_INSTALL_CONFDIR} )
 393 install( PROGRAMS settings/services/servicemenuinstallation DESTINATION ${KDE_INSTALL_BINDIR} )
 394 install( PROGRAMS settings/services/servicemenudeinstallation DESTINATION ${KDE_INSTALL_BINDIR} )
 395
 396 if(BUILD_TESTING)
 397     find_package(Qt5Test ${QT_MIN_VERSION} CONFIG REQUIRED)
 398     add_subdirectory(tests)
 399 endif()