src/CMakeLists.txt

   1
   2 configure_file(config-baloo.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-baloo.h)
   3
   4 configure_file(config-dolphin.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-dolphin.h)
   5
   6 add_definitions(-DTRANSLATION_DOMAIN=\"dolphin\" -DQT_USE_FAST_CONCATENATION -DQT_USE_FAST_OPERATOR_PLUS)
   7 remove_definitions(-DQT_NO_CAST_FROM_BYTEARRAY -DQT_NO_URL_CAST_FROM_STRING)
   8
   9 if(X11_Xrender_FOUND)
  10     set(HAVE_XRENDER TRUE)
  11 endif()
  12
  13 configure_file(config-X11.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-X11.h)
  14
  15 ##########################################
  16
  17 set(dolphinvcs_LIB_SRCS
  18     views/versioncontrol/kversioncontrolplugin.cpp
  19 )
  20
  21 add_library(dolphinvcs ${dolphinvcs_LIB_SRCS})
  22
  23 generate_export_header(dolphinvcs BASE_NAME dolphin)
  24
  25 target_link_libraries(
  26     dolphinvcs PUBLIC
  27     Qt5::Widgets
  28     KF5::KIOCore
  29 )
  30
  31 set_target_properties(dolphinvcs PROPERTIES
  32     VERSION ${DOLPHINVCS_VERSION_STRING}
  33     SOVERSION ${DOLPHINVCS_SOVERSION}
  34     EXPORT_NAME DolphinVcs
  35 )
  36
  37 ecm_generate_headers(dolphinvcs_LIB_HEADERS
  38     HEADER_NAMES
  39     KVersionControlPlugin
  40
  41     RELATIVE "views/versioncontrol"
  42     REQUIRED_HEADERS dolphinvcs_LIB_HEADERS
  43 )
  44
  45 install(TARGETS dolphinvcs EXPORT DolphinVcsTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
  46
  47 install(FILES views/versioncontrol/fileviewversioncontrolplugin.desktop DESTINATION ${KDE_INSTALL_KSERVICETYPES5DIR})
  48 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphin_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
  49 install(FILES ${dolphinvcs_LIB_HEADERS} DESTINATION "${KDE_INSTALL_INCLUDEDIR}/Dolphin" COMPONENT Devel)
  50
  51 ########### next target ###############
  52
  53 set(dolphinprivate_LIB_SRCS
  54     kitemviews/kfileitemlistview.cpp
  55     kitemviews/kfileitemlistwidget.cpp
  56     kitemviews/kfileitemmodel.cpp
  57     kitemviews/kfileitemmodelrolesupdater.cpp
  58     kitemviews/kitemlistcontainer.cpp
  59     kitemviews/kitemlistcontroller.cpp
  60     kitemviews/kitemlistgroupheader.cpp
  61     kitemviews/kitemlistheader.cpp
  62     kitemviews/kitemlistselectionmanager.cpp
  63     kitemviews/kitemliststyleoption.cpp
  64     kitemviews/kitemlistview.cpp
  65     kitemviews/kitemlistviewaccessible.cpp
  66     kitemviews/kitemlistwidget.cpp
  67     kitemviews/kitemmodelbase.cpp
  68     kitemviews/kitemset.cpp
  69     kitemviews/kstandarditem.cpp
  70     kitemviews/kstandarditemlistgroupheader.cpp
  71     kitemviews/kstandarditemlistwidget.cpp
  72     kitemviews/kstandarditemlistview.cpp
  73     kitemviews/kstandarditemmodel.cpp
  74     kitemviews/private/kdirectorycontentscounter.cpp
  75     kitemviews/private/kdirectorycontentscounterworker.cpp
  76     kitemviews/private/kfileitemclipboard.cpp
  77     kitemviews/private/kfileitemmodeldirlister.cpp
  78     kitemviews/private/kfileitemmodelfilter.cpp
  79     kitemviews/private/kitemlistheaderwidget.cpp
  80     kitemviews/private/kitemlistkeyboardsearchmanager.cpp
  81     kitemviews/private/kitemlistroleeditor.cpp
  82     kitemviews/private/kitemlistrubberband.cpp
  83     kitemviews/private/kitemlistselectiontoggle.cpp
  84     kitemviews/private/kitemlistsizehintresolver.cpp
  85     kitemviews/private/kitemlistsmoothscroller.cpp
  86     kitemviews/private/kitemlistviewanimation.cpp
  87     kitemviews/private/kitemlistviewlayouter.cpp
  88     kitemviews/private/kpixmapmodifier.cpp
  89     settings/additionalinfodialog.cpp
  90     settings/applyviewpropsjob.cpp
  91     settings/viewmodes/viewmodesettings.cpp
  92     settings/viewpropertiesdialog.cpp
  93     settings/viewpropsprogressinfo.cpp
  94     views/dolphinfileitemlistwidget.cpp
  95     views/dolphinitemlistview.cpp
  96     views/dolphinnewfilemenuobserver.cpp
  97     views/dolphinremoteencoding.cpp
  98     views/dolphinview.cpp
  99     views/dolphinviewactionhandler.cpp
 100     views/draganddrophelper.cpp
 101     views/renamedialog.cpp
 102     views/tooltips/filemetadatatooltip.cpp
 103     views/tooltips/tooltipmanager.cpp
 104     views/versioncontrol/updateitemstatesthread.cpp
 105     views/versioncontrol/versioncontrolobserver.cpp
 106     views/viewmodecontroller.cpp
 107     views/viewproperties.cpp
 108     views/zoomlevelinfo.cpp
 109     dolphinremoveaction.cpp
 110     dolphinnewfilemenu.cpp
 111     dolphindebug.cpp
 112 )
 113
 114 if(HAVE_BALOO)
 115     set(dolphinprivate_LIB_SRCS
 116         ${dolphinprivate_LIB_SRCS}
 117         kitemviews/private/kbaloorolesprovider.cpp
 118     )
 119 endif()
 120
 121 kconfig_add_kcfg_files(dolphinprivate_LIB_SRCS GENERATE_MOC
 122     settings/dolphin_compactmodesettings.kcfgc
 123     settings/dolphin_directoryviewpropertysettings.kcfgc
 124     settings/dolphin_detailsmodesettings.kcfgc
 125     settings/dolphin_iconsmodesettings.kcfgc
 126     settings/dolphin_generalsettings.kcfgc
 127     settings/dolphin_versioncontrolsettings.kcfgc
 128 )
 129
 130 add_library(dolphinprivate ${dolphinprivate_LIB_SRCS})
 131
 132 target_link_libraries(
 133     dolphinprivate PUBLIC
 134     dolphinvcs
 135     KF5::KDELibs4Support
 136     KF5::NewStuff
 137 )
 138
 139 if(HAVE_BALOO)
 140     target_link_libraries(
 141         dolphinprivate PUBLIC
 142         KF5::FileMetaData
 143         KF5::Baloo
 144         KF5::BalooWidgets
 145     )
 146 endif()
 147
 148 if(X11_Xrender_FOUND)
 149     target_link_libraries(dolphinprivate ${X11_Xrender_LIB})
 150 endif(X11_Xrender_FOUND)
 151
 152 set_target_properties(dolphinprivate PROPERTIES
 153     VERSION ${DOLPHINPRIVATE_VERSION_STRING}
 154     SOVERSION ${DOLPHINPRIVATE_SOVERSION}
 155 )
 156
 157 install(TARGETS dolphinprivate ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 158
 159 ##########################################
 160
 161 set(dolphinpart_SRCS
 162    dolphinpart.cpp
 163    dolphinpart_ext.cpp
 164    dolphindebug.cpp
 165 )
 166
 167 add_library(dolphinpart MODULE ${dolphinpart_SRCS})
 168
 169 target_link_libraries(dolphinpart
 170     dolphinprivate
 171     KF5::KDELibs4Support
 172 )
 173
 174 install(TARGETS dolphinpart DESTINATION ${PLUGIN_INSTALL_DIR})
 175
 176 install(FILES dolphinpart.rc DESTINATION ${CMAKE_INSTALL_KXMLGUI5DIR}/dolphinpart)
 177 install(FILES dolphinpart.desktop DESTINATION ${SERVICES_INSTALL_DIR})
 178
 179 ##########################################
 180
 181 set(dolphin_SRCS
 182     dolphindockwidget.cpp
 183     dolphinmainwindow.cpp
 184     dolphinviewcontainer.cpp
 185     dolphincontextmenu.cpp
 186     dolphintabbar.cpp
 187     dolphinrecenttabsmenu.cpp
 188     dolphintabpage.cpp
 189     dolphintabwidget.cpp
 190     filterbar/filterbar.cpp
 191     main.cpp
 192     panels/information/filemetadataconfigurationdialog.cpp
 193     panels/information/informationpanel.cpp
 194     panels/information/informationpanelcontent.cpp
 195     panels/information/pixmapviewer.cpp
 196     panels/information/phononwidget.cpp
 197     panels/places/placespanel.cpp
 198     panels/places/placesitem.cpp
 199     panels/places/placesitemeditdialog.cpp
 200     panels/places/placesitemlistgroupheader.cpp
 201     panels/places/placesitemlistwidget.cpp
 202     panels/places/placesitemmodel.cpp
 203     panels/places/placesitemsignalhandler.cpp
 204     panels/places/placesview.cpp
 205     panels/panel.cpp
 206     panels/folders/foldersitemlistwidget.cpp
 207     panels/folders/treeviewcontextmenu.cpp
 208     panels/folders/folderspanel.cpp
 209     search/dolphinfacetswidget.cpp
 210     search/dolphinsearchbox.cpp
 211     settings/general/behaviorsettingspage.cpp
 212     settings/general/configurepreviewplugindialog.cpp
 213     settings/general/confirmationssettingspage.cpp
 214     settings/general/generalsettingspage.cpp
 215     settings/general/previewssettingspage.cpp
 216     settings/general/statusbarsettingspage.cpp
 217     settings/dolphinsettingsdialog.cpp
 218     settings/navigation/navigationsettingspage.cpp
 219     settings/services/servicessettingspage.cpp
 220     settings/settingspagebase.cpp
 221     settings/serviceitemdelegate.cpp
 222     settings/servicemodel.cpp
 223     settings/startup/startupsettingspage.cpp
 224     settings/trash/trashsettingspage.cpp
 225     settings/viewmodes/dolphinfontrequester.cpp
 226     settings/viewmodes/viewsettingspage.cpp
 227     settings/viewmodes/viewmodesettings.cpp
 228     settings/viewmodes/viewsettingstab.cpp
 229     statusbar/dolphinstatusbar.cpp
 230     statusbar/mountpointobserver.cpp
 231     statusbar/mountpointobservercache.cpp
 232     statusbar/spaceinfotoolsmenu.cpp
 233     statusbar/spaceinfoobserver.cpp
 234     statusbar/statusbarspaceinfo.cpp
 235     views/zoomlevelinfo.cpp
 236     dolphindebug.cpp
 237 )
 238
 239 kconfig_add_kcfg_files(dolphin_SRCS GENERATE_MOC
 240     panels/folders/dolphin_folderspanelsettings.kcfgc
 241     panels/information/dolphin_informationpanelsettings.kcfgc
 242     panels/places/dolphin_placespanelsettings.kcfgc
 243     settings/dolphin_compactmodesettings.kcfgc
 244     settings/dolphin_detailsmodesettings.kcfgc
 245     settings/dolphin_generalsettings.kcfgc
 246     settings/dolphin_iconsmodesettings.kcfgc
 247     search/dolphin_searchsettings.kcfgc
 248     settings/dolphin_versioncontrolsettings.kcfgc
 249 )
 250
 251 if(NOT WIN32)
 252    set(dolphin_SRCS ${dolphin_SRCS} panels/terminal/terminalpanel.cpp)
 253 endif()
 254
 255 # TODO Does anything replace kde4_add_app_icon ?
 256 #kde4_add_app_icon(dolphin_SRCS "${KDE4_ICON_INSTALL_DIR}/oxygen/*/apps/system-file-manager.png")
 257
 258 kf5_add_kdeinit_executable(dolphin ${dolphin_SRCS})
 259
 260 target_include_directories(kdeinit_dolphin PRIVATE ${PHONON_INCLUDES})
 261
 262 target_link_libraries(kdeinit_dolphin
 263     dolphinprivate
 264     KF5::NewStuff
 265     KF5::Parts
 266     KF5::KCMUtils
 267     KF5::Solid
 268     KF5::KIOFileWidgets
 269     Phonon::phonon4qt5
 270     KF5::KDELibs4Support
 271     KF5::I18n
 272     KF5::CoreAddons
 273     KF5::DBusAddons
 274 )
 275
 276 if (KF5Activities_FOUND)
 277     target_link_libraries(
 278         kdeinit_dolphin
 279         KF5::Activities
 280     )
 281 endif()
 282
 283 install(TARGETS kdeinit_dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 284 install(TARGETS dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 285
 286 ##########################################
 287
 288 set(kcm_dolphinviewmodes_PART_SRCS
 289     settings/kcm/kcmdolphinviewmodes.cpp
 290     settings/viewmodes/dolphinfontrequester.cpp
 291     settings/viewmodes/viewmodesettings.cpp
 292     settings/viewmodes/viewsettingstab.cpp
 293     views/zoomlevelinfo.cpp)
 294
 295 set(kcm_dolphinnavigation_PART_SRCS
 296     settings/kcm/kcmdolphinnavigation.cpp
 297     settings/navigation/navigationsettingspage.cpp
 298     settings/settingspagebase.cpp)
 299
 300 set(kcm_dolphinservices_PART_SRCS
 301     settings/kcm/kcmdolphinservices.cpp
 302     settings/services/servicessettingspage.cpp
 303     settings/settingspagebase.cpp
 304     settings/serviceitemdelegate.cpp
 305     settings/servicemodel.cpp)
 306
 307 set(kcm_dolphingeneral_PART_SRCS
 308     settings/kcm/kcmdolphingeneral.cpp
 309     settings/general/behaviorsettingspage.cpp
 310     settings/general/previewssettingspage.cpp
 311     settings/general/configurepreviewplugindialog.cpp
 312     settings/general/confirmationssettingspage.cpp
 313     settings/settingspagebase.cpp
 314     settings/serviceitemdelegate.cpp
 315     settings/servicemodel.cpp)
 316
 317 kconfig_add_kcfg_files(kcm_dolphinviewmodes_PART_SRCS
 318     settings/dolphin_compactmodesettings.kcfgc
 319     settings/dolphin_directoryviewpropertysettings.kcfgc
 320     settings/dolphin_detailsmodesettings.kcfgc
 321     settings/dolphin_iconsmodesettings.kcfgc
 322     settings/dolphin_generalsettings.kcfgc
 323     settings/dolphin_versioncontrolsettings.kcfgc
 324 )
 325
 326 kconfig_add_kcfg_files(kcm_dolphinnavigation_PART_SRCS
 327     settings/dolphin_generalsettings.kcfgc)
 328
 329 kconfig_add_kcfg_files(kcm_dolphinservices_PART_SRCS
 330     settings/dolphin_generalsettings.kcfgc
 331     settings/dolphin_versioncontrolsettings.kcfgc)
 332
 333 kconfig_add_kcfg_files(kcm_dolphingeneral_PART_SRCS
 334     settings/dolphin_generalsettings.kcfgc)
 335
 336 add_library(kcm_dolphinviewmodes MODULE ${kcm_dolphinviewmodes_PART_SRCS})
 337 add_library(kcm_dolphinnavigation MODULE ${kcm_dolphinnavigation_PART_SRCS})
 338 add_library(kcm_dolphinservices MODULE ${kcm_dolphinservices_PART_SRCS})
 339 add_library(kcm_dolphingeneral MODULE ${kcm_dolphingeneral_PART_SRCS})
 340
 341 target_link_libraries(kcm_dolphinviewmodes KF5::KDELibs4Support dolphinprivate)
 342 target_link_libraries(kcm_dolphinnavigation KF5::KDELibs4Support dolphinprivate)
 343 target_link_libraries(kcm_dolphinservices KF5::KDELibs4Support dolphinprivate)
 344 target_link_libraries(kcm_dolphingeneral KF5::KDELibs4Support dolphinprivate)
 345
 346 install(TARGETS kcm_dolphinviewmodes DESTINATION ${PLUGIN_INSTALL_DIR} )
 347 install(TARGETS kcm_dolphinnavigation DESTINATION ${PLUGIN_INSTALL_DIR} )
 348 install(TARGETS kcm_dolphinservices DESTINATION ${PLUGIN_INSTALL_DIR} )
 349 install(TARGETS kcm_dolphingeneral DESTINATION ${PLUGIN_INSTALL_DIR} )
 350
 351 ########### install files ###############
 352
 353 install( PROGRAMS org.kde.dolphin.desktop DESTINATION ${XDG_APPS_INSTALL_DIR} )
 354 install( FILES settings/dolphin_directoryviewpropertysettings.kcfg
 355                settings/dolphin_generalsettings.kcfg
 356                settings/dolphin_compactmodesettings.kcfg
 357                settings/dolphin_iconsmodesettings.kcfg
 358                settings/dolphin_detailsmodesettings.kcfg
 359                settings/dolphin_versioncontrolsettings.kcfg
 360          DESTINATION ${KCFG_INSTALL_DIR} )
 361 install( FILES dolphinui.rc DESTINATION ${CMAKE_INSTALL_KXMLGUI5DIR}/dolphin )
 362 install( FILES dolphin.appdata.xml DESTINATION ${SHARE_INSTALL_PREFIX}/appdata )
 363 install( FILES settings/kcm/kcmdolphinviewmodes.desktop DESTINATION
 364 ${SERVICES_INSTALL_DIR} )
 365 install( FILES settings/kcm/kcmdolphinnavigation.desktop DESTINATION ${SERVICES_INSTALL_DIR} )
 366 install( FILES settings/kcm/kcmdolphinservices.desktop DESTINATION ${SERVICES_INSTALL_DIR} )
 367 install( FILES settings/kcm/kcmdolphingeneral.desktop DESTINATION ${SERVICES_INSTALL_DIR} )
 368 install( FILES settings/services/servicemenu.knsrc DESTINATION ${CONFIG_INSTALL_DIR} )
 369 install( PROGRAMS settings/services/servicemenuinstallation DESTINATION ${BIN_INSTALL_DIR} )
 370 install( PROGRAMS settings/services/servicemenudeinstallation DESTINATION ${BIN_INSTALL_DIR} )
 371
 372 if(BUILD_TESTING)
 373     find_package(Qt5Test ${QT_MIN_VERSION} CONFIG REQUIRED)
 374     add_subdirectory(tests)
 375 endif()