src/CMakeLists.txt

   1 macro_optional_find_package(Baloo)
   2 set_package_properties(Baloo PROPERTIES DESCRIPTION "Baloo Core libraries"
   3                        URL "http://www.kde.org"
   4                        TYPE OPTIONAL
   5                        PURPOSE "For adding desktop-wide search and tagging support to dolphin"
   6                       )
   7
   8 macro_optional_find_package(BalooWidgets)
   9 set_package_properties(BalooWidgets PROPERTIES DESCRIPTION "Baloos Widgets"
  10                        URL "http://www.kde.org"
  11                        TYPE OPTIONAL
  12                       )
  13
  14 macro_optional_find_package(KFileMetaData)
  15 set_package_properties(KFileMetaData PROPERTIES
  16                        URL "https://projects.kde.org/kfilemetadata"
  17                        TYPE OPTIONAL
  18                        PURPOSE "For accessing file metadata labels"
  19                       )
  20
  21 if (Baloo_FOUND AND BalooWidgets_FOUND AND KFileMetaData_FOUND)
  22     set(HAVE_BALOO TRUE)
  23 endif()
  24
  25 configure_file(config-baloo.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-baloo.h )
  26
  27 macro_bool_to_01(X11_Xrender_FOUND HAVE_XRENDER)
  28 configure_file(config-X11.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-X11.h )
  29
  30 include_directories( ${KACTIVITIES_INCLUDE_DIRS} ${CMAKE_CURRENT_BINARY_DIR} )
  31
  32 if(HAVE_BALOO)
  33   include_directories(${BALOO_INCLUDE_DIR} ${BALOO_WIDGETS_INCLUDE_DIR})
  34 endif()
  35
  36 add_subdirectory(tests)
  37
  38 ########### next target ###############
  39
  40 set(dolphinprivate_LIB_SRCS
  41     kitemviews/kfileitemlistview.cpp
  42     kitemviews/kfileitemlistwidget.cpp
  43     kitemviews/kfileitemmodel.cpp
  44     kitemviews/kfileitemmodelrolesupdater.cpp
  45     kitemviews/kitemlistcontainer.cpp
  46     kitemviews/kitemlistcontroller.cpp
  47     kitemviews/kitemlistgroupheader.cpp
  48     kitemviews/kitemlistheader.cpp
  49     kitemviews/kitemlistselectionmanager.cpp
  50     kitemviews/kitemliststyleoption.cpp
  51     kitemviews/kitemlistview.cpp
  52     kitemviews/kitemlistviewaccessible.cpp
  53     kitemviews/kitemlistwidget.cpp
  54     kitemviews/kitemmodelbase.cpp
  55     kitemviews/kitemset.cpp
  56     kitemviews/kstandarditem.cpp
  57     kitemviews/kstandarditemlistgroupheader.cpp
  58     kitemviews/kstandarditemlistwidget.cpp
  59     kitemviews/kstandarditemlistview.cpp
  60     kitemviews/kstandarditemmodel.cpp
  61     kitemviews/private/kdirectorycontentscounter.cpp
  62     kitemviews/private/kdirectorycontentscounterworker.cpp
  63     kitemviews/private/kfileitemclipboard.cpp
  64     kitemviews/private/kfileitemmodeldirlister.cpp
  65     kitemviews/private/kfileitemmodelfilter.cpp
  66     kitemviews/private/kitemlistheaderwidget.cpp
  67     kitemviews/private/kitemlistkeyboardsearchmanager.cpp
  68     kitemviews/private/kitemlistroleeditor.cpp
  69     kitemviews/private/kitemlistrubberband.cpp
  70     kitemviews/private/kitemlistselectiontoggle.cpp
  71     kitemviews/private/kitemlistsizehintresolver.cpp
  72     kitemviews/private/kitemlistsmoothscroller.cpp
  73     kitemviews/private/kitemlistviewanimation.cpp
  74     kitemviews/private/kitemlistviewlayouter.cpp
  75     kitemviews/private/kpixmapmodifier.cpp
  76     settings/additionalinfodialog.cpp
  77     settings/applyviewpropsjob.cpp
  78     settings/viewmodes/viewmodesettings.cpp
  79     settings/viewpropertiesdialog.cpp
  80     settings/viewpropsprogressinfo.cpp
  81     views/dolphinfileitemlistwidget.cpp
  82     views/dolphinitemlistview.cpp
  83     views/dolphinnewfilemenuobserver.cpp
  84     views/dolphinremoteencoding.cpp
  85     views/dolphinview.cpp
  86     views/dolphinviewactionhandler.cpp
  87     views/draganddrophelper.cpp
  88     views/renamedialog.cpp
  89     views/tooltips/filemetadatatooltip.cpp
  90     views/tooltips/tooltipmanager.cpp
  91     views/versioncontrol/updateitemstatesthread.cpp
  92     views/versioncontrol/versioncontrolobserver.cpp
  93     views/viewmodecontroller.cpp
  94     views/viewproperties.cpp
  95     views/zoomlevelinfo.cpp
  96     dolphinremoveaction.cpp
  97     dolphinnewfilemenu.cpp
  98 )
  99
 100 if(HAVE_BALOO)
 101     set(dolphinprivate_LIB_SRCS
 102         ${dolphinprivate_LIB_SRCS}
 103         kitemviews/private/kbaloorolesprovider.cpp
 104     )
 105 endif()
 106
 107 kde4_add_kcfg_files(dolphinprivate_LIB_SRCS
 108     settings/dolphin_compactmodesettings.kcfgc
 109     settings/dolphin_directoryviewpropertysettings.kcfgc
 110     settings/dolphin_detailsmodesettings.kcfgc
 111     settings/dolphin_iconsmodesettings.kcfgc
 112     settings/dolphin_generalsettings.kcfgc
 113     settings/dolphin_versioncontrolsettings.kcfgc
 114 )
 115
 116 kde4_add_library(dolphinprivate SHARED ${dolphinprivate_LIB_SRCS})
 117
 118 target_link_libraries(
 119     dolphinprivate
 120     ${KDE4_KFILE_LIBS}
 121     konq
 122     ${KDE4_KNEWSTUFF3_LIBS}
 123 )
 124
 125 if(HAVE_BALOO)
 126     target_link_libraries(
 127         dolphinprivate
 128         ${BALOO_LIBRARIES}
 129         ${BALOO_WIDGETS_LIBRARY}
 130         ${KFILEMETADATA_LIBRARY}
 131     )
 132 endif()
 133
 134 if(X11_Xrender_FOUND)
 135     target_link_libraries(dolphinprivate ${X11_Xrender_LIB})
 136 endif(X11_Xrender_FOUND)
 137
 138 target_link_libraries(dolphinprivate ${KDE4_PLASMA_LIBS})
 139
 140 set_target_properties(dolphinprivate PROPERTIES VERSION ${GENERIC_LIB_VERSION} SOVERSION ${GENERIC_LIB_SOVERSION} )
 141 install(TARGETS dolphinprivate  ${INSTALL_TARGETS_DEFAULT_ARGS})
 142
 143 ##########################################
 144
 145 set(dolphinpart_SRCS
 146    dolphinpart.cpp
 147 )
 148
 149 # Add dolphinpart_ext.cpp conditionally, only with KDE > 4.9.1.
 150 if (${KDE_VERSION} VERSION_GREATER "4.9.1")
 151 set(dolphinpart_SRCS
 152     ${dolphinpart_SRCS}
 153     dolphinpart_ext.cpp)
 154 endif (${KDE_VERSION} VERSION_GREATER "4.9.1")
 155
 156 kde4_add_plugin(dolphinpart ${dolphinpart_SRCS})
 157
 158 target_link_libraries(dolphinpart dolphinprivate konq ${KDE4_KPARTS_LIBS} ${KDE4_KFILE_LIBS})
 159
 160 install(TARGETS dolphinpart DESTINATION ${PLUGIN_INSTALL_DIR})
 161
 162 install(FILES dolphinpart.rc DESTINATION ${DATA_INSTALL_DIR}/dolphinpart)
 163 install(FILES dolphinpart.desktop DESTINATION ${SERVICES_INSTALL_DIR} )
 164 install(FILES views/versioncontrol/fileviewversioncontrolplugin.desktop DESTINATION ${SERVICETYPES_INSTALL_DIR})
 165
 166 ##########################################
 167
 168 set(dolphin_SRCS
 169     dolphinapplication.cpp
 170     dolphindockwidget.cpp
 171     dolphinmainwindow.cpp
 172     dolphinviewcontainer.cpp
 173     dolphincontextmenu.cpp
 174     filterbar/filterbar.cpp
 175     main.cpp
 176     panels/information/filemetadataconfigurationdialog.cpp
 177     panels/information/informationpanel.cpp
 178     panels/information/informationpanelcontent.cpp
 179     panels/information/pixmapviewer.cpp
 180     panels/information/phononwidget.cpp
 181     panels/places/placespanel.cpp
 182     panels/places/placesitem.cpp
 183     panels/places/placesitemeditdialog.cpp
 184     panels/places/placesitemlistgroupheader.cpp
 185     panels/places/placesitemlistwidget.cpp
 186     panels/places/placesitemmodel.cpp
 187     panels/places/placesitemsignalhandler.cpp
 188     panels/places/placesview.cpp
 189     panels/panel.cpp
 190     panels/folders/foldersitemlistwidget.cpp
 191     panels/folders/treeviewcontextmenu.cpp
 192     panels/folders/folderspanel.cpp
 193     search/dolphinfacetswidget.cpp
 194     search/dolphinsearchbox.cpp
 195     settings/general/behaviorsettingspage.cpp
 196     settings/general/configurepreviewplugindialog.cpp
 197     settings/general/confirmationssettingspage.cpp
 198     settings/general/generalsettingspage.cpp
 199     settings/general/previewssettingspage.cpp
 200     settings/general/statusbarsettingspage.cpp
 201     settings/dolphinsettingsdialog.cpp
 202     settings/navigation/navigationsettingspage.cpp
 203     settings/services/servicessettingspage.cpp
 204     settings/settingspagebase.cpp
 205     settings/serviceitemdelegate.cpp
 206     settings/servicemodel.cpp
 207     settings/startup/startupsettingspage.cpp
 208     settings/trash/trashsettingspage.cpp
 209     settings/viewmodes/dolphinfontrequester.cpp
 210     settings/viewmodes/viewsettingspage.cpp
 211     settings/viewmodes/viewmodesettings.cpp
 212     settings/viewmodes/viewsettingstab.cpp
 213     statusbar/dolphinstatusbar.cpp
 214     statusbar/statusbarspaceinfo.cpp
 215     views/zoomlevelinfo.cpp
 216 )
 217
 218 kde4_add_kcfg_files(dolphin_SRCS
 219     panels/folders/dolphin_folderspanelsettings.kcfgc
 220     panels/information/dolphin_informationpanelsettings.kcfgc
 221     panels/places/dolphin_placespanelsettings.kcfgc
 222     settings/dolphin_compactmodesettings.kcfgc
 223     settings/dolphin_detailsmodesettings.kcfgc
 224     settings/dolphin_generalsettings.kcfgc
 225     settings/dolphin_iconsmodesettings.kcfgc
 226     search/dolphin_searchsettings.kcfgc
 227     settings/dolphin_versioncontrolsettings.kcfgc
 228 )
 229
 230 if(NOT WIN32)
 231    set(dolphin_SRCS ${dolphin_SRCS} panels/terminal/terminalpanel.cpp)
 232 endif(NOT WIN32)
 233
 234 kde4_add_app_icon(dolphin_SRCS "${KDE4_ICON_INSTALL_DIR}/oxygen/*/apps/system-file-manager.png")
 235
 236 kde4_add_kdeinit_executable(dolphin ${dolphin_SRCS})
 237
 238 target_link_libraries(kdeinit_dolphin
 239     ${KDE4_KDEPRINT_LIBS}
 240     ${KDE4_KFILE_LIBS}
 241     ${KDE4_KPARTS_LIBS}
 242     ${KDE4_KCMUTILS_LIBRARY}
 243     konq
 244     dolphinprivate
 245     knewstuff3
 246     ${KDE4_SOLID_LIBS}
 247     ${KDE4_PHONON_LIBS}
 248 )
 249
 250 if(HAVE_BALOO)
 251     target_link_libraries(kdeinit_dolphin
 252         ${BALOO_LIBRARIES}
 253         ${BALOO_WIDGETS_LIBRARY}
 254     )
 255 endif()
 256
 257 if (KActivities_FOUND)
 258     target_link_libraries(
 259         kdeinit_dolphin
 260         ${KACTIVITIES_LIBRARY}
 261     )
 262 endif (KActivities_FOUND)
 263
 264 install(TARGETS kdeinit_dolphin ${INSTALL_TARGETS_DEFAULT_ARGS})
 265 install(TARGETS dolphin ${INSTALL_TARGETS_DEFAULT_ARGS})
 266
 267 ##########################################
 268
 269 set(kcm_dolphinviewmodes_PART_SRCS
 270     settings/kcm/kcmdolphinviewmodes.cpp
 271     settings/viewmodes/dolphinfontrequester.cpp
 272     settings/viewmodes/viewmodesettings.cpp
 273     settings/viewmodes/viewsettingstab.cpp
 274     views/zoomlevelinfo.cpp)
 275
 276 set(kcm_dolphinnavigation_PART_SRCS
 277     settings/kcm/kcmdolphinnavigation.cpp
 278     settings/navigation/navigationsettingspage.cpp
 279     settings/settingspagebase.cpp)
 280
 281 set(kcm_dolphinservices_PART_SRCS
 282     settings/kcm/kcmdolphinservices.cpp
 283     settings/services/servicessettingspage.cpp
 284     settings/settingspagebase.cpp
 285     settings/serviceitemdelegate.cpp
 286     settings/servicemodel.cpp)
 287
 288 set(kcm_dolphingeneral_PART_SRCS
 289     settings/kcm/kcmdolphingeneral.cpp
 290     settings/general/behaviorsettingspage.cpp
 291     settings/general/previewssettingspage.cpp
 292     settings/general/configurepreviewplugindialog.cpp
 293     settings/general/confirmationssettingspage.cpp
 294     settings/settingspagebase.cpp
 295     settings/serviceitemdelegate.cpp
 296     settings/servicemodel.cpp)
 297
 298 kde4_add_kcfg_files(kcm_dolphinviewmodes_PART_SRCS
 299     settings/dolphin_compactmodesettings.kcfgc
 300     settings/dolphin_directoryviewpropertysettings.kcfgc
 301     settings/dolphin_detailsmodesettings.kcfgc
 302     settings/dolphin_iconsmodesettings.kcfgc
 303     settings/dolphin_generalsettings.kcfgc
 304     settings/dolphin_versioncontrolsettings.kcfgc
 305 )
 306
 307 kde4_add_kcfg_files(kcm_dolphinnavigation_PART_SRCS
 308     settings/dolphin_generalsettings.kcfgc)
 309
 310 kde4_add_kcfg_files(kcm_dolphinservices_PART_SRCS
 311     settings/dolphin_generalsettings.kcfgc
 312     settings/dolphin_versioncontrolsettings.kcfgc)
 313
 314 kde4_add_kcfg_files(kcm_dolphingeneral_PART_SRCS
 315     settings/dolphin_generalsettings.kcfgc)
 316
 317 kde4_add_plugin(kcm_dolphinviewmodes ${kcm_dolphinviewmodes_PART_SRCS})
 318 kde4_add_plugin(kcm_dolphinnavigation ${kcm_dolphinnavigation_PART_SRCS})
 319 kde4_add_plugin(kcm_dolphinservices ${kcm_dolphinservices_PART_SRCS})
 320 kde4_add_plugin(kcm_dolphingeneral ${kcm_dolphingeneral_PART_SRCS})
 321
 322 target_link_libraries(kcm_dolphinviewmodes  ${KDE4_KDEUI_LIBS} ${KDE4_KFILE_LIBS} dolphinprivate)
 323 target_link_libraries(kcm_dolphinnavigation  ${KDE4_KDEUI_LIBS} ${KDE4_KFILE_LIBS} dolphinprivate)
 324 target_link_libraries(kcm_dolphinservices  ${KDE4_KDEUI_LIBS} ${KDE4_KFILE_LIBS} ${KDE4_KIO_LIBS} ${KDE4_KNEWSTUFF3_LIBRARY} dolphinprivate)
 325 target_link_libraries(kcm_dolphingeneral ${KDE4_KDEUI_LIBS} ${KDE4_KFILE_LIBS} ${KDE4_KIO_LIBS} dolphinprivate)
 326
 327 install(TARGETS kcm_dolphinviewmodes DESTINATION ${PLUGIN_INSTALL_DIR} )
 328 install(TARGETS kcm_dolphinnavigation DESTINATION ${PLUGIN_INSTALL_DIR} )
 329 install(TARGETS kcm_dolphinservices DESTINATION ${PLUGIN_INSTALL_DIR} )
 330 install(TARGETS kcm_dolphingeneral DESTINATION ${PLUGIN_INSTALL_DIR} )
 331
 332 #########################################
 333
 334 set(kio_search_PART_SRCS
 335     search/filenamesearchprotocol.cpp)
 336 kde4_add_plugin(kio_filenamesearch ${kio_search_PART_SRCS})
 337 target_link_libraries(kio_filenamesearch ${KDE4_KIO_LIBS})
 338 install(TARGETS kio_filenamesearch DESTINATION ${PLUGIN_INSTALL_DIR})
 339
 340 ########### install files ###############
 341
 342 install( PROGRAMS dolphin.desktop DESTINATION ${XDG_APPS_INSTALL_DIR} )
 343 install( FILES settings/dolphin_directoryviewpropertysettings.kcfg
 344                settings/dolphin_generalsettings.kcfg
 345                settings/dolphin_compactmodesettings.kcfg
 346                settings/dolphin_iconsmodesettings.kcfg
 347                settings/dolphin_detailsmodesettings.kcfg
 348                settings/dolphin_versioncontrolsettings.kcfg
 349          DESTINATION ${KCFG_INSTALL_DIR} )
 350 install( FILES dolphinui.rc DESTINATION ${DATA_INSTALL_DIR}/dolphin )
 351 install( FILES search/filenamesearch.protocol DESTINATION ${SERVICES_INSTALL_DIR} )
 352 install( FILES settings/kcm/kcmdolphinviewmodes.desktop DESTINATION
 353 ${SERVICES_INSTALL_DIR} )
 354 install( FILES settings/kcm/kcmdolphinnavigation.desktop DESTINATION ${SERVICES_INSTALL_DIR} )
 355 install( FILES settings/kcm/kcmdolphinservices.desktop DESTINATION ${SERVICES_INSTALL_DIR} )
 356 install( FILES settings/kcm/kcmdolphingeneral.desktop DESTINATION ${SERVICES_INSTALL_DIR} )
 357 install( FILES settings/services/servicemenu.knsrc DESTINATION ${CONFIG_INSTALL_DIR} )
 358 install( PROGRAMS settings/services/servicemenuinstallation DESTINATION ${BIN_INSTALL_DIR} )
 359 install( PROGRAMS settings/services/servicemenudeinstallation DESTINATION ${BIN_INSTALL_DIR} )
 360