src/CMakeLists.txt

   1 include(ECMAddAppIcon)
   2
   3 configure_file(config-baloo.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-baloo.h)
   4
   5 configure_file(config-kactivities.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-kactivities.h)
   6
   7 configure_file(config-packagekit.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-packagekit.h)
   8
   9 configure_file(config-terminal.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-terminal.h)
  10
  11 configure_file(config-kuserfeedback.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-kuserfeedback.h)
  12
  13 add_definitions(
  14     -DTRANSLATION_DOMAIN=\"dolphin\"
  15 )
  16 remove_definitions(
  17     -DQT_NO_CAST_FROM_BYTEARRAY
  18     -DQT_NO_SIGNALS_SLOTS_KEYWORDS
  19     -DQT_NO_CAST_FROM_ASCII
  20     -DQT_NO_CAST_TO_ASCII
  21     -DQT_NO_FOREACH
  22     -DQT_NO_KEYWORDS
  23 )
  24
  25 ##########################################
  26
  27 set(dolphinvcs_LIB_SRCS
  28     views/versioncontrol/kversioncontrolplugin.cpp
  29 )
  30
  31 add_library(dolphinvcs ${dolphinvcs_LIB_SRCS})
  32 generate_export_header(dolphinvcs BASE_NAME dolphinvcs)
  33
  34 target_link_libraries(
  35     dolphinvcs PUBLIC
  36     Qt5::Widgets
  37 )
  38
  39 set_target_properties(dolphinvcs PROPERTIES
  40     VERSION ${DOLPHINVCS_VERSION_STRING}
  41     SOVERSION ${DOLPHINVCS_SOVERSION}
  42     EXPORT_NAME DolphinVcs
  43 )
  44
  45 ecm_generate_headers(dolphinvcs_LIB_HEADERS
  46     HEADER_NAMES
  47     KVersionControlPlugin
  48
  49     RELATIVE "views/versioncontrol"
  50     REQUIRED_HEADERS dolphinvcs_LIB_HEADERS
  51 )
  52
  53 install(TARGETS dolphinvcs EXPORT DolphinVcsTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
  54
  55 install(FILES views/versioncontrol/fileviewversioncontrolplugin.desktop DESTINATION ${KDE_INSTALL_KSERVICETYPES5DIR})
  56 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphinvcs_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
  57 install(FILES ${dolphinvcs_LIB_HEADERS} DESTINATION "${KDE_INSTALL_INCLUDEDIR}/Dolphin" COMPONENT Devel)
  58
  59 ########### next target ###############
  60
  61 set(dolphinprivate_LIB_SRCS
  62     kitemviews/kfileitemlistview.cpp
  63     kitemviews/kfileitemlistwidget.cpp
  64     kitemviews/kfileitemmodel.cpp
  65     kitemviews/kfileitemmodelrolesupdater.cpp
  66     kitemviews/kitemlistcontainer.cpp
  67     kitemviews/kitemlistcontroller.cpp
  68     kitemviews/kitemlistgroupheader.cpp
  69     kitemviews/kitemlistheader.cpp
  70     kitemviews/kitemlistselectionmanager.cpp
  71     kitemviews/kitemliststyleoption.cpp
  72     kitemviews/kitemlistview.cpp
  73     kitemviews/kitemlistviewaccessible.cpp
  74     kitemviews/kitemlistwidget.cpp
  75     kitemviews/kitemmodelbase.cpp
  76     kitemviews/kitemset.cpp
  77     kitemviews/kstandarditem.cpp
  78     kitemviews/kstandarditemlistgroupheader.cpp
  79     kitemviews/kstandarditemlistwidget.cpp
  80     kitemviews/kstandarditemlistview.cpp
  81     kitemviews/kstandarditemmodel.cpp
  82     kitemviews/private/kdirectorycontentscounter.cpp
  83     kitemviews/private/kdirectorycontentscounterworker.cpp
  84     kitemviews/private/kfileitemclipboard.cpp
  85     kitemviews/private/kfileitemmodeldirlister.cpp
  86     kitemviews/private/kfileitemmodelfilter.cpp
  87     kitemviews/private/kitemlistheaderwidget.cpp
  88     kitemviews/private/kitemlistkeyboardsearchmanager.cpp
  89     kitemviews/private/kitemlistroleeditor.cpp
  90     kitemviews/private/kitemlistrubberband.cpp
  91     kitemviews/private/kitemlistselectiontoggle.cpp
  92     kitemviews/private/kitemlistsizehintresolver.cpp
  93     kitemviews/private/kitemlistsmoothscroller.cpp
  94     kitemviews/private/kitemlistviewanimation.cpp
  95     kitemviews/private/kitemlistviewlayouter.cpp
  96     kitemviews/private/kpixmapmodifier.cpp
  97     kitemviews/private/ktwofingerswipe.cpp
  98     kitemviews/private/ktwofingertap.cpp
  99     settings/applyviewpropsjob.cpp
 100     settings/viewmodes/viewmodesettings.cpp
 101     settings/viewpropertiesdialog.cpp
 102     settings/viewpropsprogressinfo.cpp
 103     views/dolphinfileitemlistwidget.cpp
 104     views/dolphinitemlistview.cpp
 105     views/dolphinnewfilemenuobserver.cpp
 106     views/dolphinremoteencoding.cpp
 107     views/dolphinview.cpp
 108     views/dolphinviewactionhandler.cpp
 109     views/draganddrophelper.cpp
 110     views/versioncontrol/updateitemstatesthread.cpp
 111     views/versioncontrol/versioncontrolobserver.cpp
 112     views/viewmodecontroller.cpp
 113     views/viewproperties.cpp
 114     views/zoomlevelinfo.cpp
 115     dolphinremoveaction.cpp
 116     middleclickactioneventfilter.cpp
 117     dolphinnewfilemenu.cpp
 118 )
 119
 120 ecm_qt_declare_logging_category(dolphinprivate_LIB_SRCS HEADER dolphindebug.h IDENTIFIER DolphinDebug CATEGORY_NAME org.kde.dolphin
 121     DESCRIPTION "dolphin" EXPORT DOLPHIN)
 122
 123 if(HAVE_BALOO)
 124     set(dolphinprivate_LIB_SRCS
 125         ${dolphinprivate_LIB_SRCS}
 126         views/tooltips/dolphinfilemetadatawidget.cpp
 127         views/tooltips/tooltipmanager.cpp
 128         kitemviews/private/kbaloorolesprovider.cpp
 129     )
 130 endif()
 131
 132 kconfig_add_kcfg_files(dolphinprivate_LIB_SRCS GENERATE_MOC
 133     settings/dolphin_compactmodesettings.kcfgc
 134     settings/dolphin_directoryviewpropertysettings.kcfgc
 135     settings/dolphin_detailsmodesettings.kcfgc
 136     settings/dolphin_iconsmodesettings.kcfgc
 137     settings/dolphin_generalsettings.kcfgc
 138     settings/dolphin_contextmenusettings.kcfgc
 139     settings/dolphin_versioncontrolsettings.kcfgc
 140 )
 141
 142 add_library(dolphinprivate ${dolphinprivate_LIB_SRCS})
 143 generate_export_header(dolphinprivate BASE_NAME dolphin)
 144
 145 target_link_libraries(
 146     dolphinprivate PUBLIC
 147     dolphinvcs
 148     Qt5::Concurrent
 149     Qt5::Gui
 150     KF5::I18n
 151     KF5::IconThemes
 152     KF5::KIOCore
 153     KF5::KIOWidgets
 154     KF5::KIOFileWidgets
 155     KF5::Completion
 156     KF5::TextWidgets
 157     KF5::ConfigCore
 158     KF5::NewStuff
 159     KF5::Parts
 160     KF5::WindowSystem
 161 )
 162
 163 if(HAVE_BALOO)
 164     target_link_libraries(
 165         dolphinprivate PUBLIC
 166         KF5::FileMetaData
 167         KF5::Baloo
 168         KF5::BalooWidgets
 169     )
 170 endif()
 171
 172 set_target_properties(dolphinprivate PROPERTIES
 173     VERSION ${DOLPHINPRIVATE_VERSION_STRING}
 174     SOVERSION ${DOLPHINPRIVATE_SOVERSION}
 175 )
 176
 177 install(TARGETS dolphinprivate ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} LIBRARY NAMELINK_SKIP)
 178 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphin_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
 179
 180 ##########################################
 181 configure_file(dolphinpart.desktop.in ${CMAKE_CURRENT_BINARY_DIR}/dolphinpart.desktop @ONLY)
 182
 183 set(dolphinpart_SRCS
 184    dolphinpart.cpp
 185    dolphinpart_ext.cpp
 186    dolphindebug.cpp
 187 )
 188
 189 qt5_add_resources(dolphinpart_SRCS dolphinpart.qrc)
 190
 191 add_library(dolphinpart MODULE ${dolphinpart_SRCS})
 192 kcoreaddons_desktop_to_json(dolphinpart ${CMAKE_CURRENT_BINARY_DIR}/dolphinpart.desktop)
 193
 194 target_link_libraries(dolphinpart
 195     dolphinprivate
 196 )
 197
 198 install(TARGETS dolphinpart DESTINATION ${KDE_INSTALL_PLUGINDIR}/kf5/parts)
 199
 200 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphinpart.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR})
 201
 202 ##########################################
 203
 204 set(dolphinstatic_SRCS
 205     dolphinbookmarkhandler.cpp
 206     dolphindockwidget.cpp
 207     dolphinmainwindow.cpp
 208     dolphinviewcontainer.cpp
 209     dolphincontextmenu.cpp
 210     dolphinnavigatorswidgetaction.cpp
 211     dolphintabbar.cpp
 212     dolphinplacesmodelsingleton.cpp
 213     dolphinrecenttabsmenu.cpp
 214     dolphintabpage.cpp
 215     dolphintabwidget.cpp
 216     dolphinurlnavigator.cpp
 217     dolphinurlnavigatorscontroller.cpp
 218     trash/dolphintrash.cpp
 219     filterbar/filterbar.cpp
 220     panels/places/placespanel.cpp
 221     panels/places/placesitem.cpp
 222     panels/places/placesitemlistgroupheader.cpp
 223     panels/places/placesitemlistwidget.cpp
 224     panels/places/placesitemmodel.cpp
 225     panels/places/placesitemsignalhandler.cpp
 226     panels/places/placesview.cpp
 227     panels/panel.cpp
 228     panels/folders/foldersitemlistwidget.cpp
 229     panels/folders/treeviewcontextmenu.cpp
 230     panels/folders/folderspanel.cpp
 231     panels/terminal/terminalpanel.cpp
 232     search/dolphinfacetswidget.cpp
 233     search/dolphinquery.cpp
 234     search/dolphinsearchbox.cpp
 235     settings/general/behaviorsettingspage.cpp
 236     settings/general/configurepreviewplugindialog.cpp
 237     settings/general/confirmationssettingspage.cpp
 238     settings/general/generalsettingspage.cpp
 239     settings/general/previewssettingspage.cpp
 240     settings/general/statusbarsettingspage.cpp
 241     settings/dolphinsettingsdialog.cpp
 242     settings/navigation/navigationsettingspage.cpp
 243     settings/contextmenu/contextmenusettingspage.cpp
 244     settings/settingspagebase.cpp
 245     settings/serviceitemdelegate.cpp
 246     settings/servicemodel.cpp
 247     settings/startup/startupsettingspage.cpp
 248     settings/trash/trashsettingspage.cpp
 249     settings/viewmodes/dolphinfontrequester.cpp
 250     settings/viewmodes/viewsettingspage.cpp
 251     settings/viewmodes/viewmodesettings.cpp
 252     settings/viewmodes/viewsettingstab.cpp
 253     statusbar/dolphinstatusbar.cpp
 254     statusbar/mountpointobserver.cpp
 255     statusbar/mountpointobservercache.cpp
 256     statusbar/spaceinfoobserver.cpp
 257     statusbar/statusbarspaceinfo.cpp
 258     views/zoomlevelinfo.cpp
 259     dolphindebug.cpp
 260     global.cpp
 261 )
 262
 263 if(HAVE_BALOO)
 264     set(dolphinstatic_SRCS
 265         ${dolphinstatic_SRCS}
 266         panels/information/informationpanel.cpp
 267         panels/information/informationpanelcontent.cpp
 268         panels/information/pixmapviewer.cpp
 269         panels/information/phononwidget.cpp
 270     )
 271 endif()
 272
 273 if(HAVE_KUSERFEEDBACK)
 274     set(dolphinstatic_SRCS
 275         ${dolphinstatic_SRCS}
 276         userfeedback/dolphinfeedbackprovider.cpp
 277         userfeedback/settingsdatasource.cpp
 278         userfeedback/placesdatasource.cpp
 279         settings/userfeedback/userfeedbacksettingspage.cpp
 280     )
 281 endif()
 282
 283 kconfig_add_kcfg_files(dolphinstatic_SRCS GENERATE_MOC
 284     panels/folders/dolphin_folderspanelsettings.kcfgc
 285     panels/information/dolphin_informationpanelsettings.kcfgc
 286     panels/places/dolphin_placespanelsettings.kcfgc
 287     settings/dolphin_compactmodesettings.kcfgc
 288     settings/dolphin_detailsmodesettings.kcfgc
 289     settings/dolphin_generalsettings.kcfgc
 290     settings/dolphin_contextmenusettings.kcfgc
 291     settings/dolphin_iconsmodesettings.kcfgc
 292     search/dolphin_searchsettings.kcfgc
 293     settings/dolphin_versioncontrolsettings.kcfgc
 294 )
 295
 296 qt5_add_resources(dolphinstatic_SRCS dolphin.qrc)
 297
 298 qt5_generate_dbus_interface(${CMAKE_CURRENT_SOURCE_DIR}/dolphinmainwindow.h org.kde.DolphinMainWindow.xml)
 299 qt5_add_dbus_adaptor(dolphinstatic_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindow.h DolphinMainWindow)
 300 qt5_add_dbus_interface(dolphinstatic_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindowinterface)
 301 qt5_add_dbus_interface(dolphinstatic_SRCS panels/terminal/org.kde.KIOFuse.VFS.xml kiofuse_interface)
 302
 303 add_library(dolphinstatic STATIC ${dolphinstatic_SRCS})
 304
 305 target_include_directories(dolphinstatic SYSTEM PRIVATE ${PHONON_INCLUDES})
 306 target_link_libraries(dolphinstatic
 307     dolphinprivate
 308     KF5::CoreAddons
 309     KF5::KCMUtils
 310     KF5::DBusAddons
 311     KF5::Notifications
 312     Phonon::phonon4qt5
 313 )
 314
 315 if (HAVE_KACTIVITIES)
 316     target_link_libraries(
 317         dolphinstatic
 318         KF5::Activities
 319     )
 320 endif()
 321
 322 if (HAVE_KUSERFEEDBACK)
 323     target_link_libraries(
 324         dolphinstatic
 325         KUserFeedbackCore
 326         KUserFeedbackWidgets
 327     )
 328 endif()
 329
 330 set(dolphin_SRCS
 331     dbusinterface.cpp
 332     main.cpp
 333 )
 334
 335 # Sets the icon on Windows and OSX
 336 file(GLOB ICONS_SRCS "${CMAKE_CURRENT_SOURCE_DIR}/icons/*system-file-manager.png")
 337 ecm_add_app_icon(dolphin_SRCS ICONS ${ICONS_SRCS})
 338
 339 kf5_add_kdeinit_executable(dolphin ${dolphin_SRCS})
 340
 341
 342 target_link_libraries(kdeinit_dolphin PUBLIC
 343     dolphinprivate
 344     PRIVATE
 345     dolphinstatic
 346     KF5::Crash
 347 )
 348
 349 include(DbusInterfaceMacros)
 350
 351 generate_and_install_dbus_interface(
 352     kdeinit_dolphin
 353     dbusinterface.h
 354     org.freedesktop.FileManager1.xml
 355     OPTIONS -a
 356 )
 357
 358 install(TARGETS kdeinit_dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 359 install(TARGETS dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 360
 361 ##########################################
 362
 363 set(kcm_dolphinviewmodes_PART_SRCS
 364     settings/kcm/kcmdolphinviewmodes.cpp
 365     settings/viewmodes/dolphinfontrequester.cpp
 366     settings/viewmodes/viewmodesettings.cpp
 367     settings/viewmodes/viewsettingstab.cpp
 368     views/zoomlevelinfo.cpp)
 369
 370 set(kcm_dolphinnavigation_PART_SRCS
 371     settings/kcm/kcmdolphinnavigation.cpp
 372     settings/navigation/navigationsettingspage.cpp
 373     settings/settingspagebase.cpp)
 374
 375 set(kcm_dolphingeneral_PART_SRCS
 376     settings/kcm/kcmdolphingeneral.cpp
 377     settings/general/behaviorsettingspage.cpp
 378     settings/general/previewssettingspage.cpp
 379     settings/general/configurepreviewplugindialog.cpp
 380     settings/general/confirmationssettingspage.cpp
 381     settings/settingspagebase.cpp
 382     settings/serviceitemdelegate.cpp
 383     settings/servicemodel.cpp)
 384
 385 kconfig_add_kcfg_files(kcm_dolphinviewmodes_PART_SRCS
 386     settings/dolphin_compactmodesettings.kcfgc
 387     settings/dolphin_directoryviewpropertysettings.kcfgc
 388     settings/dolphin_detailsmodesettings.kcfgc
 389     settings/dolphin_iconsmodesettings.kcfgc
 390     settings/dolphin_generalsettings.kcfgc
 391     settings/dolphin_versioncontrolsettings.kcfgc
 392 )
 393
 394 kconfig_add_kcfg_files(kcm_dolphinnavigation_PART_SRCS
 395     settings/dolphin_generalsettings.kcfgc)
 396
 397 kconfig_add_kcfg_files(kcm_dolphingeneral_PART_SRCS
 398     settings/dolphin_generalsettings.kcfgc)
 399
 400
 401 if(NOT WIN32)
 402     # The settings are still accessible from the hamburger menu
 403     add_library(kcm_dolphinviewmodes MODULE ${kcm_dolphinviewmodes_PART_SRCS})
 404     add_library(kcm_dolphinnavigation MODULE ${kcm_dolphinnavigation_PART_SRCS})
 405     add_library(kcm_dolphingeneral MODULE ${kcm_dolphingeneral_PART_SRCS})
 406
 407     target_link_libraries(kcm_dolphinviewmodes dolphinprivate)
 408     target_link_libraries(kcm_dolphinnavigation dolphinprivate)
 409     target_link_libraries(kcm_dolphingeneral dolphinprivate)
 410
 411     install( FILES org.kde.dolphin.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR} )
 412     install( FILES settings/kcm/kcmdolphinviewmodes.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 413     install( FILES settings/kcm/kcmdolphinnavigation.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 414     install( FILES settings/kcm/kcmdolphingeneral.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 415
 416     install(TARGETS kcm_dolphinviewmodes DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 417     install(TARGETS kcm_dolphinnavigation DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 418     install(TARGETS kcm_dolphingeneral DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 419 endif()
 420
 421 if(NOT WIN32)
 422     add_subdirectory(settings/contextmenu/servicemenuinstaller)
 423     install( FILES settings/contextmenu/servicemenu.knsrc DESTINATION ${KDE_INSTALL_KNSRCDIR} )
 424 endif()
 425
 426 ########### install files ###############
 427
 428 install( PROGRAMS org.kde.dolphin.desktop DESTINATION ${KDE_INSTALL_APPDIR} )
 429
 430 install( DIRECTORY DESTINATION "${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel" )
 431
 432 install(
 433     CODE "execute_process(COMMAND \"${CMAKE_COMMAND}\" -E create_symlink \"${KDE_INSTALL_FULL_APPDIR}/org.kde.dolphin.desktop\" \"\$ENV{DESTDIR}${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel/org.kde.dolphin.desktop\")"
 434 )
 435
 436 install( FILES settings/dolphin_directoryviewpropertysettings.kcfg
 437                settings/dolphin_generalsettings.kcfg
 438                settings/dolphin_contextmenusettings.kcfg
 439                settings/dolphin_compactmodesettings.kcfg
 440                settings/dolphin_iconsmodesettings.kcfg
 441                settings/dolphin_detailsmodesettings.kcfg
 442                settings/dolphin_versioncontrolsettings.kcfg
 443          DESTINATION ${KDE_INSTALL_KCFGDIR} )
 444
 445 if(BUILD_TESTING)
 446     find_package(Qt5Test ${QT_MIN_VERSION} CONFIG REQUIRED)
 447     add_subdirectory(tests)
 448 endif()