src/CMakeLists.txt

   1 include(ECMAddAppIcon)
   2
   3 configure_file(config-baloo.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-baloo.h)
   4
   5 configure_file(config-dolphin.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-dolphin.h)
   6
   7 add_definitions(
   8     -DTRANSLATION_DOMAIN=\"dolphin\"
   9     -DQT_USE_FAST_CONCATENATION
  10     -DQT_USE_FAST_OPERATOR_PLUS
  11 )
  12 remove_definitions(
  13     -DQT_NO_CAST_FROM_BYTEARRAY
  14     -DQT_NO_URL_CAST_FROM_STRING
  15     -DQT_NO_SIGNALS_SLOTS_KEYWORDS
  16     -DQT_NO_CAST_FROM_ASCII
  17     -DQT_NO_CAST_TO_ASCII
  18 )
  19
  20 ##########################################
  21
  22 set(dolphinvcs_LIB_SRCS
  23     views/versioncontrol/kversioncontrolplugin.cpp
  24 )
  25
  26 add_library(dolphinvcs ${dolphinvcs_LIB_SRCS})
  27 generate_export_header(dolphinvcs BASE_NAME dolphinvcs)
  28
  29 target_link_libraries(
  30     dolphinvcs PUBLIC
  31     Qt5::Widgets
  32 )
  33
  34 set_target_properties(dolphinvcs PROPERTIES
  35     VERSION ${DOLPHINVCS_VERSION_STRING}
  36     SOVERSION ${DOLPHINVCS_SOVERSION}
  37     EXPORT_NAME DolphinVcs
  38 )
  39
  40 ecm_generate_headers(dolphinvcs_LIB_HEADERS
  41     HEADER_NAMES
  42     KVersionControlPlugin
  43
  44     RELATIVE "views/versioncontrol"
  45     REQUIRED_HEADERS dolphinvcs_LIB_HEADERS
  46 )
  47
  48 install(TARGETS dolphinvcs EXPORT DolphinVcsTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
  49
  50 install(FILES views/versioncontrol/fileviewversioncontrolplugin.desktop DESTINATION ${KDE_INSTALL_KSERVICETYPES5DIR})
  51 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphinvcs_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
  52 install(FILES ${dolphinvcs_LIB_HEADERS} DESTINATION "${KDE_INSTALL_INCLUDEDIR}/Dolphin" COMPONENT Devel)
  53
  54 ########### next target ###############
  55
  56 set(dolphinprivate_LIB_SRCS
  57     kitemviews/kfileitemlistview.cpp
  58     kitemviews/kfileitemlistwidget.cpp
  59     kitemviews/kfileitemmodel.cpp
  60     kitemviews/kfileitemmodelrolesupdater.cpp
  61     kitemviews/kitemlistcontainer.cpp
  62     kitemviews/kitemlistcontroller.cpp
  63     kitemviews/kitemlistgroupheader.cpp
  64     kitemviews/kitemlistheader.cpp
  65     kitemviews/kitemlistselectionmanager.cpp
  66     kitemviews/kitemliststyleoption.cpp
  67     kitemviews/kitemlistview.cpp
  68     kitemviews/kitemlistviewaccessible.cpp
  69     kitemviews/kitemlistwidget.cpp
  70     kitemviews/kitemmodelbase.cpp
  71     kitemviews/kitemset.cpp
  72     kitemviews/kstandarditem.cpp
  73     kitemviews/kstandarditemlistgroupheader.cpp
  74     kitemviews/kstandarditemlistwidget.cpp
  75     kitemviews/kstandarditemlistview.cpp
  76     kitemviews/kstandarditemmodel.cpp
  77     kitemviews/private/kdirectorycontentscounter.cpp
  78     kitemviews/private/kdirectorycontentscounterworker.cpp
  79     kitemviews/private/kfileitemclipboard.cpp
  80     kitemviews/private/kfileitemmodeldirlister.cpp
  81     kitemviews/private/kfileitemmodelfilter.cpp
  82     kitemviews/private/kitemlistheaderwidget.cpp
  83     kitemviews/private/kitemlistkeyboardsearchmanager.cpp
  84     kitemviews/private/kitemlistroleeditor.cpp
  85     kitemviews/private/kitemlistrubberband.cpp
  86     kitemviews/private/kitemlistselectiontoggle.cpp
  87     kitemviews/private/kitemlistsizehintresolver.cpp
  88     kitemviews/private/kitemlistsmoothscroller.cpp
  89     kitemviews/private/kitemlistviewanimation.cpp
  90     kitemviews/private/kitemlistviewlayouter.cpp
  91     kitemviews/private/kpixmapmodifier.cpp
  92     settings/additionalinfodialog.cpp
  93     settings/applyviewpropsjob.cpp
  94     settings/viewmodes/viewmodesettings.cpp
  95     settings/viewpropertiesdialog.cpp
  96     settings/viewpropsprogressinfo.cpp
  97     views/dolphinfileitemlistwidget.cpp
  98     views/dolphinitemlistview.cpp
  99     views/dolphinnewfilemenuobserver.cpp
 100     views/dolphinremoteencoding.cpp
 101     views/dolphinview.cpp
 102     views/dolphinviewactionhandler.cpp
 103     views/draganddrophelper.cpp
 104     views/renamedialog.cpp
 105     views/tooltips/filemetadatatooltip.cpp
 106     views/tooltips/tooltipmanager.cpp
 107     views/versioncontrol/updateitemstatesthread.cpp
 108     views/versioncontrol/versioncontrolobserver.cpp
 109     views/viewmodecontroller.cpp
 110     views/viewproperties.cpp
 111     views/zoomlevelinfo.cpp
 112     dolphinremoveaction.cpp
 113     dolphinnewfilemenu.cpp
 114     dolphindebug.cpp
 115 )
 116
 117 if(HAVE_BALOO)
 118     set(dolphinprivate_LIB_SRCS
 119         ${dolphinprivate_LIB_SRCS}
 120         kitemviews/private/kbaloorolesprovider.cpp
 121     )
 122 endif()
 123
 124 kconfig_add_kcfg_files(dolphinprivate_LIB_SRCS GENERATE_MOC
 125     settings/dolphin_compactmodesettings.kcfgc
 126     settings/dolphin_directoryviewpropertysettings.kcfgc
 127     settings/dolphin_detailsmodesettings.kcfgc
 128     settings/dolphin_iconsmodesettings.kcfgc
 129     settings/dolphin_generalsettings.kcfgc
 130     settings/dolphin_versioncontrolsettings.kcfgc
 131 )
 132
 133 add_library(dolphinprivate ${dolphinprivate_LIB_SRCS})
 134 generate_export_header(dolphinprivate BASE_NAME dolphin)
 135
 136 target_link_libraries(
 137     dolphinprivate PUBLIC
 138     dolphinvcs
 139     Qt5::Gui
 140     KF5::Crash
 141     KF5::I18n
 142     KF5::IconThemes
 143     KF5::KIOCore
 144     KF5::KIOWidgets
 145     KF5::KIOFileWidgets
 146     KF5::Completion
 147     KF5::TextWidgets
 148     KF5::WindowSystem
 149     KF5::ConfigCore
 150     KF5::NewStuff
 151     KF5::Parts
 152 )
 153
 154 if(HAVE_BALOO)
 155     target_link_libraries(
 156         dolphinprivate PUBLIC
 157         KF5::FileMetaData
 158         KF5::Baloo
 159         KF5::BalooWidgets
 160     )
 161 else()
 162     target_link_libraries(
 163         dolphinprivate PUBLIC
 164         KF5::KDELibs4Support # for KFileMetaDataWidget
 165     )
 166 endif()
 167
 168 set_target_properties(dolphinprivate PROPERTIES
 169     VERSION ${DOLPHINPRIVATE_VERSION_STRING}
 170     SOVERSION ${DOLPHINPRIVATE_SOVERSION}
 171 )
 172
 173 install(TARGETS dolphinprivate ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} LIBRARY NAMELINK_SKIP)
 174 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphin_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
 175
 176 ##########################################
 177
 178 set(dolphinpart_SRCS
 179    dolphinpart.cpp
 180    dolphinpart_ext.cpp
 181    dolphindebug.cpp
 182 )
 183
 184 add_library(dolphinpart MODULE ${dolphinpart_SRCS})
 185
 186 target_link_libraries(dolphinpart
 187     dolphinprivate
 188 )
 189
 190 install(TARGETS dolphinpart DESTINATION ${KDE_INSTALL_PLUGINDIR})
 191
 192 install(FILES dolphinpart.rc DESTINATION ${KDE_INSTALL_KXMLGUI5DIR}/dolphinpart)
 193 install(FILES dolphinpart.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR})
 194
 195 ##########################################
 196
 197 set(dolphin_SRCS
 198     dolphindockwidget.cpp
 199     dolphinmainwindow.cpp
 200     dolphinviewcontainer.cpp
 201     dolphincontextmenu.cpp
 202     dolphintabbar.cpp
 203     dolphinrecenttabsmenu.cpp
 204     dolphintabpage.cpp
 205     dolphintabwidget.cpp
 206     filterbar/filterbar.cpp
 207     main.cpp
 208     panels/information/filemetadataconfigurationdialog.cpp
 209     panels/information/informationpanel.cpp
 210     panels/information/informationpanelcontent.cpp
 211     panels/information/pixmapviewer.cpp
 212     panels/information/phononwidget.cpp
 213     panels/places/placespanel.cpp
 214     panels/places/placesitem.cpp
 215     panels/places/placesitemeditdialog.cpp
 216     panels/places/placesitemlistgroupheader.cpp
 217     panels/places/placesitemlistwidget.cpp
 218     panels/places/placesitemmodel.cpp
 219     panels/places/placesitemsignalhandler.cpp
 220     panels/places/placesview.cpp
 221     panels/panel.cpp
 222     panels/folders/foldersitemlistwidget.cpp
 223     panels/folders/treeviewcontextmenu.cpp
 224     panels/folders/folderspanel.cpp
 225     search/dolphinfacetswidget.cpp
 226     search/dolphinsearchbox.cpp
 227     settings/general/behaviorsettingspage.cpp
 228     settings/general/configurepreviewplugindialog.cpp
 229     settings/general/confirmationssettingspage.cpp
 230     settings/general/generalsettingspage.cpp
 231     settings/general/previewssettingspage.cpp
 232     settings/general/statusbarsettingspage.cpp
 233     settings/dolphinsettingsdialog.cpp
 234     settings/navigation/navigationsettingspage.cpp
 235     settings/services/servicessettingspage.cpp
 236     settings/settingspagebase.cpp
 237     settings/serviceitemdelegate.cpp
 238     settings/servicemodel.cpp
 239     settings/startup/startupsettingspage.cpp
 240     settings/trash/trashsettingspage.cpp
 241     settings/viewmodes/dolphinfontrequester.cpp
 242     settings/viewmodes/viewsettingspage.cpp
 243     settings/viewmodes/viewmodesettings.cpp
 244     settings/viewmodes/viewsettingstab.cpp
 245     statusbar/dolphinstatusbar.cpp
 246     statusbar/mountpointobserver.cpp
 247     statusbar/mountpointobservercache.cpp
 248     statusbar/spaceinfoobserver.cpp
 249     statusbar/statusbarspaceinfo.cpp
 250     views/zoomlevelinfo.cpp
 251     dolphindebug.cpp
 252     dbusinterface.cpp
 253     global.cpp
 254 )
 255
 256 kconfig_add_kcfg_files(dolphin_SRCS GENERATE_MOC
 257     panels/folders/dolphin_folderspanelsettings.kcfgc
 258     panels/information/dolphin_informationpanelsettings.kcfgc
 259     panels/places/dolphin_placespanelsettings.kcfgc
 260     settings/dolphin_compactmodesettings.kcfgc
 261     settings/dolphin_detailsmodesettings.kcfgc
 262     settings/dolphin_generalsettings.kcfgc
 263     settings/dolphin_iconsmodesettings.kcfgc
 264     search/dolphin_searchsettings.kcfgc
 265     settings/dolphin_versioncontrolsettings.kcfgc
 266 )
 267
 268 if(NOT WIN32)
 269    set(dolphin_SRCS ${dolphin_SRCS} panels/terminal/terminalpanel.cpp)
 270 endif()
 271
 272 # Sets the icon on Windows and OSX
 273 file(GLOB ICONS_SRCS "${CMAKE_CURRENT_SOURCE_DIR}/icons/*system-file-manager.png")
 274 ecm_add_app_icon(dolphin_SRCS ICONS ${ICONS_SRCS})
 275
 276 kf5_add_kdeinit_executable(dolphin ${dolphin_SRCS})
 277
 278 target_include_directories(kdeinit_dolphin PRIVATE ${PHONON_INCLUDES})
 279
 280 target_link_libraries(kdeinit_dolphin
 281     dolphinprivate
 282     KF5::Parts
 283     KF5::KCMUtils
 284     KF5::Solid
 285     KF5::CoreAddons
 286     KF5::DBusAddons
 287     KF5::Bookmarks
 288     KF5::Notifications
 289     Phonon::phonon4qt5
 290 )
 291
 292 if (KF5Activities_FOUND)
 293     target_link_libraries(
 294         kdeinit_dolphin
 295         KF5::Activities
 296     )
 297 endif()
 298
 299 include(DbusInterfaceMacros)
 300
 301 generate_and_install_dbus_interface(
 302     kdeinit_dolphin
 303     dbusinterface.h
 304     org.freedesktop.FileManager1.xml
 305     OPTIONS -a
 306 )
 307
 308 install(TARGETS kdeinit_dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 309 install(TARGETS dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 310
 311 ##########################################
 312
 313 set(kcm_dolphinviewmodes_PART_SRCS
 314     settings/kcm/kcmdolphinviewmodes.cpp
 315     settings/viewmodes/dolphinfontrequester.cpp
 316     settings/viewmodes/viewmodesettings.cpp
 317     settings/viewmodes/viewsettingstab.cpp
 318     views/zoomlevelinfo.cpp)
 319
 320 set(kcm_dolphinnavigation_PART_SRCS
 321     settings/kcm/kcmdolphinnavigation.cpp
 322     settings/navigation/navigationsettingspage.cpp
 323     settings/settingspagebase.cpp)
 324
 325 set(kcm_dolphinservices_PART_SRCS
 326     settings/kcm/kcmdolphinservices.cpp
 327     settings/services/servicessettingspage.cpp
 328     settings/settingspagebase.cpp
 329     settings/serviceitemdelegate.cpp
 330     settings/servicemodel.cpp)
 331
 332 set(kcm_dolphingeneral_PART_SRCS
 333     settings/kcm/kcmdolphingeneral.cpp
 334     settings/general/behaviorsettingspage.cpp
 335     settings/general/previewssettingspage.cpp
 336     settings/general/configurepreviewplugindialog.cpp
 337     settings/general/confirmationssettingspage.cpp
 338     settings/settingspagebase.cpp
 339     settings/serviceitemdelegate.cpp
 340     settings/servicemodel.cpp)
 341
 342 kconfig_add_kcfg_files(kcm_dolphinviewmodes_PART_SRCS
 343     settings/dolphin_compactmodesettings.kcfgc
 344     settings/dolphin_directoryviewpropertysettings.kcfgc
 345     settings/dolphin_detailsmodesettings.kcfgc
 346     settings/dolphin_iconsmodesettings.kcfgc
 347     settings/dolphin_generalsettings.kcfgc
 348     settings/dolphin_versioncontrolsettings.kcfgc
 349 )
 350
 351 kconfig_add_kcfg_files(kcm_dolphinnavigation_PART_SRCS
 352     settings/dolphin_generalsettings.kcfgc)
 353
 354 kconfig_add_kcfg_files(kcm_dolphinservices_PART_SRCS
 355     settings/dolphin_generalsettings.kcfgc
 356     settings/dolphin_versioncontrolsettings.kcfgc)
 357
 358 kconfig_add_kcfg_files(kcm_dolphingeneral_PART_SRCS
 359     settings/dolphin_generalsettings.kcfgc)
 360
 361 add_library(kcm_dolphinviewmodes MODULE ${kcm_dolphinviewmodes_PART_SRCS})
 362 add_library(kcm_dolphinnavigation MODULE ${kcm_dolphinnavigation_PART_SRCS})
 363 add_library(kcm_dolphinservices MODULE ${kcm_dolphinservices_PART_SRCS})
 364 add_library(kcm_dolphingeneral MODULE ${kcm_dolphingeneral_PART_SRCS})
 365
 366 target_link_libraries(kcm_dolphinviewmodes dolphinprivate)
 367 target_link_libraries(kcm_dolphinnavigation dolphinprivate)
 368 target_link_libraries(kcm_dolphinservices dolphinprivate)
 369 target_link_libraries(kcm_dolphingeneral dolphinprivate)
 370
 371 install(TARGETS kcm_dolphinviewmodes DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 372 install(TARGETS kcm_dolphinnavigation DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 373 install(TARGETS kcm_dolphinservices DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 374 install(TARGETS kcm_dolphingeneral DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 375
 376 ########### install files ###############
 377
 378 install( PROGRAMS org.kde.dolphin.desktop DESTINATION ${KDE_INSTALL_APPDIR} )
 379 install( FILES settings/dolphin_directoryviewpropertysettings.kcfg
 380                settings/dolphin_generalsettings.kcfg
 381                settings/dolphin_compactmodesettings.kcfg
 382                settings/dolphin_iconsmodesettings.kcfg
 383                settings/dolphin_detailsmodesettings.kcfg
 384                settings/dolphin_versioncontrolsettings.kcfg
 385          DESTINATION ${KDE_INSTALL_KCFGDIR} )
 386 install( FILES dolphinui.rc DESTINATION ${KDE_INSTALL_KXMLGUI5DIR}/dolphin )
 387 install( FILES org.kde.dolphin.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR} )
 388 install( FILES settings/kcm/kcmdolphinviewmodes.desktop DESTINATION
 389 ${KDE_INSTALL_KSERVICES5DIR} )
 390 install( FILES settings/kcm/kcmdolphinnavigation.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 391 install( FILES settings/kcm/kcmdolphinservices.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 392 install( FILES settings/kcm/kcmdolphingeneral.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 393 install( FILES settings/services/servicemenu.knsrc DESTINATION ${KDE_INSTALL_CONFDIR} )
 394 install( PROGRAMS settings/services/servicemenuinstallation DESTINATION ${KDE_INSTALL_BINDIR} )
 395 install( PROGRAMS settings/services/servicemenudeinstallation DESTINATION ${KDE_INSTALL_BINDIR} )
 396
 397 if(BUILD_TESTING)
 398     find_package(Qt5Test ${QT_MIN_VERSION} CONFIG REQUIRED)
 399     add_subdirectory(tests)
 400 endif()