src/CMakeLists.txt

   1 include(ECMAddAppIcon)
   2
   3 configure_file(config-baloo.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-baloo.h)
   4
   5 configure_file(config-kactivities.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-kactivities.h)
   6
   7 configure_file(config-packagekit.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-packagekit.h)
   8
   9 configure_file(config-terminal.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-terminal.h)
  10
  11 add_definitions(
  12     -DTRANSLATION_DOMAIN=\"dolphin\"
  13 )
  14 remove_definitions(
  15     -DQT_NO_CAST_FROM_BYTEARRAY
  16     -DQT_NO_SIGNALS_SLOTS_KEYWORDS
  17     -DQT_NO_CAST_FROM_ASCII
  18     -DQT_NO_CAST_TO_ASCII
  19 )
  20
  21 ##########################################
  22
  23 set(dolphinvcs_LIB_SRCS
  24     views/versioncontrol/kversioncontrolplugin.cpp
  25 )
  26
  27 add_library(dolphinvcs ${dolphinvcs_LIB_SRCS})
  28 generate_export_header(dolphinvcs BASE_NAME dolphinvcs)
  29
  30 target_link_libraries(
  31     dolphinvcs PUBLIC
  32     Qt5::Widgets
  33 )
  34
  35 set_target_properties(dolphinvcs PROPERTIES
  36     VERSION ${DOLPHINVCS_VERSION_STRING}
  37     SOVERSION ${DOLPHINVCS_SOVERSION}
  38     EXPORT_NAME DolphinVcs
  39 )
  40
  41 ecm_generate_headers(dolphinvcs_LIB_HEADERS
  42     HEADER_NAMES
  43     KVersionControlPlugin
  44
  45     RELATIVE "views/versioncontrol"
  46     REQUIRED_HEADERS dolphinvcs_LIB_HEADERS
  47 )
  48
  49 install(TARGETS dolphinvcs EXPORT DolphinVcsTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
  50
  51 install(FILES views/versioncontrol/fileviewversioncontrolplugin.desktop DESTINATION ${KDE_INSTALL_KSERVICETYPES5DIR})
  52 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphinvcs_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
  53 install(FILES ${dolphinvcs_LIB_HEADERS} DESTINATION "${KDE_INSTALL_INCLUDEDIR}/Dolphin" COMPONENT Devel)
  54
  55 ########### next target ###############
  56
  57 set(dolphinprivate_LIB_SRCS
  58     kitemviews/kfileitemlistview.cpp
  59     kitemviews/kfileitemlistwidget.cpp
  60     kitemviews/kfileitemmodel.cpp
  61     kitemviews/kfileitemmodelrolesupdater.cpp
  62     kitemviews/kitemlistcontainer.cpp
  63     kitemviews/kitemlistcontroller.cpp
  64     kitemviews/kitemlistgroupheader.cpp
  65     kitemviews/kitemlistheader.cpp
  66     kitemviews/kitemlistselectionmanager.cpp
  67     kitemviews/kitemliststyleoption.cpp
  68     kitemviews/kitemlistview.cpp
  69     kitemviews/kitemlistviewaccessible.cpp
  70     kitemviews/kitemlistwidget.cpp
  71     kitemviews/kitemmodelbase.cpp
  72     kitemviews/kitemset.cpp
  73     kitemviews/kstandarditem.cpp
  74     kitemviews/kstandarditemlistgroupheader.cpp
  75     kitemviews/kstandarditemlistwidget.cpp
  76     kitemviews/kstandarditemlistview.cpp
  77     kitemviews/kstandarditemmodel.cpp
  78     kitemviews/private/kdirectorycontentscounter.cpp
  79     kitemviews/private/kdirectorycontentscounterworker.cpp
  80     kitemviews/private/kfileitemclipboard.cpp
  81     kitemviews/private/kfileitemmodeldirlister.cpp
  82     kitemviews/private/kfileitemmodelfilter.cpp
  83     kitemviews/private/kitemlistheaderwidget.cpp
  84     kitemviews/private/kitemlistkeyboardsearchmanager.cpp
  85     kitemviews/private/kitemlistroleeditor.cpp
  86     kitemviews/private/kitemlistrubberband.cpp
  87     kitemviews/private/kitemlistselectiontoggle.cpp
  88     kitemviews/private/kitemlistsizehintresolver.cpp
  89     kitemviews/private/kitemlistsmoothscroller.cpp
  90     kitemviews/private/kitemlistviewanimation.cpp
  91     kitemviews/private/kitemlistviewlayouter.cpp
  92     kitemviews/private/kpixmapmodifier.cpp
  93     kitemviews/private/ktwofingerswipe.cpp
  94     kitemviews/private/ktwofingertap.cpp
  95     settings/applyviewpropsjob.cpp
  96     settings/viewmodes/viewmodesettings.cpp
  97     settings/viewpropertiesdialog.cpp
  98     settings/viewpropsprogressinfo.cpp
  99     views/dolphinfileitemlistwidget.cpp
 100     views/dolphinitemlistview.cpp
 101     views/dolphinnewfilemenuobserver.cpp
 102     views/dolphinremoteencoding.cpp
 103     views/dolphinview.cpp
 104     views/dolphinviewactionhandler.cpp
 105     views/draganddrophelper.cpp
 106     views/versioncontrol/updateitemstatesthread.cpp
 107     views/versioncontrol/versioncontrolobserver.cpp
 108     views/viewmodecontroller.cpp
 109     views/viewproperties.cpp
 110     views/zoomlevelinfo.cpp
 111     dolphinremoveaction.cpp
 112     middleclickactioneventfilter.cpp
 113     dolphinnewfilemenu.cpp
 114 )
 115
 116 ecm_qt_declare_logging_category(dolphinprivate_LIB_SRCS HEADER dolphindebug.h IDENTIFIER DolphinDebug CATEGORY_NAME org.kde.dolphin)
 117
 118 if(HAVE_BALOO)
 119     set(dolphinprivate_LIB_SRCS
 120         ${dolphinprivate_LIB_SRCS}
 121         views/tooltips/dolphinfilemetadatawidget.cpp
 122         views/tooltips/tooltipmanager.cpp
 123         kitemviews/private/kbaloorolesprovider.cpp
 124     )
 125 endif()
 126
 127 kconfig_add_kcfg_files(dolphinprivate_LIB_SRCS GENERATE_MOC
 128     settings/dolphin_compactmodesettings.kcfgc
 129     settings/dolphin_directoryviewpropertysettings.kcfgc
 130     settings/dolphin_detailsmodesettings.kcfgc
 131     settings/dolphin_iconsmodesettings.kcfgc
 132     settings/dolphin_generalsettings.kcfgc
 133     settings/dolphin_versioncontrolsettings.kcfgc
 134 )
 135
 136 add_library(dolphinprivate ${dolphinprivate_LIB_SRCS})
 137 generate_export_header(dolphinprivate BASE_NAME dolphin)
 138
 139 target_link_libraries(
 140     dolphinprivate PUBLIC
 141     dolphinvcs
 142     Qt5::Concurrent
 143     Qt5::Gui
 144     KF5::I18n
 145     KF5::IconThemes
 146     KF5::KIOCore
 147     KF5::KIOWidgets
 148     KF5::KIOFileWidgets
 149     KF5::Completion
 150     KF5::TextWidgets
 151     KF5::ConfigCore
 152     KF5::NewStuff
 153     KF5::Parts
 154     KF5::WindowSystem
 155 )
 156
 157 if(HAVE_BALOO)
 158     target_link_libraries(
 159         dolphinprivate PUBLIC
 160         KF5::FileMetaData
 161         KF5::Baloo
 162         KF5::BalooWidgets
 163     )
 164 endif()
 165
 166 set_target_properties(dolphinprivate PROPERTIES
 167     VERSION ${DOLPHINPRIVATE_VERSION_STRING}
 168     SOVERSION ${DOLPHINPRIVATE_SOVERSION}
 169 )
 170
 171 install(TARGETS dolphinprivate ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} LIBRARY NAMELINK_SKIP)
 172 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphin_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
 173
 174 ##########################################
 175
 176 set(dolphinpart_SRCS
 177    dolphinpart.cpp
 178    dolphinpart_ext.cpp
 179    dolphindebug.cpp
 180 )
 181
 182 qt5_add_resources(dolphinpart_SRCS dolphinpart.qrc)
 183
 184 add_library(dolphinpart MODULE ${dolphinpart_SRCS})
 185
 186 target_link_libraries(dolphinpart
 187     dolphinprivate
 188 )
 189
 190 install(TARGETS dolphinpart DESTINATION ${KDE_INSTALL_PLUGINDIR})
 191
 192 install(FILES dolphinpart.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR})
 193
 194 ##########################################
 195
 196 set(dolphinstatic_SRCS
 197     dolphinbookmarkhandler.cpp
 198     dolphindockwidget.cpp
 199     dolphinmainwindow.cpp
 200     dolphinviewcontainer.cpp
 201     dolphincontextmenu.cpp
 202     dolphintabbar.cpp
 203     dolphinplacesmodelsingleton.cpp
 204     dolphinrecenttabsmenu.cpp
 205     dolphintabpage.cpp
 206     dolphintabwidget.cpp
 207     trash/dolphintrash.cpp
 208     filterbar/filterbar.cpp
 209     panels/places/placespanel.cpp
 210     panels/places/placesitem.cpp
 211     panels/places/placesitemlistgroupheader.cpp
 212     panels/places/placesitemlistwidget.cpp
 213     panels/places/placesitemmodel.cpp
 214     panels/places/placesitemsignalhandler.cpp
 215     panels/places/placesview.cpp
 216     panels/panel.cpp
 217     panels/folders/foldersitemlistwidget.cpp
 218     panels/folders/treeviewcontextmenu.cpp
 219     panels/folders/folderspanel.cpp
 220     panels/terminal/terminalpanel.cpp
 221     search/dolphinfacetswidget.cpp
 222     search/dolphinquery.cpp
 223     search/dolphinsearchbox.cpp
 224     settings/general/behaviorsettingspage.cpp
 225     settings/general/configurepreviewplugindialog.cpp
 226     settings/general/confirmationssettingspage.cpp
 227     settings/general/generalsettingspage.cpp
 228     settings/general/previewssettingspage.cpp
 229     settings/general/statusbarsettingspage.cpp
 230     settings/dolphinsettingsdialog.cpp
 231     settings/navigation/navigationsettingspage.cpp
 232     settings/services/servicessettingspage.cpp
 233     settings/settingspagebase.cpp
 234     settings/serviceitemdelegate.cpp
 235     settings/servicemodel.cpp
 236     settings/startup/startupsettingspage.cpp
 237     settings/trash/trashsettingspage.cpp
 238     settings/viewmodes/dolphinfontrequester.cpp
 239     settings/viewmodes/viewsettingspage.cpp
 240     settings/viewmodes/viewmodesettings.cpp
 241     settings/viewmodes/viewsettingstab.cpp
 242     statusbar/dolphinstatusbar.cpp
 243     statusbar/mountpointobserver.cpp
 244     statusbar/mountpointobservercache.cpp
 245     statusbar/spaceinfoobserver.cpp
 246     statusbar/statusbarspaceinfo.cpp
 247     views/zoomlevelinfo.cpp
 248     dolphindebug.cpp
 249     global.cpp
 250 )
 251
 252 if(HAVE_BALOO)
 253     set(dolphinstatic_SRCS
 254         ${dolphinstatic_SRCS}
 255         panels/information/informationpanel.cpp
 256         panels/information/informationpanelcontent.cpp
 257         panels/information/pixmapviewer.cpp
 258         panels/information/phononwidget.cpp
 259     )
 260 endif()
 261
 262 kconfig_add_kcfg_files(dolphinstatic_SRCS GENERATE_MOC
 263     panels/folders/dolphin_folderspanelsettings.kcfgc
 264     panels/information/dolphin_informationpanelsettings.kcfgc
 265     panels/places/dolphin_placespanelsettings.kcfgc
 266     settings/dolphin_compactmodesettings.kcfgc
 267     settings/dolphin_detailsmodesettings.kcfgc
 268     settings/dolphin_generalsettings.kcfgc
 269     settings/dolphin_iconsmodesettings.kcfgc
 270     search/dolphin_searchsettings.kcfgc
 271     settings/dolphin_versioncontrolsettings.kcfgc
 272 )
 273
 274 qt5_add_resources(dolphinstatic_SRCS dolphin.qrc)
 275
 276 qt5_generate_dbus_interface(${CMAKE_CURRENT_SOURCE_DIR}/dolphinmainwindow.h org.kde.DolphinMainWindow.xml)
 277 qt5_add_dbus_adaptor(dolphinstatic_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindow.h DolphinMainWindow)
 278 qt5_add_dbus_interface(dolphinstatic_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindowinterface)
 279 qt5_add_dbus_interface(dolphinstatic_SRCS panels/terminal/org.kde.KIOFuse.VFS.xml kiofuse_interface)
 280
 281 add_library(dolphinstatic STATIC ${dolphinstatic_SRCS})
 282
 283 target_include_directories(dolphinstatic SYSTEM PRIVATE ${PHONON_INCLUDES})
 284 target_link_libraries(dolphinstatic
 285     dolphinprivate
 286     KF5::CoreAddons
 287     KF5::KCMUtils
 288     KF5::DBusAddons
 289     KF5::Notifications
 290     Phonon::phonon4qt5
 291 )
 292
 293 if (HAVE_KACTIVITIES)
 294     target_link_libraries(
 295         dolphinstatic
 296         KF5::Activities
 297     )
 298 endif()
 299
 300 set(dolphin_SRCS
 301     dbusinterface.cpp
 302     main.cpp
 303 )
 304
 305 # Sets the icon on Windows and OSX
 306 file(GLOB ICONS_SRCS "${CMAKE_CURRENT_SOURCE_DIR}/icons/*system-file-manager.png")
 307 ecm_add_app_icon(dolphin_SRCS ICONS ${ICONS_SRCS})
 308
 309 kf5_add_kdeinit_executable(dolphin ${dolphin_SRCS})
 310
 311
 312 target_link_libraries(kdeinit_dolphin PUBLIC
 313     dolphinprivate
 314     PRIVATE
 315     dolphinstatic
 316     KF5::Crash
 317 )
 318
 319 include(DbusInterfaceMacros)
 320
 321 generate_and_install_dbus_interface(
 322     kdeinit_dolphin
 323     dbusinterface.h
 324     org.freedesktop.FileManager1.xml
 325     OPTIONS -a
 326 )
 327
 328 install(TARGETS kdeinit_dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 329 install(TARGETS dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 330
 331 ##########################################
 332
 333 set(kcm_dolphinviewmodes_PART_SRCS
 334     settings/kcm/kcmdolphinviewmodes.cpp
 335     settings/viewmodes/dolphinfontrequester.cpp
 336     settings/viewmodes/viewmodesettings.cpp
 337     settings/viewmodes/viewsettingstab.cpp
 338     views/zoomlevelinfo.cpp)
 339
 340 set(kcm_dolphinnavigation_PART_SRCS
 341     settings/kcm/kcmdolphinnavigation.cpp
 342     settings/navigation/navigationsettingspage.cpp
 343     settings/settingspagebase.cpp)
 344
 345 set(kcm_dolphinservices_PART_SRCS
 346     settings/kcm/kcmdolphinservices.cpp
 347     settings/services/servicessettingspage.cpp
 348     settings/settingspagebase.cpp
 349     settings/serviceitemdelegate.cpp
 350     settings/servicemodel.cpp)
 351
 352 set(kcm_dolphingeneral_PART_SRCS
 353     settings/kcm/kcmdolphingeneral.cpp
 354     settings/general/behaviorsettingspage.cpp
 355     settings/general/previewssettingspage.cpp
 356     settings/general/configurepreviewplugindialog.cpp
 357     settings/general/confirmationssettingspage.cpp
 358     settings/settingspagebase.cpp
 359     settings/serviceitemdelegate.cpp
 360     settings/servicemodel.cpp)
 361
 362 kconfig_add_kcfg_files(kcm_dolphinviewmodes_PART_SRCS
 363     settings/dolphin_compactmodesettings.kcfgc
 364     settings/dolphin_directoryviewpropertysettings.kcfgc
 365     settings/dolphin_detailsmodesettings.kcfgc
 366     settings/dolphin_iconsmodesettings.kcfgc
 367     settings/dolphin_generalsettings.kcfgc
 368     settings/dolphin_versioncontrolsettings.kcfgc
 369 )
 370
 371 kconfig_add_kcfg_files(kcm_dolphinnavigation_PART_SRCS
 372     settings/dolphin_generalsettings.kcfgc)
 373
 374 kconfig_add_kcfg_files(kcm_dolphinservices_PART_SRCS
 375     settings/dolphin_generalsettings.kcfgc
 376     settings/dolphin_versioncontrolsettings.kcfgc)
 377
 378 kconfig_add_kcfg_files(kcm_dolphingeneral_PART_SRCS
 379     settings/dolphin_generalsettings.kcfgc)
 380
 381
 382 if(NOT WIN32)
 383     # The settings are still accessible from the hamburger menu
 384     add_library(kcm_dolphinviewmodes MODULE ${kcm_dolphinviewmodes_PART_SRCS})
 385     add_library(kcm_dolphinnavigation MODULE ${kcm_dolphinnavigation_PART_SRCS})
 386     add_library(kcm_dolphinservices MODULE ${kcm_dolphinservices_PART_SRCS})
 387     add_library(kcm_dolphingeneral MODULE ${kcm_dolphingeneral_PART_SRCS})
 388
 389     target_link_libraries(kcm_dolphinviewmodes dolphinprivate)
 390     target_link_libraries(kcm_dolphinnavigation dolphinprivate)
 391     target_link_libraries(kcm_dolphinservices dolphinprivate)
 392     target_link_libraries(kcm_dolphingeneral dolphinprivate)
 393
 394     install( FILES org.kde.dolphin.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR} )
 395     install( FILES settings/kcm/kcmdolphinviewmodes.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 396     install( FILES settings/kcm/kcmdolphinnavigation.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 397     install( FILES settings/kcm/kcmdolphinservices.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 398     install( FILES settings/kcm/kcmdolphingeneral.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 399
 400     install(TARGETS kcm_dolphinviewmodes DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 401     install(TARGETS kcm_dolphinnavigation DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 402     install(TARGETS kcm_dolphinservices DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 403     install(TARGETS kcm_dolphingeneral DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 404 endif()
 405
 406 if(NOT WIN32)
 407     add_subdirectory(settings/services/servicemenuinstaller)
 408     install( FILES settings/services/servicemenu.knsrc DESTINATION ${KDE_INSTALL_KNSRCDIR} )
 409 endif()
 410
 411 ########### install files ###############
 412
 413 install( PROGRAMS org.kde.dolphin.desktop DESTINATION ${KDE_INSTALL_APPDIR} )
 414
 415 install( DIRECTORY DESTINATION "${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel" )
 416
 417 install(
 418     CODE "execute_process(COMMAND \"${CMAKE_COMMAND}\" -E create_symlink \"${KDE_INSTALL_FULL_APPDIR}/org.kde.dolphin.desktop\" \"\$ENV{DESTDIR}${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel/org.kde.dolphin.desktop\")"
 419 )
 420
 421 install( FILES settings/dolphin_directoryviewpropertysettings.kcfg
 422                settings/dolphin_generalsettings.kcfg
 423                settings/dolphin_compactmodesettings.kcfg
 424                settings/dolphin_iconsmodesettings.kcfg
 425                settings/dolphin_detailsmodesettings.kcfg
 426                settings/dolphin_versioncontrolsettings.kcfg
 427          DESTINATION ${KDE_INSTALL_KCFGDIR} )
 428
 429 if(BUILD_TESTING)
 430     find_package(Qt5Test ${QT_MIN_VERSION} CONFIG REQUIRED)
 431     add_subdirectory(tests)
 432 endif()