src/CMakeLists.txt

   1 include(ECMAddAppIcon)
   2
   3 configure_file(config-baloo.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-baloo.h)
   4
   5 configure_file(config-kactivities.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-kactivities.h)
   6
   7 configure_file(config-terminal.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-terminal.h)
   8
   9 add_definitions(
  10     -DTRANSLATION_DOMAIN=\"dolphin\"
  11 )
  12 remove_definitions(
  13     -DQT_NO_CAST_FROM_BYTEARRAY
  14     -DQT_NO_SIGNALS_SLOTS_KEYWORDS
  15     -DQT_NO_CAST_FROM_ASCII
  16     -DQT_NO_CAST_TO_ASCII
  17 )
  18
  19 ##########################################
  20
  21 set(dolphinvcs_LIB_SRCS
  22     views/versioncontrol/kversioncontrolplugin.cpp
  23 )
  24
  25 add_library(dolphinvcs ${dolphinvcs_LIB_SRCS})
  26 generate_export_header(dolphinvcs BASE_NAME dolphinvcs)
  27
  28 target_link_libraries(
  29     dolphinvcs PUBLIC
  30     Qt5::Widgets
  31 )
  32
  33 set_target_properties(dolphinvcs PROPERTIES
  34     VERSION ${DOLPHINVCS_VERSION_STRING}
  35     SOVERSION ${DOLPHINVCS_SOVERSION}
  36     EXPORT_NAME DolphinVcs
  37 )
  38
  39 ecm_generate_headers(dolphinvcs_LIB_HEADERS
  40     HEADER_NAMES
  41     KVersionControlPlugin
  42
  43     RELATIVE "views/versioncontrol"
  44     REQUIRED_HEADERS dolphinvcs_LIB_HEADERS
  45 )
  46
  47 install(TARGETS dolphinvcs EXPORT DolphinVcsTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
  48
  49 install(FILES views/versioncontrol/fileviewversioncontrolplugin.desktop DESTINATION ${KDE_INSTALL_KSERVICETYPES5DIR})
  50 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphinvcs_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
  51 install(FILES ${dolphinvcs_LIB_HEADERS} DESTINATION "${KDE_INSTALL_INCLUDEDIR}/Dolphin" COMPONENT Devel)
  52
  53 ########### next target ###############
  54
  55 set(dolphinprivate_LIB_SRCS
  56     kitemviews/kfileitemlistview.cpp
  57     kitemviews/kfileitemlistwidget.cpp
  58     kitemviews/kfileitemmodel.cpp
  59     kitemviews/kfileitemmodelrolesupdater.cpp
  60     kitemviews/kitemlistcontainer.cpp
  61     kitemviews/kitemlistcontroller.cpp
  62     kitemviews/kitemlistgroupheader.cpp
  63     kitemviews/kitemlistheader.cpp
  64     kitemviews/kitemlistselectionmanager.cpp
  65     kitemviews/kitemliststyleoption.cpp
  66     kitemviews/kitemlistview.cpp
  67     kitemviews/kitemlistviewaccessible.cpp
  68     kitemviews/kitemlistwidget.cpp
  69     kitemviews/kitemmodelbase.cpp
  70     kitemviews/kitemset.cpp
  71     kitemviews/kstandarditem.cpp
  72     kitemviews/kstandarditemlistgroupheader.cpp
  73     kitemviews/kstandarditemlistwidget.cpp
  74     kitemviews/kstandarditemlistview.cpp
  75     kitemviews/kstandarditemmodel.cpp
  76     kitemviews/private/kdirectorycontentscounter.cpp
  77     kitemviews/private/kdirectorycontentscounterworker.cpp
  78     kitemviews/private/kfileitemclipboard.cpp
  79     kitemviews/private/kfileitemmodeldirlister.cpp
  80     kitemviews/private/kfileitemmodelfilter.cpp
  81     kitemviews/private/kitemlistheaderwidget.cpp
  82     kitemviews/private/kitemlistkeyboardsearchmanager.cpp
  83     kitemviews/private/kitemlistroleeditor.cpp
  84     kitemviews/private/kitemlistrubberband.cpp
  85     kitemviews/private/kitemlistselectiontoggle.cpp
  86     kitemviews/private/kitemlistsizehintresolver.cpp
  87     kitemviews/private/kitemlistsmoothscroller.cpp
  88     kitemviews/private/kitemlistviewanimation.cpp
  89     kitemviews/private/kitemlistviewlayouter.cpp
  90     kitemviews/private/kpixmapmodifier.cpp
  91     settings/applyviewpropsjob.cpp
  92     settings/viewmodes/viewmodesettings.cpp
  93     settings/viewpropertiesdialog.cpp
  94     settings/viewpropsprogressinfo.cpp
  95     views/dolphinfileitemlistwidget.cpp
  96     views/dolphinitemlistview.cpp
  97     views/dolphinnewfilemenuobserver.cpp
  98     views/dolphinremoteencoding.cpp
  99     views/dolphinview.cpp
 100     views/dolphinviewactionhandler.cpp
 101     views/draganddrophelper.cpp
 102     views/renamedialog.cpp
 103     views/versioncontrol/updateitemstatesthread.cpp
 104     views/versioncontrol/versioncontrolobserver.cpp
 105     views/viewmodecontroller.cpp
 106     views/viewproperties.cpp
 107     views/zoomlevelinfo.cpp
 108     dolphinremoveaction.cpp
 109     middleclickactioneventfilter.cpp
 110     dolphinnewfilemenu.cpp
 111 )
 112
 113 ecm_qt_declare_logging_category(dolphinprivate_LIB_SRCS HEADER dolphindebug.h IDENTIFIER DolphinDebug CATEGORY_NAME org.kde.dolphin)
 114
 115 if(HAVE_BALOO)
 116     set(dolphinprivate_LIB_SRCS
 117         ${dolphinprivate_LIB_SRCS}
 118         views/tooltips/dolphinfilemetadatawidget.cpp
 119         views/tooltips/tooltipmanager.cpp
 120         kitemviews/private/kbaloorolesprovider.cpp
 121     )
 122 endif()
 123
 124 kconfig_add_kcfg_files(dolphinprivate_LIB_SRCS GENERATE_MOC
 125     settings/dolphin_compactmodesettings.kcfgc
 126     settings/dolphin_directoryviewpropertysettings.kcfgc
 127     settings/dolphin_detailsmodesettings.kcfgc
 128     settings/dolphin_iconsmodesettings.kcfgc
 129     settings/dolphin_generalsettings.kcfgc
 130     settings/dolphin_versioncontrolsettings.kcfgc
 131 )
 132
 133 add_library(dolphinprivate ${dolphinprivate_LIB_SRCS})
 134 generate_export_header(dolphinprivate BASE_NAME dolphin)
 135
 136 target_link_libraries(
 137     dolphinprivate PUBLIC
 138     dolphinvcs
 139     Qt5::Concurrent
 140     Qt5::Gui
 141     KF5::I18n
 142     KF5::IconThemes
 143     KF5::KIOCore
 144     KF5::KIOWidgets
 145     KF5::KIOFileWidgets
 146     KF5::Completion
 147     KF5::TextWidgets
 148     KF5::ConfigCore
 149     KF5::NewStuff
 150     KF5::Parts
 151 )
 152
 153 if(HAVE_BALOO)
 154     target_link_libraries(
 155         dolphinprivate PUBLIC
 156         KF5::FileMetaData
 157         KF5::Baloo
 158         KF5::BalooWidgets
 159     )
 160 endif()
 161
 162 set_target_properties(dolphinprivate PROPERTIES
 163     VERSION ${DOLPHINPRIVATE_VERSION_STRING}
 164     SOVERSION ${DOLPHINPRIVATE_SOVERSION}
 165 )
 166
 167 install(TARGETS dolphinprivate ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} LIBRARY NAMELINK_SKIP)
 168 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphin_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
 169
 170 ##########################################
 171
 172 set(dolphinpart_SRCS
 173    dolphinpart.cpp
 174    dolphinpart_ext.cpp
 175    dolphindebug.cpp
 176 )
 177
 178 qt5_add_resources(dolphinpart_SRCS dolphinpart.qrc)
 179
 180 add_library(dolphinpart MODULE ${dolphinpart_SRCS})
 181
 182 target_link_libraries(dolphinpart
 183     dolphinprivate
 184 )
 185
 186 install(TARGETS dolphinpart DESTINATION ${KDE_INSTALL_PLUGINDIR})
 187
 188 install(FILES dolphinpart.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR})
 189
 190 ##########################################
 191
 192 set(dolphinstatic_SRCS
 193     dolphindockwidget.cpp
 194     dolphinmainwindow.cpp
 195     dolphinviewcontainer.cpp
 196     dolphincontextmenu.cpp
 197     dolphintabbar.cpp
 198     dolphinplacesmodelsingleton.cpp
 199     dolphinrecenttabsmenu.cpp
 200     dolphintabpage.cpp
 201     dolphintabwidget.cpp
 202     trash/dolphintrash.cpp
 203     filterbar/filterbar.cpp
 204     panels/places/placespanel.cpp
 205     panels/places/placesitem.cpp
 206     panels/places/placesitemlistgroupheader.cpp
 207     panels/places/placesitemlistwidget.cpp
 208     panels/places/placesitemmodel.cpp
 209     panels/places/placesitemsignalhandler.cpp
 210     panels/places/placesview.cpp
 211     panels/panel.cpp
 212     panels/folders/foldersitemlistwidget.cpp
 213     panels/folders/treeviewcontextmenu.cpp
 214     panels/folders/folderspanel.cpp
 215     panels/terminal/terminalpanel.cpp
 216     search/dolphinfacetswidget.cpp
 217     search/dolphinsearchbox.cpp
 218     settings/general/behaviorsettingspage.cpp
 219     settings/general/configurepreviewplugindialog.cpp
 220     settings/general/confirmationssettingspage.cpp
 221     settings/general/generalsettingspage.cpp
 222     settings/general/previewssettingspage.cpp
 223     settings/general/statusbarsettingspage.cpp
 224     settings/dolphinsettingsdialog.cpp
 225     settings/navigation/navigationsettingspage.cpp
 226     settings/services/servicessettingspage.cpp
 227     settings/settingspagebase.cpp
 228     settings/serviceitemdelegate.cpp
 229     settings/servicemodel.cpp
 230     settings/startup/startupsettingspage.cpp
 231     settings/trash/trashsettingspage.cpp
 232     settings/viewmodes/dolphinfontrequester.cpp
 233     settings/viewmodes/viewsettingspage.cpp
 234     settings/viewmodes/viewmodesettings.cpp
 235     settings/viewmodes/viewsettingstab.cpp
 236     statusbar/dolphinstatusbar.cpp
 237     statusbar/mountpointobserver.cpp
 238     statusbar/mountpointobservercache.cpp
 239     statusbar/spaceinfoobserver.cpp
 240     statusbar/statusbarspaceinfo.cpp
 241     views/zoomlevelinfo.cpp
 242     dolphindebug.cpp
 243     global.cpp
 244 )
 245
 246 if(HAVE_BALOO)
 247     set(dolphinstatic_SRCS
 248         ${dolphinstatic_SRCS}
 249         panels/information/informationpanel.cpp
 250         panels/information/informationpanelcontent.cpp
 251         panels/information/pixmapviewer.cpp
 252         panels/information/phononwidget.cpp
 253     )
 254 endif()
 255
 256 kconfig_add_kcfg_files(dolphinstatic_SRCS GENERATE_MOC
 257     panels/folders/dolphin_folderspanelsettings.kcfgc
 258     panels/information/dolphin_informationpanelsettings.kcfgc
 259     panels/places/dolphin_placespanelsettings.kcfgc
 260     settings/dolphin_compactmodesettings.kcfgc
 261     settings/dolphin_detailsmodesettings.kcfgc
 262     settings/dolphin_generalsettings.kcfgc
 263     settings/dolphin_iconsmodesettings.kcfgc
 264     search/dolphin_searchsettings.kcfgc
 265     settings/dolphin_versioncontrolsettings.kcfgc
 266 )
 267
 268 qt5_add_resources(dolphinstatic_SRCS dolphin.qrc)
 269
 270 add_library(dolphinstatic STATIC ${dolphinstatic_SRCS})
 271
 272 target_include_directories(dolphinstatic SYSTEM PRIVATE ${PHONON_INCLUDES})
 273 target_link_libraries(dolphinstatic
 274     dolphinprivate
 275     KF5::KCMUtils
 276     KF5::DBusAddons
 277     KF5::Notifications
 278     Phonon::phonon4qt5
 279 )
 280
 281 if (HAVE_KACTIVITIES)
 282     target_link_libraries(
 283         dolphinstatic
 284         KF5::Activities
 285     )
 286 endif()
 287
 288 set(dolphin_SRCS
 289     dbusinterface.cpp
 290     main.cpp
 291 )
 292
 293 # Sets the icon on Windows and OSX
 294 file(GLOB ICONS_SRCS "${CMAKE_CURRENT_SOURCE_DIR}/icons/*system-file-manager.png")
 295 ecm_add_app_icon(dolphin_SRCS ICONS ${ICONS_SRCS})
 296
 297 kf5_add_kdeinit_executable(dolphin ${dolphin_SRCS})
 298
 299
 300 target_link_libraries(kdeinit_dolphin PRIVATE
 301     dolphinstatic
 302     dolphinprivate
 303     KF5::Crash
 304 )
 305
 306 include(DbusInterfaceMacros)
 307
 308 generate_and_install_dbus_interface(
 309     kdeinit_dolphin
 310     dbusinterface.h
 311     org.freedesktop.FileManager1.xml
 312     OPTIONS -a
 313 )
 314
 315 install(TARGETS kdeinit_dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 316 install(TARGETS dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 317
 318 ##########################################
 319
 320 set(kcm_dolphinviewmodes_PART_SRCS
 321     settings/kcm/kcmdolphinviewmodes.cpp
 322     settings/viewmodes/dolphinfontrequester.cpp
 323     settings/viewmodes/viewmodesettings.cpp
 324     settings/viewmodes/viewsettingstab.cpp
 325     views/zoomlevelinfo.cpp)
 326
 327 set(kcm_dolphinnavigation_PART_SRCS
 328     settings/kcm/kcmdolphinnavigation.cpp
 329     settings/navigation/navigationsettingspage.cpp
 330     settings/settingspagebase.cpp)
 331
 332 set(kcm_dolphinservices_PART_SRCS
 333     settings/kcm/kcmdolphinservices.cpp
 334     settings/services/servicessettingspage.cpp
 335     settings/settingspagebase.cpp
 336     settings/serviceitemdelegate.cpp
 337     settings/servicemodel.cpp)
 338
 339 set(kcm_dolphingeneral_PART_SRCS
 340     settings/kcm/kcmdolphingeneral.cpp
 341     settings/general/behaviorsettingspage.cpp
 342     settings/general/previewssettingspage.cpp
 343     settings/general/configurepreviewplugindialog.cpp
 344     settings/general/confirmationssettingspage.cpp
 345     settings/settingspagebase.cpp
 346     settings/serviceitemdelegate.cpp
 347     settings/servicemodel.cpp)
 348
 349 kconfig_add_kcfg_files(kcm_dolphinviewmodes_PART_SRCS
 350     settings/dolphin_compactmodesettings.kcfgc
 351     settings/dolphin_directoryviewpropertysettings.kcfgc
 352     settings/dolphin_detailsmodesettings.kcfgc
 353     settings/dolphin_iconsmodesettings.kcfgc
 354     settings/dolphin_generalsettings.kcfgc
 355     settings/dolphin_versioncontrolsettings.kcfgc
 356 )
 357
 358 kconfig_add_kcfg_files(kcm_dolphinnavigation_PART_SRCS
 359     settings/dolphin_generalsettings.kcfgc)
 360
 361 kconfig_add_kcfg_files(kcm_dolphinservices_PART_SRCS
 362     settings/dolphin_generalsettings.kcfgc
 363     settings/dolphin_versioncontrolsettings.kcfgc)
 364
 365 kconfig_add_kcfg_files(kcm_dolphingeneral_PART_SRCS
 366     settings/dolphin_generalsettings.kcfgc)
 367
 368 add_library(kcm_dolphinviewmodes MODULE ${kcm_dolphinviewmodes_PART_SRCS})
 369 add_library(kcm_dolphinnavigation MODULE ${kcm_dolphinnavigation_PART_SRCS})
 370 add_library(kcm_dolphinservices MODULE ${kcm_dolphinservices_PART_SRCS})
 371 add_library(kcm_dolphingeneral MODULE ${kcm_dolphingeneral_PART_SRCS})
 372
 373 target_link_libraries(kcm_dolphinviewmodes dolphinprivate)
 374 target_link_libraries(kcm_dolphinnavigation dolphinprivate)
 375 target_link_libraries(kcm_dolphinservices dolphinprivate)
 376 target_link_libraries(kcm_dolphingeneral dolphinprivate)
 377
 378 install(TARGETS kcm_dolphinviewmodes DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 379 install(TARGETS kcm_dolphinnavigation DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 380 install(TARGETS kcm_dolphinservices DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 381 install(TARGETS kcm_dolphingeneral DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 382
 383 ########### install files ###############
 384
 385 install( PROGRAMS org.kde.dolphin.desktop DESTINATION ${KDE_INSTALL_APPDIR} )
 386
 387 install( DIRECTORY DESTINATION "${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel" )
 388
 389 install(
 390     CODE "execute_process(COMMAND \"${CMAKE_COMMAND}\" -E create_symlink \"${KDE_INSTALL_FULL_APPDIR}/org.kde.dolphin.desktop\" \"\$ENV{DESTDIR}${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel/org.kde.dolphin.desktop\")"
 391 )
 392
 393 install( FILES settings/dolphin_directoryviewpropertysettings.kcfg
 394                settings/dolphin_generalsettings.kcfg
 395                settings/dolphin_compactmodesettings.kcfg
 396                settings/dolphin_iconsmodesettings.kcfg
 397                settings/dolphin_detailsmodesettings.kcfg
 398                settings/dolphin_versioncontrolsettings.kcfg
 399          DESTINATION ${KDE_INSTALL_KCFGDIR} )
 400 install( FILES org.kde.dolphin.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR} )
 401 install( FILES settings/kcm/kcmdolphinviewmodes.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 402 install( FILES settings/kcm/kcmdolphinnavigation.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 403 install( FILES settings/kcm/kcmdolphinservices.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 404 install( FILES settings/kcm/kcmdolphingeneral.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 405 install( FILES settings/services/servicemenu.knsrc DESTINATION ${KDE_INSTALL_CONFDIR} )
 406 install( PROGRAMS settings/services/servicemenuinstallation DESTINATION ${KDE_INSTALL_BINDIR} )
 407 install( PROGRAMS settings/services/servicemenudeinstallation DESTINATION ${KDE_INSTALL_BINDIR} )
 408
 409 if(BUILD_TESTING)
 410     find_package(Qt5Test ${QT_MIN_VERSION} CONFIG REQUIRED)
 411     add_subdirectory(tests)
 412 endif()