src/CMakeLists.txt

   1 include(ECMAddAppIcon)
   2
   3 configure_file(config-baloo.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-baloo.h)
   4
   5 configure_file(config-kactivities.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-kactivities.h)
   6
   7 configure_file(config-packagekit.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-packagekit.h)
   8
   9 configure_file(config-terminal.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-terminal.h)
  10
  11 configure_file(config-kuserfeedback.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-kuserfeedback.h)
  12
  13 add_definitions(
  14     -DTRANSLATION_DOMAIN=\"dolphin\"
  15 )
  16 remove_definitions(
  17     -DQT_NO_CAST_FROM_BYTEARRAY
  18     -DQT_NO_SIGNALS_SLOTS_KEYWORDS
  19     -DQT_NO_CAST_FROM_ASCII
  20     -DQT_NO_CAST_TO_ASCII
  21     -DQT_NO_FOREACH
  22     -DQT_NO_KEYWORDS
  23 )
  24
  25 ##########################################
  26
  27 set(dolphinvcs_LIB_SRCS
  28     views/versioncontrol/kversioncontrolplugin.cpp
  29 )
  30
  31 add_library(dolphinvcs ${dolphinvcs_LIB_SRCS})
  32 generate_export_header(dolphinvcs BASE_NAME dolphinvcs)
  33
  34 target_link_libraries(
  35     dolphinvcs PUBLIC
  36     Qt5::Widgets
  37 )
  38
  39 set_target_properties(dolphinvcs PROPERTIES
  40     VERSION ${DOLPHINVCS_VERSION_STRING}
  41     SOVERSION ${DOLPHINVCS_SOVERSION}
  42     EXPORT_NAME DolphinVcs
  43 )
  44
  45 ecm_generate_headers(dolphinvcs_LIB_HEADERS
  46     HEADER_NAMES
  47     KVersionControlPlugin
  48
  49     RELATIVE "views/versioncontrol"
  50     REQUIRED_HEADERS dolphinvcs_LIB_HEADERS
  51 )
  52
  53 install(TARGETS dolphinvcs EXPORT DolphinVcsTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
  54
  55 install(FILES views/versioncontrol/fileviewversioncontrolplugin.desktop DESTINATION ${KDE_INSTALL_KSERVICETYPES5DIR})
  56 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphinvcs_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
  57 install(FILES ${dolphinvcs_LIB_HEADERS} DESTINATION "${KDE_INSTALL_INCLUDEDIR}/Dolphin" COMPONENT Devel)
  58
  59 ########### next target ###############
  60
  61 set(dolphinprivate_LIB_SRCS
  62     kitemviews/kfileitemlistview.cpp
  63     kitemviews/kfileitemlistwidget.cpp
  64     kitemviews/kfileitemmodel.cpp
  65     kitemviews/kfileitemmodelrolesupdater.cpp
  66     kitemviews/kitemlistcontainer.cpp
  67     kitemviews/kitemlistcontroller.cpp
  68     kitemviews/kitemlistgroupheader.cpp
  69     kitemviews/kitemlistheader.cpp
  70     kitemviews/kitemlistselectionmanager.cpp
  71     kitemviews/kitemliststyleoption.cpp
  72     kitemviews/kitemlistview.cpp
  73     kitemviews/kitemlistviewaccessible.cpp
  74     kitemviews/kitemlistwidget.cpp
  75     kitemviews/kitemmodelbase.cpp
  76     kitemviews/kitemset.cpp
  77     kitemviews/kstandarditem.cpp
  78     kitemviews/kstandarditemlistgroupheader.cpp
  79     kitemviews/kstandarditemlistwidget.cpp
  80     kitemviews/kstandarditemlistview.cpp
  81     kitemviews/kstandarditemmodel.cpp
  82     kitemviews/private/kdirectorycontentscounter.cpp
  83     kitemviews/private/kdirectorycontentscounterworker.cpp
  84     kitemviews/private/kfileitemclipboard.cpp
  85     kitemviews/private/kfileitemmodeldirlister.cpp
  86     kitemviews/private/kfileitemmodelfilter.cpp
  87     kitemviews/private/kitemlistheaderwidget.cpp
  88     kitemviews/private/kitemlistkeyboardsearchmanager.cpp
  89     kitemviews/private/kitemlistroleeditor.cpp
  90     kitemviews/private/kitemlistrubberband.cpp
  91     kitemviews/private/kitemlistselectiontoggle.cpp
  92     kitemviews/private/kitemlistsizehintresolver.cpp
  93     kitemviews/private/kitemlistsmoothscroller.cpp
  94     kitemviews/private/kitemlistviewanimation.cpp
  95     kitemviews/private/kitemlistviewlayouter.cpp
  96     kitemviews/private/kpixmapmodifier.cpp
  97     kitemviews/private/ktwofingerswipe.cpp
  98     kitemviews/private/ktwofingertap.cpp
  99     settings/applyviewpropsjob.cpp
 100     settings/viewmodes/viewmodesettings.cpp
 101     settings/viewpropertiesdialog.cpp
 102     settings/viewpropsprogressinfo.cpp
 103     views/dolphinfileitemlistwidget.cpp
 104     views/dolphinitemlistview.cpp
 105     views/dolphinnewfilemenuobserver.cpp
 106     views/dolphinremoteencoding.cpp
 107     views/dolphinview.cpp
 108     views/dolphinviewactionhandler.cpp
 109     views/draganddrophelper.cpp
 110     views/versioncontrol/updateitemstatesthread.cpp
 111     views/versioncontrol/versioncontrolobserver.cpp
 112     views/viewmodecontroller.cpp
 113     views/viewproperties.cpp
 114     views/zoomlevelinfo.cpp
 115     dolphinremoveaction.cpp
 116     middleclickactioneventfilter.cpp
 117     dolphinnewfilemenu.cpp
 118 )
 119
 120 ecm_qt_declare_logging_category(dolphinprivate_LIB_SRCS HEADER dolphindebug.h IDENTIFIER DolphinDebug CATEGORY_NAME org.kde.dolphin)
 121
 122 if(HAVE_BALOO)
 123     set(dolphinprivate_LIB_SRCS
 124         ${dolphinprivate_LIB_SRCS}
 125         views/tooltips/dolphinfilemetadatawidget.cpp
 126         views/tooltips/tooltipmanager.cpp
 127         kitemviews/private/kbaloorolesprovider.cpp
 128     )
 129 endif()
 130
 131 kconfig_add_kcfg_files(dolphinprivate_LIB_SRCS GENERATE_MOC
 132     settings/dolphin_compactmodesettings.kcfgc
 133     settings/dolphin_directoryviewpropertysettings.kcfgc
 134     settings/dolphin_detailsmodesettings.kcfgc
 135     settings/dolphin_iconsmodesettings.kcfgc
 136     settings/dolphin_generalsettings.kcfgc
 137     settings/dolphin_versioncontrolsettings.kcfgc
 138 )
 139
 140 add_library(dolphinprivate ${dolphinprivate_LIB_SRCS})
 141 generate_export_header(dolphinprivate BASE_NAME dolphin)
 142
 143 target_link_libraries(
 144     dolphinprivate PUBLIC
 145     dolphinvcs
 146     Qt5::Concurrent
 147     Qt5::Gui
 148     KF5::I18n
 149     KF5::IconThemes
 150     KF5::KIOCore
 151     KF5::KIOWidgets
 152     KF5::KIOFileWidgets
 153     KF5::Completion
 154     KF5::TextWidgets
 155     KF5::ConfigCore
 156     KF5::NewStuff
 157     KF5::Parts
 158     KF5::WindowSystem
 159 )
 160
 161 if(HAVE_BALOO)
 162     target_link_libraries(
 163         dolphinprivate PUBLIC
 164         KF5::FileMetaData
 165         KF5::Baloo
 166         KF5::BalooWidgets
 167     )
 168 endif()
 169
 170 set_target_properties(dolphinprivate PROPERTIES
 171     VERSION ${DOLPHINPRIVATE_VERSION_STRING}
 172     SOVERSION ${DOLPHINPRIVATE_SOVERSION}
 173 )
 174
 175 install(TARGETS dolphinprivate ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} LIBRARY NAMELINK_SKIP)
 176 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphin_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
 177
 178 ##########################################
 179
 180 set(dolphinpart_SRCS
 181    dolphinpart.cpp
 182    dolphinpart_ext.cpp
 183    dolphindebug.cpp
 184 )
 185
 186 qt5_add_resources(dolphinpart_SRCS dolphinpart.qrc)
 187
 188 add_library(dolphinpart MODULE ${dolphinpart_SRCS})
 189
 190 target_link_libraries(dolphinpart
 191     dolphinprivate
 192 )
 193
 194 install(TARGETS dolphinpart DESTINATION ${KDE_INSTALL_PLUGINDIR})
 195
 196 install(FILES dolphinpart.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR})
 197
 198 ##########################################
 199
 200 set(dolphinstatic_SRCS
 201     dolphinbookmarkhandler.cpp
 202     dolphindockwidget.cpp
 203     dolphinmainwindow.cpp
 204     dolphinviewcontainer.cpp
 205     dolphincontextmenu.cpp
 206     dolphinnavigatorswidgetaction.cpp
 207     dolphintabbar.cpp
 208     dolphinplacesmodelsingleton.cpp
 209     dolphinrecenttabsmenu.cpp
 210     dolphintabpage.cpp
 211     dolphintabwidget.cpp
 212     dolphinurlnavigator.cpp
 213     dolphinurlnavigatorscontroller.cpp
 214     trash/dolphintrash.cpp
 215     filterbar/filterbar.cpp
 216     panels/places/placespanel.cpp
 217     panels/places/placesitem.cpp
 218     panels/places/placesitemlistgroupheader.cpp
 219     panels/places/placesitemlistwidget.cpp
 220     panels/places/placesitemmodel.cpp
 221     panels/places/placesitemsignalhandler.cpp
 222     panels/places/placesview.cpp
 223     panels/panel.cpp
 224     panels/folders/foldersitemlistwidget.cpp
 225     panels/folders/treeviewcontextmenu.cpp
 226     panels/folders/folderspanel.cpp
 227     panels/terminal/terminalpanel.cpp
 228     search/dolphinfacetswidget.cpp
 229     search/dolphinquery.cpp
 230     search/dolphinsearchbox.cpp
 231     settings/general/behaviorsettingspage.cpp
 232     settings/general/configurepreviewplugindialog.cpp
 233     settings/general/confirmationssettingspage.cpp
 234     settings/general/generalsettingspage.cpp
 235     settings/general/previewssettingspage.cpp
 236     settings/general/statusbarsettingspage.cpp
 237     settings/dolphinsettingsdialog.cpp
 238     settings/navigation/navigationsettingspage.cpp
 239     settings/services/servicessettingspage.cpp
 240     settings/settingspagebase.cpp
 241     settings/serviceitemdelegate.cpp
 242     settings/servicemodel.cpp
 243     settings/startup/startupsettingspage.cpp
 244     settings/trash/trashsettingspage.cpp
 245     settings/viewmodes/dolphinfontrequester.cpp
 246     settings/viewmodes/viewsettingspage.cpp
 247     settings/viewmodes/viewmodesettings.cpp
 248     settings/viewmodes/viewsettingstab.cpp
 249     statusbar/dolphinstatusbar.cpp
 250     statusbar/mountpointobserver.cpp
 251     statusbar/mountpointobservercache.cpp
 252     statusbar/spaceinfoobserver.cpp
 253     statusbar/statusbarspaceinfo.cpp
 254     views/zoomlevelinfo.cpp
 255     dolphindebug.cpp
 256     global.cpp
 257 )
 258
 259 if(HAVE_BALOO)
 260     set(dolphinstatic_SRCS
 261         ${dolphinstatic_SRCS}
 262         panels/information/informationpanel.cpp
 263         panels/information/informationpanelcontent.cpp
 264         panels/information/pixmapviewer.cpp
 265         panels/information/phononwidget.cpp
 266     )
 267 endif()
 268
 269 if(HAVE_KUSERFEEDBACK)
 270     set(dolphinstatic_SRCS
 271         ${dolphinstatic_SRCS}
 272         userfeedback/dolphinfeedbackprovider.cpp
 273         userfeedback/settingsdatasource.cpp
 274         userfeedback/placesdatasource.cpp
 275         settings/userfeedback/userfeedbacksettingspage.cpp
 276     )
 277 endif()
 278
 279 kconfig_add_kcfg_files(dolphinstatic_SRCS GENERATE_MOC
 280     panels/folders/dolphin_folderspanelsettings.kcfgc
 281     panels/information/dolphin_informationpanelsettings.kcfgc
 282     panels/places/dolphin_placespanelsettings.kcfgc
 283     settings/dolphin_compactmodesettings.kcfgc
 284     settings/dolphin_detailsmodesettings.kcfgc
 285     settings/dolphin_generalsettings.kcfgc
 286     settings/dolphin_iconsmodesettings.kcfgc
 287     search/dolphin_searchsettings.kcfgc
 288     settings/dolphin_versioncontrolsettings.kcfgc
 289 )
 290
 291 qt5_add_resources(dolphinstatic_SRCS dolphin.qrc)
 292
 293 qt5_generate_dbus_interface(${CMAKE_CURRENT_SOURCE_DIR}/dolphinmainwindow.h org.kde.DolphinMainWindow.xml)
 294 qt5_add_dbus_adaptor(dolphinstatic_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindow.h DolphinMainWindow)
 295 qt5_add_dbus_interface(dolphinstatic_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindowinterface)
 296 qt5_add_dbus_interface(dolphinstatic_SRCS panels/terminal/org.kde.KIOFuse.VFS.xml kiofuse_interface)
 297
 298 add_library(dolphinstatic STATIC ${dolphinstatic_SRCS})
 299
 300 target_include_directories(dolphinstatic SYSTEM PRIVATE ${PHONON_INCLUDES})
 301 target_link_libraries(dolphinstatic
 302     dolphinprivate
 303     KF5::CoreAddons
 304     KF5::KCMUtils
 305     KF5::DBusAddons
 306     KF5::Notifications
 307     Phonon::phonon4qt5
 308 )
 309
 310 if (HAVE_KACTIVITIES)
 311     target_link_libraries(
 312         dolphinstatic
 313         KF5::Activities
 314     )
 315 endif()
 316
 317 if (HAVE_KUSERFEEDBACK)
 318     target_link_libraries(
 319         dolphinstatic
 320         KUserFeedbackCore
 321         KUserFeedbackWidgets
 322     )
 323 endif()
 324
 325 set(dolphin_SRCS
 326     dbusinterface.cpp
 327     main.cpp
 328 )
 329
 330 # Sets the icon on Windows and OSX
 331 file(GLOB ICONS_SRCS "${CMAKE_CURRENT_SOURCE_DIR}/icons/*system-file-manager.png")
 332 ecm_add_app_icon(dolphin_SRCS ICONS ${ICONS_SRCS})
 333
 334 kf5_add_kdeinit_executable(dolphin ${dolphin_SRCS})
 335
 336
 337 target_link_libraries(kdeinit_dolphin PUBLIC
 338     dolphinprivate
 339     PRIVATE
 340     dolphinstatic
 341     KF5::Crash
 342 )
 343
 344 include(DbusInterfaceMacros)
 345
 346 generate_and_install_dbus_interface(
 347     kdeinit_dolphin
 348     dbusinterface.h
 349     org.freedesktop.FileManager1.xml
 350     OPTIONS -a
 351 )
 352
 353 install(TARGETS kdeinit_dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 354 install(TARGETS dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 355
 356 ##########################################
 357
 358 set(kcm_dolphinviewmodes_PART_SRCS
 359     settings/kcm/kcmdolphinviewmodes.cpp
 360     settings/viewmodes/dolphinfontrequester.cpp
 361     settings/viewmodes/viewmodesettings.cpp
 362     settings/viewmodes/viewsettingstab.cpp
 363     views/zoomlevelinfo.cpp)
 364
 365 set(kcm_dolphinnavigation_PART_SRCS
 366     settings/kcm/kcmdolphinnavigation.cpp
 367     settings/navigation/navigationsettingspage.cpp
 368     settings/settingspagebase.cpp)
 369
 370 set(kcm_dolphinservices_PART_SRCS
 371     settings/kcm/kcmdolphinservices.cpp
 372     settings/services/servicessettingspage.cpp
 373     settings/settingspagebase.cpp
 374     settings/serviceitemdelegate.cpp
 375     settings/servicemodel.cpp)
 376
 377 set(kcm_dolphingeneral_PART_SRCS
 378     settings/kcm/kcmdolphingeneral.cpp
 379     settings/general/behaviorsettingspage.cpp
 380     settings/general/previewssettingspage.cpp
 381     settings/general/configurepreviewplugindialog.cpp
 382     settings/general/confirmationssettingspage.cpp
 383     settings/settingspagebase.cpp
 384     settings/serviceitemdelegate.cpp
 385     settings/servicemodel.cpp)
 386
 387 kconfig_add_kcfg_files(kcm_dolphinviewmodes_PART_SRCS
 388     settings/dolphin_compactmodesettings.kcfgc
 389     settings/dolphin_directoryviewpropertysettings.kcfgc
 390     settings/dolphin_detailsmodesettings.kcfgc
 391     settings/dolphin_iconsmodesettings.kcfgc
 392     settings/dolphin_generalsettings.kcfgc
 393     settings/dolphin_versioncontrolsettings.kcfgc
 394 )
 395
 396 kconfig_add_kcfg_files(kcm_dolphinnavigation_PART_SRCS
 397     settings/dolphin_generalsettings.kcfgc)
 398
 399 kconfig_add_kcfg_files(kcm_dolphinservices_PART_SRCS
 400     settings/dolphin_generalsettings.kcfgc
 401     settings/dolphin_versioncontrolsettings.kcfgc)
 402
 403 kconfig_add_kcfg_files(kcm_dolphingeneral_PART_SRCS
 404     settings/dolphin_generalsettings.kcfgc)
 405
 406
 407 if(NOT WIN32)
 408     # The settings are still accessible from the hamburger menu
 409     add_library(kcm_dolphinviewmodes MODULE ${kcm_dolphinviewmodes_PART_SRCS})
 410     add_library(kcm_dolphinnavigation MODULE ${kcm_dolphinnavigation_PART_SRCS})
 411     add_library(kcm_dolphinservices MODULE ${kcm_dolphinservices_PART_SRCS})
 412     add_library(kcm_dolphingeneral MODULE ${kcm_dolphingeneral_PART_SRCS})
 413
 414     target_link_libraries(kcm_dolphinviewmodes dolphinprivate)
 415     target_link_libraries(kcm_dolphinnavigation dolphinprivate)
 416     target_link_libraries(kcm_dolphinservices dolphinprivate)
 417     target_link_libraries(kcm_dolphingeneral dolphinprivate)
 418
 419     install( FILES org.kde.dolphin.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR} )
 420     install( FILES settings/kcm/kcmdolphinviewmodes.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 421     install( FILES settings/kcm/kcmdolphinnavigation.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 422     install( FILES settings/kcm/kcmdolphinservices.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 423     install( FILES settings/kcm/kcmdolphingeneral.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 424
 425     install(TARGETS kcm_dolphinviewmodes DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 426     install(TARGETS kcm_dolphinnavigation DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 427     install(TARGETS kcm_dolphinservices DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 428     install(TARGETS kcm_dolphingeneral DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 429 endif()
 430
 431 if(NOT WIN32)
 432     add_subdirectory(settings/services/servicemenuinstaller)
 433     install( FILES settings/services/servicemenu.knsrc DESTINATION ${KDE_INSTALL_KNSRCDIR} )
 434 endif()
 435
 436 ########### install files ###############
 437
 438 install( PROGRAMS org.kde.dolphin.desktop DESTINATION ${KDE_INSTALL_APPDIR} )
 439
 440 install( DIRECTORY DESTINATION "${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel" )
 441
 442 install(
 443     CODE "execute_process(COMMAND \"${CMAKE_COMMAND}\" -E create_symlink \"${KDE_INSTALL_FULL_APPDIR}/org.kde.dolphin.desktop\" \"\$ENV{DESTDIR}${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel/org.kde.dolphin.desktop\")"
 444 )
 445
 446 install( FILES settings/dolphin_directoryviewpropertysettings.kcfg
 447                settings/dolphin_generalsettings.kcfg
 448                settings/dolphin_compactmodesettings.kcfg
 449                settings/dolphin_iconsmodesettings.kcfg
 450                settings/dolphin_detailsmodesettings.kcfg
 451                settings/dolphin_versioncontrolsettings.kcfg
 452          DESTINATION ${KDE_INSTALL_KCFGDIR} )
 453
 454 if(BUILD_TESTING)
 455     find_package(Qt5Test ${QT_MIN_VERSION} CONFIG REQUIRED)
 456     add_subdirectory(tests)
 457 endif()