src/CMakeLists.txt

   1 include(ECMAddAppIcon)
   2
   3 configure_file(config-dolphin.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-dolphin.h)
   4
   5 add_definitions(
   6     -DTRANSLATION_DOMAIN=\"dolphin\"
   7 )
   8 remove_definitions(
   9     -DQT_NO_CAST_FROM_BYTEARRAY
  10     -DQT_NO_CAST_FROM_ASCII
  11     -DQT_NO_CAST_TO_ASCII
  12 )
  13
  14 ##########################################
  15
  16 add_library(dolphinvcs SHARED)
  17
  18 target_sources(dolphinvcs PRIVATE
  19     views/versioncontrol/kversioncontrolplugin.cpp
  20 )
  21
  22 generate_export_header(dolphinvcs BASE_NAME dolphinvcs)
  23
  24 target_link_libraries(
  25     dolphinvcs PUBLIC
  26     Qt6::Widgets
  27 )
  28
  29 set_target_properties(dolphinvcs PROPERTIES
  30     VERSION ${DOLPHINVCS_VERSION}
  31     SOVERSION ${DOLPHINVCS_SOVERSION}
  32     EXPORT_NAME DolphinVcs
  33 )
  34
  35 ecm_generate_headers(dolphinvcs_LIB_HEADERS
  36     HEADER_NAMES
  37     KVersionControlPlugin
  38
  39     RELATIVE "views/versioncontrol"
  40     REQUIRED_HEADERS dolphinvcs_LIB_HEADERS
  41 )
  42 target_include_directories(dolphinvcs INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR}>")
  43
  44 install(TARGETS dolphinvcs EXPORT DolphinVcsTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
  45
  46 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphinvcs_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
  47 install(FILES ${dolphinvcs_LIB_HEADERS} DESTINATION "${KDE_INSTALL_INCLUDEDIR}/Dolphin" COMPONENT Devel)
  48
  49 ########### next target ###############
  50
  51 add_library(dolphinprivate SHARED)
  52
  53 target_sources(dolphinprivate PRIVATE
  54     kitemviews/kfileitemlistview.cpp
  55     kitemviews/kfileitemlistwidget.cpp
  56     kitemviews/kfileitemlisttostring.cpp
  57     kitemviews/kfileitemmodel.cpp
  58     kitemviews/kfileitemmodelrolesupdater.cpp
  59     kitemviews/kitemlistcontainer.cpp
  60     kitemviews/kitemlistcontroller.cpp
  61     kitemviews/kitemlistgroupheader.cpp
  62     kitemviews/kitemlistheader.cpp
  63     kitemviews/kitemlistselectionmanager.cpp
  64     kitemviews/kitemliststyleoption.cpp
  65     kitemviews/kitemlistview.cpp
  66     kitemviews/kitemlistviewaccessible.cpp
  67     kitemviews/kitemlistwidget.cpp
  68     kitemviews/kitemmodelbase.cpp
  69     kitemviews/kitemset.cpp
  70     kitemviews/kstandarditemlistgroupheader.cpp
  71     kitemviews/kstandarditemlistwidget.cpp
  72     kitemviews/kstandarditemlistview.cpp
  73     kitemviews/private/kdirectorycontentscounter.cpp
  74     kitemviews/private/kdirectorycontentscounterworker.cpp
  75     kitemviews/private/kfileitemclipboard.cpp
  76     kitemviews/private/kfileitemmodelfilter.cpp
  77     kitemviews/private/kitemlistheaderwidget.cpp
  78     kitemviews/private/kitemlistkeyboardsearchmanager.cpp
  79     kitemviews/private/kitemlistroleeditor.cpp
  80     kitemviews/private/kitemlistrubberband.cpp
  81     kitemviews/private/kitemlistselectiontoggle.cpp
  82     kitemviews/private/kitemlistsizehintresolver.cpp
  83     kitemviews/private/kitemlistsmoothscroller.cpp
  84     kitemviews/private/kitemlistviewanimation.cpp
  85     kitemviews/private/kitemlistviewlayouter.cpp
  86     kitemviews/private/kitemviewsutils.cpp
  87     kitemviews/private/kpixmapmodifier.cpp
  88     settings/applyviewpropsjob.cpp
  89     settings/viewmodes/viewmodesettings.cpp
  90     settings/viewpropertiesdialog.cpp
  91     settings/viewpropsprogressinfo.cpp
  92     selectionmode/actiontexthelper.cpp
  93     views/dolphinfileitemlistwidget.cpp
  94     views/dolphinitemlistview.cpp
  95     views/dolphinnewfilemenuobserver.cpp
  96     views/dolphinremoteencoding.cpp
  97     views/dolphinview.cpp
  98     views/dolphinviewactionhandler.cpp
  99     views/draganddrophelper.cpp
 100     views/versioncontrol/updateitemstatesthread.cpp
 101     views/versioncontrol/versioncontrolobserver.cpp
 102     views/viewmodecontroller.cpp
 103     views/viewproperties.cpp
 104     views/zoomlevelinfo.cpp
 105     dolphinremoveaction.cpp
 106     middleclickactioneventfilter.cpp
 107     dolphinnewfilemenu.cpp
 108
 109     kitemviews/kfileitemlistview.h
 110     kitemviews/kfileitemlistwidget.h
 111     kitemviews/kfileitemlisttostring.h
 112     kitemviews/kfileitemmodel.h
 113     kitemviews/kfileitemmodelrolesupdater.h
 114     kitemviews/kitemlistcontainer.h
 115     kitemviews/kitemlistcontroller.h
 116     kitemviews/kitemlistgroupheader.h
 117     kitemviews/kitemlistheader.h
 118     kitemviews/kitemlistselectionmanager.h
 119     kitemviews/kitemliststyleoption.h
 120     kitemviews/kitemlistview.h
 121     kitemviews/kitemlistviewaccessible.h
 122     kitemviews/kitemlistwidget.h
 123     kitemviews/kitemmodelbase.h
 124     kitemviews/kitemset.h
 125     kitemviews/kstandarditemlistgroupheader.h
 126     kitemviews/kstandarditemlistwidget.h
 127     kitemviews/kstandarditemlistview.h
 128     kitemviews/private/kdirectorycontentscounter.h
 129     kitemviews/private/kdirectorycontentscounterworker.h
 130     kitemviews/private/kfileitemclipboard.h
 131     kitemviews/private/kfileitemmodelfilter.h
 132     kitemviews/private/kitemlistheaderwidget.h
 133     kitemviews/private/kitemlistkeyboardsearchmanager.h
 134     kitemviews/private/kitemlistroleeditor.h
 135     kitemviews/private/kitemlistrubberband.h
 136     kitemviews/private/kitemlistselectiontoggle.h
 137     kitemviews/private/kitemlistsizehintresolver.h
 138     kitemviews/private/kitemlistsmoothscroller.h
 139     kitemviews/private/kitemlistviewanimation.h
 140     kitemviews/private/kitemlistviewlayouter.h
 141     kitemviews/private/kpixmapmodifier.h
 142     settings/applyviewpropsjob.h
 143     settings/viewmodes/viewmodesettings.h
 144     settings/viewpropertiesdialog.h
 145     settings/viewpropsprogressinfo.h
 146     selectionmode/actiontexthelper.h
 147     views/dolphinfileitemlistwidget.h
 148     views/dolphinitemlistview.h
 149     views/dolphinnewfilemenuobserver.h
 150     views/dolphinremoteencoding.h
 151     views/dolphinview.h
 152     views/dolphinviewactionhandler.h
 153     views/draganddrophelper.h
 154     views/versioncontrol/updateitemstatesthread.h
 155     views/versioncontrol/versioncontrolobserver.h
 156     views/viewmodecontroller.h
 157     views/viewproperties.h
 158     views/zoomlevelinfo.h
 159     dolphinremoveaction.h
 160     middleclickactioneventfilter.h
 161     dolphinnewfilemenu.h
 162 )
 163
 164 ecm_qt_declare_logging_category(dolphinprivate
 165     HEADER dolphindebug.h
 166     IDENTIFIER DolphinDebug
 167     CATEGORY_NAME org.kde.dolphin
 168     DESCRIPTION "dolphin"
 169     EXPORT DOLPHIN
 170 )
 171
 172 if(HAVE_BALOO)
 173     target_sources(dolphinprivate PRIVATE
 174         views/tooltips/dolphinfilemetadatawidget.cpp
 175         views/tooltips/tooltipmanager.cpp
 176         kitemviews/private/kbaloorolesprovider.cpp
 177         views/tooltips/dolphinfilemetadatawidget.h
 178         views/tooltips/tooltipmanager.h
 179         kitemviews/private/kbaloorolesprovider.h
 180     )
 181 endif()
 182
 183 kconfig_add_kcfg_files(dolphinprivate
 184     settings/dolphin_compactmodesettings.kcfgc
 185     settings/dolphin_directoryviewpropertysettings.kcfgc
 186     settings/dolphin_detailsmodesettings.kcfgc
 187     settings/dolphin_iconsmodesettings.kcfgc
 188     settings/dolphin_contentdisplaysettings.kcfgc
 189     settings/dolphin_generalsettings.kcfgc
 190     settings/dolphin_contextmenusettings.kcfgc
 191     settings/dolphin_versioncontrolsettings.kcfgc
 192 )
 193
 194 generate_export_header(dolphinprivate BASE_NAME dolphin)
 195
 196 target_link_libraries(
 197     dolphinprivate PUBLIC
 198     dolphinvcs
 199     Qt6::Concurrent
 200     Qt6::Gui
 201     KF6::I18n
 202     KF6::IconThemes
 203     KF6::KIOCore
 204     KF6::KIOWidgets
 205     KF6::KIOFileWidgets
 206     KF6::Completion
 207     KF6::TextWidgets
 208     KF6::ConfigCore
 209     KF6::NewStuffWidgets    # KNSWidgets::Button
 210     KF6::Parts
 211     KF6::WindowSystem
 212     KF6::WidgetsAddons
 213     KF6::Codecs
 214     KF6::KCMUtils
 215
 216     ${FTS_LIB}
 217 )
 218
 219 if(HAVE_BALOO)
 220     target_link_libraries(
 221         dolphinprivate PUBLIC
 222         KF6::FileMetaData
 223         KF6::Baloo
 224         KF6::BalooWidgets
 225     )
 226 endif()
 227
 228 set_target_properties(dolphinprivate PROPERTIES
 229     VERSION ${DOLPHINPRIVATE_VERSION}
 230     SOVERSION ${DOLPHINPRIVATE_SOVERSION}
 231 )
 232
 233 install(TARGETS dolphinprivate ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} LIBRARY NAMELINK_SKIP)
 234 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphin_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
 235
 236 ##########################################
 237 configure_file(dolphinpart.json.in ${CMAKE_CURRENT_BINARY_DIR}/dolphinpart.json @ONLY)
 238
 239 add_library(dolphinpart MODULE)
 240
 241 target_sources(dolphinpart PRIVATE
 242     dolphinpart.cpp
 243     dolphinpart_ext.cpp
 244     dolphindebug.cpp
 245     dolphinpart.h
 246     dolphinpart_ext.h
 247     dolphindebug.h
 248
 249     dolphinpart.qrc
 250 )
 251
 252 target_link_libraries(dolphinpart
 253     dolphinprivate
 254 )
 255
 256 install(TARGETS dolphinpart DESTINATION ${KDE_INSTALL_PLUGINDIR}/kf6/parts)
 257 install(FILES dolphinpartactions.desktop DESTINATION "${KDE_INSTALL_DATADIR}/dolphin/")
 258
 259 ##########################################
 260
 261 add_library(dolphinstatic STATIC)
 262
 263 target_sources(dolphinstatic PRIVATE
 264     dolphinbookmarkhandler.cpp
 265     dolphindockwidget.cpp
 266     dolphinmainwindow.cpp
 267     dolphinviewcontainer.cpp
 268     dolphincontextmenu.cpp
 269     dolphinnavigatorswidgetaction.cpp
 270     dolphintabbar.cpp
 271     dolphinplacesmodelsingleton.cpp
 272     dolphinrecenttabsmenu.cpp
 273     dolphintabpage.cpp
 274     dolphintabwidget.cpp
 275     dolphinurlnavigator.cpp
 276     dolphinurlnavigatorscontroller.cpp
 277     trash/dolphintrash.cpp
 278     filterbar/filterbar.cpp
 279     kitemviews/kfileitemlisttostring.cpp
 280     panels/places/placespanel.cpp
 281     panels/panel.cpp
 282     panels/folders/foldersitemlistwidget.cpp
 283     panels/folders/treeviewcontextmenu.cpp
 284     panels/folders/folderspanel.cpp
 285     panels/terminal/terminalpanel.cpp
 286     search/dolphinfacetswidget.cpp
 287     search/dolphinquery.cpp
 288     search/dolphinsearchbox.cpp
 289     selectionmode/actiontexthelper.cpp
 290     selectionmode/actionwithwidget.cpp
 291     selectionmode/backgroundcolorhelper.cpp
 292     selectionmode/bottombar.cpp
 293     selectionmode/bottombarcontentscontainer.cpp
 294     selectionmode/topbar.cpp
 295     settings/interface/folderstabssettingspage.cpp
 296     settings/interface/statusandlocationbarssettingspage.cpp
 297     settings/interface/confirmationssettingspage.cpp
 298     settings/interface/interfacesettingspage.cpp
 299     settings/interface/previewssettingspage.cpp
 300     settings/dolphinsettingsdialog.cpp
 301     settings/contextmenu/contextmenusettingspage.cpp
 302     settings/settingspagebase.cpp
 303     settings/servicemodel.cpp
 304     settings/trash/trashsettingspage.cpp
 305     settings/viewmodes/dolphinfontrequester.cpp
 306     settings/viewmodes/viewsettingspage.cpp
 307     settings/viewmodes/viewmodesettings.cpp
 308     settings/viewmodes/viewsettingstab.cpp
 309     settings/viewmodes/contentdisplaytab.cpp
 310     settings/viewmodes/generalviewsettingspage.cpp
 311     statusbar/dolphinstatusbar.cpp
 312     statusbar/mountpointobserver.cpp
 313     statusbar/mountpointobservercache.cpp
 314     statusbar/spaceinfoobserver.cpp
 315     statusbar/statusbarspaceinfo.cpp
 316     views/zoomlevelinfo.cpp
 317     dolphindebug.cpp
 318     global.cpp
 319     dolphin.qrc
 320
 321     dolphinbookmarkhandler.h
 322     dolphindockwidget.h
 323     dolphinmainwindow.h
 324     dolphinviewcontainer.h
 325     dolphincontextmenu.h
 326     dolphinnavigatorswidgetaction.h
 327     dolphintabbar.h
 328     dolphinplacesmodelsingleton.h
 329     dolphinrecenttabsmenu.h
 330     dolphintabpage.h
 331     dolphintabwidget.h
 332     dolphinurlnavigator.h
 333     dolphinurlnavigatorscontroller.h
 334     trash/dolphintrash.h
 335     filterbar/filterbar.h
 336     kitemviews/kfileitemlisttostring.h
 337     panels/places/placespanel.h
 338     panels/panel.h
 339     panels/folders/foldersitemlistwidget.h
 340     panels/folders/treeviewcontextmenu.h
 341     panels/folders/folderspanel.h
 342     panels/terminal/terminalpanel.h
 343     search/dolphinfacetswidget.h
 344     search/dolphinquery.h
 345     search/dolphinsearchbox.h
 346     selectionmode/actiontexthelper.h
 347     selectionmode/actionwithwidget.h
 348     selectionmode/backgroundcolorhelper.h
 349     selectionmode/bottombar.h
 350     selectionmode/bottombarcontentscontainer.h
 351     selectionmode/topbar.h
 352     settings/interface/folderstabssettingspage.h
 353     settings/interface/statusandlocationbarssettingspage.h
 354     settings/interface/confirmationssettingspage.h
 355     settings/interface/interfacesettingspage.h
 356     settings/interface/previewssettingspage.h
 357     settings/dolphinsettingsdialog.h
 358     settings/contextmenu/contextmenusettingspage.h
 359     settings/settingspagebase.h
 360     settings/servicemodel.h
 361     settings/trash/trashsettingspage.h
 362     settings/viewmodes/dolphinfontrequester.h
 363     settings/viewmodes/viewsettingspage.h
 364     settings/viewmodes/viewmodesettings.h
 365     settings/viewmodes/viewsettingstab.h
 366     settings/viewmodes/contentdisplaytab.h
 367     settings/viewmodes/generalviewsettingspage.h
 368     statusbar/dolphinstatusbar.h
 369     statusbar/mountpointobserver.h
 370     statusbar/mountpointobservercache.h
 371     statusbar/spaceinfoobserver.h
 372     statusbar/statusbarspaceinfo.h
 373     views/zoomlevelinfo.h
 374     dolphindebug.h
 375     global.h
 376 )
 377
 378 if(HAVE_BALOO)
 379     target_sources(dolphinstatic PRIVATE
 380         panels/information/informationpanel.cpp
 381         panels/information/informationpanelcontent.cpp
 382         panels/information/pixmapviewer.cpp
 383         panels/information/phononwidget.cpp
 384         panels/information/informationpanel.h
 385         panels/information/informationpanelcontent.h
 386         panels/information/pixmapviewer.h
 387         panels/information/phononwidget.h
 388     )
 389 endif()
 390
 391 if(HAVE_KUSERFEEDBACK)
 392     target_sources(dolphinstatic PRIVATE
 393         userfeedback/dolphinfeedbackprovider.cpp
 394         userfeedback/settingsdatasource.cpp
 395         userfeedback/placesdatasource.cpp
 396         settings/userfeedback/userfeedbacksettingspage.cpp
 397         userfeedback/dolphinfeedbackprovider.h
 398         userfeedback/settingsdatasource.h
 399         userfeedback/placesdatasource.h
 400         settings/userfeedback/userfeedbacksettingspage.h
 401     )
 402 endif()
 403
 404 kconfig_add_kcfg_files(dolphinstatic
 405     panels/folders/dolphin_folderspanelsettings.kcfgc
 406     panels/information/dolphin_informationpanelsettings.kcfgc
 407     panels/places/dolphin_placespanelsettings.kcfgc
 408     settings/dolphin_compactmodesettings.kcfgc
 409     settings/dolphin_detailsmodesettings.kcfgc
 410     settings/dolphin_contextmenusettings.kcfgc
 411     settings/dolphin_iconsmodesettings.kcfgc
 412     settings/dolphin_contentdisplaysettings.kcfgc
 413     search/dolphin_searchsettings.kcfgc
 414     settings/dolphin_versioncontrolsettings.kcfgc
 415 )
 416 kconfig_add_kcfg_files(dolphinstatic GENERATE_MOC
 417     settings/dolphin_generalsettings.kcfgc
 418 )
 419
 420 qt_generate_dbus_interface(${CMAKE_CURRENT_SOURCE_DIR}/dolphinmainwindow.h org.kde.DolphinMainWindow.xml)
 421 qt_add_dbus_adaptor(dolphin_dbus_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindow.h DolphinMainWindow)
 422 qt_add_dbus_interface(dolphin_dbus_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindowinterface)
 423 qt_add_dbus_interface(dolphin_dbus_SRCS panels/terminal/org.kde.KIOFuse.VFS.xml kiofuse_interface)
 424
 425 target_sources(dolphinstatic PRIVATE
 426     ${dolphin_dbus_SRCS}
 427 )
 428
 429 target_include_directories(dolphinstatic SYSTEM PRIVATE ${PHONON_INCLUDES})
 430 target_link_libraries(dolphinstatic
 431     dolphinprivate
 432     KF6::CoreAddons
 433     KF6::KCMUtils
 434     KF6::DBusAddons
 435     KF6::Notifications
 436     KF6::BookmarksWidgets
 437     Phonon::phonon4qt6
 438 )
 439
 440 if (HAVE_KACTIVITIES)
 441     target_link_libraries(
 442         dolphinstatic
 443         KF6::Activities
 444     )
 445 endif()
 446
 447 if (HAVE_KUSERFEEDBACK)
 448     target_link_libraries(
 449         dolphinstatic
 450         KF6::UserFeedbackCore
 451         KF6::UserFeedbackWidgets
 452     )
 453 endif()
 454
 455 add_executable(dolphin)
 456
 457 target_sources(dolphin PRIVATE
 458     dbusinterface.cpp
 459     dbusinterface.h
 460     main.cpp
 461 )
 462
 463 if(FLATPAK)
 464     target_compile_definitions(dolphin PRIVATE FLATPAK)
 465 endif()
 466
 467 # Sets the icon on Windows and OSX
 468 file(GLOB ICONS_SRCS "${CMAKE_CURRENT_SOURCE_DIR}/icons/*system-file-manager.png")
 469 ecm_add_app_icon(dolphin ICONS ${ICONS_SRCS})
 470
 471 target_link_libraries(dolphin
 472     PRIVATE
 473     dolphinprivate
 474     dolphinstatic
 475     KF6::Crash
 476 )
 477
 478 if (HAVE_X11)
 479     target_link_libraries(dolphin PRIVATE Qt::GuiPrivate)
 480 endif()
 481
 482 include(DbusInterfaceMacros)
 483
 484 generate_and_install_dbus_interface(
 485     dolphin
 486     dbusinterface.h
 487     org.freedesktop.FileManager1.xml
 488     OPTIONS -a
 489 )
 490
 491 install(TARGETS dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 492
 493 ##########################################
 494
 495 if(NOT WIN32)
 496     # The settings are still accessible from the hamburger menu
 497     add_library(kcm_dolphinviewmodes MODULE)
 498     add_library(kcm_dolphingeneral MODULE)
 499
 500     target_sources(kcm_dolphinviewmodes PRIVATE
 501         settings/kcm/kcmdolphinviewmodes.cpp
 502         settings/viewmodes/dolphinfontrequester.cpp
 503         settings/viewmodes/viewmodesettings.cpp
 504         settings/viewmodes/viewsettingstab.cpp
 505         settings/settingspagebase.cpp
 506         views/zoomlevelinfo.cpp
 507         settings/kcm/kcmdolphinviewmodes.h
 508         settings/viewmodes/dolphinfontrequester.h
 509         settings/viewmodes/viewmodesettings.h
 510         settings/viewmodes/viewsettingstab.h
 511         views/zoomlevelinfo.h)
 512
 513     target_sources(kcm_dolphingeneral PRIVATE
 514         settings/kcm/kcmdolphingeneral.cpp
 515         settings/interface/folderstabssettingspage.cpp
 516         settings/interface/statusandlocationbarssettingspage.cpp
 517         settings/interface/previewssettingspage.cpp
 518         settings/interface/confirmationssettingspage.cpp
 519         settings/settingspagebase.cpp
 520         settings/servicemodel.cpp
 521         dolphin_generalsettings.cpp
 522         dolphindebug.cpp
 523         dolphinmainwindowinterface.cpp
 524         views/viewproperties.cpp
 525         dolphin_directoryviewpropertysettings.cpp
 526         global.cpp
 527         settings/kcm/kcmdolphingeneral.h
 528         settings/interface/folderstabssettingspage.h
 529         settings/interface/statusandlocationbarssettingspage.h
 530         settings/interface/previewssettingspage.h
 531         settings/interface/confirmationssettingspage.h
 532         settings/settingspagebase.h
 533         settings/servicemodel.h
 534         dolphin_generalsettings.h
 535         dolphindebug.h
 536         dolphinmainwindowinterface.h
 537         views/viewproperties.h
 538         dolphin_directoryviewpropertysettings.h
 539         global.h
 540     )
 541
 542     kconfig_add_kcfg_files(kcm_dolphinviewmodes
 543         settings/dolphin_compactmodesettings.kcfgc
 544         settings/dolphin_directoryviewpropertysettings.kcfgc
 545         settings/dolphin_detailsmodesettings.kcfgc
 546         settings/dolphin_iconsmodesettings.kcfgc
 547         settings/dolphin_contentdisplaysettings.kcfgc
 548         settings/dolphin_generalsettings.kcfgc
 549         settings/dolphin_versioncontrolsettings.kcfgc
 550     )
 551
 552     kconfig_add_kcfg_files(kcm_dolphingeneral
 553         settings/dolphin_generalsettings.kcfgc)
 554
 555     target_link_libraries(kcm_dolphinviewmodes dolphinprivate)
 556     target_link_libraries(kcm_dolphingeneral dolphinprivate)
 557
 558     install( FILES org.kde.dolphin.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR} )
 559
 560     install(TARGETS kcm_dolphinviewmodes DESTINATION ${KDE_INSTALL_PLUGINDIR}/dolphin/kcms )
 561     install(TARGETS kcm_dolphingeneral DESTINATION ${KDE_INSTALL_PLUGINDIR}/dolphin/kcms )
 562 endif()
 563
 564 if(NOT WIN32)
 565     add_subdirectory(settings/contextmenu/servicemenuinstaller)
 566     install( FILES settings/contextmenu/servicemenu.knsrc DESTINATION ${KDE_INSTALL_KNSRCDIR} )
 567 endif()
 568
 569 ########### install files ###############
 570
 571 install( PROGRAMS org.kde.dolphin.desktop DESTINATION ${KDE_INSTALL_APPDIR} )
 572
 573 install( DIRECTORY DESTINATION "${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel" )
 574
 575 install(
 576     CODE "execute_process(COMMAND \"${CMAKE_COMMAND}\" -E create_symlink \"${KDE_INSTALL_FULL_APPDIR}/org.kde.dolphin.desktop\" \"\$ENV{DESTDIR}${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel/org.kde.dolphin.desktop\")"
 577 )
 578
 579 install( FILES settings/dolphin_directoryviewpropertysettings.kcfg
 580                settings/dolphin_generalsettings.kcfg
 581                settings/dolphin_contextmenusettings.kcfg
 582                settings/dolphin_compactmodesettings.kcfg
 583                settings/dolphin_iconsmodesettings.kcfg
 584                settings/dolphin_detailsmodesettings.kcfg
 585                settings/dolphin_contentdisplaysettings.kcfg
 586                settings/dolphin_versioncontrolsettings.kcfg
 587          DESTINATION ${KDE_INSTALL_KCFGDIR} )
 588
 589 install( FILES settings/dolphin_detailsmodesettings.upd
 590          DESTINATION ${KDE_INSTALL_KCONFUPDATEDIR} )
 591
 592 if(BUILD_TESTING)
 593     add_subdirectory(tests)
 594 endif()