src/CMakeLists.txt

   1 include(ECMAddAppIcon)
   2
   3 configure_file(config-dolphin.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-dolphin.h)
   4
   5 add_definitions(
   6     -DTRANSLATION_DOMAIN=\"dolphin\"
   7 )
   8 remove_definitions(
   9     -DQT_NO_CAST_FROM_BYTEARRAY
  10     -DQT_NO_CAST_FROM_ASCII
  11     -DQT_NO_CAST_TO_ASCII
  12 )
  13
  14 ##########################################
  15
  16 add_library(dolphinvcs SHARED)
  17
  18 target_sources(dolphinvcs PRIVATE
  19     views/versioncontrol/kversioncontrolplugin.cpp
  20 )
  21
  22 generate_export_header(dolphinvcs BASE_NAME dolphinvcs)
  23
  24 target_link_libraries(
  25     dolphinvcs PUBLIC
  26     Qt6::Widgets
  27 )
  28
  29 set_target_properties(dolphinvcs PROPERTIES
  30     VERSION ${DOLPHINVCS_VERSION}
  31     SOVERSION ${DOLPHINVCS_SOVERSION}
  32     EXPORT_NAME DolphinVcs
  33 )
  34
  35 ecm_generate_headers(dolphinvcs_LIB_HEADERS
  36     HEADER_NAMES
  37     KVersionControlPlugin
  38
  39     RELATIVE "views/versioncontrol"
  40     REQUIRED_HEADERS dolphinvcs_LIB_HEADERS
  41 )
  42 target_include_directories(dolphinvcs INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR}>")
  43
  44 install(TARGETS dolphinvcs EXPORT DolphinVcsTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
  45
  46 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphinvcs_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
  47 install(FILES ${dolphinvcs_LIB_HEADERS} DESTINATION "${KDE_INSTALL_INCLUDEDIR}/Dolphin" COMPONENT Devel)
  48
  49 ########### next target ###############
  50
  51 add_library(dolphinprivate SHARED)
  52
  53 target_sources(dolphinprivate PRIVATE
  54     kitemviews/kfileitemlistview.cpp
  55     kitemviews/kfileitemlistwidget.cpp
  56     kitemviews/kfileitemlisttostring.cpp
  57     kitemviews/kfileitemmodel.cpp
  58     kitemviews/kfileitemmodelrolesupdater.cpp
  59     kitemviews/kitemlistcontainer.cpp
  60     kitemviews/kitemlistcontroller.cpp
  61     kitemviews/kitemlistgroupheader.cpp
  62     kitemviews/kitemlistheader.cpp
  63     kitemviews/kitemlistselectionmanager.cpp
  64     kitemviews/kitemliststyleoption.cpp
  65     kitemviews/kitemlistview.cpp
  66     kitemviews/kitemlistviewaccessible.cpp
  67     kitemviews/kitemlistwidget.cpp
  68     kitemviews/kitemmodelbase.cpp
  69     kitemviews/kitemset.cpp
  70     kitemviews/kstandarditemlistgroupheader.cpp
  71     kitemviews/kstandarditemlistwidget.cpp
  72     kitemviews/kstandarditemlistview.cpp
  73     kitemviews/private/kdirectorycontentscounter.cpp
  74     kitemviews/private/kdirectorycontentscounterworker.cpp
  75     kitemviews/private/kfileitemclipboard.cpp
  76     kitemviews/private/kfileitemmodelfilter.cpp
  77     kitemviews/private/kitemlistheaderwidget.cpp
  78     kitemviews/private/kitemlistkeyboardsearchmanager.cpp
  79     kitemviews/private/kitemlistroleeditor.cpp
  80     kitemviews/private/kitemlistrubberband.cpp
  81     kitemviews/private/kitemlistselectiontoggle.cpp
  82     kitemviews/private/kitemlistsizehintresolver.cpp
  83     kitemviews/private/kitemlistsmoothscroller.cpp
  84     kitemviews/private/kitemlistviewanimation.cpp
  85     kitemviews/private/kitemlistviewlayouter.cpp
  86     kitemviews/private/kitemviewsutils.cpp
  87     kitemviews/private/kpixmapmodifier.cpp
  88     settings/applyviewpropsjob.cpp
  89     settings/viewmodes/viewmodesettings.cpp
  90     settings/viewpropertiesdialog.cpp
  91     settings/viewpropsprogressinfo.cpp
  92     selectionmode/actiontexthelper.cpp
  93     views/dolphinfileitemlistwidget.cpp
  94     views/dolphinitemlistview.cpp
  95     views/dolphinnewfilemenuobserver.cpp
  96     views/dolphinremoteencoding.cpp
  97     views/dolphinview.cpp
  98     views/dolphinviewactionhandler.cpp
  99     views/draganddrophelper.cpp
 100     views/versioncontrol/updateitemstatesthread.cpp
 101     views/versioncontrol/versioncontrolobserver.cpp
 102     views/viewmodecontroller.cpp
 103     views/viewproperties.cpp
 104     views/zoomlevelinfo.cpp
 105     dolphinremoveaction.cpp
 106     middleclickactioneventfilter.cpp
 107     dolphinnewfilemenu.cpp
 108
 109     kitemviews/kfileitemlistview.h
 110     kitemviews/kfileitemlistwidget.h
 111     kitemviews/kfileitemlisttostring.h
 112     kitemviews/kfileitemmodel.h
 113     kitemviews/kfileitemmodelrolesupdater.h
 114     kitemviews/kitemlistcontainer.h
 115     kitemviews/kitemlistcontroller.h
 116     kitemviews/kitemlistgroupheader.h
 117     kitemviews/kitemlistheader.h
 118     kitemviews/kitemlistselectionmanager.h
 119     kitemviews/kitemliststyleoption.h
 120     kitemviews/kitemlistview.h
 121     kitemviews/kitemlistviewaccessible.h
 122     kitemviews/kitemlistwidget.h
 123     kitemviews/kitemmodelbase.h
 124     kitemviews/kitemset.h
 125     kitemviews/kstandarditemlistgroupheader.h
 126     kitemviews/kstandarditemlistwidget.h
 127     kitemviews/kstandarditemlistview.h
 128     kitemviews/private/kdirectorycontentscounter.h
 129     kitemviews/private/kdirectorycontentscounterworker.h
 130     kitemviews/private/kfileitemclipboard.h
 131     kitemviews/private/kfileitemmodelfilter.h
 132     kitemviews/private/kitemlistheaderwidget.h
 133     kitemviews/private/kitemlistkeyboardsearchmanager.h
 134     kitemviews/private/kitemlistroleeditor.h
 135     kitemviews/private/kitemlistrubberband.h
 136     kitemviews/private/kitemlistselectiontoggle.h
 137     kitemviews/private/kitemlistsizehintresolver.h
 138     kitemviews/private/kitemlistsmoothscroller.h
 139     kitemviews/private/kitemlistviewanimation.h
 140     kitemviews/private/kitemlistviewlayouter.h
 141     kitemviews/private/kpixmapmodifier.h
 142     settings/applyviewpropsjob.h
 143     settings/viewmodes/viewmodesettings.h
 144     settings/viewpropertiesdialog.h
 145     settings/viewpropsprogressinfo.h
 146     selectionmode/actiontexthelper.h
 147     views/dolphinfileitemlistwidget.h
 148     views/dolphinitemlistview.h
 149     views/dolphinnewfilemenuobserver.h
 150     views/dolphinremoteencoding.h
 151     views/dolphinview.h
 152     views/dolphinviewactionhandler.h
 153     views/draganddrophelper.h
 154     views/versioncontrol/updateitemstatesthread.h
 155     views/versioncontrol/versioncontrolobserver.h
 156     views/viewmodecontroller.h
 157     views/viewproperties.h
 158     views/zoomlevelinfo.h
 159     dolphinremoveaction.h
 160     middleclickactioneventfilter.h
 161     dolphinnewfilemenu.h
 162 )
 163
 164 ecm_qt_declare_logging_category(dolphinprivate
 165     HEADER dolphindebug.h
 166     IDENTIFIER DolphinDebug
 167     CATEGORY_NAME org.kde.dolphin
 168     DESCRIPTION "dolphin"
 169     EXPORT DOLPHIN
 170 )
 171
 172 if(HAVE_BALOO)
 173     target_sources(dolphinprivate PRIVATE
 174         views/tooltips/dolphinfilemetadatawidget.cpp
 175         views/tooltips/tooltipmanager.cpp
 176         kitemviews/private/kbaloorolesprovider.cpp
 177         views/tooltips/dolphinfilemetadatawidget.h
 178         views/tooltips/tooltipmanager.h
 179         kitemviews/private/kbaloorolesprovider.h
 180     )
 181 endif()
 182
 183 kconfig_add_kcfg_files(dolphinprivate
 184     settings/dolphin_compactmodesettings.kcfgc
 185     settings/dolphin_directoryviewpropertysettings.kcfgc
 186     settings/dolphin_detailsmodesettings.kcfgc
 187     settings/dolphin_iconsmodesettings.kcfgc
 188     settings/dolphin_contentdisplaysettings.kcfgc
 189     settings/dolphin_generalsettings.kcfgc
 190     settings/dolphin_contextmenusettings.kcfgc
 191     settings/dolphin_versioncontrolsettings.kcfgc
 192 )
 193
 194 generate_export_header(dolphinprivate BASE_NAME dolphin)
 195
 196 target_link_libraries(
 197     dolphinprivate PUBLIC
 198     dolphinvcs
 199     Qt6::Concurrent
 200     Qt6::Gui
 201     KF6::I18n
 202     KF6::IconThemes
 203     KF6::KIOCore
 204     KF6::KIOWidgets
 205     KF6::KIOFileWidgets
 206     KF6::Completion
 207     KF6::TextWidgets
 208     KF6::ConfigCore
 209     KF6::NewStuffWidgets    # KNSWidgets::Button
 210     KF6::Parts
 211     KF6::WindowSystem
 212     KF6::WidgetsAddons
 213     KF6::Codecs
 214     KF6::KCMUtils
 215
 216     ${FTS_LIB}
 217 )
 218
 219 if(HAVE_BALOO)
 220     target_link_libraries(
 221         dolphinprivate PUBLIC
 222         KF6::FileMetaData
 223         KF6::Baloo
 224         KF6::BalooWidgets
 225     )
 226 endif()
 227
 228 set_target_properties(dolphinprivate PROPERTIES
 229     VERSION ${DOLPHINPRIVATE_VERSION}
 230     SOVERSION ${DOLPHINPRIVATE_SOVERSION}
 231 )
 232
 233 install(TARGETS dolphinprivate ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} LIBRARY NAMELINK_SKIP)
 234 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphin_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
 235
 236 ##########################################
 237 configure_file(dolphinpart.json.in ${CMAKE_CURRENT_BINARY_DIR}/dolphinpart.json @ONLY)
 238
 239 add_library(dolphinpart MODULE)
 240
 241 target_sources(dolphinpart PRIVATE
 242     dolphinpart.cpp
 243     dolphinpart_ext.cpp
 244     dolphindebug.cpp
 245     dolphinpart.h
 246     dolphinpart_ext.h
 247     dolphindebug.h
 248
 249     dolphinpart.qrc
 250 )
 251
 252 target_link_libraries(dolphinpart
 253     dolphinprivate
 254 )
 255
 256 install(TARGETS dolphinpart DESTINATION ${KDE_INSTALL_PLUGINDIR}/kf6/parts)
 257 install(FILES dolphinpartactions.desktop DESTINATION "${KDE_INSTALL_DATADIR}/dolphin/")
 258
 259 ##########################################
 260
 261 add_library(dolphinstatic STATIC)
 262
 263 target_sources(dolphinstatic PRIVATE
 264     admin/bar.cpp
 265     admin/workerintegration.cpp
 266     animatedheightwidget.cpp
 267     disabledactionnotifier.cpp
 268     dolphinbookmarkhandler.cpp
 269     dolphindockwidget.cpp
 270     dolphinmainwindow.cpp
 271     dolphinviewcontainer.cpp
 272     dolphincontextmenu.cpp
 273     dolphinnavigatorswidgetaction.cpp
 274     dolphintabbar.cpp
 275     dolphinplacesmodelsingleton.cpp
 276     dolphinrecenttabsmenu.cpp
 277     dolphintabpage.cpp
 278     dolphintabwidget.cpp
 279     dolphinurlnavigator.cpp
 280     dolphinurlnavigatorscontroller.cpp
 281     trash/dolphintrash.cpp
 282     filterbar/filterbar.cpp
 283     kitemviews/kfileitemlisttostring.cpp
 284     panels/places/placespanel.cpp
 285     panels/panel.cpp
 286     panels/folders/foldersitemlistwidget.cpp
 287     panels/folders/treeviewcontextmenu.cpp
 288     panels/folders/folderspanel.cpp
 289     panels/terminal/terminalpanel.cpp
 290     search/dolphinfacetswidget.cpp
 291     search/dolphinquery.cpp
 292     search/dolphinsearchbox.cpp
 293     selectionmode/actiontexthelper.cpp
 294     selectionmode/actionwithwidget.cpp
 295     selectionmode/backgroundcolorhelper.cpp
 296     selectionmode/bottombar.cpp
 297     selectionmode/bottombarcontentscontainer.cpp
 298     selectionmode/topbar.cpp
 299     settings/interface/folderstabssettingspage.cpp
 300     settings/interface/statusandlocationbarssettingspage.cpp
 301     settings/interface/confirmationssettingspage.cpp
 302     settings/interface/interfacesettingspage.cpp
 303     settings/interface/previewssettingspage.cpp
 304     settings/dolphinsettingsdialog.cpp
 305     settings/contextmenu/contextmenusettingspage.cpp
 306     settings/settingspagebase.cpp
 307     settings/servicemodel.cpp
 308     settings/trash/trashsettingspage.cpp
 309     settings/viewmodes/dolphinfontrequester.cpp
 310     settings/viewmodes/viewsettingspage.cpp
 311     settings/viewmodes/viewmodesettings.cpp
 312     settings/viewmodes/viewsettingstab.cpp
 313     settings/viewmodes/contentdisplaytab.cpp
 314     settings/viewmodes/generalviewsettingspage.cpp
 315     statusbar/dolphinstatusbar.cpp
 316     statusbar/mountpointobserver.cpp
 317     statusbar/mountpointobservercache.cpp
 318     statusbar/spaceinfoobserver.cpp
 319     statusbar/statusbarspaceinfo.cpp
 320     views/zoomlevelinfo.cpp
 321     dolphindebug.cpp
 322     global.cpp
 323     dolphin.qrc
 324
 325     admin/bar.h
 326     admin/workerintegration.h
 327     animatedheightwidget.h
 328     dolphinbookmarkhandler.h
 329     dolphindockwidget.h
 330     dolphinmainwindow.h
 331     dolphinviewcontainer.h
 332     dolphincontextmenu.h
 333     dolphinnavigatorswidgetaction.h
 334     dolphintabbar.h
 335     dolphinplacesmodelsingleton.h
 336     dolphinrecenttabsmenu.h
 337     dolphintabpage.h
 338     dolphintabwidget.h
 339     dolphinurlnavigator.h
 340     dolphinurlnavigatorscontroller.h
 341     trash/dolphintrash.h
 342     filterbar/filterbar.h
 343     kitemviews/kfileitemlisttostring.h
 344     panels/places/placespanel.h
 345     panels/panel.h
 346     panels/folders/foldersitemlistwidget.h
 347     panels/folders/treeviewcontextmenu.h
 348     panels/folders/folderspanel.h
 349     panels/terminal/terminalpanel.h
 350     search/dolphinfacetswidget.h
 351     search/dolphinquery.h
 352     search/dolphinsearchbox.h
 353     selectionmode/actiontexthelper.h
 354     selectionmode/actionwithwidget.h
 355     selectionmode/backgroundcolorhelper.h
 356     selectionmode/bottombar.h
 357     selectionmode/bottombarcontentscontainer.h
 358     selectionmode/topbar.h
 359     settings/interface/folderstabssettingspage.h
 360     settings/interface/statusandlocationbarssettingspage.h
 361     settings/interface/confirmationssettingspage.h
 362     settings/interface/interfacesettingspage.h
 363     settings/interface/previewssettingspage.h
 364     settings/dolphinsettingsdialog.h
 365     settings/contextmenu/contextmenusettingspage.h
 366     settings/settingspagebase.h
 367     settings/servicemodel.h
 368     settings/trash/trashsettingspage.h
 369     settings/viewmodes/dolphinfontrequester.h
 370     settings/viewmodes/viewsettingspage.h
 371     settings/viewmodes/viewmodesettings.h
 372     settings/viewmodes/viewsettingstab.h
 373     settings/viewmodes/contentdisplaytab.h
 374     settings/viewmodes/generalviewsettingspage.h
 375     statusbar/dolphinstatusbar.h
 376     statusbar/mountpointobserver.h
 377     statusbar/mountpointobservercache.h
 378     statusbar/spaceinfoobserver.h
 379     statusbar/statusbarspaceinfo.h
 380     views/zoomlevelinfo.h
 381     dolphindebug.h
 382     global.h
 383 )
 384
 385 if(HAVE_BALOO)
 386     target_sources(dolphinstatic PRIVATE
 387         panels/information/informationpanel.cpp
 388         panels/information/informationpanelcontent.cpp
 389         panels/information/pixmapviewer.cpp
 390         panels/information/phononwidget.cpp
 391         settings/interface/panelsettingspage.cpp
 392         panels/information/informationpanel.h
 393         panels/information/informationpanelcontent.h
 394         panels/information/pixmapviewer.h
 395         panels/information/phononwidget.h
 396         settings/interface/panelsettingspage.h
 397     )
 398
 399     kconfig_add_kcfg_files(dolphinstatic
 400         panels/information/dolphin_informationpanelsettings.kcfgc
 401     )
 402
 403 endif()
 404
 405 if(HAVE_KUSERFEEDBACK)
 406     target_sources(dolphinstatic PRIVATE
 407         userfeedback/dolphinfeedbackprovider.cpp
 408         userfeedback/settingsdatasource.cpp
 409         userfeedback/placesdatasource.cpp
 410         settings/userfeedback/userfeedbacksettingspage.cpp
 411         userfeedback/dolphinfeedbackprovider.h
 412         userfeedback/settingsdatasource.h
 413         userfeedback/placesdatasource.h
 414         settings/userfeedback/userfeedbacksettingspage.h
 415     )
 416 endif()
 417
 418 kconfig_add_kcfg_files(dolphinstatic
 419     panels/folders/dolphin_folderspanelsettings.kcfgc
 420     panels/places/dolphin_placespanelsettings.kcfgc
 421     settings/dolphin_compactmodesettings.kcfgc
 422     settings/dolphin_detailsmodesettings.kcfgc
 423     settings/dolphin_contextmenusettings.kcfgc
 424     settings/dolphin_iconsmodesettings.kcfgc
 425     settings/dolphin_contentdisplaysettings.kcfgc
 426     search/dolphin_searchsettings.kcfgc
 427     settings/dolphin_versioncontrolsettings.kcfgc
 428 )
 429 kconfig_add_kcfg_files(dolphinstatic GENERATE_MOC
 430     settings/dolphin_generalsettings.kcfgc
 431 )
 432
 433 qt_generate_dbus_interface(${CMAKE_CURRENT_SOURCE_DIR}/dolphinmainwindow.h org.kde.DolphinMainWindow.xml)
 434 qt_add_dbus_adaptor(dolphin_dbus_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindow.h DolphinMainWindow)
 435 qt_add_dbus_interface(dolphin_dbus_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindowinterface)
 436 qt_add_dbus_interface(dolphin_dbus_SRCS panels/terminal/org.kde.KIOFuse.VFS.xml kiofuse_interface)
 437
 438 target_sources(dolphinstatic PRIVATE
 439     ${dolphin_dbus_SRCS}
 440 )
 441
 442 target_include_directories(dolphinstatic SYSTEM PRIVATE ${PHONON_INCLUDES})
 443 target_link_libraries(dolphinstatic
 444     dolphinprivate
 445     KF6::CoreAddons
 446     KF6::KCMUtils
 447     KF6::DBusAddons
 448     KF6::Notifications
 449     KF6::BookmarksWidgets
 450     Phonon::phonon4qt6
 451 )
 452
 453 if (HAVE_PLASMA_ACTIVITIES)
 454     target_link_libraries(
 455         dolphinstatic
 456         Plasma::Activities
 457     )
 458 endif()
 459
 460 if (HAVE_KUSERFEEDBACK)
 461     target_link_libraries(
 462         dolphinstatic
 463         KF6::UserFeedbackCore
 464         KF6::UserFeedbackWidgets
 465     )
 466 endif()
 467
 468 add_executable(dolphin)
 469
 470 target_sources(dolphin PRIVATE
 471     dbusinterface.cpp
 472     dbusinterface.h
 473     main.cpp
 474 )
 475
 476 if(FLATPAK)
 477     target_compile_definitions(dolphin PRIVATE FLATPAK)
 478 endif()
 479
 480 # Install the icons on macOS and Windows
 481 ecm_add_app_icon(dolphin
 482     ICONS
 483         icons/128-apps-org.kde.dolphin.png
 484         icons/16-apps-org.kde.dolphin.png
 485         icons/22-apps-org.kde.dolphin.png
 486         icons/32-apps-org.kde.dolphin.png
 487         icons/48-apps-org.kde.dolphin.png
 488         icons/64-apps-org.kde.dolphin.png
 489 )
 490
 491 install(FILES icons/org.kde.dolphin.svg DESTINATION ${KDE_INSTALL_ICONDIR}/hicolor/scalable/apps)
 492
 493 target_link_libraries(dolphin
 494     PRIVATE
 495     dolphinprivate
 496     dolphinstatic
 497     KF6::Crash
 498 )
 499
 500 if (HAVE_X11)
 501     target_link_libraries(dolphin PRIVATE Qt::GuiPrivate)
 502 endif()
 503
 504 include(DbusInterfaceMacros)
 505
 506 generate_and_install_dbus_interface(
 507     dolphin
 508     dbusinterface.h
 509     org.freedesktop.FileManager1.xml
 510     OPTIONS -a
 511 )
 512
 513 install(TARGETS dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 514
 515 ##########################################
 516
 517 if(NOT WIN32)
 518     # The settings are still accessible from the hamburger menu
 519     add_library(kcm_dolphinviewmodes MODULE)
 520     add_library(kcm_dolphingeneral MODULE)
 521
 522     target_sources(kcm_dolphinviewmodes PRIVATE
 523         settings/kcm/kcmdolphinviewmodes.cpp
 524         settings/viewmodes/dolphinfontrequester.cpp
 525         settings/viewmodes/viewmodesettings.cpp
 526         settings/viewmodes/viewsettingstab.cpp
 527         settings/settingspagebase.cpp
 528         views/zoomlevelinfo.cpp
 529         settings/kcm/kcmdolphinviewmodes.h
 530         settings/viewmodes/dolphinfontrequester.h
 531         settings/viewmodes/viewmodesettings.h
 532         settings/viewmodes/viewsettingstab.h
 533         views/zoomlevelinfo.h)
 534
 535     target_sources(kcm_dolphingeneral PRIVATE
 536         settings/kcm/kcmdolphingeneral.cpp
 537         settings/interface/folderstabssettingspage.cpp
 538         settings/interface/statusandlocationbarssettingspage.cpp
 539         settings/interface/previewssettingspage.cpp
 540         settings/interface/confirmationssettingspage.cpp
 541         settings/settingspagebase.cpp
 542         settings/servicemodel.cpp
 543         dolphin_generalsettings.cpp
 544         dolphindebug.cpp
 545         dolphinmainwindowinterface.cpp
 546         views/viewproperties.cpp
 547         dolphin_directoryviewpropertysettings.cpp
 548         global.cpp
 549         settings/kcm/kcmdolphingeneral.h
 550         settings/interface/folderstabssettingspage.h
 551         settings/interface/statusandlocationbarssettingspage.h
 552         settings/interface/previewssettingspage.h
 553         settings/interface/confirmationssettingspage.h
 554         settings/settingspagebase.h
 555         settings/servicemodel.h
 556         dolphin_generalsettings.h
 557         dolphindebug.h
 558         dolphinmainwindowinterface.h
 559         views/viewproperties.h
 560         dolphin_directoryviewpropertysettings.h
 561         global.h
 562     )
 563
 564     kconfig_add_kcfg_files(kcm_dolphinviewmodes
 565         settings/dolphin_compactmodesettings.kcfgc
 566         settings/dolphin_directoryviewpropertysettings.kcfgc
 567         settings/dolphin_detailsmodesettings.kcfgc
 568         settings/dolphin_iconsmodesettings.kcfgc
 569         settings/dolphin_contentdisplaysettings.kcfgc
 570         settings/dolphin_generalsettings.kcfgc
 571         settings/dolphin_versioncontrolsettings.kcfgc
 572     )
 573
 574     kconfig_add_kcfg_files(kcm_dolphingeneral
 575         settings/dolphin_generalsettings.kcfgc)
 576
 577     target_link_libraries(kcm_dolphinviewmodes dolphinprivate)
 578     target_link_libraries(kcm_dolphingeneral dolphinprivate)
 579
 580     install( FILES org.kde.dolphin.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR} )
 581
 582     install(TARGETS kcm_dolphinviewmodes DESTINATION ${KDE_INSTALL_PLUGINDIR}/dolphin/kcms )
 583     install(TARGETS kcm_dolphingeneral DESTINATION ${KDE_INSTALL_PLUGINDIR}/dolphin/kcms )
 584 endif()
 585
 586 if(NOT WIN32)
 587     add_subdirectory(settings/contextmenu/servicemenuinstaller)
 588     install( FILES settings/contextmenu/servicemenu.knsrc DESTINATION ${KDE_INSTALL_KNSRCDIR} )
 589 endif()
 590
 591 ########### install files ###############
 592
 593 install( PROGRAMS org.kde.dolphin.desktop DESTINATION ${KDE_INSTALL_APPDIR} )
 594
 595 install( DIRECTORY DESTINATION "${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel" )
 596
 597 install(
 598     CODE "execute_process(COMMAND \"${CMAKE_COMMAND}\" -E create_symlink \"${KDE_INSTALL_FULL_APPDIR}/org.kde.dolphin.desktop\" \"\$ENV{DESTDIR}${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel/org.kde.dolphin.desktop\")"
 599 )
 600
 601 install( FILES settings/dolphin_directoryviewpropertysettings.kcfg
 602                settings/dolphin_generalsettings.kcfg
 603                settings/dolphin_contextmenusettings.kcfg
 604                settings/dolphin_compactmodesettings.kcfg
 605                settings/dolphin_iconsmodesettings.kcfg
 606                settings/dolphin_detailsmodesettings.kcfg
 607                settings/dolphin_contentdisplaysettings.kcfg
 608                settings/dolphin_versioncontrolsettings.kcfg
 609          DESTINATION ${KDE_INSTALL_KCFGDIR} )
 610
 611 install( FILES settings/dolphin_detailsmodesettings.upd
 612                settings/dolphin_directorysizemode.upd
 613                settings/dolphin_directorysizemode.py
 614          DESTINATION ${KDE_INSTALL_KCONFUPDATEDIR} )
 615
 616 if(BUILD_TESTING)
 617     add_subdirectory(tests)
 618 endif()