src/CMakeLists.txt

   1 include(ECMAddAppIcon)
   2
   3 configure_file(config-baloo.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-baloo.h)
   4
   5 configure_file(config-kactivities.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-kactivities.h)
   6
   7 configure_file(config-packagekit.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-packagekit.h)
   8
   9 configure_file(config-terminal.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-terminal.h)
  10
  11 configure_file(config-kuserfeedback.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-kuserfeedback.h)
  12
  13 add_definitions(
  14     -DTRANSLATION_DOMAIN=\"dolphin\"
  15 )
  16 remove_definitions(
  17     -DQT_NO_CAST_FROM_BYTEARRAY
  18     -DQT_NO_SIGNALS_SLOTS_KEYWORDS
  19     -DQT_NO_CAST_FROM_ASCII
  20     -DQT_NO_CAST_TO_ASCII
  21     -DQT_NO_FOREACH
  22     -DQT_NO_KEYWORDS
  23 )
  24
  25 ##########################################
  26
  27 set(dolphinvcs_LIB_SRCS
  28     views/versioncontrol/kversioncontrolplugin.cpp
  29 )
  30
  31 add_library(dolphinvcs ${dolphinvcs_LIB_SRCS})
  32 generate_export_header(dolphinvcs BASE_NAME dolphinvcs)
  33
  34 target_link_libraries(
  35     dolphinvcs PUBLIC
  36     Qt5::Widgets
  37 )
  38
  39 set_target_properties(dolphinvcs PROPERTIES
  40     VERSION ${DOLPHINVCS_VERSION_STRING}
  41     SOVERSION ${DOLPHINVCS_SOVERSION}
  42     EXPORT_NAME DolphinVcs
  43 )
  44
  45 ecm_generate_headers(dolphinvcs_LIB_HEADERS
  46     HEADER_NAMES
  47     KVersionControlPlugin
  48
  49     RELATIVE "views/versioncontrol"
  50     REQUIRED_HEADERS dolphinvcs_LIB_HEADERS
  51 )
  52
  53 install(TARGETS dolphinvcs EXPORT DolphinVcsTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
  54
  55 install(FILES views/versioncontrol/fileviewversioncontrolplugin.desktop DESTINATION ${KDE_INSTALL_KSERVICETYPES5DIR})
  56 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphinvcs_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
  57 install(FILES ${dolphinvcs_LIB_HEADERS} DESTINATION "${KDE_INSTALL_INCLUDEDIR}/Dolphin" COMPONENT Devel)
  58
  59 ########### next target ###############
  60
  61 set(dolphinprivate_LIB_SRCS
  62     kitemviews/kfileitemlistview.cpp
  63     kitemviews/kfileitemlistwidget.cpp
  64     kitemviews/kfileitemmodel.cpp
  65     kitemviews/kfileitemmodelrolesupdater.cpp
  66     kitemviews/kitemlistcontainer.cpp
  67     kitemviews/kitemlistcontroller.cpp
  68     kitemviews/kitemlistgroupheader.cpp
  69     kitemviews/kitemlistheader.cpp
  70     kitemviews/kitemlistselectionmanager.cpp
  71     kitemviews/kitemliststyleoption.cpp
  72     kitemviews/kitemlistview.cpp
  73     kitemviews/kitemlistviewaccessible.cpp
  74     kitemviews/kitemlistwidget.cpp
  75     kitemviews/kitemmodelbase.cpp
  76     kitemviews/kitemset.cpp
  77     kitemviews/kstandarditem.cpp
  78     kitemviews/kstandarditemlistgroupheader.cpp
  79     kitemviews/kstandarditemlistwidget.cpp
  80     kitemviews/kstandarditemlistview.cpp
  81     kitemviews/kstandarditemmodel.cpp
  82     kitemviews/private/kdirectorycontentscounter.cpp
  83     kitemviews/private/kdirectorycontentscounterworker.cpp
  84     kitemviews/private/kfileitemclipboard.cpp
  85     kitemviews/private/kfileitemmodeldirlister.cpp
  86     kitemviews/private/kfileitemmodelfilter.cpp
  87     kitemviews/private/kitemlistheaderwidget.cpp
  88     kitemviews/private/kitemlistkeyboardsearchmanager.cpp
  89     kitemviews/private/kitemlistroleeditor.cpp
  90     kitemviews/private/kitemlistrubberband.cpp
  91     kitemviews/private/kitemlistselectiontoggle.cpp
  92     kitemviews/private/kitemlistsizehintresolver.cpp
  93     kitemviews/private/kitemlistsmoothscroller.cpp
  94     kitemviews/private/kitemlistviewanimation.cpp
  95     kitemviews/private/kitemlistviewlayouter.cpp
  96     kitemviews/private/kpixmapmodifier.cpp
  97     kitemviews/private/ktwofingerswipe.cpp
  98     kitemviews/private/ktwofingertap.cpp
  99     settings/applyviewpropsjob.cpp
 100     settings/viewmodes/viewmodesettings.cpp
 101     settings/viewpropertiesdialog.cpp
 102     settings/viewpropsprogressinfo.cpp
 103     views/dolphinfileitemlistwidget.cpp
 104     views/dolphinitemlistview.cpp
 105     views/dolphinnewfilemenuobserver.cpp
 106     views/dolphinremoteencoding.cpp
 107     views/dolphinview.cpp
 108     views/dolphinviewactionhandler.cpp
 109     views/draganddrophelper.cpp
 110     views/versioncontrol/updateitemstatesthread.cpp
 111     views/versioncontrol/versioncontrolobserver.cpp
 112     views/viewmodecontroller.cpp
 113     views/viewproperties.cpp
 114     views/zoomlevelinfo.cpp
 115     dolphinremoveaction.cpp
 116     middleclickactioneventfilter.cpp
 117     dolphinnewfilemenu.cpp
 118 )
 119
 120 ecm_qt_declare_logging_category(dolphinprivate_LIB_SRCS HEADER dolphindebug.h IDENTIFIER DolphinDebug CATEGORY_NAME org.kde.dolphin)
 121
 122 if(HAVE_BALOO)
 123     set(dolphinprivate_LIB_SRCS
 124         ${dolphinprivate_LIB_SRCS}
 125         views/tooltips/dolphinfilemetadatawidget.cpp
 126         views/tooltips/tooltipmanager.cpp
 127         kitemviews/private/kbaloorolesprovider.cpp
 128     )
 129 endif()
 130
 131 kconfig_add_kcfg_files(dolphinprivate_LIB_SRCS GENERATE_MOC
 132     settings/dolphin_compactmodesettings.kcfgc
 133     settings/dolphin_directoryviewpropertysettings.kcfgc
 134     settings/dolphin_detailsmodesettings.kcfgc
 135     settings/dolphin_iconsmodesettings.kcfgc
 136     settings/dolphin_generalsettings.kcfgc
 137     settings/dolphin_versioncontrolsettings.kcfgc
 138 )
 139
 140 add_library(dolphinprivate ${dolphinprivate_LIB_SRCS})
 141 generate_export_header(dolphinprivate BASE_NAME dolphin)
 142
 143 target_link_libraries(
 144     dolphinprivate PUBLIC
 145     dolphinvcs
 146     Qt5::Concurrent
 147     Qt5::Gui
 148     KF5::I18n
 149     KF5::IconThemes
 150     KF5::KIOCore
 151     KF5::KIOWidgets
 152     KF5::KIOFileWidgets
 153     KF5::Completion
 154     KF5::TextWidgets
 155     KF5::ConfigCore
 156     KF5::NewStuff
 157     KF5::Parts
 158     KF5::WindowSystem
 159 )
 160
 161 if(HAVE_BALOO)
 162     target_link_libraries(
 163         dolphinprivate PUBLIC
 164         KF5::FileMetaData
 165         KF5::Baloo
 166         KF5::BalooWidgets
 167     )
 168 endif()
 169
 170 set_target_properties(dolphinprivate PROPERTIES
 171     VERSION ${DOLPHINPRIVATE_VERSION_STRING}
 172     SOVERSION ${DOLPHINPRIVATE_SOVERSION}
 173 )
 174
 175 install(TARGETS dolphinprivate ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} LIBRARY NAMELINK_SKIP)
 176 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphin_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
 177
 178 ##########################################
 179 configure_file(dolphinpart.desktop.in ${CMAKE_CURRENT_BINARY_DIR}/dolphinpart.desktop @ONLY)
 180
 181 set(dolphinpart_SRCS
 182    dolphinpart.cpp
 183    dolphinpart_ext.cpp
 184    dolphindebug.cpp
 185 )
 186
 187 qt5_add_resources(dolphinpart_SRCS dolphinpart.qrc)
 188
 189 add_library(dolphinpart MODULE ${dolphinpart_SRCS})
 190 kcoreaddons_desktop_to_json(dolphinpart ${CMAKE_CURRENT_BINARY_DIR}/dolphinpart.desktop)
 191
 192 target_link_libraries(dolphinpart
 193     dolphinprivate
 194 )
 195
 196 install(TARGETS dolphinpart DESTINATION ${KDE_INSTALL_PLUGINDIR}/kf5/parts)
 197
 198 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphinpart.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR})
 199
 200 ##########################################
 201
 202 set(dolphinstatic_SRCS
 203     dolphinbookmarkhandler.cpp
 204     dolphindockwidget.cpp
 205     dolphinmainwindow.cpp
 206     dolphinviewcontainer.cpp
 207     dolphincontextmenu.cpp
 208     dolphinnavigatorswidgetaction.cpp
 209     dolphintabbar.cpp
 210     dolphinplacesmodelsingleton.cpp
 211     dolphinrecenttabsmenu.cpp
 212     dolphintabpage.cpp
 213     dolphintabwidget.cpp
 214     dolphinurlnavigator.cpp
 215     dolphinurlnavigatorscontroller.cpp
 216     trash/dolphintrash.cpp
 217     filterbar/filterbar.cpp
 218     panels/places/placespanel.cpp
 219     panels/places/placesitem.cpp
 220     panels/places/placesitemlistgroupheader.cpp
 221     panels/places/placesitemlistwidget.cpp
 222     panels/places/placesitemmodel.cpp
 223     panels/places/placesitemsignalhandler.cpp
 224     panels/places/placesview.cpp
 225     panels/panel.cpp
 226     panels/folders/foldersitemlistwidget.cpp
 227     panels/folders/treeviewcontextmenu.cpp
 228     panels/folders/folderspanel.cpp
 229     panels/terminal/terminalpanel.cpp
 230     search/dolphinfacetswidget.cpp
 231     search/dolphinquery.cpp
 232     search/dolphinsearchbox.cpp
 233     settings/general/behaviorsettingspage.cpp
 234     settings/general/configurepreviewplugindialog.cpp
 235     settings/general/confirmationssettingspage.cpp
 236     settings/general/generalsettingspage.cpp
 237     settings/general/previewssettingspage.cpp
 238     settings/general/statusbarsettingspage.cpp
 239     settings/dolphinsettingsdialog.cpp
 240     settings/navigation/navigationsettingspage.cpp
 241     settings/services/servicessettingspage.cpp
 242     settings/settingspagebase.cpp
 243     settings/serviceitemdelegate.cpp
 244     settings/servicemodel.cpp
 245     settings/startup/startupsettingspage.cpp
 246     settings/trash/trashsettingspage.cpp
 247     settings/viewmodes/dolphinfontrequester.cpp
 248     settings/viewmodes/viewsettingspage.cpp
 249     settings/viewmodes/viewmodesettings.cpp
 250     settings/viewmodes/viewsettingstab.cpp
 251     statusbar/dolphinstatusbar.cpp
 252     statusbar/mountpointobserver.cpp
 253     statusbar/mountpointobservercache.cpp
 254     statusbar/spaceinfoobserver.cpp
 255     statusbar/statusbarspaceinfo.cpp
 256     views/zoomlevelinfo.cpp
 257     dolphindebug.cpp
 258     global.cpp
 259 )
 260
 261 if(HAVE_BALOO)
 262     set(dolphinstatic_SRCS
 263         ${dolphinstatic_SRCS}
 264         panels/information/informationpanel.cpp
 265         panels/information/informationpanelcontent.cpp
 266         panels/information/pixmapviewer.cpp
 267         panels/information/phononwidget.cpp
 268     )
 269 endif()
 270
 271 if(HAVE_KUSERFEEDBACK)
 272     set(dolphinstatic_SRCS
 273         ${dolphinstatic_SRCS}
 274         userfeedback/dolphinfeedbackprovider.cpp
 275         userfeedback/settingsdatasource.cpp
 276         userfeedback/placesdatasource.cpp
 277         settings/userfeedback/userfeedbacksettingspage.cpp
 278     )
 279 endif()
 280
 281 kconfig_add_kcfg_files(dolphinstatic_SRCS GENERATE_MOC
 282     panels/folders/dolphin_folderspanelsettings.kcfgc
 283     panels/information/dolphin_informationpanelsettings.kcfgc
 284     panels/places/dolphin_placespanelsettings.kcfgc
 285     settings/dolphin_compactmodesettings.kcfgc
 286     settings/dolphin_detailsmodesettings.kcfgc
 287     settings/dolphin_generalsettings.kcfgc
 288     settings/dolphin_iconsmodesettings.kcfgc
 289     search/dolphin_searchsettings.kcfgc
 290     settings/dolphin_versioncontrolsettings.kcfgc
 291 )
 292
 293 qt5_add_resources(dolphinstatic_SRCS dolphin.qrc)
 294
 295 qt5_generate_dbus_interface(${CMAKE_CURRENT_SOURCE_DIR}/dolphinmainwindow.h org.kde.DolphinMainWindow.xml)
 296 qt5_add_dbus_adaptor(dolphinstatic_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindow.h DolphinMainWindow)
 297 qt5_add_dbus_interface(dolphinstatic_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindowinterface)
 298 qt5_add_dbus_interface(dolphinstatic_SRCS panels/terminal/org.kde.KIOFuse.VFS.xml kiofuse_interface)
 299
 300 add_library(dolphinstatic STATIC ${dolphinstatic_SRCS})
 301
 302 target_include_directories(dolphinstatic SYSTEM PRIVATE ${PHONON_INCLUDES})
 303 target_link_libraries(dolphinstatic
 304     dolphinprivate
 305     KF5::CoreAddons
 306     KF5::KCMUtils
 307     KF5::DBusAddons
 308     KF5::Notifications
 309     Phonon::phonon4qt5
 310 )
 311
 312 if (HAVE_KACTIVITIES)
 313     target_link_libraries(
 314         dolphinstatic
 315         KF5::Activities
 316     )
 317 endif()
 318
 319 if (HAVE_KUSERFEEDBACK)
 320     target_link_libraries(
 321         dolphinstatic
 322         KUserFeedbackCore
 323         KUserFeedbackWidgets
 324     )
 325 endif()
 326
 327 set(dolphin_SRCS
 328     dbusinterface.cpp
 329     main.cpp
 330 )
 331
 332 # Sets the icon on Windows and OSX
 333 file(GLOB ICONS_SRCS "${CMAKE_CURRENT_SOURCE_DIR}/icons/*system-file-manager.png")
 334 ecm_add_app_icon(dolphin_SRCS ICONS ${ICONS_SRCS})
 335
 336 kf5_add_kdeinit_executable(dolphin ${dolphin_SRCS})
 337
 338
 339 target_link_libraries(kdeinit_dolphin PUBLIC
 340     dolphinprivate
 341     PRIVATE
 342     dolphinstatic
 343     KF5::Crash
 344 )
 345
 346 include(DbusInterfaceMacros)
 347
 348 generate_and_install_dbus_interface(
 349     kdeinit_dolphin
 350     dbusinterface.h
 351     org.freedesktop.FileManager1.xml
 352     OPTIONS -a
 353 )
 354
 355 install(TARGETS kdeinit_dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 356 install(TARGETS dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 357
 358 ##########################################
 359
 360 set(kcm_dolphinviewmodes_PART_SRCS
 361     settings/kcm/kcmdolphinviewmodes.cpp
 362     settings/viewmodes/dolphinfontrequester.cpp
 363     settings/viewmodes/viewmodesettings.cpp
 364     settings/viewmodes/viewsettingstab.cpp
 365     views/zoomlevelinfo.cpp)
 366
 367 set(kcm_dolphinnavigation_PART_SRCS
 368     settings/kcm/kcmdolphinnavigation.cpp
 369     settings/navigation/navigationsettingspage.cpp
 370     settings/settingspagebase.cpp)
 371
 372 set(kcm_dolphinservices_PART_SRCS
 373     settings/kcm/kcmdolphinservices.cpp
 374     settings/services/servicessettingspage.cpp
 375     settings/settingspagebase.cpp
 376     settings/serviceitemdelegate.cpp
 377     settings/servicemodel.cpp)
 378
 379 set(kcm_dolphingeneral_PART_SRCS
 380     settings/kcm/kcmdolphingeneral.cpp
 381     settings/general/behaviorsettingspage.cpp
 382     settings/general/previewssettingspage.cpp
 383     settings/general/configurepreviewplugindialog.cpp
 384     settings/general/confirmationssettingspage.cpp
 385     settings/settingspagebase.cpp
 386     settings/serviceitemdelegate.cpp
 387     settings/servicemodel.cpp)
 388
 389 kconfig_add_kcfg_files(kcm_dolphinviewmodes_PART_SRCS
 390     settings/dolphin_compactmodesettings.kcfgc
 391     settings/dolphin_directoryviewpropertysettings.kcfgc
 392     settings/dolphin_detailsmodesettings.kcfgc
 393     settings/dolphin_iconsmodesettings.kcfgc
 394     settings/dolphin_generalsettings.kcfgc
 395     settings/dolphin_versioncontrolsettings.kcfgc
 396 )
 397
 398 kconfig_add_kcfg_files(kcm_dolphinnavigation_PART_SRCS
 399     settings/dolphin_generalsettings.kcfgc)
 400
 401 kconfig_add_kcfg_files(kcm_dolphinservices_PART_SRCS
 402     settings/dolphin_generalsettings.kcfgc
 403     settings/dolphin_versioncontrolsettings.kcfgc)
 404
 405 kconfig_add_kcfg_files(kcm_dolphingeneral_PART_SRCS
 406     settings/dolphin_generalsettings.kcfgc)
 407
 408
 409 if(NOT WIN32)
 410     # The settings are still accessible from the hamburger menu
 411     add_library(kcm_dolphinviewmodes MODULE ${kcm_dolphinviewmodes_PART_SRCS})
 412     add_library(kcm_dolphinnavigation MODULE ${kcm_dolphinnavigation_PART_SRCS})
 413     add_library(kcm_dolphinservices MODULE ${kcm_dolphinservices_PART_SRCS})
 414     add_library(kcm_dolphingeneral MODULE ${kcm_dolphingeneral_PART_SRCS})
 415
 416     target_link_libraries(kcm_dolphinviewmodes dolphinprivate)
 417     target_link_libraries(kcm_dolphinnavigation dolphinprivate)
 418     target_link_libraries(kcm_dolphinservices dolphinprivate)
 419     target_link_libraries(kcm_dolphingeneral dolphinprivate)
 420
 421     install( FILES org.kde.dolphin.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR} )
 422     install( FILES settings/kcm/kcmdolphinviewmodes.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 423     install( FILES settings/kcm/kcmdolphinnavigation.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 424     install( FILES settings/kcm/kcmdolphinservices.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 425     install( FILES settings/kcm/kcmdolphingeneral.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 426
 427     install(TARGETS kcm_dolphinviewmodes DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 428     install(TARGETS kcm_dolphinnavigation DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 429     install(TARGETS kcm_dolphinservices DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 430     install(TARGETS kcm_dolphingeneral DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 431 endif()
 432
 433 if(NOT WIN32)
 434     add_subdirectory(settings/services/servicemenuinstaller)
 435     install( FILES settings/services/servicemenu.knsrc DESTINATION ${KDE_INSTALL_KNSRCDIR} )
 436 endif()
 437
 438 ########### install files ###############
 439
 440 install( PROGRAMS org.kde.dolphin.desktop DESTINATION ${KDE_INSTALL_APPDIR} )
 441
 442 install( DIRECTORY DESTINATION "${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel" )
 443
 444 install(
 445     CODE "execute_process(COMMAND \"${CMAKE_COMMAND}\" -E create_symlink \"${KDE_INSTALL_FULL_APPDIR}/org.kde.dolphin.desktop\" \"\$ENV{DESTDIR}${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel/org.kde.dolphin.desktop\")"
 446 )
 447
 448 install( FILES settings/dolphin_directoryviewpropertysettings.kcfg
 449                settings/dolphin_generalsettings.kcfg
 450                settings/dolphin_compactmodesettings.kcfg
 451                settings/dolphin_iconsmodesettings.kcfg
 452                settings/dolphin_detailsmodesettings.kcfg
 453                settings/dolphin_versioncontrolsettings.kcfg
 454          DESTINATION ${KDE_INSTALL_KCFGDIR} )
 455
 456 if(BUILD_TESTING)
 457     find_package(Qt5Test ${QT_MIN_VERSION} CONFIG REQUIRED)
 458     add_subdirectory(tests)
 459 endif()