src/CMakeLists.txt

   1 include(ECMAddAppIcon)
   2
   3 configure_file(config-dolphin.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-dolphin.h)
   4
   5 add_definitions(
   6     -DTRANSLATION_DOMAIN=\"dolphin\"
   7 )
   8 remove_definitions(
   9     -DQT_NO_CAST_FROM_BYTEARRAY
  10     -DQT_NO_CAST_FROM_ASCII
  11     -DQT_NO_CAST_TO_ASCII
  12 )
  13
  14 ##########################################
  15
  16 add_library(dolphinvcs SHARED)
  17
  18 target_sources(dolphinvcs PRIVATE
  19     views/versioncontrol/kversioncontrolplugin.cpp
  20 )
  21
  22 generate_export_header(dolphinvcs BASE_NAME dolphinvcs)
  23
  24 target_link_libraries(
  25     dolphinvcs PUBLIC
  26     Qt${QT_MAJOR_VERSION}::Widgets
  27 )
  28
  29 set_target_properties(dolphinvcs PROPERTIES
  30     VERSION ${DOLPHINVCS_VERSION}
  31     SOVERSION ${DOLPHINVCS_SOVERSION}
  32     EXPORT_NAME DolphinVcs
  33 )
  34
  35 ecm_generate_headers(dolphinvcs_LIB_HEADERS
  36     HEADER_NAMES
  37     KVersionControlPlugin
  38
  39     RELATIVE "views/versioncontrol"
  40     REQUIRED_HEADERS dolphinvcs_LIB_HEADERS
  41 )
  42
  43 install(TARGETS dolphinvcs EXPORT DolphinVcsTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
  44
  45 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphinvcs_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
  46 install(FILES ${dolphinvcs_LIB_HEADERS} DESTINATION "${KDE_INSTALL_INCLUDEDIR}/Dolphin" COMPONENT Devel)
  47
  48 ########### next target ###############
  49
  50 add_library(dolphinprivate SHARED)
  51
  52 target_sources(dolphinprivate PRIVATE
  53     kitemviews/kfileitemlistview.cpp
  54     kitemviews/kfileitemlistwidget.cpp
  55     kitemviews/kfileitemlisttostring.cpp
  56     kitemviews/kfileitemmodel.cpp
  57     kitemviews/kfileitemmodelrolesupdater.cpp
  58     kitemviews/kitemlistcontainer.cpp
  59     kitemviews/kitemlistcontroller.cpp
  60     kitemviews/kitemlistgroupheader.cpp
  61     kitemviews/kitemlistheader.cpp
  62     kitemviews/kitemlistselectionmanager.cpp
  63     kitemviews/kitemliststyleoption.cpp
  64     kitemviews/kitemlistview.cpp
  65     kitemviews/kitemlistviewaccessible.cpp
  66     kitemviews/kitemlistwidget.cpp
  67     kitemviews/kitemmodelbase.cpp
  68     kitemviews/kitemset.cpp
  69     kitemviews/kstandarditemlistgroupheader.cpp
  70     kitemviews/kstandarditemlistwidget.cpp
  71     kitemviews/kstandarditemlistview.cpp
  72     kitemviews/private/kdirectorycontentscounter.cpp
  73     kitemviews/private/kdirectorycontentscounterworker.cpp
  74     kitemviews/private/kfileitemclipboard.cpp
  75     kitemviews/private/kfileitemmodelfilter.cpp
  76     kitemviews/private/kitemlistheaderwidget.cpp
  77     kitemviews/private/kitemlistkeyboardsearchmanager.cpp
  78     kitemviews/private/kitemlistroleeditor.cpp
  79     kitemviews/private/kitemlistrubberband.cpp
  80     kitemviews/private/kitemlistselectiontoggle.cpp
  81     kitemviews/private/kitemlistsizehintresolver.cpp
  82     kitemviews/private/kitemlistsmoothscroller.cpp
  83     kitemviews/private/kitemlistviewanimation.cpp
  84     kitemviews/private/kitemlistviewlayouter.cpp
  85     kitemviews/private/kpixmapmodifier.cpp
  86     settings/applyviewpropsjob.cpp
  87     settings/viewmodes/viewmodesettings.cpp
  88     settings/viewpropertiesdialog.cpp
  89     settings/viewpropsprogressinfo.cpp
  90     selectionmode/actiontexthelper.cpp
  91     views/dolphinfileitemlistwidget.cpp
  92     views/dolphinitemlistview.cpp
  93     views/dolphinnewfilemenuobserver.cpp
  94     views/dolphinremoteencoding.cpp
  95     views/dolphinview.cpp
  96     views/dolphinviewactionhandler.cpp
  97     views/draganddrophelper.cpp
  98     views/versioncontrol/updateitemstatesthread.cpp
  99     views/versioncontrol/versioncontrolobserver.cpp
 100     views/viewmodecontroller.cpp
 101     views/viewproperties.cpp
 102     views/zoomlevelinfo.cpp
 103     dolphinremoveaction.cpp
 104     middleclickactioneventfilter.cpp
 105     dolphinnewfilemenu.cpp
 106
 107     kitemviews/kfileitemlistview.h
 108     kitemviews/kfileitemlistwidget.h
 109     kitemviews/kfileitemlisttostring.h
 110     kitemviews/kfileitemmodel.h
 111     kitemviews/kfileitemmodelrolesupdater.h
 112     kitemviews/kitemlistcontainer.h
 113     kitemviews/kitemlistcontroller.h
 114     kitemviews/kitemlistgroupheader.h
 115     kitemviews/kitemlistheader.h
 116     kitemviews/kitemlistselectionmanager.h
 117     kitemviews/kitemliststyleoption.h
 118     kitemviews/kitemlistview.h
 119     kitemviews/kitemlistviewaccessible.h
 120     kitemviews/kitemlistwidget.h
 121     kitemviews/kitemmodelbase.h
 122     kitemviews/kitemset.h
 123     kitemviews/kstandarditemlistgroupheader.h
 124     kitemviews/kstandarditemlistwidget.h
 125     kitemviews/kstandarditemlistview.h
 126     kitemviews/private/kdirectorycontentscounter.h
 127     kitemviews/private/kdirectorycontentscounterworker.h
 128     kitemviews/private/kfileitemclipboard.h
 129     kitemviews/private/kfileitemmodelfilter.h
 130     kitemviews/private/kitemlistheaderwidget.h
 131     kitemviews/private/kitemlistkeyboardsearchmanager.h
 132     kitemviews/private/kitemlistroleeditor.h
 133     kitemviews/private/kitemlistrubberband.h
 134     kitemviews/private/kitemlistselectiontoggle.h
 135     kitemviews/private/kitemlistsizehintresolver.h
 136     kitemviews/private/kitemlistsmoothscroller.h
 137     kitemviews/private/kitemlistviewanimation.h
 138     kitemviews/private/kitemlistviewlayouter.h
 139     kitemviews/private/kpixmapmodifier.h
 140     settings/applyviewpropsjob.h
 141     settings/viewmodes/viewmodesettings.h
 142     settings/viewpropertiesdialog.h
 143     settings/viewpropsprogressinfo.h
 144     selectionmode/actiontexthelper.h
 145     views/dolphinfileitemlistwidget.h
 146     views/dolphinitemlistview.h
 147     views/dolphinnewfilemenuobserver.h
 148     views/dolphinremoteencoding.h
 149     views/dolphinview.h
 150     views/dolphinviewactionhandler.h
 151     views/draganddrophelper.h
 152     views/versioncontrol/updateitemstatesthread.h
 153     views/versioncontrol/versioncontrolobserver.h
 154     views/viewmodecontroller.h
 155     views/viewproperties.h
 156     views/zoomlevelinfo.h
 157     dolphinremoveaction.h
 158     middleclickactioneventfilter.h
 159     dolphinnewfilemenu.h
 160 )
 161
 162 ecm_qt_declare_logging_category(dolphinprivate
 163     HEADER dolphindebug.h
 164     IDENTIFIER DolphinDebug
 165     CATEGORY_NAME org.kde.dolphin
 166     DESCRIPTION "dolphin"
 167     EXPORT DOLPHIN
 168 )
 169
 170 if(HAVE_BALOO)
 171     target_sources(dolphinprivate PRIVATE
 172         views/tooltips/dolphinfilemetadatawidget.cpp
 173         views/tooltips/tooltipmanager.cpp
 174         kitemviews/private/kbaloorolesprovider.cpp
 175         views/tooltips/dolphinfilemetadatawidget.h
 176         views/tooltips/tooltipmanager.h
 177         kitemviews/private/kbaloorolesprovider.h
 178     )
 179 endif()
 180
 181 kconfig_add_kcfg_files(dolphinprivate
 182     settings/dolphin_compactmodesettings.kcfgc
 183     settings/dolphin_directoryviewpropertysettings.kcfgc
 184     settings/dolphin_detailsmodesettings.kcfgc
 185     settings/dolphin_iconsmodesettings.kcfgc
 186     settings/dolphin_generalsettings.kcfgc
 187     settings/dolphin_contextmenusettings.kcfgc
 188     settings/dolphin_versioncontrolsettings.kcfgc
 189 )
 190
 191 generate_export_header(dolphinprivate BASE_NAME dolphin)
 192
 193 target_link_libraries(
 194     dolphinprivate PUBLIC
 195     dolphinvcs
 196     Qt${QT_MAJOR_VERSION}::Concurrent
 197     Qt${QT_MAJOR_VERSION}::Gui
 198     KF6::I18n
 199     KF6::IconThemes
 200     KF6::KIOCore
 201     KF6::KIOWidgets
 202     KF6::KIOFileWidgets
 203     KF6::Completion
 204     KF6::TextWidgets
 205     KF6::ConfigCore
 206     KF6::NewStuffWidgets    # KNSWidgets::Button
 207     KF6::Parts
 208     KF6::WindowSystem
 209     KF6::WidgetsAddons
 210     KF6::Codecs
 211     KF6::KCMUtils
 212
 213     KF6::MoreTools
 214 )
 215
 216 if(HAVE_BALOO)
 217     target_link_libraries(
 218         dolphinprivate PUBLIC
 219         KF6::FileMetaData
 220         KF6::Baloo
 221         KF6::BalooWidgets
 222     )
 223 endif()
 224
 225 set_target_properties(dolphinprivate PROPERTIES
 226     VERSION ${DOLPHINPRIVATE_VERSION}
 227     SOVERSION ${DOLPHINPRIVATE_SOVERSION}
 228 )
 229
 230 install(TARGETS dolphinprivate ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} LIBRARY NAMELINK_SKIP)
 231 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphin_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
 232
 233 ##########################################
 234 configure_file(dolphinpart.json.in ${CMAKE_CURRENT_BINARY_DIR}/dolphinpart.json @ONLY)
 235
 236 add_library(dolphinpart MODULE)
 237
 238 target_sources(dolphinpart PRIVATE
 239     dolphinpart.cpp
 240     dolphinpart_ext.cpp
 241     dolphindebug.cpp
 242     dolphinpart.h
 243     dolphinpart_ext.h
 244     dolphindebug.h
 245
 246     dolphinpart.qrc
 247 )
 248
 249 target_link_libraries(dolphinpart
 250     dolphinprivate
 251 )
 252
 253 install(TARGETS dolphinpart DESTINATION ${KDE_INSTALL_PLUGINDIR}/kf${QT_MAJOR_VERSION}/parts)
 254 install(FILES dolphinpartactions.desktop DESTINATION "${KDE_INSTALL_DATADIR}/dolphin/")
 255
 256 ##########################################
 257
 258 add_library(dolphinstatic STATIC)
 259
 260 target_sources(dolphinstatic PRIVATE
 261     dolphinbookmarkhandler.cpp
 262     dolphindockwidget.cpp
 263     dolphinmainwindow.cpp
 264     dolphinviewcontainer.cpp
 265     dolphincontextmenu.cpp
 266     dolphinnavigatorswidgetaction.cpp
 267     dolphintabbar.cpp
 268     dolphinplacesmodelsingleton.cpp
 269     dolphinrecenttabsmenu.cpp
 270     dolphintabpage.cpp
 271     dolphintabwidget.cpp
 272     dolphinurlnavigator.cpp
 273     dolphinurlnavigatorscontroller.cpp
 274     trash/dolphintrash.cpp
 275     filterbar/filterbar.cpp
 276     kitemviews/kfileitemlisttostring.cpp
 277     panels/places/placespanel.cpp
 278     panels/panel.cpp
 279     panels/folders/foldersitemlistwidget.cpp
 280     panels/folders/treeviewcontextmenu.cpp
 281     panels/folders/folderspanel.cpp
 282     panels/terminal/terminalpanel.cpp
 283     search/dolphinfacetswidget.cpp
 284     search/dolphinquery.cpp
 285     search/dolphinsearchbox.cpp
 286     selectionmode/actiontexthelper.cpp
 287     selectionmode/actionwithwidget.cpp
 288     selectionmode/backgroundcolorhelper.cpp
 289     selectionmode/bottombar.cpp
 290     selectionmode/bottombarcontentscontainer.cpp
 291     selectionmode/topbar.cpp
 292     settings/general/behaviorsettingspage.cpp
 293     settings/general/confirmationssettingspage.cpp
 294     settings/general/generalsettingspage.cpp
 295     settings/general/previewssettingspage.cpp
 296     settings/general/statusbarsettingspage.cpp
 297     settings/dolphinsettingsdialog.cpp
 298     settings/navigation/navigationsettingspage.cpp
 299     settings/contextmenu/contextmenusettingspage.cpp
 300     settings/settingspagebase.cpp
 301     settings/serviceitemdelegate.cpp
 302     settings/servicemodel.cpp
 303     settings/startup/startupsettingspage.cpp
 304     settings/trash/trashsettingspage.cpp
 305     settings/viewmodes/dolphinfontrequester.cpp
 306     settings/viewmodes/viewsettingspage.cpp
 307     settings/viewmodes/viewmodesettings.cpp
 308     settings/viewmodes/viewsettingstab.cpp
 309     statusbar/dolphinstatusbar.cpp
 310     statusbar/mountpointobserver.cpp
 311     statusbar/mountpointobservercache.cpp
 312     statusbar/spaceinfoobserver.cpp
 313     statusbar/statusbarspaceinfo.cpp
 314     views/zoomlevelinfo.cpp
 315     dolphindebug.cpp
 316     global.cpp
 317     dolphin.qrc
 318
 319     dolphinbookmarkhandler.h
 320     dolphindockwidget.h
 321     dolphinmainwindow.h
 322     dolphinviewcontainer.h
 323     dolphincontextmenu.h
 324     dolphinnavigatorswidgetaction.h
 325     dolphintabbar.h
 326     dolphinplacesmodelsingleton.h
 327     dolphinrecenttabsmenu.h
 328     dolphintabpage.h
 329     dolphintabwidget.h
 330     dolphinurlnavigator.h
 331     dolphinurlnavigatorscontroller.h
 332     trash/dolphintrash.h
 333     filterbar/filterbar.h
 334     kitemviews/kfileitemlisttostring.h
 335     panels/places/placespanel.h
 336     panels/panel.h
 337     panels/folders/foldersitemlistwidget.h
 338     panels/folders/treeviewcontextmenu.h
 339     panels/folders/folderspanel.h
 340     panels/terminal/terminalpanel.h
 341     search/dolphinfacetswidget.h
 342     search/dolphinquery.h
 343     search/dolphinsearchbox.h
 344     selectionmode/actiontexthelper.h
 345     selectionmode/actionwithwidget.h
 346     selectionmode/backgroundcolorhelper.h
 347     selectionmode/bottombar.h
 348     selectionmode/bottombarcontentscontainer.h
 349     selectionmode/topbar.h
 350     settings/general/behaviorsettingspage.h
 351     settings/general/confirmationssettingspage.h
 352     settings/general/generalsettingspage.h
 353     settings/general/previewssettingspage.h
 354     settings/general/statusbarsettingspage.h
 355     settings/dolphinsettingsdialog.h
 356     settings/navigation/navigationsettingspage.h
 357     settings/contextmenu/contextmenusettingspage.h
 358     settings/settingspagebase.h
 359     settings/serviceitemdelegate.h
 360     settings/servicemodel.h
 361     settings/startup/startupsettingspage.h
 362     settings/trash/trashsettingspage.h
 363     settings/viewmodes/dolphinfontrequester.h
 364     settings/viewmodes/viewsettingspage.h
 365     settings/viewmodes/viewmodesettings.h
 366     settings/viewmodes/viewsettingstab.h
 367     statusbar/dolphinstatusbar.h
 368     statusbar/mountpointobserver.h
 369     statusbar/mountpointobservercache.h
 370     statusbar/spaceinfoobserver.h
 371     statusbar/statusbarspaceinfo.h
 372     views/zoomlevelinfo.h
 373     dolphindebug.h
 374     global.h
 375 )
 376
 377 if(HAVE_BALOO)
 378     target_sources(dolphinstatic PRIVATE
 379         panels/information/informationpanel.cpp
 380         panels/information/informationpanelcontent.cpp
 381         panels/information/pixmapviewer.cpp
 382         panels/information/phononwidget.cpp
 383         panels/information/informationpanel.h
 384         panels/information/informationpanelcontent.h
 385         panels/information/pixmapviewer.h
 386         panels/information/phononwidget.h
 387     )
 388 endif()
 389
 390 if(HAVE_KUSERFEEDBACK)
 391     target_sources(dolphinstatic PRIVATE
 392         userfeedback/dolphinfeedbackprovider.cpp
 393         userfeedback/settingsdatasource.cpp
 394         userfeedback/placesdatasource.cpp
 395         settings/userfeedback/userfeedbacksettingspage.cpp
 396         userfeedback/dolphinfeedbackprovider.h
 397         userfeedback/settingsdatasource.h
 398         userfeedback/placesdatasource.h
 399         settings/userfeedback/userfeedbacksettingspage.h
 400     )
 401 endif()
 402
 403 kconfig_add_kcfg_files(dolphinstatic
 404     panels/folders/dolphin_folderspanelsettings.kcfgc
 405     panels/information/dolphin_informationpanelsettings.kcfgc
 406     panels/places/dolphin_placespanelsettings.kcfgc
 407     settings/dolphin_compactmodesettings.kcfgc
 408     settings/dolphin_detailsmodesettings.kcfgc
 409     settings/dolphin_contextmenusettings.kcfgc
 410     settings/dolphin_iconsmodesettings.kcfgc
 411     search/dolphin_searchsettings.kcfgc
 412     settings/dolphin_versioncontrolsettings.kcfgc
 413 )
 414 kconfig_add_kcfg_files(dolphinstatic GENERATE_MOC
 415     settings/dolphin_generalsettings.kcfgc
 416 )
 417
 418 qt_generate_dbus_interface(${CMAKE_CURRENT_SOURCE_DIR}/dolphinmainwindow.h org.kde.DolphinMainWindow.xml)
 419 qt_add_dbus_adaptor(dolphin_dbus_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindow.h DolphinMainWindow)
 420 qt_add_dbus_interface(dolphin_dbus_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindowinterface)
 421 qt_add_dbus_interface(dolphin_dbus_SRCS panels/terminal/org.kde.KIOFuse.VFS.xml kiofuse_interface)
 422
 423 target_sources(dolphinstatic PRIVATE
 424     ${dolphin_dbus_SRCS}
 425 )
 426
 427 target_include_directories(dolphinstatic SYSTEM PRIVATE ${PHONON_INCLUDES})
 428 target_link_libraries(dolphinstatic
 429     dolphinprivate
 430     KF6::CoreAddons
 431     KF6::KCMUtils
 432     KF6::DBusAddons
 433     KF6::Notifications
 434     Phonon::phonon4qt${QT_MAJOR_VERSION}
 435 )
 436
 437 if (HAVE_KACTIVITIES)
 438     target_link_libraries(
 439         dolphinstatic
 440         KF6::Activities
 441     )
 442 endif()
 443
 444 if (HAVE_KUSERFEEDBACK)
 445     target_link_libraries(
 446         dolphinstatic
 447         KUserFeedbackCoreQt6
 448         KUserFeedbackWidgetsQt6
 449     )
 450 endif()
 451
 452 add_executable(dolphin)
 453
 454 target_sources(dolphin PRIVATE
 455     dbusinterface.cpp
 456     dbusinterface.h
 457     main.cpp
 458 )
 459
 460 if(FLATPAK)
 461     target_compile_definitions(dolphin PRIVATE FLATPAK)
 462 endif()
 463
 464 # Sets the icon on Windows and OSX
 465 file(GLOB ICONS_SRCS "${CMAKE_CURRENT_SOURCE_DIR}/icons/*system-file-manager.png")
 466 ecm_add_app_icon(dolphin ICONS ${ICONS_SRCS})
 467
 468 target_link_libraries(dolphin
 469     PRIVATE
 470     dolphinprivate
 471     dolphinstatic
 472     KF6::Crash
 473 )
 474
 475 if (HAVE_X11)
 476     if (QT_MAJOR_VERSION STREQUAL "5")
 477         target_link_libraries(dolphin PRIVATE Qt{QT_MAJOR_VERSION}::X11Extras)
 478     else()
 479         target_link_libraries(dolphin PRIVATE Qt::GuiPrivate)
 480     endif()
 481 endif()
 482
 483 include(DbusInterfaceMacros)
 484
 485 generate_and_install_dbus_interface(
 486     dolphin
 487     dbusinterface.h
 488     org.freedesktop.FileManager1.xml
 489     OPTIONS -a
 490 )
 491
 492 install(TARGETS dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 493
 494 ##########################################
 495
 496 if(NOT WIN32)
 497     # The settings are still accessible from the hamburger menu
 498     add_library(kcm_dolphinviewmodes MODULE)
 499     add_library(kcm_dolphinnavigation MODULE)
 500     add_library(kcm_dolphingeneral MODULE)
 501
 502     target_sources(kcm_dolphinviewmodes PRIVATE
 503         settings/kcm/kcmdolphinviewmodes.cpp
 504         settings/viewmodes/dolphinfontrequester.cpp
 505         settings/viewmodes/viewmodesettings.cpp
 506         settings/viewmodes/viewsettingstab.cpp
 507         views/zoomlevelinfo.cpp
 508         settings/kcm/kcmdolphinviewmodes.h
 509         settings/viewmodes/dolphinfontrequester.h
 510         settings/viewmodes/viewmodesettings.h
 511         settings/viewmodes/viewsettingstab.h
 512         views/zoomlevelinfo.h)
 513
 514     target_sources(kcm_dolphinnavigation PRIVATE
 515         settings/kcm/kcmdolphinnavigation.cpp
 516         settings/navigation/navigationsettingspage.cpp
 517         settings/settingspagebase.cpp
 518         settings/kcm/kcmdolphinnavigation.h
 519         settings/navigation/navigationsettingspage.h
 520         settings/settingspagebase.h
 521     )
 522
 523     target_sources(kcm_dolphingeneral PRIVATE
 524         settings/kcm/kcmdolphingeneral.cpp
 525         settings/general/behaviorsettingspage.cpp
 526         settings/general/previewssettingspage.cpp
 527         settings/general/confirmationssettingspage.cpp
 528         settings/settingspagebase.cpp
 529         settings/serviceitemdelegate.cpp
 530         settings/servicemodel.cpp
 531         settings/kcm/kcmdolphingeneral.h
 532         settings/general/behaviorsettingspage.h
 533         settings/general/previewssettingspage.h
 534         settings/general/confirmationssettingspage.h
 535         settings/settingspagebase.h
 536         settings/serviceitemdelegate.h
 537         settings/servicemodel.h
 538     )
 539
 540     kconfig_add_kcfg_files(kcm_dolphinviewmodes
 541         settings/dolphin_compactmodesettings.kcfgc
 542         settings/dolphin_directoryviewpropertysettings.kcfgc
 543         settings/dolphin_detailsmodesettings.kcfgc
 544         settings/dolphin_iconsmodesettings.kcfgc
 545         settings/dolphin_generalsettings.kcfgc
 546         settings/dolphin_versioncontrolsettings.kcfgc
 547     )
 548
 549     kconfig_add_kcfg_files(kcm_dolphinnavigation
 550         settings/dolphin_generalsettings.kcfgc)
 551
 552     kconfig_add_kcfg_files(kcm_dolphingeneral
 553         settings/dolphin_generalsettings.kcfgc)
 554
 555     target_link_libraries(kcm_dolphinviewmodes dolphinprivate)
 556     target_link_libraries(kcm_dolphinnavigation dolphinprivate)
 557     target_link_libraries(kcm_dolphingeneral dolphinprivate)
 558
 559     install( FILES org.kde.dolphin.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR} )
 560
 561     install(TARGETS kcm_dolphinviewmodes DESTINATION ${KDE_INSTALL_PLUGINDIR}/dolphin/kcms )
 562     install(TARGETS kcm_dolphinnavigation DESTINATION ${KDE_INSTALL_PLUGINDIR}/dolphin/kcms )
 563     install(TARGETS kcm_dolphingeneral DESTINATION ${KDE_INSTALL_PLUGINDIR}/dolphin/kcms )
 564 endif()
 565
 566 if(NOT WIN32)
 567     add_subdirectory(settings/contextmenu/servicemenuinstaller)
 568     install( FILES settings/contextmenu/servicemenu.knsrc DESTINATION ${KDE_INSTALL_KNSRCDIR} )
 569 endif()
 570
 571 ########### install files ###############
 572
 573 install( PROGRAMS org.kde.dolphin.desktop DESTINATION ${KDE_INSTALL_APPDIR} )
 574
 575 install( DIRECTORY DESTINATION "${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel" )
 576
 577 install(
 578     CODE "execute_process(COMMAND \"${CMAKE_COMMAND}\" -E create_symlink \"${KDE_INSTALL_FULL_APPDIR}/org.kde.dolphin.desktop\" \"\$ENV{DESTDIR}${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel/org.kde.dolphin.desktop\")"
 579 )
 580
 581 install( FILES settings/dolphin_directoryviewpropertysettings.kcfg
 582                settings/dolphin_generalsettings.kcfg
 583                settings/dolphin_contextmenusettings.kcfg
 584                settings/dolphin_compactmodesettings.kcfg
 585                settings/dolphin_iconsmodesettings.kcfg
 586                settings/dolphin_detailsmodesettings.kcfg
 587                settings/dolphin_versioncontrolsettings.kcfg
 588          DESTINATION ${KDE_INSTALL_KCFGDIR} )
 589
 590 install( FILES settings/dolphin_detailsmodesettings.upd
 591          DESTINATION ${KDE_INSTALL_KCONFUPDATEDIR} )
 592
 593 if(BUILD_TESTING)
 594     add_subdirectory(tests)
 595 endif()