CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8.12)
   2
   3 project(Dolphin)
   4
   5 # ECM setup
   6 find_package(ECM 1.6.0 CONFIG REQUIRED)
   7 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
   8
   9 set(DOLPHIN_VERSION "4.97.0")
  10
  11 include(ECMSetupVersion)
  12 include(ECMGenerateHeaders)
  13 include(GenerateExportHeader)
  14 include(FeatureSummary)
  15 include(KDEInstallDirs)
  16 include(KDECMakeSettings)
  17 include(KDEFrameworkCompilerSettings)
  18
  19 ecm_setup_version(${DOLPHIN_VERSION} VARIABLE_PREFIX DOLPHINVCS
  20                   VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/dolphinvcs_version.h"
  21                   PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/DolphinVcsConfigVersion.cmake"
  22                   SOVERSION 5
  23 )
  24
  25 ecm_setup_version(${DOLPHIN_VERSION} VARIABLE_PREFIX DOLPHINPRIVATE
  26                   SOVERSION 5
  27 )
  28
  29 find_package(KF5 REQUIRED COMPONENTS DocTools Init KCMUtils KDELibs4Support NewStuff CoreAddons I18n DBusAddons)
  30 find_package(KF5 COMPONENTS Activities)
  31
  32 find_package(Phonon4Qt5 CONFIG REQUIRED)
  33
  34 find_package(KF5Baloo 4.97)
  35 set_package_properties(KF5Baloo PROPERTIES DESCRIPTION "Baloo Core libraries"
  36                        URL "http://www.kde.org"
  37                        TYPE OPTIONAL
  38                        PURPOSE "For adding desktop-wide search and tagging support to dolphin"
  39                       )
  40
  41 find_package(KF5BalooWidgets 4.97)
  42 set_package_properties(KF5BalooWidgets PROPERTIES DESCRIPTION "Baloos Widgets"
  43                        URL "http://www.kde.org"
  44                        TYPE OPTIONAL
  45                       )
  46
  47 find_package(KF5FileMetaData 4.97)
  48 set_package_properties(KF5FileMetaData PROPERTIES
  49                        URL "https://projects.kde.org/kfilemetadata"
  50                        TYPE OPTIONAL
  51                        PURPOSE "For accessing file metadata labels"
  52                       )
  53
  54 if (KF5Baloo_FOUND AND KF5BalooWidgets_FOUND AND KF5FileMetaData_FOUND)
  55     message(STATUS "Baloo packages are found")
  56     set(HAVE_BALOO TRUE)
  57 endif()
  58
  59 add_subdirectory(src)
  60 add_subdirectory(docs)
  61
  62 # CMake files
  63 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/Dolphin")
  64
  65 ecm_configure_package_config_file(
  66     "${CMAKE_CURRENT_SOURCE_DIR}/DolphinVcsConfig.cmake.in"
  67     "${CMAKE_CURRENT_BINARY_DIR}/DolphinVcsConfig.cmake"
  68     INSTALL_DESTINATION ${CMAKECONFIG_INSTALL_DIR}
  69 )
  70
  71 install(FILES
  72     "${CMAKE_CURRENT_BINARY_DIR}/DolphinVcsConfig.cmake"
  73     "${CMAKE_CURRENT_BINARY_DIR}/DolphinVcsConfigVersion.cmake"
  74     DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
  75     COMPONENT Devel
  76 )
  77
  78 install(EXPORT DolphinVcsTargets
  79     DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
  80     FILE DolphinVcsTargets.cmake
  81 )
  82
  83 install(FILES
  84     "${CMAKE_CURRENT_BINARY_DIR}/dolphinvcs_version.h"
  85     DESTINATION "${KDE_INSTALL_INCLUDEDIR}/Dolphin"
  86     COMPONENT Devel
  87 )
  88
  89 # TODO Remove the if/endif lines if Dolphin is split.
  90 if ("${CMAKE_SOURCE_DIR}" STREQUAL "${Dolphin_SOURCE_DIR}")
  91   feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)
  92 endif()