src/CMakeLists.txt

   1 include(ECMAddAppIcon)
   2
   3 configure_file(config-dolphin.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-dolphin.h)
   4
   5 add_definitions(
   6     -DTRANSLATION_DOMAIN=\"dolphin\"
   7 )
   8 remove_definitions(
   9     -DQT_NO_CAST_FROM_BYTEARRAY
  10     -DQT_NO_CAST_FROM_ASCII
  11     -DQT_NO_CAST_TO_ASCII
  12 )
  13
  14 ##########################################
  15
  16 add_library(dolphinvcs SHARED)
  17
  18 target_sources(dolphinvcs PRIVATE
  19     views/versioncontrol/kversioncontrolplugin.cpp
  20 )
  21
  22 generate_export_header(dolphinvcs BASE_NAME dolphinvcs)
  23
  24 target_link_libraries(
  25     dolphinvcs PUBLIC
  26     Qt${QT_MAJOR_VERSION}::Widgets
  27 )
  28
  29 set_target_properties(dolphinvcs PROPERTIES
  30     VERSION ${DOLPHINVCS_VERSION}
  31     SOVERSION ${DOLPHINVCS_SOVERSION}
  32     EXPORT_NAME DolphinVcs
  33 )
  34
  35 ecm_generate_headers(dolphinvcs_LIB_HEADERS
  36     HEADER_NAMES
  37     KVersionControlPlugin
  38
  39     RELATIVE "views/versioncontrol"
  40     REQUIRED_HEADERS dolphinvcs_LIB_HEADERS
  41 )
  42
  43 install(TARGETS dolphinvcs EXPORT DolphinVcsTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
  44
  45 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphinvcs_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
  46 install(FILES ${dolphinvcs_LIB_HEADERS} DESTINATION "${KDE_INSTALL_INCLUDEDIR}/Dolphin" COMPONENT Devel)
  47
  48 ########### next target ###############
  49
  50 add_library(dolphinprivate SHARED)
  51
  52 target_sources(dolphinprivate PRIVATE
  53     kitemviews/kfileitemlistview.cpp
  54     kitemviews/kfileitemlistwidget.cpp
  55     kitemviews/kfileitemlisttostring.cpp
  56     kitemviews/kfileitemmodel.cpp
  57     kitemviews/kfileitemmodelrolesupdater.cpp
  58     kitemviews/kitemlistcontainer.cpp
  59     kitemviews/kitemlistcontroller.cpp
  60     kitemviews/kitemlistgroupheader.cpp
  61     kitemviews/kitemlistheader.cpp
  62     kitemviews/kitemlistselectionmanager.cpp
  63     kitemviews/kitemliststyleoption.cpp
  64     kitemviews/kitemlistview.cpp
  65     kitemviews/kitemlistviewaccessible.cpp
  66     kitemviews/kitemlistwidget.cpp
  67     kitemviews/kitemmodelbase.cpp
  68     kitemviews/kitemset.cpp
  69     kitemviews/kstandarditemlistgroupheader.cpp
  70     kitemviews/kstandarditemlistwidget.cpp
  71     kitemviews/kstandarditemlistview.cpp
  72     kitemviews/private/kdirectorycontentscounter.cpp
  73     kitemviews/private/kdirectorycontentscounterworker.cpp
  74     kitemviews/private/kfileitemclipboard.cpp
  75     kitemviews/private/kfileitemmodelfilter.cpp
  76     kitemviews/private/kitemlistheaderwidget.cpp
  77     kitemviews/private/kitemlistkeyboardsearchmanager.cpp
  78     kitemviews/private/kitemlistroleeditor.cpp
  79     kitemviews/private/kitemlistrubberband.cpp
  80     kitemviews/private/kitemlistselectiontoggle.cpp
  81     kitemviews/private/kitemlistsizehintresolver.cpp
  82     kitemviews/private/kitemlistsmoothscroller.cpp
  83     kitemviews/private/kitemlistviewanimation.cpp
  84     kitemviews/private/kitemlistviewlayouter.cpp
  85     kitemviews/private/kpixmapmodifier.cpp
  86     settings/applyviewpropsjob.cpp
  87     settings/viewmodes/viewmodesettings.cpp
  88     settings/viewpropertiesdialog.cpp
  89     settings/viewpropsprogressinfo.cpp
  90     selectionmode/actiontexthelper.cpp
  91     views/dolphinfileitemlistwidget.cpp
  92     views/dolphinitemlistview.cpp
  93     views/dolphinnewfilemenuobserver.cpp
  94     views/dolphinremoteencoding.cpp
  95     views/dolphinview.cpp
  96     views/dolphinviewactionhandler.cpp
  97     views/draganddrophelper.cpp
  98     views/versioncontrol/updateitemstatesthread.cpp
  99     views/versioncontrol/versioncontrolobserver.cpp
 100     views/viewmodecontroller.cpp
 101     views/viewproperties.cpp
 102     views/zoomlevelinfo.cpp
 103     dolphinremoveaction.cpp
 104     middleclickactioneventfilter.cpp
 105     dolphinnewfilemenu.cpp
 106
 107     kitemviews/kfileitemlistview.h
 108     kitemviews/kfileitemlistwidget.h
 109     kitemviews/kfileitemlisttostring.h
 110     kitemviews/kfileitemmodel.h
 111     kitemviews/kfileitemmodelrolesupdater.h
 112     kitemviews/kitemlistcontainer.h
 113     kitemviews/kitemlistcontroller.h
 114     kitemviews/kitemlistgroupheader.h
 115     kitemviews/kitemlistheader.h
 116     kitemviews/kitemlistselectionmanager.h
 117     kitemviews/kitemliststyleoption.h
 118     kitemviews/kitemlistview.h
 119     kitemviews/kitemlistviewaccessible.h
 120     kitemviews/kitemlistwidget.h
 121     kitemviews/kitemmodelbase.h
 122     kitemviews/kitemset.h
 123     kitemviews/kstandarditemlistgroupheader.h
 124     kitemviews/kstandarditemlistwidget.h
 125     kitemviews/kstandarditemlistview.h
 126     kitemviews/private/kdirectorycontentscounter.h
 127     kitemviews/private/kdirectorycontentscounterworker.h
 128     kitemviews/private/kfileitemclipboard.h
 129     kitemviews/private/kfileitemmodelfilter.h
 130     kitemviews/private/kitemlistheaderwidget.h
 131     kitemviews/private/kitemlistkeyboardsearchmanager.h
 132     kitemviews/private/kitemlistroleeditor.h
 133     kitemviews/private/kitemlistrubberband.h
 134     kitemviews/private/kitemlistselectiontoggle.h
 135     kitemviews/private/kitemlistsizehintresolver.h
 136     kitemviews/private/kitemlistsmoothscroller.h
 137     kitemviews/private/kitemlistviewanimation.h
 138     kitemviews/private/kitemlistviewlayouter.h
 139     kitemviews/private/kpixmapmodifier.h
 140     settings/applyviewpropsjob.h
 141     settings/viewmodes/viewmodesettings.h
 142     settings/viewpropertiesdialog.h
 143     settings/viewpropsprogressinfo.h
 144     selectionmode/actiontexthelper.h
 145     views/dolphinfileitemlistwidget.h
 146     views/dolphinitemlistview.h
 147     views/dolphinnewfilemenuobserver.h
 148     views/dolphinremoteencoding.h
 149     views/dolphinview.h
 150     views/dolphinviewactionhandler.h
 151     views/draganddrophelper.h
 152     views/versioncontrol/updateitemstatesthread.h
 153     views/versioncontrol/versioncontrolobserver.h
 154     views/viewmodecontroller.h
 155     views/viewproperties.h
 156     views/zoomlevelinfo.h
 157     dolphinremoveaction.h
 158     middleclickactioneventfilter.h
 159     dolphinnewfilemenu.h
 160 )
 161
 162 ecm_qt_declare_logging_category(dolphinprivate
 163     HEADER dolphindebug.h
 164     IDENTIFIER DolphinDebug
 165     CATEGORY_NAME org.kde.dolphin
 166     DESCRIPTION "dolphin"
 167     EXPORT DOLPHIN
 168 )
 169
 170 if(HAVE_BALOO)
 171     target_sources(dolphinprivate PRIVATE
 172         views/tooltips/dolphinfilemetadatawidget.cpp
 173         views/tooltips/tooltipmanager.cpp
 174         kitemviews/private/kbaloorolesprovider.cpp
 175         views/tooltips/dolphinfilemetadatawidget.h
 176         views/tooltips/tooltipmanager.h
 177         kitemviews/private/kbaloorolesprovider.h
 178     )
 179 endif()
 180
 181 kconfig_add_kcfg_files(dolphinprivate
 182     settings/dolphin_compactmodesettings.kcfgc
 183     settings/dolphin_directoryviewpropertysettings.kcfgc
 184     settings/dolphin_detailsmodesettings.kcfgc
 185     settings/dolphin_iconsmodesettings.kcfgc
 186     settings/dolphin_generalsettings.kcfgc
 187     settings/dolphin_contextmenusettings.kcfgc
 188     settings/dolphin_versioncontrolsettings.kcfgc
 189 )
 190
 191 generate_export_header(dolphinprivate BASE_NAME dolphin)
 192
 193 target_link_libraries(
 194     dolphinprivate PUBLIC
 195     dolphinvcs
 196     Qt${QT_MAJOR_VERSION}::Concurrent
 197     Qt${QT_MAJOR_VERSION}::Gui
 198     KF5::I18n
 199     KF5::IconThemes
 200     KF5::KIOCore
 201     KF5::KIOWidgets
 202     KF5::KIOFileWidgets
 203     KF5::Completion
 204     KF5::TextWidgets
 205     KF5::ConfigCore
 206     KF5::NewStuff
 207     KF5::NewStuffWidgets    # KNSWidgets::Button
 208     KF5::Parts
 209     KF5::WindowSystem
 210     KF5::WidgetsAddons
 211 )
 212
 213 if(HAVE_BALOO)
 214     target_link_libraries(
 215         dolphinprivate PUBLIC
 216         KF5::FileMetaData
 217         KF5::Baloo
 218         KF5::BalooWidgets
 219     )
 220 endif()
 221
 222 set_target_properties(dolphinprivate PROPERTIES
 223     VERSION ${DOLPHINPRIVATE_VERSION}
 224     SOVERSION ${DOLPHINPRIVATE_SOVERSION}
 225 )
 226
 227 install(TARGETS dolphinprivate ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} LIBRARY NAMELINK_SKIP)
 228 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphin_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
 229
 230 ##########################################
 231 configure_file(dolphinpart.json.in ${CMAKE_CURRENT_BINARY_DIR}/dolphinpart.json @ONLY)
 232
 233 add_library(dolphinpart MODULE)
 234
 235 target_sources(dolphinpart PRIVATE
 236     dolphinpart.cpp
 237     dolphinpart_ext.cpp
 238     dolphindebug.cpp
 239     dolphinpart.h
 240     dolphinpart_ext.h
 241     dolphindebug.h
 242
 243     dolphinpart.qrc
 244 )
 245
 246 target_link_libraries(dolphinpart
 247     dolphinprivate
 248 )
 249
 250 install(TARGETS dolphinpart DESTINATION ${KDE_INSTALL_PLUGINDIR}/kf${QT_MAJOR_VERSION}/parts)
 251 install(FILES dolphinpartactions.desktop DESTINATION "${KDE_INSTALL_DATADIR}/dolphin/")
 252
 253 ##########################################
 254
 255 add_library(dolphinstatic STATIC)
 256
 257 target_sources(dolphinstatic PRIVATE
 258     dolphinbookmarkhandler.cpp
 259     dolphindockwidget.cpp
 260     dolphinmainwindow.cpp
 261     dolphinviewcontainer.cpp
 262     dolphincontextmenu.cpp
 263     dolphinnavigatorswidgetaction.cpp
 264     dolphintabbar.cpp
 265     dolphinplacesmodelsingleton.cpp
 266     dolphinrecenttabsmenu.cpp
 267     dolphintabpage.cpp
 268     dolphintabwidget.cpp
 269     dolphinurlnavigator.cpp
 270     dolphinurlnavigatorscontroller.cpp
 271     trash/dolphintrash.cpp
 272     filterbar/filterbar.cpp
 273     kitemviews/kfileitemlisttostring.cpp
 274     panels/places/placespanel.cpp
 275     panels/panel.cpp
 276     panels/folders/foldersitemlistwidget.cpp
 277     panels/folders/treeviewcontextmenu.cpp
 278     panels/folders/folderspanel.cpp
 279     panels/terminal/terminalpanel.cpp
 280     search/dolphinfacetswidget.cpp
 281     search/dolphinquery.cpp
 282     search/dolphinsearchbox.cpp
 283     selectionmode/actiontexthelper.cpp
 284     selectionmode/actionwithwidget.cpp
 285     selectionmode/backgroundcolorhelper.cpp
 286     selectionmode/bottombar.cpp
 287     selectionmode/bottombarcontentscontainer.cpp
 288     selectionmode/topbar.cpp
 289     settings/general/behaviorsettingspage.cpp
 290     settings/general/configurepreviewplugindialog.cpp
 291     settings/general/confirmationssettingspage.cpp
 292     settings/general/generalsettingspage.cpp
 293     settings/general/previewssettingspage.cpp
 294     settings/general/statusbarsettingspage.cpp
 295     settings/dolphinsettingsdialog.cpp
 296     settings/navigation/navigationsettingspage.cpp
 297     settings/contextmenu/contextmenusettingspage.cpp
 298     settings/settingspagebase.cpp
 299     settings/serviceitemdelegate.cpp
 300     settings/servicemodel.cpp
 301     settings/startup/startupsettingspage.cpp
 302     settings/trash/trashsettingspage.cpp
 303     settings/viewmodes/dolphinfontrequester.cpp
 304     settings/viewmodes/viewsettingspage.cpp
 305     settings/viewmodes/viewmodesettings.cpp
 306     settings/viewmodes/viewsettingstab.cpp
 307     statusbar/dolphinstatusbar.cpp
 308     statusbar/mountpointobserver.cpp
 309     statusbar/mountpointobservercache.cpp
 310     statusbar/spaceinfoobserver.cpp
 311     statusbar/statusbarspaceinfo.cpp
 312     views/zoomlevelinfo.cpp
 313     dolphindebug.cpp
 314     global.cpp
 315     dolphin.qrc
 316
 317     dolphinbookmarkhandler.h
 318     dolphindockwidget.h
 319     dolphinmainwindow.h
 320     dolphinviewcontainer.h
 321     dolphincontextmenu.h
 322     dolphinnavigatorswidgetaction.h
 323     dolphintabbar.h
 324     dolphinplacesmodelsingleton.h
 325     dolphinrecenttabsmenu.h
 326     dolphintabpage.h
 327     dolphintabwidget.h
 328     dolphinurlnavigator.h
 329     dolphinurlnavigatorscontroller.h
 330     trash/dolphintrash.h
 331     filterbar/filterbar.h
 332     kitemviews/kfileitemlisttostring.h
 333     panels/places/placespanel.h
 334     panels/panel.h
 335     panels/folders/foldersitemlistwidget.h
 336     panels/folders/treeviewcontextmenu.h
 337     panels/folders/folderspanel.h
 338     panels/terminal/terminalpanel.h
 339     search/dolphinfacetswidget.h
 340     search/dolphinquery.h
 341     search/dolphinsearchbox.h
 342     selectionmode/actiontexthelper.h
 343     selectionmode/actionwithwidget.h
 344     selectionmode/backgroundcolorhelper.h
 345     selectionmode/bottombar.h
 346     selectionmode/bottombarcontentscontainer.h
 347     selectionmode/topbar.h
 348     settings/general/behaviorsettingspage.h
 349     settings/general/configurepreviewplugindialog.h
 350     settings/general/confirmationssettingspage.h
 351     settings/general/generalsettingspage.h
 352     settings/general/previewssettingspage.h
 353     settings/general/statusbarsettingspage.h
 354     settings/dolphinsettingsdialog.h
 355     settings/navigation/navigationsettingspage.h
 356     settings/contextmenu/contextmenusettingspage.h
 357     settings/settingspagebase.h
 358     settings/serviceitemdelegate.h
 359     settings/servicemodel.h
 360     settings/startup/startupsettingspage.h
 361     settings/trash/trashsettingspage.h
 362     settings/viewmodes/dolphinfontrequester.h
 363     settings/viewmodes/viewsettingspage.h
 364     settings/viewmodes/viewmodesettings.h
 365     settings/viewmodes/viewsettingstab.h
 366     statusbar/dolphinstatusbar.h
 367     statusbar/mountpointobserver.h
 368     statusbar/mountpointobservercache.h
 369     statusbar/spaceinfoobserver.h
 370     statusbar/statusbarspaceinfo.h
 371     views/zoomlevelinfo.h
 372     dolphindebug.h
 373     global.h
 374 )
 375
 376 if(HAVE_BALOO)
 377     target_sources(dolphinstatic PRIVATE
 378         panels/information/informationpanel.cpp
 379         panels/information/informationpanelcontent.cpp
 380         panels/information/pixmapviewer.cpp
 381         panels/information/phononwidget.cpp
 382         panels/information/informationpanel.h
 383         panels/information/informationpanelcontent.h
 384         panels/information/pixmapviewer.h
 385         panels/information/phononwidget.h
 386     )
 387 endif()
 388
 389 if(HAVE_KUSERFEEDBACK)
 390     target_sources(dolphinstatic PRIVATE
 391         userfeedback/dolphinfeedbackprovider.cpp
 392         userfeedback/settingsdatasource.cpp
 393         userfeedback/placesdatasource.cpp
 394         settings/userfeedback/userfeedbacksettingspage.cpp
 395         userfeedback/dolphinfeedbackprovider.h
 396         userfeedback/settingsdatasource.h
 397         userfeedback/placesdatasource.h
 398         settings/userfeedback/userfeedbacksettingspage.h
 399     )
 400 endif()
 401
 402 kconfig_add_kcfg_files(dolphinstatic
 403     panels/folders/dolphin_folderspanelsettings.kcfgc
 404     panels/information/dolphin_informationpanelsettings.kcfgc
 405     panels/places/dolphin_placespanelsettings.kcfgc
 406     settings/dolphin_compactmodesettings.kcfgc
 407     settings/dolphin_detailsmodesettings.kcfgc
 408     settings/dolphin_contextmenusettings.kcfgc
 409     settings/dolphin_iconsmodesettings.kcfgc
 410     search/dolphin_searchsettings.kcfgc
 411     settings/dolphin_versioncontrolsettings.kcfgc
 412 )
 413 kconfig_add_kcfg_files(dolphinstatic GENERATE_MOC
 414     settings/dolphin_generalsettings.kcfgc
 415 )
 416
 417 qt_generate_dbus_interface(${CMAKE_CURRENT_SOURCE_DIR}/dolphinmainwindow.h org.kde.DolphinMainWindow.xml)
 418 qt_add_dbus_adaptor(dolphin_dbus_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindow.h DolphinMainWindow)
 419 qt_add_dbus_interface(dolphin_dbus_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindowinterface)
 420 qt_add_dbus_interface(dolphin_dbus_SRCS panels/terminal/org.kde.KIOFuse.VFS.xml kiofuse_interface)
 421
 422 target_sources(dolphinstatic PRIVATE
 423     ${dolphin_dbus_SRCS}
 424 )
 425
 426 target_include_directories(dolphinstatic SYSTEM PRIVATE ${PHONON_INCLUDES})
 427 target_link_libraries(dolphinstatic
 428     dolphinprivate
 429     KF5::CoreAddons
 430     KF5::KCMUtils
 431     KF5::DBusAddons
 432     KF5::Notifications
 433     Phonon::phonon4qt${QT_MAJOR_VERSION}
 434 )
 435
 436 if (HAVE_KACTIVITIES)
 437     target_link_libraries(
 438         dolphinstatic
 439         KF5::Activities
 440     )
 441 endif()
 442
 443 if (HAVE_KUSERFEEDBACK)
 444     target_link_libraries(
 445         dolphinstatic
 446         KUserFeedbackCore
 447         KUserFeedbackWidgets
 448     )
 449 endif()
 450
 451 add_executable(dolphin)
 452
 453 target_sources(dolphin PRIVATE
 454     dbusinterface.cpp
 455     dbusinterface.h
 456     main.cpp
 457 )
 458
 459 if(FLATPAK)
 460     target_compile_definitions(dolphin PRIVATE FLATPAK)
 461 endif()
 462
 463 # Sets the icon on Windows and OSX
 464 file(GLOB ICONS_SRCS "${CMAKE_CURRENT_SOURCE_DIR}/icons/*system-file-manager.png")
 465 ecm_add_app_icon(dolphin ICONS ${ICONS_SRCS})
 466
 467 target_link_libraries(dolphin
 468     PRIVATE
 469     dolphinprivate
 470     dolphinstatic
 471     KF5::Crash
 472 )
 473
 474 include(DbusInterfaceMacros)
 475
 476 generate_and_install_dbus_interface(
 477     dolphin
 478     dbusinterface.h
 479     org.freedesktop.FileManager1.xml
 480     OPTIONS -a
 481 )
 482
 483 install(TARGETS dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 484
 485 ##########################################
 486
 487 if(NOT WIN32)
 488     # The settings are still accessible from the hamburger menu
 489     add_library(kcm_dolphinviewmodes MODULE)
 490     add_library(kcm_dolphinnavigation MODULE)
 491     add_library(kcm_dolphingeneral MODULE)
 492
 493     target_sources(kcm_dolphinviewmodes PRIVATE
 494         settings/kcm/kcmdolphinviewmodes.cpp
 495         settings/viewmodes/dolphinfontrequester.cpp
 496         settings/viewmodes/viewmodesettings.cpp
 497         settings/viewmodes/viewsettingstab.cpp
 498         views/zoomlevelinfo.cpp
 499         settings/kcm/kcmdolphinviewmodes.h
 500         settings/viewmodes/dolphinfontrequester.h
 501         settings/viewmodes/viewmodesettings.h
 502         settings/viewmodes/viewsettingstab.h
 503         views/zoomlevelinfo.h)
 504
 505     target_sources(kcm_dolphinnavigation PRIVATE
 506         settings/kcm/kcmdolphinnavigation.cpp
 507         settings/navigation/navigationsettingspage.cpp
 508         settings/settingspagebase.cpp
 509         settings/kcm/kcmdolphinnavigation.h
 510         settings/navigation/navigationsettingspage.h
 511         settings/settingspagebase.h
 512     )
 513
 514     target_sources(kcm_dolphingeneral PRIVATE
 515         settings/kcm/kcmdolphingeneral.cpp
 516         settings/general/behaviorsettingspage.cpp
 517         settings/general/previewssettingspage.cpp
 518         settings/general/configurepreviewplugindialog.cpp
 519         settings/general/confirmationssettingspage.cpp
 520         settings/settingspagebase.cpp
 521         settings/serviceitemdelegate.cpp
 522         settings/servicemodel.cpp
 523         settings/kcm/kcmdolphingeneral.h
 524         settings/general/behaviorsettingspage.h
 525         settings/general/previewssettingspage.h
 526         settings/general/configurepreviewplugindialog.h
 527         settings/general/confirmationssettingspage.h
 528         settings/settingspagebase.h
 529         settings/serviceitemdelegate.h
 530         settings/servicemodel.h
 531     )
 532
 533     kconfig_add_kcfg_files(kcm_dolphinviewmodes
 534         settings/dolphin_compactmodesettings.kcfgc
 535         settings/dolphin_directoryviewpropertysettings.kcfgc
 536         settings/dolphin_detailsmodesettings.kcfgc
 537         settings/dolphin_iconsmodesettings.kcfgc
 538         settings/dolphin_generalsettings.kcfgc
 539         settings/dolphin_versioncontrolsettings.kcfgc
 540     )
 541
 542     kconfig_add_kcfg_files(kcm_dolphinnavigation
 543         settings/dolphin_generalsettings.kcfgc)
 544
 545     kconfig_add_kcfg_files(kcm_dolphingeneral
 546         settings/dolphin_generalsettings.kcfgc)
 547
 548     target_link_libraries(kcm_dolphinviewmodes dolphinprivate)
 549     target_link_libraries(kcm_dolphinnavigation dolphinprivate)
 550     target_link_libraries(kcm_dolphingeneral dolphinprivate)
 551
 552     install( FILES org.kde.dolphin.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR} )
 553
 554     install(TARGETS kcm_dolphinviewmodes DESTINATION ${KDE_INSTALL_PLUGINDIR}/dolphin/kcms )
 555     install(TARGETS kcm_dolphinnavigation DESTINATION ${KDE_INSTALL_PLUGINDIR}/dolphin/kcms )
 556     install(TARGETS kcm_dolphingeneral DESTINATION ${KDE_INSTALL_PLUGINDIR}/dolphin/kcms )
 557 endif()
 558
 559 if(NOT WIN32)
 560     add_subdirectory(settings/contextmenu/servicemenuinstaller)
 561     install( FILES settings/contextmenu/servicemenu.knsrc DESTINATION ${KDE_INSTALL_KNSRCDIR} )
 562 endif()
 563
 564 ########### install files ###############
 565
 566 install( PROGRAMS org.kde.dolphin.desktop DESTINATION ${KDE_INSTALL_APPDIR} )
 567
 568 install( DIRECTORY DESTINATION "${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel" )
 569
 570 install(
 571     CODE "execute_process(COMMAND \"${CMAKE_COMMAND}\" -E create_symlink \"${KDE_INSTALL_FULL_APPDIR}/org.kde.dolphin.desktop\" \"\$ENV{DESTDIR}${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel/org.kde.dolphin.desktop\")"
 572 )
 573
 574 install( FILES settings/dolphin_directoryviewpropertysettings.kcfg
 575                settings/dolphin_generalsettings.kcfg
 576                settings/dolphin_contextmenusettings.kcfg
 577                settings/dolphin_compactmodesettings.kcfg
 578                settings/dolphin_iconsmodesettings.kcfg
 579                settings/dolphin_detailsmodesettings.kcfg
 580                settings/dolphin_versioncontrolsettings.kcfg
 581          DESTINATION ${KDE_INSTALL_KCFGDIR} )
 582
 583 install( FILES settings/dolphin_detailsmodesettings.upd
 584          DESTINATION ${KDE_INSTALL_KCONFUPDATEDIR} )
 585
 586 if(BUILD_TESTING)
 587     add_subdirectory(tests)
 588 endif()