src/CMakeLists.txt

   1 include(ECMAddAppIcon)
   2
   3 configure_file(config-dolphin.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-dolphin.h)
   4
   5 add_definitions(
   6     -DTRANSLATION_DOMAIN=\"dolphin\"
   7 )
   8 remove_definitions(
   9     -DQT_NO_CAST_FROM_BYTEARRAY
  10     -DQT_NO_CAST_FROM_ASCII
  11     -DQT_NO_CAST_TO_ASCII
  12 )
  13
  14 ##########################################
  15
  16 add_library(dolphinvcs SHARED)
  17
  18 target_sources(dolphinvcs PRIVATE
  19     views/versioncontrol/kversioncontrolplugin.cpp
  20 )
  21
  22 generate_export_header(dolphinvcs BASE_NAME dolphinvcs)
  23
  24 target_link_libraries(
  25     dolphinvcs PUBLIC
  26     Qt${QT_MAJOR_VERSION}::Widgets
  27 )
  28
  29 set_target_properties(dolphinvcs PROPERTIES
  30     VERSION ${DOLPHINVCS_VERSION}
  31     SOVERSION ${DOLPHINVCS_SOVERSION}
  32     EXPORT_NAME DolphinVcs
  33 )
  34
  35 ecm_generate_headers(dolphinvcs_LIB_HEADERS
  36     HEADER_NAMES
  37     KVersionControlPlugin
  38
  39     RELATIVE "views/versioncontrol"
  40     REQUIRED_HEADERS dolphinvcs_LIB_HEADERS
  41 )
  42
  43 install(TARGETS dolphinvcs EXPORT DolphinVcsTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
  44
  45 install(FILES views/versioncontrol/fileviewversioncontrolplugin.desktop DESTINATION ${KDE_INSTALL_KSERVICETYPESDIR})
  46 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphinvcs_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
  47 install(FILES ${dolphinvcs_LIB_HEADERS} DESTINATION "${KDE_INSTALL_INCLUDEDIR}/Dolphin" COMPONENT Devel)
  48
  49 ########### next target ###############
  50
  51 add_library(dolphinprivate SHARED)
  52
  53 target_sources(dolphinprivate PRIVATE
  54     kitemviews/kfileitemlistview.cpp
  55     kitemviews/kfileitemlistwidget.cpp
  56     kitemviews/kfileitemlisttostring.cpp
  57     kitemviews/kfileitemmodel.cpp
  58     kitemviews/kfileitemmodelrolesupdater.cpp
  59     kitemviews/kitemlistcontainer.cpp
  60     kitemviews/kitemlistcontroller.cpp
  61     kitemviews/kitemlistgroupheader.cpp
  62     kitemviews/kitemlistheader.cpp
  63     kitemviews/kitemlistselectionmanager.cpp
  64     kitemviews/kitemliststyleoption.cpp
  65     kitemviews/kitemlistview.cpp
  66     kitemviews/kitemlistviewaccessible.cpp
  67     kitemviews/kitemlistwidget.cpp
  68     kitemviews/kitemmodelbase.cpp
  69     kitemviews/kitemset.cpp
  70     kitemviews/kstandarditemlistgroupheader.cpp
  71     kitemviews/kstandarditemlistwidget.cpp
  72     kitemviews/kstandarditemlistview.cpp
  73     kitemviews/private/kdirectorycontentscounter.cpp
  74     kitemviews/private/kdirectorycontentscounterworker.cpp
  75     kitemviews/private/kfileitemclipboard.cpp
  76     kitemviews/private/kfileitemmodelfilter.cpp
  77     kitemviews/private/kitemlistheaderwidget.cpp
  78     kitemviews/private/kitemlistkeyboardsearchmanager.cpp
  79     kitemviews/private/kitemlistroleeditor.cpp
  80     kitemviews/private/kitemlistrubberband.cpp
  81     kitemviews/private/kitemlistselectiontoggle.cpp
  82     kitemviews/private/kitemlistsizehintresolver.cpp
  83     kitemviews/private/kitemlistsmoothscroller.cpp
  84     kitemviews/private/kitemlistviewanimation.cpp
  85     kitemviews/private/kitemlistviewlayouter.cpp
  86     kitemviews/private/kpixmapmodifier.cpp
  87     settings/applyviewpropsjob.cpp
  88     settings/viewmodes/viewmodesettings.cpp
  89     settings/viewpropertiesdialog.cpp
  90     settings/viewpropsprogressinfo.cpp
  91     views/dolphinfileitemlistwidget.cpp
  92     views/dolphinitemlistview.cpp
  93     views/dolphinnewfilemenuobserver.cpp
  94     views/dolphinremoteencoding.cpp
  95     views/dolphinview.cpp
  96     views/dolphinviewactionhandler.cpp
  97     views/draganddrophelper.cpp
  98     views/versioncontrol/updateitemstatesthread.cpp
  99     views/versioncontrol/versioncontrolobserver.cpp
 100     views/viewmodecontroller.cpp
 101     views/viewproperties.cpp
 102     views/zoomlevelinfo.cpp
 103     dolphinremoveaction.cpp
 104     middleclickactioneventfilter.cpp
 105     dolphinnewfilemenu.cpp
 106 )
 107
 108 ecm_qt_declare_logging_category(dolphinprivate
 109     HEADER dolphindebug.h
 110     IDENTIFIER DolphinDebug
 111     CATEGORY_NAME org.kde.dolphin
 112     DESCRIPTION "dolphin"
 113     EXPORT DOLPHIN
 114 )
 115
 116 if(HAVE_BALOO)
 117     target_sources(dolphinprivate PRIVATE
 118         views/tooltips/dolphinfilemetadatawidget.cpp
 119         views/tooltips/tooltipmanager.cpp
 120         kitemviews/private/kbaloorolesprovider.cpp
 121     )
 122 endif()
 123
 124 kconfig_add_kcfg_files(dolphinprivate
 125     settings/dolphin_compactmodesettings.kcfgc
 126     settings/dolphin_directoryviewpropertysettings.kcfgc
 127     settings/dolphin_detailsmodesettings.kcfgc
 128     settings/dolphin_iconsmodesettings.kcfgc
 129     settings/dolphin_generalsettings.kcfgc
 130     settings/dolphin_contextmenusettings.kcfgc
 131     settings/dolphin_versioncontrolsettings.kcfgc
 132 )
 133
 134 generate_export_header(dolphinprivate BASE_NAME dolphin)
 135
 136 target_link_libraries(
 137     dolphinprivate PUBLIC
 138     dolphinvcs
 139     Qt${QT_MAJOR_VERSION}::Concurrent
 140     Qt${QT_MAJOR_VERSION}::Gui
 141     KF5::I18n
 142     KF5::IconThemes
 143     KF5::KIOCore
 144     KF5::KIOWidgets
 145     KF5::KIOFileWidgets
 146     KF5::Completion
 147     KF5::TextWidgets
 148     KF5::ConfigCore
 149     KF5::NewStuff
 150     KF5::NewStuffWidgets    # KNSWidgets::Button
 151     KF5::Parts
 152     KF5::WindowSystem
 153     KF5::WidgetsAddons
 154 )
 155
 156 if(HAVE_BALOO)
 157     target_link_libraries(
 158         dolphinprivate PUBLIC
 159         KF5::FileMetaData
 160         KF5::Baloo
 161         KF5::BalooWidgets
 162     )
 163 endif()
 164
 165 set_target_properties(dolphinprivate PROPERTIES
 166     VERSION ${DOLPHINPRIVATE_VERSION}
 167     SOVERSION ${DOLPHINPRIVATE_SOVERSION}
 168 )
 169
 170 install(TARGETS dolphinprivate ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} LIBRARY NAMELINK_SKIP)
 171 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphin_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
 172
 173 ##########################################
 174 configure_file(dolphinpart.json.in ${CMAKE_CURRENT_BINARY_DIR}/dolphinpart.json @ONLY)
 175
 176 add_library(dolphinpart MODULE)
 177
 178 target_sources(dolphinpart PRIVATE
 179     dolphinpart.cpp
 180     dolphinpart_ext.cpp
 181     dolphindebug.cpp
 182
 183     dolphinpart.qrc
 184 )
 185
 186 target_link_libraries(dolphinpart
 187     dolphinprivate
 188 )
 189
 190 install(TARGETS dolphinpart DESTINATION ${KDE_INSTALL_PLUGINDIR}/kf${QT_MAJOR_VERSION}/parts)
 191
 192 ##########################################
 193
 194 add_library(dolphinstatic STATIC)
 195
 196 target_sources(dolphinstatic PRIVATE
 197     dolphinbookmarkhandler.cpp
 198     dolphindockwidget.cpp
 199     dolphinmainwindow.cpp
 200     dolphinviewcontainer.cpp
 201     dolphincontextmenu.cpp
 202     dolphinnavigatorswidgetaction.cpp
 203     dolphintabbar.cpp
 204     dolphinplacesmodelsingleton.cpp
 205     dolphinrecenttabsmenu.cpp
 206     dolphintabpage.cpp
 207     dolphintabwidget.cpp
 208     dolphinurlnavigator.cpp
 209     dolphinurlnavigatorscontroller.cpp
 210     trash/dolphintrash.cpp
 211     filterbar/filterbar.cpp
 212     panels/places/placespanel.cpp
 213     panels/panel.cpp
 214     panels/folders/foldersitemlistwidget.cpp
 215     panels/folders/treeviewcontextmenu.cpp
 216     panels/folders/folderspanel.cpp
 217     panels/terminal/terminalpanel.cpp
 218     search/dolphinfacetswidget.cpp
 219     search/dolphinquery.cpp
 220     search/dolphinsearchbox.cpp
 221     settings/general/behaviorsettingspage.cpp
 222     settings/general/configurepreviewplugindialog.cpp
 223     settings/general/confirmationssettingspage.cpp
 224     settings/general/generalsettingspage.cpp
 225     settings/general/previewssettingspage.cpp
 226     settings/general/statusbarsettingspage.cpp
 227     settings/dolphinsettingsdialog.cpp
 228     settings/navigation/navigationsettingspage.cpp
 229     settings/contextmenu/contextmenusettingspage.cpp
 230     settings/settingspagebase.cpp
 231     settings/serviceitemdelegate.cpp
 232     settings/servicemodel.cpp
 233     settings/startup/startupsettingspage.cpp
 234     settings/trash/trashsettingspage.cpp
 235     settings/viewmodes/dolphinfontrequester.cpp
 236     settings/viewmodes/viewsettingspage.cpp
 237     settings/viewmodes/viewmodesettings.cpp
 238     settings/viewmodes/viewsettingstab.cpp
 239     statusbar/dolphinstatusbar.cpp
 240     statusbar/mountpointobserver.cpp
 241     statusbar/mountpointobservercache.cpp
 242     statusbar/spaceinfoobserver.cpp
 243     statusbar/statusbarspaceinfo.cpp
 244     views/zoomlevelinfo.cpp
 245     dolphindebug.cpp
 246     global.cpp
 247     dolphin.qrc
 248 )
 249
 250 if(HAVE_BALOO)
 251     target_sources(dolphinstatic PRIVATE
 252         panels/information/informationpanel.cpp
 253         panels/information/informationpanelcontent.cpp
 254         panels/information/pixmapviewer.cpp
 255         panels/information/phononwidget.cpp
 256     )
 257 endif()
 258
 259 if(HAVE_KUSERFEEDBACK)
 260     target_sources(dolphinstatic PRIVATE
 261         userfeedback/dolphinfeedbackprovider.cpp
 262         userfeedback/settingsdatasource.cpp
 263         userfeedback/placesdatasource.cpp
 264         settings/userfeedback/userfeedbacksettingspage.cpp
 265     )
 266 endif()
 267
 268 kconfig_add_kcfg_files(dolphinstatic
 269     panels/folders/dolphin_folderspanelsettings.kcfgc
 270     panels/information/dolphin_informationpanelsettings.kcfgc
 271     panels/places/dolphin_placespanelsettings.kcfgc
 272     settings/dolphin_compactmodesettings.kcfgc
 273     settings/dolphin_detailsmodesettings.kcfgc
 274     settings/dolphin_contextmenusettings.kcfgc
 275     settings/dolphin_iconsmodesettings.kcfgc
 276     search/dolphin_searchsettings.kcfgc
 277     settings/dolphin_versioncontrolsettings.kcfgc
 278 )
 279 kconfig_add_kcfg_files(dolphinstatic GENERATE_MOC
 280     settings/dolphin_generalsettings.kcfgc
 281 )
 282
 283 qt_generate_dbus_interface(${CMAKE_CURRENT_SOURCE_DIR}/dolphinmainwindow.h org.kde.DolphinMainWindow.xml)
 284 qt_add_dbus_adaptor(dolphin_dbus_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindow.h DolphinMainWindow)
 285 qt_add_dbus_interface(dolphin_dbus_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindowinterface)
 286 qt_add_dbus_interface(dolphin_dbus_SRCS panels/terminal/org.kde.KIOFuse.VFS.xml kiofuse_interface)
 287
 288 target_sources(dolphinstatic PRIVATE
 289     ${dolphin_dbus_SRCS}
 290 )
 291
 292 target_include_directories(dolphinstatic SYSTEM PRIVATE ${PHONON_INCLUDES})
 293 target_link_libraries(dolphinstatic
 294     dolphinprivate
 295     KF5::CoreAddons
 296     KF5::KCMUtils
 297     KF5::DBusAddons
 298     KF5::Notifications
 299     Phonon::phonon4qt${QT_MAJOR_VERSION}
 300 )
 301
 302 if (HAVE_KACTIVITIES)
 303     target_link_libraries(
 304         dolphinstatic
 305         KF5::Activities
 306     )
 307 endif()
 308
 309 if (HAVE_KUSERFEEDBACK)
 310     target_link_libraries(
 311         dolphinstatic
 312         KUserFeedbackCore
 313         KUserFeedbackWidgets
 314     )
 315 endif()
 316
 317 add_executable(dolphin)
 318
 319 target_sources(dolphin PRIVATE
 320     dbusinterface.cpp
 321     main.cpp
 322 )
 323
 324 if(FLATPAK)
 325     target_compile_definitions(dolphin PRIVATE FLATPAK)
 326 endif()
 327
 328 # Sets the icon on Windows and OSX
 329 file(GLOB ICONS_SRCS "${CMAKE_CURRENT_SOURCE_DIR}/icons/*system-file-manager.png")
 330 ecm_add_app_icon(dolphin ICONS ${ICONS_SRCS})
 331
 332 target_link_libraries(dolphin
 333     PRIVATE
 334     dolphinprivate
 335     dolphinstatic
 336     KF5::Crash
 337 )
 338
 339 include(DbusInterfaceMacros)
 340
 341 generate_and_install_dbus_interface(
 342     dolphin
 343     dbusinterface.h
 344     org.freedesktop.FileManager1.xml
 345     OPTIONS -a
 346 )
 347
 348 install(TARGETS dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 349
 350 ##########################################
 351
 352 if(NOT WIN32)
 353     # The settings are still accessible from the hamburger menu
 354     add_library(kcm_dolphinviewmodes MODULE)
 355     add_library(kcm_dolphinnavigation MODULE)
 356     add_library(kcm_dolphingeneral MODULE)
 357
 358     target_sources(kcm_dolphinviewmodes PRIVATE
 359         settings/kcm/kcmdolphinviewmodes.cpp
 360         settings/viewmodes/dolphinfontrequester.cpp
 361         settings/viewmodes/viewmodesettings.cpp
 362         settings/viewmodes/viewsettingstab.cpp
 363         views/zoomlevelinfo.cpp)
 364
 365     target_sources(kcm_dolphinnavigation PRIVATE
 366         settings/kcm/kcmdolphinnavigation.cpp
 367         settings/navigation/navigationsettingspage.cpp
 368         settings/settingspagebase.cpp)
 369
 370     target_sources(kcm_dolphingeneral PRIVATE
 371         settings/kcm/kcmdolphingeneral.cpp
 372         settings/general/behaviorsettingspage.cpp
 373         settings/general/previewssettingspage.cpp
 374         settings/general/configurepreviewplugindialog.cpp
 375         settings/general/confirmationssettingspage.cpp
 376         settings/settingspagebase.cpp
 377         settings/serviceitemdelegate.cpp
 378         settings/servicemodel.cpp)
 379
 380     kconfig_add_kcfg_files(kcm_dolphinviewmodes
 381         settings/dolphin_compactmodesettings.kcfgc
 382         settings/dolphin_directoryviewpropertysettings.kcfgc
 383         settings/dolphin_detailsmodesettings.kcfgc
 384         settings/dolphin_iconsmodesettings.kcfgc
 385         settings/dolphin_generalsettings.kcfgc
 386         settings/dolphin_versioncontrolsettings.kcfgc
 387     )
 388
 389     kconfig_add_kcfg_files(kcm_dolphinnavigation
 390         settings/dolphin_generalsettings.kcfgc)
 391
 392     kconfig_add_kcfg_files(kcm_dolphingeneral
 393         settings/dolphin_generalsettings.kcfgc)
 394
 395     target_link_libraries(kcm_dolphinviewmodes dolphinprivate)
 396     target_link_libraries(kcm_dolphinnavigation dolphinprivate)
 397     target_link_libraries(kcm_dolphingeneral dolphinprivate)
 398
 399     install( FILES org.kde.dolphin.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR} )
 400
 401     install(TARGETS kcm_dolphinviewmodes DESTINATION ${KDE_INSTALL_PLUGINDIR}/dolphin/kcms )
 402     install(TARGETS kcm_dolphinnavigation DESTINATION ${KDE_INSTALL_PLUGINDIR}/dolphin/kcms )
 403     install(TARGETS kcm_dolphingeneral DESTINATION ${KDE_INSTALL_PLUGINDIR}/dolphin/kcms )
 404 endif()
 405
 406 if(NOT WIN32)
 407     add_subdirectory(settings/contextmenu/servicemenuinstaller)
 408     install( FILES settings/contextmenu/servicemenu.knsrc DESTINATION ${KDE_INSTALL_KNSRCDIR} )
 409 endif()
 410
 411 ########### install files ###############
 412
 413 install( PROGRAMS org.kde.dolphin.desktop DESTINATION ${KDE_INSTALL_APPDIR} )
 414
 415 install( DIRECTORY DESTINATION "${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel" )
 416
 417 install(
 418     CODE "execute_process(COMMAND \"${CMAKE_COMMAND}\" -E create_symlink \"${KDE_INSTALL_FULL_APPDIR}/org.kde.dolphin.desktop\" \"\$ENV{DESTDIR}${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel/org.kde.dolphin.desktop\")"
 419 )
 420
 421 install( FILES settings/dolphin_directoryviewpropertysettings.kcfg
 422                settings/dolphin_generalsettings.kcfg
 423                settings/dolphin_contextmenusettings.kcfg
 424                settings/dolphin_compactmodesettings.kcfg
 425                settings/dolphin_iconsmodesettings.kcfg
 426                settings/dolphin_detailsmodesettings.kcfg
 427                settings/dolphin_versioncontrolsettings.kcfg
 428          DESTINATION ${KDE_INSTALL_KCFGDIR} )
 429
 430 install( FILES settings/dolphin_detailsmodesettings.upd
 431          DESTINATION ${KDE_INSTALL_KCONFUPDATEDIR} )
 432
 433 if(BUILD_TESTING)
 434     add_subdirectory(tests)
 435 endif()