src/CMakeLists.txt

   1 include(ECMAddAppIcon)
   2
   3 configure_file(config-baloo.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-baloo.h)
   4
   5 configure_file(config-kactivities.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-kactivities.h)
   6
   7 configure_file(config-packagekit.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-packagekit.h)
   8
   9 configure_file(config-terminal.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-terminal.h)
  10
  11 configure_file(config-kuserfeedback.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-kuserfeedback.h)
  12
  13 add_definitions(
  14     -DTRANSLATION_DOMAIN=\"dolphin\"
  15 )
  16 remove_definitions(
  17     -DQT_NO_CAST_FROM_BYTEARRAY
  18     -DQT_NO_SIGNALS_SLOTS_KEYWORDS
  19     -DQT_NO_CAST_FROM_ASCII
  20     -DQT_NO_CAST_TO_ASCII
  21     -DQT_NO_FOREACH
  22     -DQT_NO_KEYWORDS
  23 )
  24
  25 ##########################################
  26
  27 set(dolphinvcs_LIB_SRCS
  28     views/versioncontrol/kversioncontrolplugin.cpp
  29 )
  30
  31 add_library(dolphinvcs ${dolphinvcs_LIB_SRCS})
  32 generate_export_header(dolphinvcs BASE_NAME dolphinvcs)
  33
  34 target_link_libraries(
  35     dolphinvcs PUBLIC
  36     Qt5::Widgets
  37 )
  38
  39 set_target_properties(dolphinvcs PROPERTIES
  40     VERSION ${DOLPHINVCS_VERSION_STRING}
  41     SOVERSION ${DOLPHINVCS_SOVERSION}
  42     EXPORT_NAME DolphinVcs
  43 )
  44
  45 ecm_generate_headers(dolphinvcs_LIB_HEADERS
  46     HEADER_NAMES
  47     KVersionControlPlugin
  48
  49     RELATIVE "views/versioncontrol"
  50     REQUIRED_HEADERS dolphinvcs_LIB_HEADERS
  51 )
  52
  53 install(TARGETS dolphinvcs EXPORT DolphinVcsTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
  54
  55 install(FILES views/versioncontrol/fileviewversioncontrolplugin.desktop DESTINATION ${KDE_INSTALL_KSERVICETYPES5DIR})
  56 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphinvcs_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
  57 install(FILES ${dolphinvcs_LIB_HEADERS} DESTINATION "${KDE_INSTALL_INCLUDEDIR}/Dolphin" COMPONENT Devel)
  58
  59 ########### next target ###############
  60
  61 set(dolphinprivate_LIB_SRCS
  62     kitemviews/kfileitemlistview.cpp
  63     kitemviews/kfileitemlistwidget.cpp
  64     kitemviews/kfileitemmodel.cpp
  65     kitemviews/kfileitemmodelrolesupdater.cpp
  66     kitemviews/kitemlistcontainer.cpp
  67     kitemviews/kitemlistcontroller.cpp
  68     kitemviews/kitemlistgroupheader.cpp
  69     kitemviews/kitemlistheader.cpp
  70     kitemviews/kitemlistselectionmanager.cpp
  71     kitemviews/kitemliststyleoption.cpp
  72     kitemviews/kitemlistview.cpp
  73     kitemviews/kitemlistviewaccessible.cpp
  74     kitemviews/kitemlistwidget.cpp
  75     kitemviews/kitemmodelbase.cpp
  76     kitemviews/kitemset.cpp
  77     kitemviews/kstandarditem.cpp
  78     kitemviews/kstandarditemlistgroupheader.cpp
  79     kitemviews/kstandarditemlistwidget.cpp
  80     kitemviews/kstandarditemlistview.cpp
  81     kitemviews/kstandarditemmodel.cpp
  82     kitemviews/private/kdirectorycontentscounter.cpp
  83     kitemviews/private/kdirectorycontentscounterworker.cpp
  84     kitemviews/private/kfileitemclipboard.cpp
  85     kitemviews/private/kfileitemmodeldirlister.cpp
  86     kitemviews/private/kfileitemmodelfilter.cpp
  87     kitemviews/private/kitemlistheaderwidget.cpp
  88     kitemviews/private/kitemlistkeyboardsearchmanager.cpp
  89     kitemviews/private/kitemlistroleeditor.cpp
  90     kitemviews/private/kitemlistrubberband.cpp
  91     kitemviews/private/kitemlistselectiontoggle.cpp
  92     kitemviews/private/kitemlistsizehintresolver.cpp
  93     kitemviews/private/kitemlistsmoothscroller.cpp
  94     kitemviews/private/kitemlistviewanimation.cpp
  95     kitemviews/private/kitemlistviewlayouter.cpp
  96     kitemviews/private/kpixmapmodifier.cpp
  97     kitemviews/private/ktwofingerswipe.cpp
  98     kitemviews/private/ktwofingertap.cpp
  99     settings/applyviewpropsjob.cpp
 100     settings/viewmodes/viewmodesettings.cpp
 101     settings/viewpropertiesdialog.cpp
 102     settings/viewpropsprogressinfo.cpp
 103     views/dolphinfileitemlistwidget.cpp
 104     views/dolphinitemlistview.cpp
 105     views/dolphinnewfilemenuobserver.cpp
 106     views/dolphinremoteencoding.cpp
 107     views/dolphinview.cpp
 108     views/dolphinviewactionhandler.cpp
 109     views/draganddrophelper.cpp
 110     views/versioncontrol/updateitemstatesthread.cpp
 111     views/versioncontrol/versioncontrolobserver.cpp
 112     views/viewmodecontroller.cpp
 113     views/viewproperties.cpp
 114     views/zoomlevelinfo.cpp
 115     dolphinremoveaction.cpp
 116     middleclickactioneventfilter.cpp
 117     dolphinnewfilemenu.cpp
 118 )
 119
 120 ecm_qt_declare_logging_category(dolphinprivate_LIB_SRCS HEADER dolphindebug.h IDENTIFIER DolphinDebug CATEGORY_NAME org.kde.dolphin)
 121
 122 if(HAVE_BALOO)
 123     set(dolphinprivate_LIB_SRCS
 124         ${dolphinprivate_LIB_SRCS}
 125         views/tooltips/dolphinfilemetadatawidget.cpp
 126         views/tooltips/tooltipmanager.cpp
 127         kitemviews/private/kbaloorolesprovider.cpp
 128     )
 129 endif()
 130
 131 kconfig_add_kcfg_files(dolphinprivate_LIB_SRCS GENERATE_MOC
 132     settings/dolphin_compactmodesettings.kcfgc
 133     settings/dolphin_directoryviewpropertysettings.kcfgc
 134     settings/dolphin_detailsmodesettings.kcfgc
 135     settings/dolphin_iconsmodesettings.kcfgc
 136     settings/dolphin_generalsettings.kcfgc
 137     settings/dolphin_versioncontrolsettings.kcfgc
 138 )
 139
 140 add_library(dolphinprivate ${dolphinprivate_LIB_SRCS})
 141 generate_export_header(dolphinprivate BASE_NAME dolphin)
 142
 143 target_link_libraries(
 144     dolphinprivate PUBLIC
 145     dolphinvcs
 146     Qt5::Concurrent
 147     Qt5::Gui
 148     KF5::I18n
 149     KF5::IconThemes
 150     KF5::KIOCore
 151     KF5::KIOWidgets
 152     KF5::KIOFileWidgets
 153     KF5::Completion
 154     KF5::TextWidgets
 155     KF5::ConfigCore
 156     KF5::NewStuff
 157     KF5::Parts
 158     KF5::WindowSystem
 159 )
 160
 161 if(HAVE_BALOO)
 162     target_link_libraries(
 163         dolphinprivate PUBLIC
 164         KF5::FileMetaData
 165         KF5::Baloo
 166         KF5::BalooWidgets
 167     )
 168 endif()
 169
 170 set_target_properties(dolphinprivate PROPERTIES
 171     VERSION ${DOLPHINPRIVATE_VERSION_STRING}
 172     SOVERSION ${DOLPHINPRIVATE_SOVERSION}
 173 )
 174
 175 install(TARGETS dolphinprivate ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} LIBRARY NAMELINK_SKIP)
 176 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphin_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
 177
 178 ##########################################
 179
 180 set(dolphinpart_SRCS
 181    dolphinpart.cpp
 182    dolphinpart_ext.cpp
 183    dolphindebug.cpp
 184 )
 185
 186 qt5_add_resources(dolphinpart_SRCS dolphinpart.qrc)
 187
 188 add_library(dolphinpart MODULE ${dolphinpart_SRCS})
 189
 190 target_link_libraries(dolphinpart
 191     dolphinprivate
 192 )
 193
 194 install(TARGETS dolphinpart DESTINATION ${KDE_INSTALL_PLUGINDIR})
 195
 196 install(FILES dolphinpart.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR})
 197
 198 ##########################################
 199
 200 set(dolphinstatic_SRCS
 201     dolphinbookmarkhandler.cpp
 202     dolphindockwidget.cpp
 203     dolphinmainwindow.cpp
 204     dolphinviewcontainer.cpp
 205     dolphincontextmenu.cpp
 206     dolphintabbar.cpp
 207     dolphinplacesmodelsingleton.cpp
 208     dolphinrecenttabsmenu.cpp
 209     dolphintabpage.cpp
 210     dolphintabwidget.cpp
 211     trash/dolphintrash.cpp
 212     filterbar/filterbar.cpp
 213     panels/places/placespanel.cpp
 214     panels/places/placesitem.cpp
 215     panels/places/placesitemlistgroupheader.cpp
 216     panels/places/placesitemlistwidget.cpp
 217     panels/places/placesitemmodel.cpp
 218     panels/places/placesitemsignalhandler.cpp
 219     panels/places/placesview.cpp
 220     panels/panel.cpp
 221     panels/folders/foldersitemlistwidget.cpp
 222     panels/folders/treeviewcontextmenu.cpp
 223     panels/folders/folderspanel.cpp
 224     panels/terminal/terminalpanel.cpp
 225     search/dolphinfacetswidget.cpp
 226     search/dolphinquery.cpp
 227     search/dolphinsearchbox.cpp
 228     settings/general/behaviorsettingspage.cpp
 229     settings/general/configurepreviewplugindialog.cpp
 230     settings/general/confirmationssettingspage.cpp
 231     settings/general/generalsettingspage.cpp
 232     settings/general/previewssettingspage.cpp
 233     settings/general/statusbarsettingspage.cpp
 234     settings/dolphinsettingsdialog.cpp
 235     settings/navigation/navigationsettingspage.cpp
 236     settings/services/servicessettingspage.cpp
 237     settings/settingspagebase.cpp
 238     settings/serviceitemdelegate.cpp
 239     settings/servicemodel.cpp
 240     settings/startup/startupsettingspage.cpp
 241     settings/trash/trashsettingspage.cpp
 242     settings/viewmodes/dolphinfontrequester.cpp
 243     settings/viewmodes/viewsettingspage.cpp
 244     settings/viewmodes/viewmodesettings.cpp
 245     settings/viewmodes/viewsettingstab.cpp
 246     statusbar/dolphinstatusbar.cpp
 247     statusbar/mountpointobserver.cpp
 248     statusbar/mountpointobservercache.cpp
 249     statusbar/spaceinfoobserver.cpp
 250     statusbar/statusbarspaceinfo.cpp
 251     views/zoomlevelinfo.cpp
 252     dolphindebug.cpp
 253     global.cpp
 254 )
 255
 256 if(HAVE_BALOO)
 257     set(dolphinstatic_SRCS
 258         ${dolphinstatic_SRCS}
 259         panels/information/informationpanel.cpp
 260         panels/information/informationpanelcontent.cpp
 261         panels/information/pixmapviewer.cpp
 262         panels/information/phononwidget.cpp
 263     )
 264 endif()
 265
 266 if(HAVE_KUSERFEEDBACK)
 267     set(dolphinstatic_SRCS
 268         ${dolphinstatic_SRCS}
 269         userfeedback/dolphinfeedbackprovider.cpp
 270         userfeedback/settingsdatasource.cpp
 271         userfeedback/placesdatasource.cpp
 272         settings/userfeedback/userfeedbacksettingspage.cpp
 273     )
 274 endif()
 275
 276 kconfig_add_kcfg_files(dolphinstatic_SRCS GENERATE_MOC
 277     panels/folders/dolphin_folderspanelsettings.kcfgc
 278     panels/information/dolphin_informationpanelsettings.kcfgc
 279     panels/places/dolphin_placespanelsettings.kcfgc
 280     settings/dolphin_compactmodesettings.kcfgc
 281     settings/dolphin_detailsmodesettings.kcfgc
 282     settings/dolphin_generalsettings.kcfgc
 283     settings/dolphin_iconsmodesettings.kcfgc
 284     search/dolphin_searchsettings.kcfgc
 285     settings/dolphin_versioncontrolsettings.kcfgc
 286 )
 287
 288 qt5_add_resources(dolphinstatic_SRCS dolphin.qrc)
 289
 290 qt5_generate_dbus_interface(${CMAKE_CURRENT_SOURCE_DIR}/dolphinmainwindow.h org.kde.DolphinMainWindow.xml)
 291 qt5_add_dbus_adaptor(dolphinstatic_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindow.h DolphinMainWindow)
 292 qt5_add_dbus_interface(dolphinstatic_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindowinterface)
 293 qt5_add_dbus_interface(dolphinstatic_SRCS panels/terminal/org.kde.KIOFuse.VFS.xml kiofuse_interface)
 294
 295 add_library(dolphinstatic STATIC ${dolphinstatic_SRCS})
 296
 297 target_include_directories(dolphinstatic SYSTEM PRIVATE ${PHONON_INCLUDES})
 298 target_link_libraries(dolphinstatic
 299     dolphinprivate
 300     KF5::CoreAddons
 301     KF5::KCMUtils
 302     KF5::DBusAddons
 303     KF5::Notifications
 304     Phonon::phonon4qt5
 305 )
 306
 307 if (HAVE_KACTIVITIES)
 308     target_link_libraries(
 309         dolphinstatic
 310         KF5::Activities
 311     )
 312 endif()
 313
 314 if (HAVE_KUSERFEEDBACK)
 315     target_link_libraries(
 316         dolphinstatic
 317         KUserFeedbackCore
 318         KUserFeedbackWidgets
 319     )
 320 endif()
 321
 322 set(dolphin_SRCS
 323     dbusinterface.cpp
 324     main.cpp
 325 )
 326
 327 # Sets the icon on Windows and OSX
 328 file(GLOB ICONS_SRCS "${CMAKE_CURRENT_SOURCE_DIR}/icons/*system-file-manager.png")
 329 ecm_add_app_icon(dolphin_SRCS ICONS ${ICONS_SRCS})
 330
 331 kf5_add_kdeinit_executable(dolphin ${dolphin_SRCS})
 332
 333
 334 target_link_libraries(kdeinit_dolphin PUBLIC
 335     dolphinprivate
 336     PRIVATE
 337     dolphinstatic
 338     KF5::Crash
 339 )
 340
 341 include(DbusInterfaceMacros)
 342
 343 generate_and_install_dbus_interface(
 344     kdeinit_dolphin
 345     dbusinterface.h
 346     org.freedesktop.FileManager1.xml
 347     OPTIONS -a
 348 )
 349
 350 install(TARGETS kdeinit_dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 351 install(TARGETS dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 352
 353 ##########################################
 354
 355 set(kcm_dolphinviewmodes_PART_SRCS
 356     settings/kcm/kcmdolphinviewmodes.cpp
 357     settings/viewmodes/dolphinfontrequester.cpp
 358     settings/viewmodes/viewmodesettings.cpp
 359     settings/viewmodes/viewsettingstab.cpp
 360     views/zoomlevelinfo.cpp)
 361
 362 set(kcm_dolphinnavigation_PART_SRCS
 363     settings/kcm/kcmdolphinnavigation.cpp
 364     settings/navigation/navigationsettingspage.cpp
 365     settings/settingspagebase.cpp)
 366
 367 set(kcm_dolphinservices_PART_SRCS
 368     settings/kcm/kcmdolphinservices.cpp
 369     settings/services/servicessettingspage.cpp
 370     settings/settingspagebase.cpp
 371     settings/serviceitemdelegate.cpp
 372     settings/servicemodel.cpp)
 373
 374 set(kcm_dolphingeneral_PART_SRCS
 375     settings/kcm/kcmdolphingeneral.cpp
 376     settings/general/behaviorsettingspage.cpp
 377     settings/general/previewssettingspage.cpp
 378     settings/general/configurepreviewplugindialog.cpp
 379     settings/general/confirmationssettingspage.cpp
 380     settings/settingspagebase.cpp
 381     settings/serviceitemdelegate.cpp
 382     settings/servicemodel.cpp)
 383
 384 kconfig_add_kcfg_files(kcm_dolphinviewmodes_PART_SRCS
 385     settings/dolphin_compactmodesettings.kcfgc
 386     settings/dolphin_directoryviewpropertysettings.kcfgc
 387     settings/dolphin_detailsmodesettings.kcfgc
 388     settings/dolphin_iconsmodesettings.kcfgc
 389     settings/dolphin_generalsettings.kcfgc
 390     settings/dolphin_versioncontrolsettings.kcfgc
 391 )
 392
 393 kconfig_add_kcfg_files(kcm_dolphinnavigation_PART_SRCS
 394     settings/dolphin_generalsettings.kcfgc)
 395
 396 kconfig_add_kcfg_files(kcm_dolphinservices_PART_SRCS
 397     settings/dolphin_generalsettings.kcfgc
 398     settings/dolphin_versioncontrolsettings.kcfgc)
 399
 400 kconfig_add_kcfg_files(kcm_dolphingeneral_PART_SRCS
 401     settings/dolphin_generalsettings.kcfgc)
 402
 403
 404 if(NOT WIN32)
 405     # The settings are still accessible from the hamburger menu
 406     add_library(kcm_dolphinviewmodes MODULE ${kcm_dolphinviewmodes_PART_SRCS})
 407     add_library(kcm_dolphinnavigation MODULE ${kcm_dolphinnavigation_PART_SRCS})
 408     add_library(kcm_dolphinservices MODULE ${kcm_dolphinservices_PART_SRCS})
 409     add_library(kcm_dolphingeneral MODULE ${kcm_dolphingeneral_PART_SRCS})
 410
 411     target_link_libraries(kcm_dolphinviewmodes dolphinprivate)
 412     target_link_libraries(kcm_dolphinnavigation dolphinprivate)
 413     target_link_libraries(kcm_dolphinservices dolphinprivate)
 414     target_link_libraries(kcm_dolphingeneral dolphinprivate)
 415
 416     install( FILES org.kde.dolphin.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR} )
 417     install( FILES settings/kcm/kcmdolphinviewmodes.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 418     install( FILES settings/kcm/kcmdolphinnavigation.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 419     install( FILES settings/kcm/kcmdolphinservices.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 420     install( FILES settings/kcm/kcmdolphingeneral.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 421
 422     install(TARGETS kcm_dolphinviewmodes DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 423     install(TARGETS kcm_dolphinnavigation DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 424     install(TARGETS kcm_dolphinservices DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 425     install(TARGETS kcm_dolphingeneral DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 426 endif()
 427
 428 if(NOT WIN32)
 429     add_subdirectory(settings/services/servicemenuinstaller)
 430     install( FILES settings/services/servicemenu.knsrc DESTINATION ${KDE_INSTALL_KNSRCDIR} )
 431 endif()
 432
 433 ########### install files ###############
 434
 435 install( PROGRAMS org.kde.dolphin.desktop DESTINATION ${KDE_INSTALL_APPDIR} )
 436
 437 install( DIRECTORY DESTINATION "${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel" )
 438
 439 install(
 440     CODE "execute_process(COMMAND \"${CMAKE_COMMAND}\" -E create_symlink \"${KDE_INSTALL_FULL_APPDIR}/org.kde.dolphin.desktop\" \"\$ENV{DESTDIR}${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel/org.kde.dolphin.desktop\")"
 441 )
 442
 443 install( FILES settings/dolphin_directoryviewpropertysettings.kcfg
 444                settings/dolphin_generalsettings.kcfg
 445                settings/dolphin_compactmodesettings.kcfg
 446                settings/dolphin_iconsmodesettings.kcfg
 447                settings/dolphin_detailsmodesettings.kcfg
 448                settings/dolphin_versioncontrolsettings.kcfg
 449          DESTINATION ${KDE_INSTALL_KCFGDIR} )
 450
 451 if(BUILD_TESTING)
 452     find_package(Qt5Test ${QT_MIN_VERSION} CONFIG REQUIRED)
 453     add_subdirectory(tests)
 454 endif()