src/CMakeLists.txt

   1 include(ECMAddAppIcon)
   2
   3 configure_file(config-baloo.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-baloo.h)
   4
   5 configure_file(config-kactivities.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-kactivities.h)
   6
   7 configure_file(config-packagekit.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-packagekit.h)
   8
   9 configure_file(config-terminal.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-terminal.h)
  10
  11 configure_file(config-kuserfeedback.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-kuserfeedback.h)
  12
  13 add_definitions(
  14     -DTRANSLATION_DOMAIN=\"dolphin\"
  15 )
  16 remove_definitions(
  17     -DQT_NO_CAST_FROM_BYTEARRAY
  18     -DQT_NO_CAST_FROM_ASCII
  19     -DQT_NO_CAST_TO_ASCII
  20 )
  21
  22 ##########################################
  23
  24 add_library(dolphinvcs SHARED)
  25
  26 target_sources(dolphinvcs PRIVATE
  27     views/versioncontrol/kversioncontrolplugin.cpp
  28 )
  29
  30 generate_export_header(dolphinvcs BASE_NAME dolphinvcs)
  31
  32 target_link_libraries(
  33     dolphinvcs PUBLIC
  34     Qt${QT_MAJOR_VERSION}::Widgets
  35 )
  36
  37 set_target_properties(dolphinvcs PROPERTIES
  38     VERSION ${DOLPHINVCS_VERSION}
  39     SOVERSION ${DOLPHINVCS_SOVERSION}
  40     EXPORT_NAME DolphinVcs
  41 )
  42
  43 ecm_generate_headers(dolphinvcs_LIB_HEADERS
  44     HEADER_NAMES
  45     KVersionControlPlugin
  46
  47     RELATIVE "views/versioncontrol"
  48     REQUIRED_HEADERS dolphinvcs_LIB_HEADERS
  49 )
  50
  51 install(TARGETS dolphinvcs EXPORT DolphinVcsTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
  52
  53 install(FILES views/versioncontrol/fileviewversioncontrolplugin.desktop DESTINATION ${KDE_INSTALL_KSERVICETYPESDIR})
  54 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphinvcs_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
  55 install(FILES ${dolphinvcs_LIB_HEADERS} DESTINATION "${KDE_INSTALL_INCLUDEDIR}/Dolphin" COMPONENT Devel)
  56
  57 ########### next target ###############
  58
  59 add_library(dolphinprivate SHARED)
  60
  61 target_sources(dolphinprivate PRIVATE
  62     kitemviews/kfileitemlistview.cpp
  63     kitemviews/kfileitemlistwidget.cpp
  64     kitemviews/kfileitemlisttostring.cpp
  65     kitemviews/kfileitemmodel.cpp
  66     kitemviews/kfileitemmodelrolesupdater.cpp
  67     kitemviews/kitemlistcontainer.cpp
  68     kitemviews/kitemlistcontroller.cpp
  69     kitemviews/kitemlistgroupheader.cpp
  70     kitemviews/kitemlistheader.cpp
  71     kitemviews/kitemlistselectionmanager.cpp
  72     kitemviews/kitemliststyleoption.cpp
  73     kitemviews/kitemlistview.cpp
  74     kitemviews/kitemlistviewaccessible.cpp
  75     kitemviews/kitemlistwidget.cpp
  76     kitemviews/kitemmodelbase.cpp
  77     kitemviews/kitemset.cpp
  78     kitemviews/kstandarditemlistgroupheader.cpp
  79     kitemviews/kstandarditemlistwidget.cpp
  80     kitemviews/kstandarditemlistview.cpp
  81     kitemviews/private/kdirectorycontentscounter.cpp
  82     kitemviews/private/kdirectorycontentscounterworker.cpp
  83     kitemviews/private/kfileitemclipboard.cpp
  84     kitemviews/private/kfileitemmodelfilter.cpp
  85     kitemviews/private/kitemlistheaderwidget.cpp
  86     kitemviews/private/kitemlistkeyboardsearchmanager.cpp
  87     kitemviews/private/kitemlistroleeditor.cpp
  88     kitemviews/private/kitemlistrubberband.cpp
  89     kitemviews/private/kitemlistselectiontoggle.cpp
  90     kitemviews/private/kitemlistsizehintresolver.cpp
  91     kitemviews/private/kitemlistsmoothscroller.cpp
  92     kitemviews/private/kitemlistviewanimation.cpp
  93     kitemviews/private/kitemlistviewlayouter.cpp
  94     kitemviews/private/kpixmapmodifier.cpp
  95     kitemviews/private/ktwofingerswipe.cpp
  96     kitemviews/private/ktwofingertap.cpp
  97     settings/applyviewpropsjob.cpp
  98     settings/viewmodes/viewmodesettings.cpp
  99     settings/viewpropertiesdialog.cpp
 100     settings/viewpropsprogressinfo.cpp
 101     views/dolphinfileitemlistwidget.cpp
 102     views/dolphinitemlistview.cpp
 103     views/dolphinnewfilemenuobserver.cpp
 104     views/dolphinremoteencoding.cpp
 105     views/dolphinview.cpp
 106     views/dolphinviewactionhandler.cpp
 107     views/draganddrophelper.cpp
 108     views/versioncontrol/updateitemstatesthread.cpp
 109     views/versioncontrol/versioncontrolobserver.cpp
 110     views/viewmodecontroller.cpp
 111     views/viewproperties.cpp
 112     views/zoomlevelinfo.cpp
 113     dolphinremoveaction.cpp
 114     middleclickactioneventfilter.cpp
 115     dolphinnewfilemenu.cpp
 116 )
 117
 118 ecm_qt_declare_logging_category(dolphinprivate
 119     HEADER dolphindebug.h
 120     IDENTIFIER DolphinDebug
 121     CATEGORY_NAME org.kde.dolphin
 122     DESCRIPTION "dolphin"
 123     EXPORT DOLPHIN
 124 )
 125
 126 if(HAVE_BALOO)
 127     target_sources(dolphinprivate PRIVATE
 128         views/tooltips/dolphinfilemetadatawidget.cpp
 129         views/tooltips/tooltipmanager.cpp
 130         kitemviews/private/kbaloorolesprovider.cpp
 131     )
 132 endif()
 133
 134 kconfig_add_kcfg_files(dolphinprivate
 135     settings/dolphin_compactmodesettings.kcfgc
 136     settings/dolphin_directoryviewpropertysettings.kcfgc
 137     settings/dolphin_detailsmodesettings.kcfgc
 138     settings/dolphin_iconsmodesettings.kcfgc
 139     settings/dolphin_generalsettings.kcfgc
 140     settings/dolphin_contextmenusettings.kcfgc
 141     settings/dolphin_versioncontrolsettings.kcfgc
 142 )
 143
 144 generate_export_header(dolphinprivate BASE_NAME dolphin)
 145
 146 target_link_libraries(
 147     dolphinprivate PUBLIC
 148     dolphinvcs
 149     Qt${QT_MAJOR_VERSION}::Concurrent
 150     Qt${QT_MAJOR_VERSION}::Gui
 151     KF5::I18n
 152     KF5::IconThemes
 153     KF5::KIOCore
 154     KF5::KIOWidgets
 155     KF5::KIOFileWidgets
 156     KF5::Completion
 157     KF5::TextWidgets
 158     KF5::ConfigCore
 159     KF5::NewStuff
 160     KF5::Parts
 161     KF5::WindowSystem
 162 )
 163
 164 if(HAVE_BALOO)
 165     target_link_libraries(
 166         dolphinprivate PUBLIC
 167         KF5::FileMetaData
 168         KF5::Baloo
 169         KF5::BalooWidgets
 170     )
 171 endif()
 172
 173 set_target_properties(dolphinprivate PROPERTIES
 174     VERSION ${DOLPHINPRIVATE_VERSION}
 175     SOVERSION ${DOLPHINPRIVATE_SOVERSION}
 176 )
 177
 178 install(TARGETS dolphinprivate ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} LIBRARY NAMELINK_SKIP)
 179 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphin_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
 180
 181 ##########################################
 182 configure_file(dolphinpart.desktop.in ${CMAKE_CURRENT_BINARY_DIR}/dolphinpart.desktop @ONLY)
 183
 184 add_library(dolphinpart MODULE)
 185
 186 target_sources(dolphinpart PRIVATE
 187     dolphinpart.cpp
 188     dolphinpart_ext.cpp
 189     dolphindebug.cpp
 190
 191     dolphinpart.qrc
 192 )
 193
 194 kcoreaddons_desktop_to_json(dolphinpart ${CMAKE_CURRENT_BINARY_DIR}/dolphinpart.desktop)
 195
 196 target_link_libraries(dolphinpart
 197     dolphinprivate
 198 )
 199
 200 install(TARGETS dolphinpart DESTINATION ${KDE_INSTALL_PLUGINDIR}/kf5/parts)
 201
 202 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphinpart.desktop DESTINATION ${KDE_INSTALL_KSERVICESDIR})
 203
 204 ##########################################
 205
 206 add_library(dolphinstatic STATIC)
 207
 208 target_sources(dolphinstatic PRIVATE
 209     dolphinbookmarkhandler.cpp
 210     dolphindockwidget.cpp
 211     dolphinmainwindow.cpp
 212     dolphinviewcontainer.cpp
 213     dolphincontextmenu.cpp
 214     dolphinnavigatorswidgetaction.cpp
 215     dolphintabbar.cpp
 216     dolphinplacesmodelsingleton.cpp
 217     dolphinrecenttabsmenu.cpp
 218     dolphintabpage.cpp
 219     dolphintabwidget.cpp
 220     dolphinurlnavigator.cpp
 221     dolphinurlnavigatorscontroller.cpp
 222     trash/dolphintrash.cpp
 223     filterbar/filterbar.cpp
 224     panels/places/placespanel.cpp
 225     panels/panel.cpp
 226     panels/folders/foldersitemlistwidget.cpp
 227     panels/folders/treeviewcontextmenu.cpp
 228     panels/folders/folderspanel.cpp
 229     panels/terminal/terminalpanel.cpp
 230     search/dolphinfacetswidget.cpp
 231     search/dolphinquery.cpp
 232     search/dolphinsearchbox.cpp
 233     settings/general/behaviorsettingspage.cpp
 234     settings/general/configurepreviewplugindialog.cpp
 235     settings/general/confirmationssettingspage.cpp
 236     settings/general/generalsettingspage.cpp
 237     settings/general/previewssettingspage.cpp
 238     settings/general/statusbarsettingspage.cpp
 239     settings/dolphinsettingsdialog.cpp
 240     settings/navigation/navigationsettingspage.cpp
 241     settings/contextmenu/contextmenusettingspage.cpp
 242     settings/settingspagebase.cpp
 243     settings/serviceitemdelegate.cpp
 244     settings/servicemodel.cpp
 245     settings/startup/startupsettingspage.cpp
 246     settings/trash/trashsettingspage.cpp
 247     settings/viewmodes/dolphinfontrequester.cpp
 248     settings/viewmodes/viewsettingspage.cpp
 249     settings/viewmodes/viewmodesettings.cpp
 250     settings/viewmodes/viewsettingstab.cpp
 251     statusbar/dolphinstatusbar.cpp
 252     statusbar/mountpointobserver.cpp
 253     statusbar/mountpointobservercache.cpp
 254     statusbar/spaceinfoobserver.cpp
 255     statusbar/statusbarspaceinfo.cpp
 256     views/zoomlevelinfo.cpp
 257     dolphindebug.cpp
 258     global.cpp
 259     dolphin.qrc
 260 )
 261
 262 if(HAVE_BALOO)
 263     target_sources(dolphinstatic PRIVATE
 264         panels/information/informationpanel.cpp
 265         panels/information/informationpanelcontent.cpp
 266         panels/information/pixmapviewer.cpp
 267         panels/information/phononwidget.cpp
 268     )
 269 endif()
 270
 271 if(HAVE_KUSERFEEDBACK)
 272     target_sources(dolphinstatic PRIVATE
 273         userfeedback/dolphinfeedbackprovider.cpp
 274         userfeedback/settingsdatasource.cpp
 275         userfeedback/placesdatasource.cpp
 276         settings/userfeedback/userfeedbacksettingspage.cpp
 277     )
 278 endif()
 279
 280 kconfig_add_kcfg_files(dolphinstatic
 281     panels/folders/dolphin_folderspanelsettings.kcfgc
 282     panels/information/dolphin_informationpanelsettings.kcfgc
 283     panels/places/dolphin_placespanelsettings.kcfgc
 284     settings/dolphin_compactmodesettings.kcfgc
 285     settings/dolphin_detailsmodesettings.kcfgc
 286     settings/dolphin_contextmenusettings.kcfgc
 287     settings/dolphin_iconsmodesettings.kcfgc
 288     search/dolphin_searchsettings.kcfgc
 289     settings/dolphin_versioncontrolsettings.kcfgc
 290 )
 291 kconfig_add_kcfg_files(dolphinstatic GENERATE_MOC
 292     settings/dolphin_generalsettings.kcfgc
 293 )
 294
 295 qt_generate_dbus_interface(${CMAKE_CURRENT_SOURCE_DIR}/dolphinmainwindow.h org.kde.DolphinMainWindow.xml)
 296 qt_add_dbus_adaptor(dolphin_dbus_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindow.h DolphinMainWindow)
 297 qt_add_dbus_interface(dolphin_dbus_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindowinterface)
 298 qt_add_dbus_interface(dolphin_dbus_SRCS panels/terminal/org.kde.KIOFuse.VFS.xml kiofuse_interface)
 299
 300 target_sources(dolphinstatic PRIVATE
 301     ${dolphin_dbus_SRCS}
 302 )
 303
 304 target_include_directories(dolphinstatic SYSTEM PRIVATE ${PHONON_INCLUDES})
 305 target_link_libraries(dolphinstatic
 306     dolphinprivate
 307     KF5::CoreAddons
 308     KF5::KCMUtils
 309     KF5::DBusAddons
 310     KF5::Notifications
 311     Phonon::phonon4qt${QT_MAJOR_VERSION}
 312 )
 313
 314 if (HAVE_KACTIVITIES)
 315     target_link_libraries(
 316         dolphinstatic
 317         KF5::Activities
 318     )
 319 endif()
 320
 321 if (HAVE_KUSERFEEDBACK)
 322     target_link_libraries(
 323         dolphinstatic
 324         KUserFeedbackCore
 325         KUserFeedbackWidgets
 326     )
 327 endif()
 328
 329 add_executable(dolphin)
 330
 331 target_sources(dolphin PRIVATE
 332     dbusinterface.cpp
 333     main.cpp
 334 )
 335
 336 if(FLATPAK)
 337     target_compile_definitions(dolphin PRIVATE FLATPAK)
 338 endif()
 339
 340 # Sets the icon on Windows and OSX
 341 file(GLOB ICONS_SRCS "${CMAKE_CURRENT_SOURCE_DIR}/icons/*system-file-manager.png")
 342 ecm_add_app_icon(dolphin ICONS ${ICONS_SRCS})
 343
 344 target_link_libraries(dolphin
 345     PRIVATE
 346     dolphinprivate
 347     dolphinstatic
 348     KF5::Crash
 349 )
 350
 351 include(DbusInterfaceMacros)
 352
 353 generate_and_install_dbus_interface(
 354     dolphin
 355     dbusinterface.h
 356     org.freedesktop.FileManager1.xml
 357     OPTIONS -a
 358 )
 359
 360 install(TARGETS dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 361
 362 ##########################################
 363
 364 if(NOT WIN32)
 365     # The settings are still accessible from the hamburger menu
 366     add_library(kcm_dolphinviewmodes)
 367     kcoreaddons_desktop_to_json(kcm_dolphinviewmodes settings/kcm/kcmdolphinviewmodes.desktop)
 368     add_library(kcm_dolphinnavigation)
 369     kcoreaddons_desktop_to_json(kcm_dolphinnavigation settings/kcm/kcmdolphinnavigation.desktop)
 370     add_library(kcm_dolphingeneral)
 371     kcoreaddons_desktop_to_json(kcm_dolphingeneral settings/kcm/kcmdolphingeneral.desktop)
 372
 373     target_sources(kcm_dolphinviewmodes PRIVATE
 374         settings/kcm/kcmdolphinviewmodes.cpp
 375         settings/viewmodes/dolphinfontrequester.cpp
 376         settings/viewmodes/viewmodesettings.cpp
 377         settings/viewmodes/viewsettingstab.cpp
 378         views/zoomlevelinfo.cpp)
 379
 380     target_sources(kcm_dolphinnavigation PRIVATE
 381         settings/kcm/kcmdolphinnavigation.cpp
 382         settings/navigation/navigationsettingspage.cpp
 383         settings/settingspagebase.cpp)
 384
 385     target_sources(kcm_dolphingeneral PRIVATE
 386         settings/kcm/kcmdolphingeneral.cpp
 387         settings/general/behaviorsettingspage.cpp
 388         settings/general/previewssettingspage.cpp
 389         settings/general/configurepreviewplugindialog.cpp
 390         settings/general/confirmationssettingspage.cpp
 391         settings/settingspagebase.cpp
 392         settings/serviceitemdelegate.cpp
 393         settings/servicemodel.cpp)
 394
 395     kconfig_add_kcfg_files(kcm_dolphinviewmodes
 396         settings/dolphin_compactmodesettings.kcfgc
 397         settings/dolphin_directoryviewpropertysettings.kcfgc
 398         settings/dolphin_detailsmodesettings.kcfgc
 399         settings/dolphin_iconsmodesettings.kcfgc
 400         settings/dolphin_generalsettings.kcfgc
 401         settings/dolphin_versioncontrolsettings.kcfgc
 402     )
 403
 404     kconfig_add_kcfg_files(kcm_dolphinnavigation
 405         settings/dolphin_generalsettings.kcfgc)
 406
 407     kconfig_add_kcfg_files(kcm_dolphingeneral
 408         settings/dolphin_generalsettings.kcfgc)
 409
 410     target_link_libraries(kcm_dolphinviewmodes dolphinprivate)
 411     target_link_libraries(kcm_dolphinnavigation dolphinprivate)
 412     target_link_libraries(kcm_dolphingeneral dolphinprivate)
 413
 414     install( FILES org.kde.dolphin.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR} )
 415     install( FILES settings/kcm/kcmdolphinviewmodes.desktop DESTINATION ${KDE_INSTALL_KSERVICESDIR} )
 416     install( FILES settings/kcm/kcmdolphinnavigation.desktop DESTINATION ${KDE_INSTALL_KSERVICESDIR} )
 417     install( FILES settings/kcm/kcmdolphingeneral.desktop DESTINATION ${KDE_INSTALL_KSERVICESDIR} )
 418
 419     install(TARGETS kcm_dolphinviewmodes DESTINATION ${KDE_INSTALL_PLUGINDIR}/dolphin/kcms )
 420     install(TARGETS kcm_dolphinnavigation DESTINATION ${KDE_INSTALL_PLUGINDIR}/dolphin/kcms )
 421     install(TARGETS kcm_dolphingeneral DESTINATION ${KDE_INSTALL_PLUGINDIR}/dolphin/kcms )
 422 endif()
 423
 424 if(NOT WIN32)
 425     add_subdirectory(settings/contextmenu/servicemenuinstaller)
 426     install( FILES settings/contextmenu/servicemenu.knsrc DESTINATION ${KDE_INSTALL_KNSRCDIR} )
 427 endif()
 428
 429 ########### install files ###############
 430
 431 install( PROGRAMS org.kde.dolphin.desktop DESTINATION ${KDE_INSTALL_APPDIR} )
 432
 433 install( DIRECTORY DESTINATION "${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel" )
 434
 435 install(
 436     CODE "execute_process(COMMAND \"${CMAKE_COMMAND}\" -E create_symlink \"${KDE_INSTALL_FULL_APPDIR}/org.kde.dolphin.desktop\" \"\$ENV{DESTDIR}${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel/org.kde.dolphin.desktop\")"
 437 )
 438
 439 install( FILES settings/dolphin_directoryviewpropertysettings.kcfg
 440                settings/dolphin_generalsettings.kcfg
 441                settings/dolphin_contextmenusettings.kcfg
 442                settings/dolphin_compactmodesettings.kcfg
 443                settings/dolphin_iconsmodesettings.kcfg
 444                settings/dolphin_detailsmodesettings.kcfg
 445                settings/dolphin_versioncontrolsettings.kcfg
 446          DESTINATION ${KDE_INSTALL_KCFGDIR} )
 447
 448 if(BUILD_TESTING)
 449     add_subdirectory(tests)
 450 endif()