src/CMakeLists.txt

   1 include(ECMAddAppIcon)
   2
   3 configure_file(config-baloo.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-baloo.h)
   4
   5 configure_file(config-kactivities.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-kactivities.h)
   6
   7 configure_file(config-packagekit.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-packagekit.h)
   8
   9 configure_file(config-terminal.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-terminal.h)
  10
  11 configure_file(config-kuserfeedback.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-kuserfeedback.h)
  12
  13 add_definitions(
  14     -DTRANSLATION_DOMAIN=\"dolphin\"
  15 )
  16 remove_definitions(
  17     -DQT_NO_CAST_FROM_BYTEARRAY
  18     -DQT_NO_CAST_FROM_ASCII
  19     -DQT_NO_CAST_TO_ASCII
  20 )
  21
  22 ##########################################
  23
  24 add_library(dolphinvcs SHARED)
  25
  26 target_sources(dolphinvcs PRIVATE
  27     views/versioncontrol/kversioncontrolplugin.cpp
  28 )
  29
  30 generate_export_header(dolphinvcs BASE_NAME dolphinvcs)
  31
  32 target_link_libraries(
  33     dolphinvcs PUBLIC
  34     Qt${QT_MAJOR_VERSION}::Widgets
  35 )
  36
  37 set_target_properties(dolphinvcs PROPERTIES
  38     VERSION ${DOLPHINVCS_VERSION}
  39     SOVERSION ${DOLPHINVCS_SOVERSION}
  40     EXPORT_NAME DolphinVcs
  41 )
  42
  43 ecm_generate_headers(dolphinvcs_LIB_HEADERS
  44     HEADER_NAMES
  45     KVersionControlPlugin
  46
  47     RELATIVE "views/versioncontrol"
  48     REQUIRED_HEADERS dolphinvcs_LIB_HEADERS
  49 )
  50
  51 install(TARGETS dolphinvcs EXPORT DolphinVcsTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
  52
  53 install(FILES views/versioncontrol/fileviewversioncontrolplugin.desktop DESTINATION ${KDE_INSTALL_KSERVICETYPESDIR})
  54 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphinvcs_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
  55 install(FILES ${dolphinvcs_LIB_HEADERS} DESTINATION "${KDE_INSTALL_INCLUDEDIR}/Dolphin" COMPONENT Devel)
  56
  57 ########### next target ###############
  58
  59 add_library(dolphinprivate SHARED)
  60
  61 target_sources(dolphinprivate PRIVATE
  62     kitemviews/kfileitemlistview.cpp
  63     kitemviews/kfileitemlistwidget.cpp
  64     kitemviews/kfileitemmodel.cpp
  65     kitemviews/kfileitemmodelrolesupdater.cpp
  66     kitemviews/kitemlistcontainer.cpp
  67     kitemviews/kitemlistcontroller.cpp
  68     kitemviews/kitemlistgroupheader.cpp
  69     kitemviews/kitemlistheader.cpp
  70     kitemviews/kitemlistselectionmanager.cpp
  71     kitemviews/kitemliststyleoption.cpp
  72     kitemviews/kitemlistview.cpp
  73     kitemviews/kitemlistviewaccessible.cpp
  74     kitemviews/kitemlistwidget.cpp
  75     kitemviews/kitemmodelbase.cpp
  76     kitemviews/kitemset.cpp
  77     kitemviews/kstandarditemlistgroupheader.cpp
  78     kitemviews/kstandarditemlistwidget.cpp
  79     kitemviews/kstandarditemlistview.cpp
  80     kitemviews/private/kdirectorycontentscounter.cpp
  81     kitemviews/private/kdirectorycontentscounterworker.cpp
  82     kitemviews/private/kfileitemclipboard.cpp
  83     kitemviews/private/kfileitemmodelfilter.cpp
  84     kitemviews/private/kitemlistheaderwidget.cpp
  85     kitemviews/private/kitemlistkeyboardsearchmanager.cpp
  86     kitemviews/private/kitemlistroleeditor.cpp
  87     kitemviews/private/kitemlistrubberband.cpp
  88     kitemviews/private/kitemlistselectiontoggle.cpp
  89     kitemviews/private/kitemlistsizehintresolver.cpp
  90     kitemviews/private/kitemlistsmoothscroller.cpp
  91     kitemviews/private/kitemlistviewanimation.cpp
  92     kitemviews/private/kitemlistviewlayouter.cpp
  93     kitemviews/private/kpixmapmodifier.cpp
  94     kitemviews/private/ktwofingerswipe.cpp
  95     kitemviews/private/ktwofingertap.cpp
  96     settings/applyviewpropsjob.cpp
  97     settings/viewmodes/viewmodesettings.cpp
  98     settings/viewpropertiesdialog.cpp
  99     settings/viewpropsprogressinfo.cpp
 100     views/dolphinfileitemlistwidget.cpp
 101     views/dolphinitemlistview.cpp
 102     views/dolphinnewfilemenuobserver.cpp
 103     views/dolphinremoteencoding.cpp
 104     views/dolphinview.cpp
 105     views/dolphinviewactionhandler.cpp
 106     views/draganddrophelper.cpp
 107     views/versioncontrol/updateitemstatesthread.cpp
 108     views/versioncontrol/versioncontrolobserver.cpp
 109     views/viewmodecontroller.cpp
 110     views/viewproperties.cpp
 111     views/zoomlevelinfo.cpp
 112     dolphinremoveaction.cpp
 113     middleclickactioneventfilter.cpp
 114     dolphinnewfilemenu.cpp
 115 )
 116
 117 ecm_qt_declare_logging_category(dolphinprivate
 118     HEADER dolphindebug.h
 119     IDENTIFIER DolphinDebug
 120     CATEGORY_NAME org.kde.dolphin
 121     DESCRIPTION "dolphin"
 122     EXPORT DOLPHIN
 123 )
 124
 125 if(HAVE_BALOO)
 126     target_sources(dolphinprivate PRIVATE
 127         views/tooltips/dolphinfilemetadatawidget.cpp
 128         views/tooltips/tooltipmanager.cpp
 129         kitemviews/private/kbaloorolesprovider.cpp
 130     )
 131 endif()
 132
 133 kconfig_add_kcfg_files(dolphinprivate
 134     settings/dolphin_compactmodesettings.kcfgc
 135     settings/dolphin_directoryviewpropertysettings.kcfgc
 136     settings/dolphin_detailsmodesettings.kcfgc
 137     settings/dolphin_iconsmodesettings.kcfgc
 138     settings/dolphin_generalsettings.kcfgc
 139     settings/dolphin_contextmenusettings.kcfgc
 140     settings/dolphin_versioncontrolsettings.kcfgc
 141 )
 142
 143 generate_export_header(dolphinprivate BASE_NAME dolphin)
 144
 145 target_link_libraries(
 146     dolphinprivate PUBLIC
 147     dolphinvcs
 148     Qt${QT_MAJOR_VERSION}::Concurrent
 149     Qt${QT_MAJOR_VERSION}::Gui
 150     KF5::I18n
 151     KF5::IconThemes
 152     KF5::KIOCore
 153     KF5::KIOWidgets
 154     KF5::KIOFileWidgets
 155     KF5::Completion
 156     KF5::TextWidgets
 157     KF5::ConfigCore
 158     KF5::NewStuff
 159     KF5::Parts
 160     KF5::WindowSystem
 161 )
 162
 163 if(HAVE_BALOO)
 164     target_link_libraries(
 165         dolphinprivate PUBLIC
 166         KF5::FileMetaData
 167         KF5::Baloo
 168         KF5::BalooWidgets
 169     )
 170 endif()
 171
 172 set_target_properties(dolphinprivate PROPERTIES
 173     VERSION ${DOLPHINPRIVATE_VERSION}
 174     SOVERSION ${DOLPHINPRIVATE_SOVERSION}
 175 )
 176
 177 install(TARGETS dolphinprivate ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} LIBRARY NAMELINK_SKIP)
 178 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphin_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
 179
 180 ##########################################
 181 configure_file(dolphinpart.desktop.in ${CMAKE_CURRENT_BINARY_DIR}/dolphinpart.desktop @ONLY)
 182
 183 add_library(dolphinpart MODULE)
 184
 185 target_sources(dolphinpart PRIVATE
 186     dolphinpart.cpp
 187     dolphinpart_ext.cpp
 188     dolphindebug.cpp
 189
 190     dolphinpart.qrc
 191 )
 192
 193 kcoreaddons_desktop_to_json(dolphinpart ${CMAKE_CURRENT_BINARY_DIR}/dolphinpart.desktop)
 194
 195 target_link_libraries(dolphinpart
 196     dolphinprivate
 197 )
 198
 199 install(TARGETS dolphinpart DESTINATION ${KDE_INSTALL_PLUGINDIR}/kf5/parts)
 200
 201 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphinpart.desktop DESTINATION ${KDE_INSTALL_KSERVICESDIR})
 202
 203 ##########################################
 204
 205 add_library(dolphinstatic STATIC)
 206
 207 target_sources(dolphinstatic PRIVATE
 208     dolphinbookmarkhandler.cpp
 209     dolphindockwidget.cpp
 210     dolphinmainwindow.cpp
 211     dolphinviewcontainer.cpp
 212     dolphincontextmenu.cpp
 213     dolphinnavigatorswidgetaction.cpp
 214     dolphintabbar.cpp
 215     dolphinplacesmodelsingleton.cpp
 216     dolphinrecenttabsmenu.cpp
 217     dolphintabpage.cpp
 218     dolphintabwidget.cpp
 219     dolphinurlnavigator.cpp
 220     dolphinurlnavigatorscontroller.cpp
 221     trash/dolphintrash.cpp
 222     filterbar/filterbar.cpp
 223     panels/places/placespanel.cpp
 224     panels/panel.cpp
 225     panels/folders/foldersitemlistwidget.cpp
 226     panels/folders/treeviewcontextmenu.cpp
 227     panels/folders/folderspanel.cpp
 228     panels/terminal/terminalpanel.cpp
 229     search/dolphinfacetswidget.cpp
 230     search/dolphinquery.cpp
 231     search/dolphinsearchbox.cpp
 232     settings/general/behaviorsettingspage.cpp
 233     settings/general/configurepreviewplugindialog.cpp
 234     settings/general/confirmationssettingspage.cpp
 235     settings/general/generalsettingspage.cpp
 236     settings/general/previewssettingspage.cpp
 237     settings/general/statusbarsettingspage.cpp
 238     settings/dolphinsettingsdialog.cpp
 239     settings/navigation/navigationsettingspage.cpp
 240     settings/contextmenu/contextmenusettingspage.cpp
 241     settings/settingspagebase.cpp
 242     settings/serviceitemdelegate.cpp
 243     settings/servicemodel.cpp
 244     settings/startup/startupsettingspage.cpp
 245     settings/trash/trashsettingspage.cpp
 246     settings/viewmodes/dolphinfontrequester.cpp
 247     settings/viewmodes/viewsettingspage.cpp
 248     settings/viewmodes/viewmodesettings.cpp
 249     settings/viewmodes/viewsettingstab.cpp
 250     statusbar/dolphinstatusbar.cpp
 251     statusbar/mountpointobserver.cpp
 252     statusbar/mountpointobservercache.cpp
 253     statusbar/spaceinfoobserver.cpp
 254     statusbar/statusbarspaceinfo.cpp
 255     views/zoomlevelinfo.cpp
 256     dolphindebug.cpp
 257     global.cpp
 258     dolphin.qrc
 259 )
 260
 261 if(HAVE_BALOO)
 262     target_sources(dolphinstatic PRIVATE
 263         panels/information/informationpanel.cpp
 264         panels/information/informationpanelcontent.cpp
 265         panels/information/pixmapviewer.cpp
 266         panels/information/phononwidget.cpp
 267     )
 268 endif()
 269
 270 if(HAVE_KUSERFEEDBACK)
 271     target_sources(dolphinstatic PRIVATE
 272         userfeedback/dolphinfeedbackprovider.cpp
 273         userfeedback/settingsdatasource.cpp
 274         userfeedback/placesdatasource.cpp
 275         settings/userfeedback/userfeedbacksettingspage.cpp
 276     )
 277 endif()
 278
 279 kconfig_add_kcfg_files(dolphinstatic
 280     panels/folders/dolphin_folderspanelsettings.kcfgc
 281     panels/information/dolphin_informationpanelsettings.kcfgc
 282     panels/places/dolphin_placespanelsettings.kcfgc
 283     settings/dolphin_compactmodesettings.kcfgc
 284     settings/dolphin_detailsmodesettings.kcfgc
 285     settings/dolphin_contextmenusettings.kcfgc
 286     settings/dolphin_iconsmodesettings.kcfgc
 287     search/dolphin_searchsettings.kcfgc
 288     settings/dolphin_versioncontrolsettings.kcfgc
 289 )
 290 kconfig_add_kcfg_files(dolphinstatic GENERATE_MOC
 291     settings/dolphin_generalsettings.kcfgc
 292 )
 293
 294 qt_generate_dbus_interface(${CMAKE_CURRENT_SOURCE_DIR}/dolphinmainwindow.h org.kde.DolphinMainWindow.xml)
 295 qt_add_dbus_adaptor(dolphin_dbus_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindow.h DolphinMainWindow)
 296 qt_add_dbus_interface(dolphin_dbus_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindowinterface)
 297 qt_add_dbus_interface(dolphin_dbus_SRCS panels/terminal/org.kde.KIOFuse.VFS.xml kiofuse_interface)
 298
 299 target_sources(dolphinstatic PRIVATE
 300     ${dolphin_dbus_SRCS}
 301 )
 302
 303 target_include_directories(dolphinstatic SYSTEM PRIVATE ${PHONON_INCLUDES})
 304 target_link_libraries(dolphinstatic
 305     dolphinprivate
 306     KF5::CoreAddons
 307     KF5::KCMUtils
 308     KF5::DBusAddons
 309     KF5::Notifications
 310     Phonon::phonon4qt5
 311 )
 312
 313 if (HAVE_KACTIVITIES)
 314     target_link_libraries(
 315         dolphinstatic
 316         KF5::Activities
 317     )
 318 endif()
 319
 320 if (HAVE_KUSERFEEDBACK)
 321     target_link_libraries(
 322         dolphinstatic
 323         KUserFeedbackCore
 324         KUserFeedbackWidgets
 325     )
 326 endif()
 327
 328 add_executable(dolphin)
 329
 330 target_sources(dolphin PRIVATE
 331     dbusinterface.cpp
 332     main.cpp
 333 )
 334
 335 if(FLATPAK)
 336     target_compile_definitions(dolphin PRIVATE FLATPAK)
 337 endif()
 338
 339 # Sets the icon on Windows and OSX
 340 file(GLOB ICONS_SRCS "${CMAKE_CURRENT_SOURCE_DIR}/icons/*system-file-manager.png")
 341 ecm_add_app_icon(dolphin ICONS ${ICONS_SRCS})
 342
 343 target_link_libraries(dolphin
 344     PRIVATE
 345     dolphinprivate
 346     dolphinstatic
 347     KF5::Crash
 348 )
 349
 350 include(DbusInterfaceMacros)
 351
 352 generate_and_install_dbus_interface(
 353     dolphin
 354     dbusinterface.h
 355     org.freedesktop.FileManager1.xml
 356     OPTIONS -a
 357 )
 358
 359 install(TARGETS dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 360
 361 ##########################################
 362
 363 if(NOT WIN32)
 364     # The settings are still accessible from the hamburger menu
 365     add_library(kcm_dolphinviewmodes)
 366     kcoreaddons_desktop_to_json(kcm_dolphinviewmodes settings/kcm/kcmdolphinviewmodes.desktop)
 367     add_library(kcm_dolphinnavigation)
 368     kcoreaddons_desktop_to_json(kcm_dolphinnavigation settings/kcm/kcmdolphinnavigation.desktop)
 369     add_library(kcm_dolphingeneral)
 370     kcoreaddons_desktop_to_json(kcm_dolphingeneral settings/kcm/kcmdolphingeneral.desktop)
 371
 372     target_sources(kcm_dolphinviewmodes PRIVATE
 373         settings/kcm/kcmdolphinviewmodes.cpp
 374         settings/viewmodes/dolphinfontrequester.cpp
 375         settings/viewmodes/viewmodesettings.cpp
 376         settings/viewmodes/viewsettingstab.cpp
 377         views/zoomlevelinfo.cpp)
 378
 379     target_sources(kcm_dolphinnavigation PRIVATE
 380         settings/kcm/kcmdolphinnavigation.cpp
 381         settings/navigation/navigationsettingspage.cpp
 382         settings/settingspagebase.cpp)
 383
 384     target_sources(kcm_dolphingeneral PRIVATE
 385         settings/kcm/kcmdolphingeneral.cpp
 386         settings/general/behaviorsettingspage.cpp
 387         settings/general/previewssettingspage.cpp
 388         settings/general/configurepreviewplugindialog.cpp
 389         settings/general/confirmationssettingspage.cpp
 390         settings/settingspagebase.cpp
 391         settings/serviceitemdelegate.cpp
 392         settings/servicemodel.cpp)
 393
 394     kconfig_add_kcfg_files(kcm_dolphinviewmodes
 395         settings/dolphin_compactmodesettings.kcfgc
 396         settings/dolphin_directoryviewpropertysettings.kcfgc
 397         settings/dolphin_detailsmodesettings.kcfgc
 398         settings/dolphin_iconsmodesettings.kcfgc
 399         settings/dolphin_generalsettings.kcfgc
 400         settings/dolphin_versioncontrolsettings.kcfgc
 401     )
 402
 403     kconfig_add_kcfg_files(kcm_dolphinnavigation
 404         settings/dolphin_generalsettings.kcfgc)
 405
 406     kconfig_add_kcfg_files(kcm_dolphingeneral
 407         settings/dolphin_generalsettings.kcfgc)
 408
 409     target_link_libraries(kcm_dolphinviewmodes dolphinprivate)
 410     target_link_libraries(kcm_dolphinnavigation dolphinprivate)
 411     target_link_libraries(kcm_dolphingeneral dolphinprivate)
 412
 413     install( FILES org.kde.dolphin.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR} )
 414     install( FILES settings/kcm/kcmdolphinviewmodes.desktop DESTINATION ${KDE_INSTALL_KSERVICESDIR} )
 415     install( FILES settings/kcm/kcmdolphinnavigation.desktop DESTINATION ${KDE_INSTALL_KSERVICESDIR} )
 416     install( FILES settings/kcm/kcmdolphingeneral.desktop DESTINATION ${KDE_INSTALL_KSERVICESDIR} )
 417
 418     install(TARGETS kcm_dolphinviewmodes DESTINATION ${KDE_INSTALL_PLUGINDIR}/dolphin/kcms )
 419     install(TARGETS kcm_dolphinnavigation DESTINATION ${KDE_INSTALL_PLUGINDIR}/dolphin/kcms )
 420     install(TARGETS kcm_dolphingeneral DESTINATION ${KDE_INSTALL_PLUGINDIR}/dolphin/kcms )
 421 endif()
 422
 423 if(NOT WIN32)
 424     add_subdirectory(settings/contextmenu/servicemenuinstaller)
 425     install( FILES settings/contextmenu/servicemenu.knsrc DESTINATION ${KDE_INSTALL_KNSRCDIR} )
 426 endif()
 427
 428 ########### install files ###############
 429
 430 install( PROGRAMS org.kde.dolphin.desktop DESTINATION ${KDE_INSTALL_APPDIR} )
 431
 432 install( DIRECTORY DESTINATION "${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel" )
 433
 434 install(
 435     CODE "execute_process(COMMAND \"${CMAKE_COMMAND}\" -E create_symlink \"${KDE_INSTALL_FULL_APPDIR}/org.kde.dolphin.desktop\" \"\$ENV{DESTDIR}${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel/org.kde.dolphin.desktop\")"
 436 )
 437
 438 install( FILES settings/dolphin_directoryviewpropertysettings.kcfg
 439                settings/dolphin_generalsettings.kcfg
 440                settings/dolphin_contextmenusettings.kcfg
 441                settings/dolphin_compactmodesettings.kcfg
 442                settings/dolphin_iconsmodesettings.kcfg
 443                settings/dolphin_detailsmodesettings.kcfg
 444                settings/dolphin_versioncontrolsettings.kcfg
 445          DESTINATION ${KDE_INSTALL_KCFGDIR} )
 446
 447 if(BUILD_TESTING)
 448     add_subdirectory(tests)
 449 endif()