CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8.12)
   2
   3 project(Dolphin)
   4
   5 # KDE Application Version, managed by release script
   6 set (KDE_APPLICATIONS_VERSION_MAJOR "15")
   7 set (KDE_APPLICATIONS_VERSION_MINOR "08")
   8 set (KDE_APPLICATIONS_VERSION_MICRO "3")
   9 set (KDE_APPLICATIONS_VERSION "${KDE_APPLICATIONS_VERSION_MAJOR}.${KDE_APPLICATIONS_VERSION_MINOR}.${KDE_APPLICATIONS_VERSION_MICRO}")
  10
  11 set(QT_MIN_VERSION "5.4.0")
  12 set(KF5_MIN_VERSION "5.16.0")
  13 set(ECM_MIN_VERSION "1.6.0")
  14
  15 # ECM setup
  16 find_package(ECM ${ECM_MIN_VERSION} CONFIG REQUIRED)
  17 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH} ${CMAKE_SOURCE_DIR}/cmake)
  18
  19 include(ECMSetupVersion)
  20 include(ECMGenerateHeaders)
  21 include(ECMPackageConfigHelpers)
  22 include(GenerateExportHeader)
  23 include(FeatureSummary)
  24 include(KDEInstallDirs)
  25 include(KDECMakeSettings)
  26 include(KDEFrameworkCompilerSettings)
  27
  28 ecm_setup_version(${KDE_APPLICATIONS_VERSION} VARIABLE_PREFIX DOLPHIN
  29                   VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/src/dolphin_version.h"
  30 )
  31
  32 ecm_setup_version("5.0.0" VARIABLE_PREFIX DOLPHINVCS
  33                   VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/dolphinvcs_version.h"
  34                   PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/DolphinVcsConfigVersion.cmake"
  35                   SOVERSION 5
  36 )
  37
  38 ecm_setup_version("5.0.0" VARIABLE_PREFIX DOLPHINPRIVATE
  39                   SOVERSION 5
  40 )
  41
  42 find_package(Qt5 ${QT_MIN_VERSION} CONFIG REQUIRED COMPONENTS
  43     Core
  44     Concurrent
  45     Widgets
  46     Gui
  47     DBus
  48 )
  49
  50 find_package(KF5 ${KF5_MIN_VERSION} REQUIRED COMPONENTS
  51     DocTools
  52     Init
  53     KCMUtils
  54     NewStuff
  55     CoreAddons
  56     I18n
  57     DBusAddons
  58     Bookmarks
  59     Config
  60     KIO
  61     Parts
  62     Solid
  63     IconThemes
  64     Completion
  65     TextWidgets
  66     WindowSystem
  67     Notifications
  68 )
  69 find_package(KF5 ${KF5_MIN_VERSION} OPTIONAL_COMPONENTS
  70     Activities
  71 )
  72
  73 find_package(Phonon4Qt5 CONFIG REQUIRED)
  74
  75 find_package(KF5Baloo 4.97)
  76 set_package_properties(KF5Baloo PROPERTIES DESCRIPTION "Baloo Core libraries"
  77                        URL "http://www.kde.org"
  78                        TYPE OPTIONAL
  79                        PURPOSE "For adding desktop-wide search and tagging support to dolphin"
  80                       )
  81
  82 find_package(KF5BalooWidgets 4.97)
  83 set_package_properties(KF5BalooWidgets PROPERTIES DESCRIPTION "Baloos Widgets"
  84                        URL "http://www.kde.org"
  85                        TYPE OPTIONAL
  86                       )
  87
  88 find_package(KF5FileMetaData 4.97)
  89 set_package_properties(KF5FileMetaData PROPERTIES
  90                        URL "https://projects.kde.org/kfilemetadata"
  91                        TYPE OPTIONAL
  92                        PURPOSE "For accessing file metadata labels"
  93                       )
  94
  95 if (KF5Baloo_FOUND AND KF5BalooWidgets_FOUND AND KF5FileMetaData_FOUND)
  96     message(STATUS "Baloo packages are found")
  97     set(HAVE_BALOO TRUE)
  98 else()
  99     find_package(KF5 ${KF5_MIN_VERSION} REQUIRED COMPONENTS
 100         KDELibs4Support # for KFileMetaDataWidget
 101     )
 102 endif()
 103
 104 add_subdirectory(src)
 105 add_subdirectory(doc)
 106
 107 # CMake files
 108 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/DolphinVcs")
 109
 110 ecm_configure_package_config_file(
 111     "${CMAKE_CURRENT_SOURCE_DIR}/DolphinVcsConfig.cmake.in"
 112     "${CMAKE_CURRENT_BINARY_DIR}/DolphinVcsConfig.cmake"
 113     INSTALL_DESTINATION ${CMAKECONFIG_INSTALL_DIR}
 114 )
 115
 116 install(FILES
 117     "${CMAKE_CURRENT_BINARY_DIR}/DolphinVcsConfig.cmake"
 118     "${CMAKE_CURRENT_BINARY_DIR}/DolphinVcsConfigVersion.cmake"
 119     DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
 120     COMPONENT Devel
 121 )
 122
 123 install(EXPORT DolphinVcsTargets
 124     DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
 125     FILE DolphinVcsTargets.cmake
 126 )
 127
 128 install(FILES
 129     "${CMAKE_CURRENT_BINARY_DIR}/dolphinvcs_version.h"
 130     DESTINATION "${KDE_INSTALL_INCLUDEDIR}/Dolphin"
 131     COMPONENT Devel
 132 )
 133
 134 configure_file(org.kde.dolphin.FileManager1.service.in
 135                ${CMAKE_CURRENT_BINARY_DIR}/org.kde.dolphin.FileManager1.service)
 136 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/org.kde.dolphin.FileManager1.service
 137         DESTINATION ${DBUS_SERVICES_INSTALL_DIR})
 138
 139 feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)
 140