src/CMakeLists.txt

   1 include(ECMAddAppIcon)
   2
   3 configure_file(config-baloo.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-baloo.h)
   4
   5 configure_file(config-kactivities.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-kactivities.h)
   6
   7 configure_file(config-packagekit.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-packagekit.h)
   8
   9 configure_file(config-terminal.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-terminal.h)
  10
  11 configure_file(config-kuserfeedback.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-kuserfeedback.h)
  12
  13 add_definitions(
  14     -DTRANSLATION_DOMAIN=\"dolphin\"
  15 )
  16 remove_definitions(
  17     -DQT_NO_CAST_FROM_BYTEARRAY
  18     -DQT_NO_CAST_FROM_ASCII
  19     -DQT_NO_CAST_TO_ASCII
  20 )
  21
  22 ##########################################
  23
  24 add_library(dolphinvcs SHARED)
  25
  26 target_sources(dolphinvcs PRIVATE
  27     views/versioncontrol/kversioncontrolplugin.cpp
  28 )
  29
  30 generate_export_header(dolphinvcs BASE_NAME dolphinvcs)
  31
  32 target_link_libraries(
  33     dolphinvcs PUBLIC
  34     Qt${QT_MAJOR_VERSION}::Widgets
  35 )
  36
  37 set_target_properties(dolphinvcs PROPERTIES
  38     VERSION ${DOLPHINVCS_VERSION}
  39     SOVERSION ${DOLPHINVCS_SOVERSION}
  40     EXPORT_NAME DolphinVcs
  41 )
  42
  43 ecm_generate_headers(dolphinvcs_LIB_HEADERS
  44     HEADER_NAMES
  45     KVersionControlPlugin
  46
  47     RELATIVE "views/versioncontrol"
  48     REQUIRED_HEADERS dolphinvcs_LIB_HEADERS
  49 )
  50
  51 install(TARGETS dolphinvcs EXPORT DolphinVcsTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
  52
  53 install(FILES views/versioncontrol/fileviewversioncontrolplugin.desktop DESTINATION ${KDE_INSTALL_KSERVICETYPESDIR})
  54 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphinvcs_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
  55 install(FILES ${dolphinvcs_LIB_HEADERS} DESTINATION "${KDE_INSTALL_INCLUDEDIR}/Dolphin" COMPONENT Devel)
  56
  57 ########### next target ###############
  58
  59 add_library(dolphinprivate SHARED)
  60
  61 target_sources(dolphinprivate PRIVATE
  62     kitemviews/kfileitemlistview.cpp
  63     kitemviews/kfileitemlistwidget.cpp
  64     kitemviews/kfileitemlisttostring.cpp
  65     kitemviews/kfileitemmodel.cpp
  66     kitemviews/kfileitemmodelrolesupdater.cpp
  67     kitemviews/kitemlistcontainer.cpp
  68     kitemviews/kitemlistcontroller.cpp
  69     kitemviews/kitemlistgroupheader.cpp
  70     kitemviews/kitemlistheader.cpp
  71     kitemviews/kitemlistselectionmanager.cpp
  72     kitemviews/kitemliststyleoption.cpp
  73     kitemviews/kitemlistview.cpp
  74     kitemviews/kitemlistviewaccessible.cpp
  75     kitemviews/kitemlistwidget.cpp
  76     kitemviews/kitemmodelbase.cpp
  77     kitemviews/kitemset.cpp
  78     kitemviews/kstandarditemlistgroupheader.cpp
  79     kitemviews/kstandarditemlistwidget.cpp
  80     kitemviews/kstandarditemlistview.cpp
  81     kitemviews/private/kdirectorycontentscounter.cpp
  82     kitemviews/private/kdirectorycontentscounterworker.cpp
  83     kitemviews/private/kfileitemclipboard.cpp
  84     kitemviews/private/kfileitemmodelfilter.cpp
  85     kitemviews/private/kitemlistheaderwidget.cpp
  86     kitemviews/private/kitemlistkeyboardsearchmanager.cpp
  87     kitemviews/private/kitemlistroleeditor.cpp
  88     kitemviews/private/kitemlistrubberband.cpp
  89     kitemviews/private/kitemlistselectiontoggle.cpp
  90     kitemviews/private/kitemlistsizehintresolver.cpp
  91     kitemviews/private/kitemlistsmoothscroller.cpp
  92     kitemviews/private/kitemlistviewanimation.cpp
  93     kitemviews/private/kitemlistviewlayouter.cpp
  94     kitemviews/private/kpixmapmodifier.cpp
  95     settings/applyviewpropsjob.cpp
  96     settings/viewmodes/viewmodesettings.cpp
  97     settings/viewpropertiesdialog.cpp
  98     settings/viewpropsprogressinfo.cpp
  99     views/dolphinfileitemlistwidget.cpp
 100     views/dolphinitemlistview.cpp
 101     views/dolphinnewfilemenuobserver.cpp
 102     views/dolphinremoteencoding.cpp
 103     views/dolphinview.cpp
 104     views/dolphinviewactionhandler.cpp
 105     views/draganddrophelper.cpp
 106     views/versioncontrol/updateitemstatesthread.cpp
 107     views/versioncontrol/versioncontrolobserver.cpp
 108     views/viewmodecontroller.cpp
 109     views/viewproperties.cpp
 110     views/zoomlevelinfo.cpp
 111     dolphinremoveaction.cpp
 112     middleclickactioneventfilter.cpp
 113     dolphinnewfilemenu.cpp
 114 )
 115
 116 ecm_qt_declare_logging_category(dolphinprivate
 117     HEADER dolphindebug.h
 118     IDENTIFIER DolphinDebug
 119     CATEGORY_NAME org.kde.dolphin
 120     DESCRIPTION "dolphin"
 121     EXPORT DOLPHIN
 122 )
 123
 124 if(HAVE_BALOO)
 125     target_sources(dolphinprivate PRIVATE
 126         views/tooltips/dolphinfilemetadatawidget.cpp
 127         views/tooltips/tooltipmanager.cpp
 128         kitemviews/private/kbaloorolesprovider.cpp
 129     )
 130 endif()
 131
 132 kconfig_add_kcfg_files(dolphinprivate
 133     settings/dolphin_compactmodesettings.kcfgc
 134     settings/dolphin_directoryviewpropertysettings.kcfgc
 135     settings/dolphin_detailsmodesettings.kcfgc
 136     settings/dolphin_iconsmodesettings.kcfgc
 137     settings/dolphin_generalsettings.kcfgc
 138     settings/dolphin_contextmenusettings.kcfgc
 139     settings/dolphin_versioncontrolsettings.kcfgc
 140 )
 141
 142 generate_export_header(dolphinprivate BASE_NAME dolphin)
 143
 144 target_link_libraries(
 145     dolphinprivate PUBLIC
 146     dolphinvcs
 147     Qt${QT_MAJOR_VERSION}::Concurrent
 148     Qt${QT_MAJOR_VERSION}::Gui
 149     KF5::I18n
 150     KF5::IconThemes
 151     KF5::KIOCore
 152     KF5::KIOWidgets
 153     KF5::KIOFileWidgets
 154     KF5::Completion
 155     KF5::TextWidgets
 156     KF5::ConfigCore
 157     KF5::NewStuff
 158     KF5::NewStuffWidgets    # KNSWidgets::Button
 159     KF5::Parts
 160     KF5::WindowSystem
 161     KF5::WidgetsAddons
 162 )
 163
 164 if(HAVE_BALOO)
 165     target_link_libraries(
 166         dolphinprivate PUBLIC
 167         KF5::FileMetaData
 168         KF5::Baloo
 169         KF5::BalooWidgets
 170     )
 171 endif()
 172
 173 set_target_properties(dolphinprivate PROPERTIES
 174     VERSION ${DOLPHINPRIVATE_VERSION}
 175     SOVERSION ${DOLPHINPRIVATE_SOVERSION}
 176 )
 177
 178 install(TARGETS dolphinprivate ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} LIBRARY NAMELINK_SKIP)
 179 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphin_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
 180
 181 ##########################################
 182 configure_file(dolphinpart.json.in ${CMAKE_CURRENT_BINARY_DIR}/dolphinpart.json @ONLY)
 183
 184 add_library(dolphinpart MODULE)
 185
 186 target_sources(dolphinpart PRIVATE
 187     dolphinpart.cpp
 188     dolphinpart_ext.cpp
 189     dolphindebug.cpp
 190
 191     dolphinpart.qrc
 192 )
 193
 194 target_link_libraries(dolphinpart
 195     dolphinprivate
 196 )
 197
 198 install(TARGETS dolphinpart DESTINATION ${KDE_INSTALL_PLUGINDIR}/kf5/parts)
 199
 200 ##########################################
 201
 202 add_library(dolphinstatic STATIC)
 203
 204 target_sources(dolphinstatic PRIVATE
 205     dolphinbookmarkhandler.cpp
 206     dolphindockwidget.cpp
 207     dolphinmainwindow.cpp
 208     dolphinviewcontainer.cpp
 209     dolphincontextmenu.cpp
 210     dolphinnavigatorswidgetaction.cpp
 211     dolphintabbar.cpp
 212     dolphinplacesmodelsingleton.cpp
 213     dolphinrecenttabsmenu.cpp
 214     dolphintabpage.cpp
 215     dolphintabwidget.cpp
 216     dolphinurlnavigator.cpp
 217     dolphinurlnavigatorscontroller.cpp
 218     trash/dolphintrash.cpp
 219     filterbar/filterbar.cpp
 220     panels/places/placespanel.cpp
 221     panels/panel.cpp
 222     panels/folders/foldersitemlistwidget.cpp
 223     panels/folders/treeviewcontextmenu.cpp
 224     panels/folders/folderspanel.cpp
 225     panels/terminal/terminalpanel.cpp
 226     search/dolphinfacetswidget.cpp
 227     search/dolphinquery.cpp
 228     search/dolphinsearchbox.cpp
 229     settings/general/behaviorsettingspage.cpp
 230     settings/general/configurepreviewplugindialog.cpp
 231     settings/general/confirmationssettingspage.cpp
 232     settings/general/generalsettingspage.cpp
 233     settings/general/previewssettingspage.cpp
 234     settings/general/statusbarsettingspage.cpp
 235     settings/dolphinsettingsdialog.cpp
 236     settings/navigation/navigationsettingspage.cpp
 237     settings/contextmenu/contextmenusettingspage.cpp
 238     settings/settingspagebase.cpp
 239     settings/serviceitemdelegate.cpp
 240     settings/servicemodel.cpp
 241     settings/startup/startupsettingspage.cpp
 242     settings/trash/trashsettingspage.cpp
 243     settings/viewmodes/dolphinfontrequester.cpp
 244     settings/viewmodes/viewsettingspage.cpp
 245     settings/viewmodes/viewmodesettings.cpp
 246     settings/viewmodes/viewsettingstab.cpp
 247     statusbar/dolphinstatusbar.cpp
 248     statusbar/mountpointobserver.cpp
 249     statusbar/mountpointobservercache.cpp
 250     statusbar/spaceinfoobserver.cpp
 251     statusbar/statusbarspaceinfo.cpp
 252     views/zoomlevelinfo.cpp
 253     dolphindebug.cpp
 254     global.cpp
 255     dolphin.qrc
 256 )
 257
 258 if(HAVE_BALOO)
 259     target_sources(dolphinstatic PRIVATE
 260         panels/information/informationpanel.cpp
 261         panels/information/informationpanelcontent.cpp
 262         panels/information/pixmapviewer.cpp
 263         panels/information/phononwidget.cpp
 264     )
 265 endif()
 266
 267 if(HAVE_KUSERFEEDBACK)
 268     target_sources(dolphinstatic PRIVATE
 269         userfeedback/dolphinfeedbackprovider.cpp
 270         userfeedback/settingsdatasource.cpp
 271         userfeedback/placesdatasource.cpp
 272         settings/userfeedback/userfeedbacksettingspage.cpp
 273     )
 274 endif()
 275
 276 kconfig_add_kcfg_files(dolphinstatic
 277     panels/folders/dolphin_folderspanelsettings.kcfgc
 278     panels/information/dolphin_informationpanelsettings.kcfgc
 279     panels/places/dolphin_placespanelsettings.kcfgc
 280     settings/dolphin_compactmodesettings.kcfgc
 281     settings/dolphin_detailsmodesettings.kcfgc
 282     settings/dolphin_contextmenusettings.kcfgc
 283     settings/dolphin_iconsmodesettings.kcfgc
 284     search/dolphin_searchsettings.kcfgc
 285     settings/dolphin_versioncontrolsettings.kcfgc
 286 )
 287 kconfig_add_kcfg_files(dolphinstatic GENERATE_MOC
 288     settings/dolphin_generalsettings.kcfgc
 289 )
 290
 291 qt_generate_dbus_interface(${CMAKE_CURRENT_SOURCE_DIR}/dolphinmainwindow.h org.kde.DolphinMainWindow.xml)
 292 qt_add_dbus_adaptor(dolphin_dbus_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindow.h DolphinMainWindow)
 293 qt_add_dbus_interface(dolphin_dbus_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindowinterface)
 294 qt_add_dbus_interface(dolphin_dbus_SRCS panels/terminal/org.kde.KIOFuse.VFS.xml kiofuse_interface)
 295
 296 target_sources(dolphinstatic PRIVATE
 297     ${dolphin_dbus_SRCS}
 298 )
 299
 300 target_include_directories(dolphinstatic SYSTEM PRIVATE ${PHONON_INCLUDES})
 301 target_link_libraries(dolphinstatic
 302     dolphinprivate
 303     KF5::CoreAddons
 304     KF5::KCMUtils
 305     KF5::DBusAddons
 306     KF5::Notifications
 307     Phonon::phonon4qt${QT_MAJOR_VERSION}
 308 )
 309
 310 if (HAVE_KACTIVITIES)
 311     target_link_libraries(
 312         dolphinstatic
 313         KF5::Activities
 314     )
 315 endif()
 316
 317 if (HAVE_KUSERFEEDBACK)
 318     target_link_libraries(
 319         dolphinstatic
 320         KUserFeedbackCore
 321         KUserFeedbackWidgets
 322     )
 323 endif()
 324
 325 add_executable(dolphin)
 326
 327 target_sources(dolphin PRIVATE
 328     dbusinterface.cpp
 329     main.cpp
 330 )
 331
 332 if(FLATPAK)
 333     target_compile_definitions(dolphin PRIVATE FLATPAK)
 334 endif()
 335
 336 # Sets the icon on Windows and OSX
 337 file(GLOB ICONS_SRCS "${CMAKE_CURRENT_SOURCE_DIR}/icons/*system-file-manager.png")
 338 ecm_add_app_icon(dolphin ICONS ${ICONS_SRCS})
 339
 340 target_link_libraries(dolphin
 341     PRIVATE
 342     dolphinprivate
 343     dolphinstatic
 344     KF5::Crash
 345 )
 346
 347 include(DbusInterfaceMacros)
 348
 349 generate_and_install_dbus_interface(
 350     dolphin
 351     dbusinterface.h
 352     org.freedesktop.FileManager1.xml
 353     OPTIONS -a
 354 )
 355
 356 install(TARGETS dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 357
 358 ##########################################
 359
 360 if(NOT WIN32)
 361     # The settings are still accessible from the hamburger menu
 362     add_library(kcm_dolphinviewmodes MODULE)
 363     add_library(kcm_dolphinnavigation MODULE)
 364     add_library(kcm_dolphingeneral MODULE)
 365
 366     target_sources(kcm_dolphinviewmodes PRIVATE
 367         settings/kcm/kcmdolphinviewmodes.cpp
 368         settings/viewmodes/dolphinfontrequester.cpp
 369         settings/viewmodes/viewmodesettings.cpp
 370         settings/viewmodes/viewsettingstab.cpp
 371         views/zoomlevelinfo.cpp)
 372
 373     target_sources(kcm_dolphinnavigation PRIVATE
 374         settings/kcm/kcmdolphinnavigation.cpp
 375         settings/navigation/navigationsettingspage.cpp
 376         settings/settingspagebase.cpp)
 377
 378     target_sources(kcm_dolphingeneral PRIVATE
 379         settings/kcm/kcmdolphingeneral.cpp
 380         settings/general/behaviorsettingspage.cpp
 381         settings/general/previewssettingspage.cpp
 382         settings/general/configurepreviewplugindialog.cpp
 383         settings/general/confirmationssettingspage.cpp
 384         settings/settingspagebase.cpp
 385         settings/serviceitemdelegate.cpp
 386         settings/servicemodel.cpp)
 387
 388     kconfig_add_kcfg_files(kcm_dolphinviewmodes
 389         settings/dolphin_compactmodesettings.kcfgc
 390         settings/dolphin_directoryviewpropertysettings.kcfgc
 391         settings/dolphin_detailsmodesettings.kcfgc
 392         settings/dolphin_iconsmodesettings.kcfgc
 393         settings/dolphin_generalsettings.kcfgc
 394         settings/dolphin_versioncontrolsettings.kcfgc
 395     )
 396
 397     kconfig_add_kcfg_files(kcm_dolphinnavigation
 398         settings/dolphin_generalsettings.kcfgc)
 399
 400     kconfig_add_kcfg_files(kcm_dolphingeneral
 401         settings/dolphin_generalsettings.kcfgc)
 402
 403     target_link_libraries(kcm_dolphinviewmodes dolphinprivate)
 404     target_link_libraries(kcm_dolphinnavigation dolphinprivate)
 405     target_link_libraries(kcm_dolphingeneral dolphinprivate)
 406
 407     install( FILES org.kde.dolphin.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR} )
 408
 409     install(TARGETS kcm_dolphinviewmodes DESTINATION ${KDE_INSTALL_PLUGINDIR}/dolphin/kcms )
 410     install(TARGETS kcm_dolphinnavigation DESTINATION ${KDE_INSTALL_PLUGINDIR}/dolphin/kcms )
 411     install(TARGETS kcm_dolphingeneral DESTINATION ${KDE_INSTALL_PLUGINDIR}/dolphin/kcms )
 412 endif()
 413
 414 if(NOT WIN32)
 415     add_subdirectory(settings/contextmenu/servicemenuinstaller)
 416     install( FILES settings/contextmenu/servicemenu.knsrc DESTINATION ${KDE_INSTALL_KNSRCDIR} )
 417 endif()
 418
 419 ########### install files ###############
 420
 421 install( PROGRAMS org.kde.dolphin.desktop DESTINATION ${KDE_INSTALL_APPDIR} )
 422
 423 install( DIRECTORY DESTINATION "${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel" )
 424
 425 install(
 426     CODE "execute_process(COMMAND \"${CMAKE_COMMAND}\" -E create_symlink \"${KDE_INSTALL_FULL_APPDIR}/org.kde.dolphin.desktop\" \"\$ENV{DESTDIR}${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel/org.kde.dolphin.desktop\")"
 427 )
 428
 429 install( FILES settings/dolphin_directoryviewpropertysettings.kcfg
 430                settings/dolphin_generalsettings.kcfg
 431                settings/dolphin_contextmenusettings.kcfg
 432                settings/dolphin_compactmodesettings.kcfg
 433                settings/dolphin_iconsmodesettings.kcfg
 434                settings/dolphin_detailsmodesettings.kcfg
 435                settings/dolphin_versioncontrolsettings.kcfg
 436          DESTINATION ${KDE_INSTALL_KCFGDIR} )
 437
 438 install( FILES settings/dolphin_detailsmodesettings.upd
 439          DESTINATION ${KDE_INSTALL_KCONFUPDATEDIR} )
 440
 441 if(BUILD_TESTING)
 442     add_subdirectory(tests)
 443 endif()