src/CMakeLists.txt

   1
   2 configure_file(config-baloo.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-baloo.h)
   3
   4 configure_file(config-dolphin.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-dolphin.h)
   5
   6 add_definitions(
   7     -DTRANSLATION_DOMAIN=\"dolphin\"
   8     -DQT_USE_FAST_CONCATENATION
   9     -DQT_USE_FAST_OPERATOR_PLUS
  10 )
  11 remove_definitions(
  12     -DQT_NO_CAST_FROM_BYTEARRAY
  13     -DQT_NO_URL_CAST_FROM_STRING
  14     -DQT_NO_SIGNALS_SLOTS_KEYWORDS
  15     -DQT_NO_CAST_FROM_ASCII
  16     -DQT_NO_CAST_TO_ASCII
  17 )
  18
  19 ##########################################
  20
  21 set(dolphinvcs_LIB_SRCS
  22     views/versioncontrol/kversioncontrolplugin.cpp
  23 )
  24
  25 add_library(dolphinvcs ${dolphinvcs_LIB_SRCS})
  26 generate_export_header(dolphinvcs BASE_NAME dolphinvcs)
  27
  28 target_link_libraries(
  29     dolphinvcs PUBLIC
  30     Qt5::Widgets
  31 )
  32
  33 set_target_properties(dolphinvcs PROPERTIES
  34     VERSION ${DOLPHINVCS_VERSION_STRING}
  35     SOVERSION ${DOLPHINVCS_SOVERSION}
  36     EXPORT_NAME DolphinVcs
  37 )
  38
  39 ecm_generate_headers(dolphinvcs_LIB_HEADERS
  40     HEADER_NAMES
  41     KVersionControlPlugin
  42
  43     RELATIVE "views/versioncontrol"
  44     REQUIRED_HEADERS dolphinvcs_LIB_HEADERS
  45 )
  46
  47 install(TARGETS dolphinvcs EXPORT DolphinVcsTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
  48
  49 install(FILES views/versioncontrol/fileviewversioncontrolplugin.desktop DESTINATION ${KDE_INSTALL_KSERVICETYPES5DIR})
  50 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphinvcs_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
  51 install(FILES ${dolphinvcs_LIB_HEADERS} DESTINATION "${KDE_INSTALL_INCLUDEDIR}/Dolphin" COMPONENT Devel)
  52
  53 ########### next target ###############
  54
  55 set(dolphinprivate_LIB_SRCS
  56     kitemviews/kfileitemlistview.cpp
  57     kitemviews/kfileitemlistwidget.cpp
  58     kitemviews/kfileitemmodel.cpp
  59     kitemviews/kfileitemmodelrolesupdater.cpp
  60     kitemviews/kitemlistcontainer.cpp
  61     kitemviews/kitemlistcontroller.cpp
  62     kitemviews/kitemlistgroupheader.cpp
  63     kitemviews/kitemlistheader.cpp
  64     kitemviews/kitemlistselectionmanager.cpp
  65     kitemviews/kitemliststyleoption.cpp
  66     kitemviews/kitemlistview.cpp
  67     kitemviews/kitemlistviewaccessible.cpp
  68     kitemviews/kitemlistwidget.cpp
  69     kitemviews/kitemmodelbase.cpp
  70     kitemviews/kitemset.cpp
  71     kitemviews/kstandarditem.cpp
  72     kitemviews/kstandarditemlistgroupheader.cpp
  73     kitemviews/kstandarditemlistwidget.cpp
  74     kitemviews/kstandarditemlistview.cpp
  75     kitemviews/kstandarditemmodel.cpp
  76     kitemviews/private/kdirectorycontentscounter.cpp
  77     kitemviews/private/kdirectorycontentscounterworker.cpp
  78     kitemviews/private/kfileitemclipboard.cpp
  79     kitemviews/private/kfileitemmodeldirlister.cpp
  80     kitemviews/private/kfileitemmodelfilter.cpp
  81     kitemviews/private/kitemlistheaderwidget.cpp
  82     kitemviews/private/kitemlistkeyboardsearchmanager.cpp
  83     kitemviews/private/kitemlistroleeditor.cpp
  84     kitemviews/private/kitemlistrubberband.cpp
  85     kitemviews/private/kitemlistselectiontoggle.cpp
  86     kitemviews/private/kitemlistsizehintresolver.cpp
  87     kitemviews/private/kitemlistsmoothscroller.cpp
  88     kitemviews/private/kitemlistviewanimation.cpp
  89     kitemviews/private/kitemlistviewlayouter.cpp
  90     kitemviews/private/kpixmapmodifier.cpp
  91     settings/additionalinfodialog.cpp
  92     settings/applyviewpropsjob.cpp
  93     settings/viewmodes/viewmodesettings.cpp
  94     settings/viewpropertiesdialog.cpp
  95     settings/viewpropsprogressinfo.cpp
  96     views/dolphinfileitemlistwidget.cpp
  97     views/dolphinitemlistview.cpp
  98     views/dolphinnewfilemenuobserver.cpp
  99     views/dolphinremoteencoding.cpp
 100     views/dolphinview.cpp
 101     views/dolphinviewactionhandler.cpp
 102     views/draganddrophelper.cpp
 103     views/renamedialog.cpp
 104     views/tooltips/filemetadatatooltip.cpp
 105     views/tooltips/tooltipmanager.cpp
 106     views/versioncontrol/updateitemstatesthread.cpp
 107     views/versioncontrol/versioncontrolobserver.cpp
 108     views/viewmodecontroller.cpp
 109     views/viewproperties.cpp
 110     views/zoomlevelinfo.cpp
 111     dolphinremoveaction.cpp
 112     dolphinnewfilemenu.cpp
 113     dolphindebug.cpp
 114 )
 115
 116 if(HAVE_BALOO)
 117     set(dolphinprivate_LIB_SRCS
 118         ${dolphinprivate_LIB_SRCS}
 119         kitemviews/private/kbaloorolesprovider.cpp
 120     )
 121 endif()
 122
 123 kconfig_add_kcfg_files(dolphinprivate_LIB_SRCS GENERATE_MOC
 124     settings/dolphin_compactmodesettings.kcfgc
 125     settings/dolphin_directoryviewpropertysettings.kcfgc
 126     settings/dolphin_detailsmodesettings.kcfgc
 127     settings/dolphin_iconsmodesettings.kcfgc
 128     settings/dolphin_generalsettings.kcfgc
 129     settings/dolphin_versioncontrolsettings.kcfgc
 130 )
 131
 132 add_library(dolphinprivate ${dolphinprivate_LIB_SRCS})
 133 generate_export_header(dolphinprivate BASE_NAME dolphin)
 134
 135 target_link_libraries(
 136     dolphinprivate PUBLIC
 137     dolphinvcs
 138     Qt5::Gui
 139     KF5::Crash
 140     KF5::I18n
 141     KF5::IconThemes
 142     KF5::KIOCore
 143     KF5::KIOWidgets
 144     KF5::KIOFileWidgets
 145     KF5::Completion
 146     KF5::TextWidgets
 147     KF5::WindowSystem
 148     KF5::ConfigCore
 149     KF5::NewStuff
 150     KF5::Parts
 151 )
 152
 153 if(HAVE_BALOO)
 154     target_link_libraries(
 155         dolphinprivate PUBLIC
 156         KF5::FileMetaData
 157         KF5::Baloo
 158         KF5::BalooWidgets
 159     )
 160 else()
 161     target_link_libraries(
 162         dolphinprivate PUBLIC
 163         KF5::KDELibs4Support # for KFileMetaDataWidget
 164     )
 165 endif()
 166
 167 set_target_properties(dolphinprivate PROPERTIES
 168     VERSION ${DOLPHINPRIVATE_VERSION_STRING}
 169     SOVERSION ${DOLPHINPRIVATE_SOVERSION}
 170 )
 171
 172 install(TARGETS dolphinprivate ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} LIBRARY NAMELINK_SKIP)
 173 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphin_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
 174
 175 ##########################################
 176
 177 set(dolphinpart_SRCS
 178    dolphinpart.cpp
 179    dolphinpart_ext.cpp
 180    dolphindebug.cpp
 181 )
 182
 183 add_library(dolphinpart MODULE ${dolphinpart_SRCS})
 184
 185 target_link_libraries(dolphinpart
 186     dolphinprivate
 187 )
 188
 189 install(TARGETS dolphinpart DESTINATION ${KDE_INSTALL_PLUGINDIR})
 190
 191 install(FILES dolphinpart.rc DESTINATION ${KDE_INSTALL_KXMLGUI5DIR}/dolphinpart)
 192 install(FILES dolphinpart.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR})
 193
 194 ##########################################
 195
 196 set(dolphin_SRCS
 197     dolphindockwidget.cpp
 198     dolphinmainwindow.cpp
 199     dolphinviewcontainer.cpp
 200     dolphincontextmenu.cpp
 201     dolphintabbar.cpp
 202     dolphinrecenttabsmenu.cpp
 203     dolphintabpage.cpp
 204     dolphintabwidget.cpp
 205     filterbar/filterbar.cpp
 206     main.cpp
 207     panels/information/filemetadataconfigurationdialog.cpp
 208     panels/information/informationpanel.cpp
 209     panels/information/informationpanelcontent.cpp
 210     panels/information/pixmapviewer.cpp
 211     panels/information/phononwidget.cpp
 212     panels/places/placespanel.cpp
 213     panels/places/placesitem.cpp
 214     panels/places/placesitemeditdialog.cpp
 215     panels/places/placesitemlistgroupheader.cpp
 216     panels/places/placesitemlistwidget.cpp
 217     panels/places/placesitemmodel.cpp
 218     panels/places/placesitemsignalhandler.cpp
 219     panels/places/placesview.cpp
 220     panels/panel.cpp
 221     panels/folders/foldersitemlistwidget.cpp
 222     panels/folders/treeviewcontextmenu.cpp
 223     panels/folders/folderspanel.cpp
 224     search/dolphinfacetswidget.cpp
 225     search/dolphinsearchbox.cpp
 226     settings/general/behaviorsettingspage.cpp
 227     settings/general/configurepreviewplugindialog.cpp
 228     settings/general/confirmationssettingspage.cpp
 229     settings/general/generalsettingspage.cpp
 230     settings/general/previewssettingspage.cpp
 231     settings/general/statusbarsettingspage.cpp
 232     settings/dolphinsettingsdialog.cpp
 233     settings/navigation/navigationsettingspage.cpp
 234     settings/services/servicessettingspage.cpp
 235     settings/settingspagebase.cpp
 236     settings/serviceitemdelegate.cpp
 237     settings/servicemodel.cpp
 238     settings/startup/startupsettingspage.cpp
 239     settings/trash/trashsettingspage.cpp
 240     settings/viewmodes/dolphinfontrequester.cpp
 241     settings/viewmodes/viewsettingspage.cpp
 242     settings/viewmodes/viewmodesettings.cpp
 243     settings/viewmodes/viewsettingstab.cpp
 244     statusbar/dolphinstatusbar.cpp
 245     statusbar/mountpointobserver.cpp
 246     statusbar/mountpointobservercache.cpp
 247     statusbar/spaceinfoobserver.cpp
 248     statusbar/statusbarspaceinfo.cpp
 249     views/zoomlevelinfo.cpp
 250     dolphindebug.cpp
 251     dbusinterface.cpp
 252     global.cpp
 253 )
 254
 255 kconfig_add_kcfg_files(dolphin_SRCS GENERATE_MOC
 256     panels/folders/dolphin_folderspanelsettings.kcfgc
 257     panels/information/dolphin_informationpanelsettings.kcfgc
 258     panels/places/dolphin_placespanelsettings.kcfgc
 259     settings/dolphin_compactmodesettings.kcfgc
 260     settings/dolphin_detailsmodesettings.kcfgc
 261     settings/dolphin_generalsettings.kcfgc
 262     settings/dolphin_iconsmodesettings.kcfgc
 263     search/dolphin_searchsettings.kcfgc
 264     settings/dolphin_versioncontrolsettings.kcfgc
 265 )
 266
 267 if(NOT WIN32)
 268    set(dolphin_SRCS ${dolphin_SRCS} panels/terminal/terminalpanel.cpp)
 269 endif()
 270
 271 # TODO Does anything replace kde4_add_app_icon ?
 272 #kde4_add_app_icon(dolphin_SRCS "${KDE4_ICON_INSTALL_DIR}/oxygen/*/apps/system-file-manager.png")
 273
 274 kf5_add_kdeinit_executable(dolphin ${dolphin_SRCS})
 275
 276 target_include_directories(kdeinit_dolphin PRIVATE ${PHONON_INCLUDES})
 277
 278 target_link_libraries(kdeinit_dolphin
 279     dolphinprivate
 280     KF5::Parts
 281     KF5::KCMUtils
 282     KF5::Solid
 283     KF5::CoreAddons
 284     KF5::DBusAddons
 285     KF5::Bookmarks
 286     KF5::Notifications
 287     Phonon::phonon4qt5
 288 )
 289
 290 if (KF5Activities_FOUND)
 291     target_link_libraries(
 292         kdeinit_dolphin
 293         KF5::Activities
 294     )
 295 endif()
 296
 297 include(DbusInterfaceMacros)
 298
 299 generate_and_install_dbus_interface(
 300     kdeinit_dolphin
 301     dbusinterface.h
 302     org.freedesktop.FileManager1.xml
 303     OPTIONS -a
 304 )
 305
 306 install(TARGETS kdeinit_dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 307 install(TARGETS dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 308
 309 ##########################################
 310
 311 set(kcm_dolphinviewmodes_PART_SRCS
 312     settings/kcm/kcmdolphinviewmodes.cpp
 313     settings/viewmodes/dolphinfontrequester.cpp
 314     settings/viewmodes/viewmodesettings.cpp
 315     settings/viewmodes/viewsettingstab.cpp
 316     views/zoomlevelinfo.cpp)
 317
 318 set(kcm_dolphinnavigation_PART_SRCS
 319     settings/kcm/kcmdolphinnavigation.cpp
 320     settings/navigation/navigationsettingspage.cpp
 321     settings/settingspagebase.cpp)
 322
 323 set(kcm_dolphinservices_PART_SRCS
 324     settings/kcm/kcmdolphinservices.cpp
 325     settings/services/servicessettingspage.cpp
 326     settings/settingspagebase.cpp
 327     settings/serviceitemdelegate.cpp
 328     settings/servicemodel.cpp)
 329
 330 set(kcm_dolphingeneral_PART_SRCS
 331     settings/kcm/kcmdolphingeneral.cpp
 332     settings/general/behaviorsettingspage.cpp
 333     settings/general/previewssettingspage.cpp
 334     settings/general/configurepreviewplugindialog.cpp
 335     settings/general/confirmationssettingspage.cpp
 336     settings/settingspagebase.cpp
 337     settings/serviceitemdelegate.cpp
 338     settings/servicemodel.cpp)
 339
 340 kconfig_add_kcfg_files(kcm_dolphinviewmodes_PART_SRCS
 341     settings/dolphin_compactmodesettings.kcfgc
 342     settings/dolphin_directoryviewpropertysettings.kcfgc
 343     settings/dolphin_detailsmodesettings.kcfgc
 344     settings/dolphin_iconsmodesettings.kcfgc
 345     settings/dolphin_generalsettings.kcfgc
 346     settings/dolphin_versioncontrolsettings.kcfgc
 347 )
 348
 349 kconfig_add_kcfg_files(kcm_dolphinnavigation_PART_SRCS
 350     settings/dolphin_generalsettings.kcfgc)
 351
 352 kconfig_add_kcfg_files(kcm_dolphinservices_PART_SRCS
 353     settings/dolphin_generalsettings.kcfgc
 354     settings/dolphin_versioncontrolsettings.kcfgc)
 355
 356 kconfig_add_kcfg_files(kcm_dolphingeneral_PART_SRCS
 357     settings/dolphin_generalsettings.kcfgc)
 358
 359 add_library(kcm_dolphinviewmodes MODULE ${kcm_dolphinviewmodes_PART_SRCS})
 360 add_library(kcm_dolphinnavigation MODULE ${kcm_dolphinnavigation_PART_SRCS})
 361 add_library(kcm_dolphinservices MODULE ${kcm_dolphinservices_PART_SRCS})
 362 add_library(kcm_dolphingeneral MODULE ${kcm_dolphingeneral_PART_SRCS})
 363
 364 target_link_libraries(kcm_dolphinviewmodes dolphinprivate)
 365 target_link_libraries(kcm_dolphinnavigation dolphinprivate)
 366 target_link_libraries(kcm_dolphinservices dolphinprivate)
 367 target_link_libraries(kcm_dolphingeneral dolphinprivate)
 368
 369 install(TARGETS kcm_dolphinviewmodes DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 370 install(TARGETS kcm_dolphinnavigation DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 371 install(TARGETS kcm_dolphinservices DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 372 install(TARGETS kcm_dolphingeneral DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 373
 374 ########### install files ###############
 375
 376 install( PROGRAMS org.kde.dolphin.desktop DESTINATION ${KDE_INSTALL_APPDIR} )
 377 install( FILES settings/dolphin_directoryviewpropertysettings.kcfg
 378                settings/dolphin_generalsettings.kcfg
 379                settings/dolphin_compactmodesettings.kcfg
 380                settings/dolphin_iconsmodesettings.kcfg
 381                settings/dolphin_detailsmodesettings.kcfg
 382                settings/dolphin_versioncontrolsettings.kcfg
 383          DESTINATION ${KDE_INSTALL_KCFGDIR} )
 384 install( FILES dolphinui.rc DESTINATION ${KDE_INSTALL_KXMLGUI5DIR}/dolphin )
 385 install( FILES org.kde.dolphin.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR} )
 386 install( FILES settings/kcm/kcmdolphinviewmodes.desktop DESTINATION
 387 ${KDE_INSTALL_KSERVICES5DIR} )
 388 install( FILES settings/kcm/kcmdolphinnavigation.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 389 install( FILES settings/kcm/kcmdolphinservices.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 390 install( FILES settings/kcm/kcmdolphingeneral.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 391 install( FILES settings/services/servicemenu.knsrc DESTINATION ${KDE_INSTALL_CONFDIR} )
 392 install( PROGRAMS settings/services/servicemenuinstallation DESTINATION ${KDE_INSTALL_BINDIR} )
 393 install( PROGRAMS settings/services/servicemenudeinstallation DESTINATION ${KDE_INSTALL_BINDIR} )
 394
 395 if(BUILD_TESTING)
 396     find_package(Qt5Test ${QT_MIN_VERSION} CONFIG REQUIRED)
 397     add_subdirectory(tests)
 398 endif()