src/CMakeLists.txt

   1 include(ECMAddAppIcon)
   2
   3 configure_file(config-baloo.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-baloo.h)
   4
   5 configure_file(config-kactivities.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-kactivities.h)
   6
   7 configure_file(config-packagekit.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-packagekit.h)
   8
   9 configure_file(config-terminal.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-terminal.h)
  10
  11 add_definitions(
  12     -DTRANSLATION_DOMAIN=\"dolphin\"
  13 )
  14 remove_definitions(
  15     -DQT_NO_CAST_FROM_BYTEARRAY
  16     -DQT_NO_SIGNALS_SLOTS_KEYWORDS
  17     -DQT_NO_CAST_FROM_ASCII
  18     -DQT_NO_CAST_TO_ASCII
  19     -DQT_NO_FOREACH
  20     -DQT_NO_KEYWORDS
  21 )
  22
  23 ##########################################
  24
  25 set(dolphinvcs_LIB_SRCS
  26     views/versioncontrol/kversioncontrolplugin.cpp
  27 )
  28
  29 add_library(dolphinvcs ${dolphinvcs_LIB_SRCS})
  30 generate_export_header(dolphinvcs BASE_NAME dolphinvcs)
  31
  32 target_link_libraries(
  33     dolphinvcs PUBLIC
  34     Qt5::Widgets
  35 )
  36
  37 set_target_properties(dolphinvcs PROPERTIES
  38     VERSION ${DOLPHINVCS_VERSION_STRING}
  39     SOVERSION ${DOLPHINVCS_SOVERSION}
  40     EXPORT_NAME DolphinVcs
  41 )
  42
  43 ecm_generate_headers(dolphinvcs_LIB_HEADERS
  44     HEADER_NAMES
  45     KVersionControlPlugin
  46
  47     RELATIVE "views/versioncontrol"
  48     REQUIRED_HEADERS dolphinvcs_LIB_HEADERS
  49 )
  50
  51 install(TARGETS dolphinvcs EXPORT DolphinVcsTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
  52
  53 install(FILES views/versioncontrol/fileviewversioncontrolplugin.desktop DESTINATION ${KDE_INSTALL_KSERVICETYPES5DIR})
  54 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphinvcs_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
  55 install(FILES ${dolphinvcs_LIB_HEADERS} DESTINATION "${KDE_INSTALL_INCLUDEDIR}/Dolphin" COMPONENT Devel)
  56
  57 ########### next target ###############
  58
  59 set(dolphinprivate_LIB_SRCS
  60     kitemviews/kfileitemlistview.cpp
  61     kitemviews/kfileitemlistwidget.cpp
  62     kitemviews/kfileitemmodel.cpp
  63     kitemviews/kfileitemmodelrolesupdater.cpp
  64     kitemviews/kitemlistcontainer.cpp
  65     kitemviews/kitemlistcontroller.cpp
  66     kitemviews/kitemlistgroupheader.cpp
  67     kitemviews/kitemlistheader.cpp
  68     kitemviews/kitemlistselectionmanager.cpp
  69     kitemviews/kitemliststyleoption.cpp
  70     kitemviews/kitemlistview.cpp
  71     kitemviews/kitemlistviewaccessible.cpp
  72     kitemviews/kitemlistwidget.cpp
  73     kitemviews/kitemmodelbase.cpp
  74     kitemviews/kitemset.cpp
  75     kitemviews/kstandarditem.cpp
  76     kitemviews/kstandarditemlistgroupheader.cpp
  77     kitemviews/kstandarditemlistwidget.cpp
  78     kitemviews/kstandarditemlistview.cpp
  79     kitemviews/kstandarditemmodel.cpp
  80     kitemviews/private/kdirectorycontentscounter.cpp
  81     kitemviews/private/kdirectorycontentscounterworker.cpp
  82     kitemviews/private/kfileitemclipboard.cpp
  83     kitemviews/private/kfileitemmodeldirlister.cpp
  84     kitemviews/private/kfileitemmodelfilter.cpp
  85     kitemviews/private/kitemlistheaderwidget.cpp
  86     kitemviews/private/kitemlistkeyboardsearchmanager.cpp
  87     kitemviews/private/kitemlistroleeditor.cpp
  88     kitemviews/private/kitemlistrubberband.cpp
  89     kitemviews/private/kitemlistselectiontoggle.cpp
  90     kitemviews/private/kitemlistsizehintresolver.cpp
  91     kitemviews/private/kitemlistsmoothscroller.cpp
  92     kitemviews/private/kitemlistviewanimation.cpp
  93     kitemviews/private/kitemlistviewlayouter.cpp
  94     kitemviews/private/kpixmapmodifier.cpp
  95     kitemviews/private/ktwofingerswipe.cpp
  96     kitemviews/private/ktwofingertap.cpp
  97     settings/applyviewpropsjob.cpp
  98     settings/viewmodes/viewmodesettings.cpp
  99     settings/viewpropertiesdialog.cpp
 100     settings/viewpropsprogressinfo.cpp
 101     views/dolphinfileitemlistwidget.cpp
 102     views/dolphinitemlistview.cpp
 103     views/dolphinnewfilemenuobserver.cpp
 104     views/dolphinremoteencoding.cpp
 105     views/dolphinview.cpp
 106     views/dolphinviewactionhandler.cpp
 107     views/draganddrophelper.cpp
 108     views/versioncontrol/updateitemstatesthread.cpp
 109     views/versioncontrol/versioncontrolobserver.cpp
 110     views/viewmodecontroller.cpp
 111     views/viewproperties.cpp
 112     views/zoomlevelinfo.cpp
 113     dolphinremoveaction.cpp
 114     middleclickactioneventfilter.cpp
 115     dolphinnewfilemenu.cpp
 116 )
 117
 118 ecm_qt_declare_logging_category(dolphinprivate_LIB_SRCS HEADER dolphindebug.h IDENTIFIER DolphinDebug CATEGORY_NAME org.kde.dolphin)
 119
 120 if(HAVE_BALOO)
 121     set(dolphinprivate_LIB_SRCS
 122         ${dolphinprivate_LIB_SRCS}
 123         views/tooltips/dolphinfilemetadatawidget.cpp
 124         views/tooltips/tooltipmanager.cpp
 125         kitemviews/private/kbaloorolesprovider.cpp
 126     )
 127 endif()
 128
 129 kconfig_add_kcfg_files(dolphinprivate_LIB_SRCS GENERATE_MOC
 130     settings/dolphin_compactmodesettings.kcfgc
 131     settings/dolphin_directoryviewpropertysettings.kcfgc
 132     settings/dolphin_detailsmodesettings.kcfgc
 133     settings/dolphin_iconsmodesettings.kcfgc
 134     settings/dolphin_generalsettings.kcfgc
 135     settings/dolphin_versioncontrolsettings.kcfgc
 136 )
 137
 138 add_library(dolphinprivate ${dolphinprivate_LIB_SRCS})
 139 generate_export_header(dolphinprivate BASE_NAME dolphin)
 140
 141 target_link_libraries(
 142     dolphinprivate PUBLIC
 143     dolphinvcs
 144     Qt5::Concurrent
 145     Qt5::Gui
 146     KF5::I18n
 147     KF5::IconThemes
 148     KF5::KIOCore
 149     KF5::KIOWidgets
 150     KF5::KIOFileWidgets
 151     KF5::Completion
 152     KF5::TextWidgets
 153     KF5::ConfigCore
 154     KF5::NewStuff
 155     KF5::Parts
 156     KF5::WindowSystem
 157 )
 158
 159 if(HAVE_BALOO)
 160     target_link_libraries(
 161         dolphinprivate PUBLIC
 162         KF5::FileMetaData
 163         KF5::Baloo
 164         KF5::BalooWidgets
 165     )
 166 endif()
 167
 168 set_target_properties(dolphinprivate PROPERTIES
 169     VERSION ${DOLPHINPRIVATE_VERSION_STRING}
 170     SOVERSION ${DOLPHINPRIVATE_SOVERSION}
 171 )
 172
 173 install(TARGETS dolphinprivate ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} LIBRARY NAMELINK_SKIP)
 174 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphin_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
 175
 176 ##########################################
 177
 178 set(dolphinpart_SRCS
 179    dolphinpart.cpp
 180    dolphinpart_ext.cpp
 181    dolphindebug.cpp
 182 )
 183
 184 qt5_add_resources(dolphinpart_SRCS dolphinpart.qrc)
 185
 186 add_library(dolphinpart MODULE ${dolphinpart_SRCS})
 187
 188 target_link_libraries(dolphinpart
 189     dolphinprivate
 190 )
 191
 192 install(TARGETS dolphinpart DESTINATION ${KDE_INSTALL_PLUGINDIR})
 193
 194 install(FILES dolphinpart.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR})
 195
 196 ##########################################
 197
 198 set(dolphinstatic_SRCS
 199     dolphinbookmarkhandler.cpp
 200     dolphindockwidget.cpp
 201     dolphinmainwindow.cpp
 202     dolphinviewcontainer.cpp
 203     dolphincontextmenu.cpp
 204     dolphintabbar.cpp
 205     dolphinplacesmodelsingleton.cpp
 206     dolphinrecenttabsmenu.cpp
 207     dolphintabpage.cpp
 208     dolphintabwidget.cpp
 209     trash/dolphintrash.cpp
 210     filterbar/filterbar.cpp
 211     panels/places/placespanel.cpp
 212     panels/places/placesitem.cpp
 213     panels/places/placesitemlistgroupheader.cpp
 214     panels/places/placesitemlistwidget.cpp
 215     panels/places/placesitemmodel.cpp
 216     panels/places/placesitemsignalhandler.cpp
 217     panels/places/placesview.cpp
 218     panels/panel.cpp
 219     panels/folders/foldersitemlistwidget.cpp
 220     panels/folders/treeviewcontextmenu.cpp
 221     panels/folders/folderspanel.cpp
 222     panels/terminal/terminalpanel.cpp
 223     search/dolphinfacetswidget.cpp
 224     search/dolphinquery.cpp
 225     search/dolphinsearchbox.cpp
 226     settings/general/behaviorsettingspage.cpp
 227     settings/general/configurepreviewplugindialog.cpp
 228     settings/general/confirmationssettingspage.cpp
 229     settings/general/generalsettingspage.cpp
 230     settings/general/previewssettingspage.cpp
 231     settings/general/statusbarsettingspage.cpp
 232     settings/dolphinsettingsdialog.cpp
 233     settings/navigation/navigationsettingspage.cpp
 234     settings/services/servicessettingspage.cpp
 235     settings/settingspagebase.cpp
 236     settings/serviceitemdelegate.cpp
 237     settings/servicemodel.cpp
 238     settings/startup/startupsettingspage.cpp
 239     settings/trash/trashsettingspage.cpp
 240     settings/viewmodes/dolphinfontrequester.cpp
 241     settings/viewmodes/viewsettingspage.cpp
 242     settings/viewmodes/viewmodesettings.cpp
 243     settings/viewmodes/viewsettingstab.cpp
 244     statusbar/dolphinstatusbar.cpp
 245     statusbar/mountpointobserver.cpp
 246     statusbar/mountpointobservercache.cpp
 247     statusbar/spaceinfoobserver.cpp
 248     statusbar/statusbarspaceinfo.cpp
 249     views/zoomlevelinfo.cpp
 250     dolphindebug.cpp
 251     global.cpp
 252 )
 253
 254 if(HAVE_BALOO)
 255     set(dolphinstatic_SRCS
 256         ${dolphinstatic_SRCS}
 257         panels/information/informationpanel.cpp
 258         panels/information/informationpanelcontent.cpp
 259         panels/information/pixmapviewer.cpp
 260         panels/information/phononwidget.cpp
 261     )
 262 endif()
 263
 264 kconfig_add_kcfg_files(dolphinstatic_SRCS GENERATE_MOC
 265     panels/folders/dolphin_folderspanelsettings.kcfgc
 266     panels/information/dolphin_informationpanelsettings.kcfgc
 267     panels/places/dolphin_placespanelsettings.kcfgc
 268     settings/dolphin_compactmodesettings.kcfgc
 269     settings/dolphin_detailsmodesettings.kcfgc
 270     settings/dolphin_generalsettings.kcfgc
 271     settings/dolphin_iconsmodesettings.kcfgc
 272     search/dolphin_searchsettings.kcfgc
 273     settings/dolphin_versioncontrolsettings.kcfgc
 274 )
 275
 276 qt5_add_resources(dolphinstatic_SRCS dolphin.qrc)
 277
 278 qt5_generate_dbus_interface(${CMAKE_CURRENT_SOURCE_DIR}/dolphinmainwindow.h org.kde.DolphinMainWindow.xml)
 279 qt5_add_dbus_adaptor(dolphinstatic_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindow.h DolphinMainWindow)
 280 qt5_add_dbus_interface(dolphinstatic_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindowinterface)
 281 qt5_add_dbus_interface(dolphinstatic_SRCS panels/terminal/org.kde.KIOFuse.VFS.xml kiofuse_interface)
 282
 283 add_library(dolphinstatic STATIC ${dolphinstatic_SRCS})
 284
 285 target_include_directories(dolphinstatic SYSTEM PRIVATE ${PHONON_INCLUDES})
 286 target_link_libraries(dolphinstatic
 287     dolphinprivate
 288     KF5::CoreAddons
 289     KF5::KCMUtils
 290     KF5::DBusAddons
 291     KF5::Notifications
 292     Phonon::phonon4qt5
 293 )
 294
 295 if (HAVE_KACTIVITIES)
 296     target_link_libraries(
 297         dolphinstatic
 298         KF5::Activities
 299     )
 300 endif()
 301
 302 set(dolphin_SRCS
 303     dbusinterface.cpp
 304     main.cpp
 305 )
 306
 307 # Sets the icon on Windows and OSX
 308 file(GLOB ICONS_SRCS "${CMAKE_CURRENT_SOURCE_DIR}/icons/*system-file-manager.png")
 309 ecm_add_app_icon(dolphin_SRCS ICONS ${ICONS_SRCS})
 310
 311 kf5_add_kdeinit_executable(dolphin ${dolphin_SRCS})
 312
 313
 314 target_link_libraries(kdeinit_dolphin PUBLIC
 315     dolphinprivate
 316     PRIVATE
 317     dolphinstatic
 318     KF5::Crash
 319 )
 320
 321 include(DbusInterfaceMacros)
 322
 323 generate_and_install_dbus_interface(
 324     kdeinit_dolphin
 325     dbusinterface.h
 326     org.freedesktop.FileManager1.xml
 327     OPTIONS -a
 328 )
 329
 330 install(TARGETS kdeinit_dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 331 install(TARGETS dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 332
 333 ##########################################
 334
 335 set(kcm_dolphinviewmodes_PART_SRCS
 336     settings/kcm/kcmdolphinviewmodes.cpp
 337     settings/viewmodes/dolphinfontrequester.cpp
 338     settings/viewmodes/viewmodesettings.cpp
 339     settings/viewmodes/viewsettingstab.cpp
 340     views/zoomlevelinfo.cpp)
 341
 342 set(kcm_dolphinnavigation_PART_SRCS
 343     settings/kcm/kcmdolphinnavigation.cpp
 344     settings/navigation/navigationsettingspage.cpp
 345     settings/settingspagebase.cpp)
 346
 347 set(kcm_dolphinservices_PART_SRCS
 348     settings/kcm/kcmdolphinservices.cpp
 349     settings/services/servicessettingspage.cpp
 350     settings/settingspagebase.cpp
 351     settings/serviceitemdelegate.cpp
 352     settings/servicemodel.cpp)
 353
 354 set(kcm_dolphingeneral_PART_SRCS
 355     settings/kcm/kcmdolphingeneral.cpp
 356     settings/general/behaviorsettingspage.cpp
 357     settings/general/previewssettingspage.cpp
 358     settings/general/configurepreviewplugindialog.cpp
 359     settings/general/confirmationssettingspage.cpp
 360     settings/settingspagebase.cpp
 361     settings/serviceitemdelegate.cpp
 362     settings/servicemodel.cpp)
 363
 364 kconfig_add_kcfg_files(kcm_dolphinviewmodes_PART_SRCS
 365     settings/dolphin_compactmodesettings.kcfgc
 366     settings/dolphin_directoryviewpropertysettings.kcfgc
 367     settings/dolphin_detailsmodesettings.kcfgc
 368     settings/dolphin_iconsmodesettings.kcfgc
 369     settings/dolphin_generalsettings.kcfgc
 370     settings/dolphin_versioncontrolsettings.kcfgc
 371 )
 372
 373 kconfig_add_kcfg_files(kcm_dolphinnavigation_PART_SRCS
 374     settings/dolphin_generalsettings.kcfgc)
 375
 376 kconfig_add_kcfg_files(kcm_dolphinservices_PART_SRCS
 377     settings/dolphin_generalsettings.kcfgc
 378     settings/dolphin_versioncontrolsettings.kcfgc)
 379
 380 kconfig_add_kcfg_files(kcm_dolphingeneral_PART_SRCS
 381     settings/dolphin_generalsettings.kcfgc)
 382
 383
 384 if(NOT WIN32)
 385     # The settings are still accessible from the hamburger menu
 386     add_library(kcm_dolphinviewmodes MODULE ${kcm_dolphinviewmodes_PART_SRCS})
 387     add_library(kcm_dolphinnavigation MODULE ${kcm_dolphinnavigation_PART_SRCS})
 388     add_library(kcm_dolphinservices MODULE ${kcm_dolphinservices_PART_SRCS})
 389     add_library(kcm_dolphingeneral MODULE ${kcm_dolphingeneral_PART_SRCS})
 390
 391     target_link_libraries(kcm_dolphinviewmodes dolphinprivate)
 392     target_link_libraries(kcm_dolphinnavigation dolphinprivate)
 393     target_link_libraries(kcm_dolphinservices dolphinprivate)
 394     target_link_libraries(kcm_dolphingeneral dolphinprivate)
 395
 396     install( FILES org.kde.dolphin.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR} )
 397     install( FILES settings/kcm/kcmdolphinviewmodes.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 398     install( FILES settings/kcm/kcmdolphinnavigation.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 399     install( FILES settings/kcm/kcmdolphinservices.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 400     install( FILES settings/kcm/kcmdolphingeneral.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 401
 402     install(TARGETS kcm_dolphinviewmodes DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 403     install(TARGETS kcm_dolphinnavigation DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 404     install(TARGETS kcm_dolphinservices DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 405     install(TARGETS kcm_dolphingeneral DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 406 endif()
 407
 408 if(NOT WIN32)
 409     add_subdirectory(settings/services/servicemenuinstaller)
 410     install( FILES settings/services/servicemenu.knsrc DESTINATION ${KDE_INSTALL_KNSRCDIR} )
 411 endif()
 412
 413 ########### install files ###############
 414
 415 install( PROGRAMS org.kde.dolphin.desktop DESTINATION ${KDE_INSTALL_APPDIR} )
 416
 417 install( DIRECTORY DESTINATION "${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel" )
 418
 419 install(
 420     CODE "execute_process(COMMAND \"${CMAKE_COMMAND}\" -E create_symlink \"${KDE_INSTALL_FULL_APPDIR}/org.kde.dolphin.desktop\" \"\$ENV{DESTDIR}${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel/org.kde.dolphin.desktop\")"
 421 )
 422
 423 install( FILES settings/dolphin_directoryviewpropertysettings.kcfg
 424                settings/dolphin_generalsettings.kcfg
 425                settings/dolphin_compactmodesettings.kcfg
 426                settings/dolphin_iconsmodesettings.kcfg
 427                settings/dolphin_detailsmodesettings.kcfg
 428                settings/dolphin_versioncontrolsettings.kcfg
 429          DESTINATION ${KDE_INSTALL_KCFGDIR} )
 430
 431 if(BUILD_TESTING)
 432     find_package(Qt5Test ${QT_MIN_VERSION} CONFIG REQUIRED)
 433     add_subdirectory(tests)
 434 endif()