src/CMakeLists.txt

   1
   2 configure_file(config-baloo.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-baloo.h)
   3
   4 configure_file(config-dolphin.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-dolphin.h)
   5
   6 add_definitions(
   7     -DTRANSLATION_DOMAIN=\"dolphin\"
   8     -DQT_USE_FAST_CONCATENATION
   9     -DQT_USE_FAST_OPERATOR_PLUS
  10 )
  11 remove_definitions(
  12     -DQT_NO_CAST_FROM_BYTEARRAY
  13     -DQT_NO_URL_CAST_FROM_STRING
  14     -DQT_NO_SIGNALS_SLOTS_KEYWORDS
  15     -DQT_NO_CAST_FROM_ASCII
  16     -DQT_NO_CAST_TO_ASCII
  17 )
  18
  19 if(X11_Xrender_FOUND)
  20     set(HAVE_XRENDER TRUE)
  21 endif()
  22
  23 configure_file(config-X11.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-X11.h)
  24
  25 ##########################################
  26
  27 set(dolphinvcs_LIB_SRCS
  28     views/versioncontrol/kversioncontrolplugin.cpp
  29 )
  30
  31 add_library(dolphinvcs ${dolphinvcs_LIB_SRCS})
  32
  33 generate_export_header(dolphinvcs BASE_NAME dolphin)
  34
  35 target_link_libraries(
  36     dolphinvcs PUBLIC
  37     Qt5::Widgets
  38     KF5::KIOCore
  39 )
  40
  41 set_target_properties(dolphinvcs PROPERTIES
  42     VERSION ${DOLPHINVCS_VERSION_STRING}
  43     SOVERSION ${DOLPHINVCS_SOVERSION}
  44     EXPORT_NAME DolphinVcs
  45 )
  46
  47 ecm_generate_headers(dolphinvcs_LIB_HEADERS
  48     HEADER_NAMES
  49     KVersionControlPlugin
  50
  51     RELATIVE "views/versioncontrol"
  52     REQUIRED_HEADERS dolphinvcs_LIB_HEADERS
  53 )
  54
  55 install(TARGETS dolphinvcs EXPORT DolphinVcsTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
  56
  57 install(FILES views/versioncontrol/fileviewversioncontrolplugin.desktop DESTINATION ${KDE_INSTALL_KSERVICETYPES5DIR})
  58 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphin_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
  59 install(FILES ${dolphinvcs_LIB_HEADERS} DESTINATION "${KDE_INSTALL_INCLUDEDIR}/Dolphin" COMPONENT Devel)
  60
  61 ########### next target ###############
  62
  63 set(dolphinprivate_LIB_SRCS
  64     kitemviews/kfileitemlistview.cpp
  65     kitemviews/kfileitemlistwidget.cpp
  66     kitemviews/kfileitemmodel.cpp
  67     kitemviews/kfileitemmodelrolesupdater.cpp
  68     kitemviews/kitemlistcontainer.cpp
  69     kitemviews/kitemlistcontroller.cpp
  70     kitemviews/kitemlistgroupheader.cpp
  71     kitemviews/kitemlistheader.cpp
  72     kitemviews/kitemlistselectionmanager.cpp
  73     kitemviews/kitemliststyleoption.cpp
  74     kitemviews/kitemlistview.cpp
  75     kitemviews/kitemlistviewaccessible.cpp
  76     kitemviews/kitemlistwidget.cpp
  77     kitemviews/kitemmodelbase.cpp
  78     kitemviews/kitemset.cpp
  79     kitemviews/kstandarditem.cpp
  80     kitemviews/kstandarditemlistgroupheader.cpp
  81     kitemviews/kstandarditemlistwidget.cpp
  82     kitemviews/kstandarditemlistview.cpp
  83     kitemviews/kstandarditemmodel.cpp
  84     kitemviews/private/kdirectorycontentscounter.cpp
  85     kitemviews/private/kdirectorycontentscounterworker.cpp
  86     kitemviews/private/kfileitemclipboard.cpp
  87     kitemviews/private/kfileitemmodeldirlister.cpp
  88     kitemviews/private/kfileitemmodelfilter.cpp
  89     kitemviews/private/kitemlistheaderwidget.cpp
  90     kitemviews/private/kitemlistkeyboardsearchmanager.cpp
  91     kitemviews/private/kitemlistroleeditor.cpp
  92     kitemviews/private/kitemlistrubberband.cpp
  93     kitemviews/private/kitemlistselectiontoggle.cpp
  94     kitemviews/private/kitemlistsizehintresolver.cpp
  95     kitemviews/private/kitemlistsmoothscroller.cpp
  96     kitemviews/private/kitemlistviewanimation.cpp
  97     kitemviews/private/kitemlistviewlayouter.cpp
  98     kitemviews/private/kpixmapmodifier.cpp
  99     settings/additionalinfodialog.cpp
 100     settings/applyviewpropsjob.cpp
 101     settings/viewmodes/viewmodesettings.cpp
 102     settings/viewpropertiesdialog.cpp
 103     settings/viewpropsprogressinfo.cpp
 104     views/dolphinfileitemlistwidget.cpp
 105     views/dolphinitemlistview.cpp
 106     views/dolphinnewfilemenuobserver.cpp
 107     views/dolphinremoteencoding.cpp
 108     views/dolphinview.cpp
 109     views/dolphinviewactionhandler.cpp
 110     views/draganddrophelper.cpp
 111     views/renamedialog.cpp
 112     views/tooltips/filemetadatatooltip.cpp
 113     views/tooltips/tooltipmanager.cpp
 114     views/versioncontrol/updateitemstatesthread.cpp
 115     views/versioncontrol/versioncontrolobserver.cpp
 116     views/viewmodecontroller.cpp
 117     views/viewproperties.cpp
 118     views/zoomlevelinfo.cpp
 119     dolphinremoveaction.cpp
 120     dolphinnewfilemenu.cpp
 121     dolphindebug.cpp
 122 )
 123
 124 if(HAVE_BALOO)
 125     set(dolphinprivate_LIB_SRCS
 126         ${dolphinprivate_LIB_SRCS}
 127         kitemviews/private/kbaloorolesprovider.cpp
 128     )
 129 endif()
 130
 131 kconfig_add_kcfg_files(dolphinprivate_LIB_SRCS GENERATE_MOC
 132     settings/dolphin_compactmodesettings.kcfgc
 133     settings/dolphin_directoryviewpropertysettings.kcfgc
 134     settings/dolphin_detailsmodesettings.kcfgc
 135     settings/dolphin_iconsmodesettings.kcfgc
 136     settings/dolphin_generalsettings.kcfgc
 137     settings/dolphin_versioncontrolsettings.kcfgc
 138 )
 139
 140 add_library(dolphinprivate ${dolphinprivate_LIB_SRCS})
 141
 142 target_link_libraries(
 143     dolphinprivate PUBLIC
 144     dolphinvcs
 145     Qt5::Gui
 146     KF5::I18n
 147     KF5::IconThemes
 148     KF5::KIOCore
 149     KF5::KIOWidgets
 150     KF5::KIOFileWidgets
 151     KF5::Completion
 152     KF5::TextEditor
 153     KF5::WindowSystem
 154     KF5::ConfigCore
 155     KF5::NewStuff
 156 )
 157
 158 if(HAVE_BALOO)
 159     target_link_libraries(
 160         dolphinprivate PUBLIC
 161         KF5::FileMetaData
 162         KF5::Baloo
 163         KF5::BalooWidgets
 164     )
 165 else()
 166     target_link_libraries(
 167         dolphinprivate PUBLIC
 168         KF5::KDELibs4Support # for KFileMetaDataWidget
 169     )
 170 endif()
 171
 172 if(X11_Xrender_FOUND)
 173     target_link_libraries(dolphinprivate ${X11_Xrender_LIB})
 174 endif(X11_Xrender_FOUND)
 175
 176 set_target_properties(dolphinprivate PROPERTIES
 177     VERSION ${DOLPHINPRIVATE_VERSION_STRING}
 178     SOVERSION ${DOLPHINPRIVATE_SOVERSION}
 179 )
 180
 181 install(TARGETS dolphinprivate ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 182
 183 ##########################################
 184
 185 set(dolphinpart_SRCS
 186    dolphinpart.cpp
 187    dolphinpart_ext.cpp
 188    dolphindebug.cpp
 189 )
 190
 191 add_library(dolphinpart MODULE ${dolphinpart_SRCS})
 192
 193 target_link_libraries(dolphinpart
 194     dolphinprivate
 195 )
 196
 197 install(TARGETS dolphinpart DESTINATION ${PLUGIN_INSTALL_DIR})
 198
 199 install(FILES dolphinpart.rc DESTINATION ${CMAKE_INSTALL_KXMLGUI5DIR}/dolphinpart)
 200 install(FILES dolphinpart.desktop DESTINATION ${SERVICES_INSTALL_DIR})
 201
 202 ##########################################
 203
 204 set(dolphin_SRCS
 205     dolphindockwidget.cpp
 206     dolphinmainwindow.cpp
 207     dolphinviewcontainer.cpp
 208     dolphincontextmenu.cpp
 209     dolphintabbar.cpp
 210     dolphinrecenttabsmenu.cpp
 211     dolphintabpage.cpp
 212     dolphintabwidget.cpp
 213     filterbar/filterbar.cpp
 214     main.cpp
 215     panels/information/filemetadataconfigurationdialog.cpp
 216     panels/information/informationpanel.cpp
 217     panels/information/informationpanelcontent.cpp
 218     panels/information/pixmapviewer.cpp
 219     panels/information/phononwidget.cpp
 220     panels/places/placespanel.cpp
 221     panels/places/placesitem.cpp
 222     panels/places/placesitemeditdialog.cpp
 223     panels/places/placesitemlistgroupheader.cpp
 224     panels/places/placesitemlistwidget.cpp
 225     panels/places/placesitemmodel.cpp
 226     panels/places/placesitemsignalhandler.cpp
 227     panels/places/placesview.cpp
 228     panels/panel.cpp
 229     panels/folders/foldersitemlistwidget.cpp
 230     panels/folders/treeviewcontextmenu.cpp
 231     panels/folders/folderspanel.cpp
 232     search/dolphinfacetswidget.cpp
 233     search/dolphinsearchbox.cpp
 234     settings/general/behaviorsettingspage.cpp
 235     settings/general/configurepreviewplugindialog.cpp
 236     settings/general/confirmationssettingspage.cpp
 237     settings/general/generalsettingspage.cpp
 238     settings/general/previewssettingspage.cpp
 239     settings/general/statusbarsettingspage.cpp
 240     settings/dolphinsettingsdialog.cpp
 241     settings/navigation/navigationsettingspage.cpp
 242     settings/services/servicessettingspage.cpp
 243     settings/settingspagebase.cpp
 244     settings/serviceitemdelegate.cpp
 245     settings/servicemodel.cpp
 246     settings/startup/startupsettingspage.cpp
 247     settings/trash/trashsettingspage.cpp
 248     settings/viewmodes/dolphinfontrequester.cpp
 249     settings/viewmodes/viewsettingspage.cpp
 250     settings/viewmodes/viewmodesettings.cpp
 251     settings/viewmodes/viewsettingstab.cpp
 252     statusbar/dolphinstatusbar.cpp
 253     statusbar/mountpointobserver.cpp
 254     statusbar/mountpointobservercache.cpp
 255     statusbar/spaceinfotoolsmenu.cpp
 256     statusbar/spaceinfoobserver.cpp
 257     statusbar/statusbarspaceinfo.cpp
 258     views/zoomlevelinfo.cpp
 259     dolphindebug.cpp
 260 )
 261
 262 kconfig_add_kcfg_files(dolphin_SRCS GENERATE_MOC
 263     panels/folders/dolphin_folderspanelsettings.kcfgc
 264     panels/information/dolphin_informationpanelsettings.kcfgc
 265     panels/places/dolphin_placespanelsettings.kcfgc
 266     settings/dolphin_compactmodesettings.kcfgc
 267     settings/dolphin_detailsmodesettings.kcfgc
 268     settings/dolphin_generalsettings.kcfgc
 269     settings/dolphin_iconsmodesettings.kcfgc
 270     search/dolphin_searchsettings.kcfgc
 271     settings/dolphin_versioncontrolsettings.kcfgc
 272 )
 273
 274 if(NOT WIN32)
 275    set(dolphin_SRCS ${dolphin_SRCS} panels/terminal/terminalpanel.cpp)
 276 endif()
 277
 278 # TODO Does anything replace kde4_add_app_icon ?
 279 #kde4_add_app_icon(dolphin_SRCS "${KDE4_ICON_INSTALL_DIR}/oxygen/*/apps/system-file-manager.png")
 280
 281 kf5_add_kdeinit_executable(dolphin ${dolphin_SRCS})
 282
 283 target_include_directories(kdeinit_dolphin PRIVATE ${PHONON_INCLUDES})
 284
 285 target_link_libraries(kdeinit_dolphin
 286     dolphinprivate
 287     KF5::Parts
 288     KF5::KCMUtils
 289     KF5::Solid
 290     KF5::CoreAddons
 291     KF5::DBusAddons
 292     KF5::Bookmarks
 293     KF5::Notifications
 294     Phonon::phonon4qt5
 295 )
 296
 297 if (KF5Activities_FOUND)
 298     target_link_libraries(
 299         kdeinit_dolphin
 300         KF5::Activities
 301     )
 302 endif()
 303
 304 install(TARGETS kdeinit_dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 305 install(TARGETS dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 306
 307 ##########################################
 308
 309 set(kcm_dolphinviewmodes_PART_SRCS
 310     settings/kcm/kcmdolphinviewmodes.cpp
 311     settings/viewmodes/dolphinfontrequester.cpp
 312     settings/viewmodes/viewmodesettings.cpp
 313     settings/viewmodes/viewsettingstab.cpp
 314     views/zoomlevelinfo.cpp)
 315
 316 set(kcm_dolphinnavigation_PART_SRCS
 317     settings/kcm/kcmdolphinnavigation.cpp
 318     settings/navigation/navigationsettingspage.cpp
 319     settings/settingspagebase.cpp)
 320
 321 set(kcm_dolphinservices_PART_SRCS
 322     settings/kcm/kcmdolphinservices.cpp
 323     settings/services/servicessettingspage.cpp
 324     settings/settingspagebase.cpp
 325     settings/serviceitemdelegate.cpp
 326     settings/servicemodel.cpp)
 327
 328 set(kcm_dolphingeneral_PART_SRCS
 329     settings/kcm/kcmdolphingeneral.cpp
 330     settings/general/behaviorsettingspage.cpp
 331     settings/general/previewssettingspage.cpp
 332     settings/general/configurepreviewplugindialog.cpp
 333     settings/general/confirmationssettingspage.cpp
 334     settings/settingspagebase.cpp
 335     settings/serviceitemdelegate.cpp
 336     settings/servicemodel.cpp)
 337
 338 kconfig_add_kcfg_files(kcm_dolphinviewmodes_PART_SRCS
 339     settings/dolphin_compactmodesettings.kcfgc
 340     settings/dolphin_directoryviewpropertysettings.kcfgc
 341     settings/dolphin_detailsmodesettings.kcfgc
 342     settings/dolphin_iconsmodesettings.kcfgc
 343     settings/dolphin_generalsettings.kcfgc
 344     settings/dolphin_versioncontrolsettings.kcfgc
 345 )
 346
 347 kconfig_add_kcfg_files(kcm_dolphinnavigation_PART_SRCS
 348     settings/dolphin_generalsettings.kcfgc)
 349
 350 kconfig_add_kcfg_files(kcm_dolphinservices_PART_SRCS
 351     settings/dolphin_generalsettings.kcfgc
 352     settings/dolphin_versioncontrolsettings.kcfgc)
 353
 354 kconfig_add_kcfg_files(kcm_dolphingeneral_PART_SRCS
 355     settings/dolphin_generalsettings.kcfgc)
 356
 357 add_library(kcm_dolphinviewmodes MODULE ${kcm_dolphinviewmodes_PART_SRCS})
 358 add_library(kcm_dolphinnavigation MODULE ${kcm_dolphinnavigation_PART_SRCS})
 359 add_library(kcm_dolphinservices MODULE ${kcm_dolphinservices_PART_SRCS})
 360 add_library(kcm_dolphingeneral MODULE ${kcm_dolphingeneral_PART_SRCS})
 361
 362 target_link_libraries(kcm_dolphinviewmodes dolphinprivate)
 363 target_link_libraries(kcm_dolphinnavigation dolphinprivate)
 364 target_link_libraries(kcm_dolphinservices dolphinprivate)
 365 target_link_libraries(kcm_dolphingeneral dolphinprivate)
 366
 367 install(TARGETS kcm_dolphinviewmodes DESTINATION ${PLUGIN_INSTALL_DIR} )
 368 install(TARGETS kcm_dolphinnavigation DESTINATION ${PLUGIN_INSTALL_DIR} )
 369 install(TARGETS kcm_dolphinservices DESTINATION ${PLUGIN_INSTALL_DIR} )
 370 install(TARGETS kcm_dolphingeneral DESTINATION ${PLUGIN_INSTALL_DIR} )
 371
 372 ########### install files ###############
 373
 374 install( PROGRAMS org.kde.dolphin.desktop DESTINATION ${XDG_APPS_INSTALL_DIR} )
 375 install( FILES settings/dolphin_directoryviewpropertysettings.kcfg
 376                settings/dolphin_generalsettings.kcfg
 377                settings/dolphin_compactmodesettings.kcfg
 378                settings/dolphin_iconsmodesettings.kcfg
 379                settings/dolphin_detailsmodesettings.kcfg
 380                settings/dolphin_versioncontrolsettings.kcfg
 381          DESTINATION ${KCFG_INSTALL_DIR} )
 382 install( FILES dolphinui.rc DESTINATION ${CMAKE_INSTALL_KXMLGUI5DIR}/dolphin )
 383 install( FILES dolphin.appdata.xml DESTINATION ${SHARE_INSTALL_PREFIX}/appdata )
 384 install( FILES settings/kcm/kcmdolphinviewmodes.desktop DESTINATION
 385 ${SERVICES_INSTALL_DIR} )
 386 install( FILES settings/kcm/kcmdolphinnavigation.desktop DESTINATION ${SERVICES_INSTALL_DIR} )
 387 install( FILES settings/kcm/kcmdolphinservices.desktop DESTINATION ${SERVICES_INSTALL_DIR} )
 388 install( FILES settings/kcm/kcmdolphingeneral.desktop DESTINATION ${SERVICES_INSTALL_DIR} )
 389 install( FILES settings/services/servicemenu.knsrc DESTINATION ${CONFIG_INSTALL_DIR} )
 390 install( PROGRAMS settings/services/servicemenuinstallation DESTINATION ${BIN_INSTALL_DIR} )
 391 install( PROGRAMS settings/services/servicemenudeinstallation DESTINATION ${BIN_INSTALL_DIR} )
 392
 393 if(BUILD_TESTING)
 394     find_package(Qt5Test ${QT_MIN_VERSION} CONFIG REQUIRED)
 395     add_subdirectory(tests)
 396 endif()