src/CMakeLists.txt

   1 include(ECMAddAppIcon)
   2
   3 configure_file(config-baloo.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-baloo.h)
   4
   5 configure_file(config-dolphin.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-dolphin.h)
   6
   7 add_definitions(
   8     -DTRANSLATION_DOMAIN=\"dolphin\"
   9     -DQT_USE_FAST_CONCATENATION
  10     -DQT_USE_FAST_OPERATOR_PLUS
  11 )
  12 remove_definitions(
  13     -DQT_NO_CAST_FROM_BYTEARRAY
  14     -DQT_NO_URL_CAST_FROM_STRING
  15     -DQT_NO_SIGNALS_SLOTS_KEYWORDS
  16     -DQT_NO_CAST_FROM_ASCII
  17     -DQT_NO_CAST_TO_ASCII
  18 )
  19
  20 ##########################################
  21
  22 set(dolphinvcs_LIB_SRCS
  23     views/versioncontrol/kversioncontrolplugin.cpp
  24 )
  25
  26 add_library(dolphinvcs ${dolphinvcs_LIB_SRCS})
  27 generate_export_header(dolphinvcs BASE_NAME dolphinvcs)
  28
  29 target_link_libraries(
  30     dolphinvcs PUBLIC
  31     Qt5::Widgets
  32 )
  33
  34 set_target_properties(dolphinvcs PROPERTIES
  35     VERSION ${DOLPHINVCS_VERSION_STRING}
  36     SOVERSION ${DOLPHINVCS_SOVERSION}
  37     EXPORT_NAME DolphinVcs
  38 )
  39
  40 ecm_generate_headers(dolphinvcs_LIB_HEADERS
  41     HEADER_NAMES
  42     KVersionControlPlugin
  43
  44     RELATIVE "views/versioncontrol"
  45     REQUIRED_HEADERS dolphinvcs_LIB_HEADERS
  46 )
  47
  48 install(TARGETS dolphinvcs EXPORT DolphinVcsTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
  49
  50 install(FILES views/versioncontrol/fileviewversioncontrolplugin.desktop DESTINATION ${KDE_INSTALL_KSERVICETYPES5DIR})
  51 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphinvcs_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
  52 install(FILES ${dolphinvcs_LIB_HEADERS} DESTINATION "${KDE_INSTALL_INCLUDEDIR}/Dolphin" COMPONENT Devel)
  53
  54 ########### next target ###############
  55
  56 set(dolphinprivate_LIB_SRCS
  57     kitemviews/kfileitemlistview.cpp
  58     kitemviews/kfileitemlistwidget.cpp
  59     kitemviews/kfileitemmodel.cpp
  60     kitemviews/kfileitemmodelrolesupdater.cpp
  61     kitemviews/kitemlistcontainer.cpp
  62     kitemviews/kitemlistcontroller.cpp
  63     kitemviews/kitemlistgroupheader.cpp
  64     kitemviews/kitemlistheader.cpp
  65     kitemviews/kitemlistselectionmanager.cpp
  66     kitemviews/kitemliststyleoption.cpp
  67     kitemviews/kitemlistview.cpp
  68     kitemviews/kitemlistviewaccessible.cpp
  69     kitemviews/kitemlistwidget.cpp
  70     kitemviews/kitemmodelbase.cpp
  71     kitemviews/kitemset.cpp
  72     kitemviews/kstandarditem.cpp
  73     kitemviews/kstandarditemlistgroupheader.cpp
  74     kitemviews/kstandarditemlistwidget.cpp
  75     kitemviews/kstandarditemlistview.cpp
  76     kitemviews/kstandarditemmodel.cpp
  77     kitemviews/private/kdirectorycontentscounter.cpp
  78     kitemviews/private/kdirectorycontentscounterworker.cpp
  79     kitemviews/private/kfileitemclipboard.cpp
  80     kitemviews/private/kfileitemmodeldirlister.cpp
  81     kitemviews/private/kfileitemmodelfilter.cpp
  82     kitemviews/private/kitemlistheaderwidget.cpp
  83     kitemviews/private/kitemlistkeyboardsearchmanager.cpp
  84     kitemviews/private/kitemlistroleeditor.cpp
  85     kitemviews/private/kitemlistrubberband.cpp
  86     kitemviews/private/kitemlistselectiontoggle.cpp
  87     kitemviews/private/kitemlistsizehintresolver.cpp
  88     kitemviews/private/kitemlistsmoothscroller.cpp
  89     kitemviews/private/kitemlistviewanimation.cpp
  90     kitemviews/private/kitemlistviewlayouter.cpp
  91     kitemviews/private/kpixmapmodifier.cpp
  92     settings/additionalinfodialog.cpp
  93     settings/applyviewpropsjob.cpp
  94     settings/viewmodes/viewmodesettings.cpp
  95     settings/viewpropertiesdialog.cpp
  96     settings/viewpropsprogressinfo.cpp
  97     views/dolphinfileitemlistwidget.cpp
  98     views/dolphinitemlistview.cpp
  99     views/dolphinnewfilemenuobserver.cpp
 100     views/dolphinremoteencoding.cpp
 101     views/dolphinview.cpp
 102     views/dolphinviewactionhandler.cpp
 103     views/draganddrophelper.cpp
 104     views/renamedialog.cpp
 105     views/tooltips/dolphinfilemetadatawidget.cpp
 106     views/tooltips/tooltipmanager.cpp
 107     views/versioncontrol/updateitemstatesthread.cpp
 108     views/versioncontrol/versioncontrolobserver.cpp
 109     views/viewmodecontroller.cpp
 110     views/viewproperties.cpp
 111     views/zoomlevelinfo.cpp
 112     dolphinremoveaction.cpp
 113     middleclickactioneventfilter.cpp
 114     dolphinnewfilemenu.cpp
 115     dolphindebug.cpp
 116 )
 117
 118 if(HAVE_BALOO)
 119     set(dolphinprivate_LIB_SRCS
 120         ${dolphinprivate_LIB_SRCS}
 121         kitemviews/private/kbaloorolesprovider.cpp
 122     )
 123 endif()
 124
 125 kconfig_add_kcfg_files(dolphinprivate_LIB_SRCS GENERATE_MOC
 126     settings/dolphin_compactmodesettings.kcfgc
 127     settings/dolphin_directoryviewpropertysettings.kcfgc
 128     settings/dolphin_detailsmodesettings.kcfgc
 129     settings/dolphin_iconsmodesettings.kcfgc
 130     settings/dolphin_generalsettings.kcfgc
 131     settings/dolphin_versioncontrolsettings.kcfgc
 132 )
 133
 134 add_library(dolphinprivate ${dolphinprivate_LIB_SRCS})
 135 generate_export_header(dolphinprivate BASE_NAME dolphin)
 136
 137 target_link_libraries(
 138     dolphinprivate PUBLIC
 139     dolphinvcs
 140     Qt5::Concurrent
 141     Qt5::Gui
 142     KF5::Crash
 143     KF5::I18n
 144     KF5::IconThemes
 145     KF5::KIOCore
 146     KF5::KIOWidgets
 147     KF5::KIOFileWidgets
 148     KF5::Completion
 149     KF5::TextWidgets
 150     KF5::ConfigCore
 151     KF5::NewStuff
 152     KF5::Parts
 153 )
 154
 155 if(HAVE_BALOO)
 156     target_link_libraries(
 157         dolphinprivate PUBLIC
 158         KF5::FileMetaData
 159         KF5::Baloo
 160         KF5::BalooWidgets
 161     )
 162 else()
 163     target_link_libraries(
 164         dolphinprivate PUBLIC
 165         KF5::KDELibs4Support # for KFileMetaDataWidget
 166     )
 167 endif()
 168
 169 set_target_properties(dolphinprivate PROPERTIES
 170     VERSION ${DOLPHINPRIVATE_VERSION_STRING}
 171     SOVERSION ${DOLPHINPRIVATE_SOVERSION}
 172 )
 173
 174 install(TARGETS dolphinprivate ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} LIBRARY NAMELINK_SKIP)
 175 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphin_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
 176
 177 ##########################################
 178
 179 set(dolphinpart_SRCS
 180    dolphinpart.cpp
 181    dolphinpart_ext.cpp
 182    dolphindebug.cpp
 183 )
 184
 185 qt5_add_resources(dolphinpart_SRCS dolphinpart.qrc)
 186
 187 add_library(dolphinpart MODULE ${dolphinpart_SRCS})
 188
 189 target_link_libraries(dolphinpart
 190     dolphinprivate
 191 )
 192
 193 install(TARGETS dolphinpart DESTINATION ${KDE_INSTALL_PLUGINDIR})
 194
 195 install(FILES dolphinpart.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR})
 196
 197 ##########################################
 198
 199 set(dolphinstatic_SRCS
 200     dolphindockwidget.cpp
 201     dolphinmainwindow.cpp
 202     dolphinviewcontainer.cpp
 203     dolphincontextmenu.cpp
 204     dolphintabbar.cpp
 205     dolphinrecenttabsmenu.cpp
 206     dolphintabpage.cpp
 207     dolphintabwidget.cpp
 208     filterbar/filterbar.cpp
 209     main.cpp
 210     panels/information/filemetadataconfigurationdialog.cpp
 211     panels/information/informationpanel.cpp
 212     panels/information/informationpanelcontent.cpp
 213     panels/information/pixmapviewer.cpp
 214     panels/information/phononwidget.cpp
 215     panels/places/placespanel.cpp
 216     panels/places/placesitem.cpp
 217     panels/places/placesitemeditdialog.cpp
 218     panels/places/placesitemlistgroupheader.cpp
 219     panels/places/placesitemlistwidget.cpp
 220     panels/places/placesitemmodel.cpp
 221     panels/places/placesitemsignalhandler.cpp
 222     panels/places/placesview.cpp
 223     panels/panel.cpp
 224     panels/folders/foldersitemlistwidget.cpp
 225     panels/folders/treeviewcontextmenu.cpp
 226     panels/folders/folderspanel.cpp
 227     panels/terminal/terminalpanel.cpp
 228     search/dolphinfacetswidget.cpp
 229     search/dolphinsearchbox.cpp
 230     settings/general/behaviorsettingspage.cpp
 231     settings/general/configurepreviewplugindialog.cpp
 232     settings/general/confirmationssettingspage.cpp
 233     settings/general/generalsettingspage.cpp
 234     settings/general/previewssettingspage.cpp
 235     settings/general/statusbarsettingspage.cpp
 236     settings/dolphinsettingsdialog.cpp
 237     settings/navigation/navigationsettingspage.cpp
 238     settings/services/servicessettingspage.cpp
 239     settings/settingspagebase.cpp
 240     settings/serviceitemdelegate.cpp
 241     settings/servicemodel.cpp
 242     settings/startup/startupsettingspage.cpp
 243     settings/trash/trashsettingspage.cpp
 244     settings/viewmodes/dolphinfontrequester.cpp
 245     settings/viewmodes/viewsettingspage.cpp
 246     settings/viewmodes/viewmodesettings.cpp
 247     settings/viewmodes/viewsettingstab.cpp
 248     statusbar/dolphinstatusbar.cpp
 249     statusbar/mountpointobserver.cpp
 250     statusbar/mountpointobservercache.cpp
 251     statusbar/spaceinfoobserver.cpp
 252     statusbar/statusbarspaceinfo.cpp
 253     views/zoomlevelinfo.cpp
 254     dolphindebug.cpp
 255     global.cpp
 256 )
 257
 258 kconfig_add_kcfg_files(dolphinstatic_SRCS GENERATE_MOC
 259     panels/folders/dolphin_folderspanelsettings.kcfgc
 260     panels/information/dolphin_informationpanelsettings.kcfgc
 261     panels/places/dolphin_placespanelsettings.kcfgc
 262     settings/dolphin_compactmodesettings.kcfgc
 263     settings/dolphin_detailsmodesettings.kcfgc
 264     settings/dolphin_generalsettings.kcfgc
 265     settings/dolphin_iconsmodesettings.kcfgc
 266     search/dolphin_searchsettings.kcfgc
 267     settings/dolphin_versioncontrolsettings.kcfgc
 268 )
 269
 270 qt5_add_resources(dolphinstatic_SRCS dolphin.qrc)
 271
 272 add_library(dolphinstatic STATIC ${dolphinstatic_SRCS})
 273
 274 target_include_directories(dolphinstatic PRIVATE ${PHONON_INCLUDES})
 275 target_link_libraries(dolphinstatic
 276     dolphinprivate
 277     KF5::KCMUtils
 278     KF5::DBusAddons
 279     KF5::Notifications
 280     Phonon::phonon4qt5
 281 )
 282
 283 if (KF5Activities_FOUND)
 284     target_link_libraries(
 285         dolphinstatic
 286         KF5::Activities
 287     )
 288 endif()
 289
 290 set(dolphin_SRCS
 291     dbusinterface.cpp
 292     main.cpp
 293 )
 294
 295 # Sets the icon on Windows and OSX
 296 file(GLOB ICONS_SRCS "${CMAKE_CURRENT_SOURCE_DIR}/icons/*system-file-manager.png")
 297 ecm_add_app_icon(dolphin_SRCS ICONS ${ICONS_SRCS})
 298
 299 kf5_add_kdeinit_executable(dolphin ${dolphin_SRCS})
 300
 301
 302 target_link_libraries(kdeinit_dolphin
 303     dolphinstatic
 304     dolphinprivate
 305 )
 306
 307 include(DbusInterfaceMacros)
 308
 309 generate_and_install_dbus_interface(
 310     kdeinit_dolphin
 311     dbusinterface.h
 312     org.freedesktop.FileManager1.xml
 313     OPTIONS -a
 314 )
 315
 316 install(TARGETS kdeinit_dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 317 install(TARGETS dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 318
 319 ##########################################
 320
 321 set(kcm_dolphinviewmodes_PART_SRCS
 322     settings/kcm/kcmdolphinviewmodes.cpp
 323     settings/viewmodes/dolphinfontrequester.cpp
 324     settings/viewmodes/viewmodesettings.cpp
 325     settings/viewmodes/viewsettingstab.cpp
 326     views/zoomlevelinfo.cpp)
 327
 328 set(kcm_dolphinnavigation_PART_SRCS
 329     settings/kcm/kcmdolphinnavigation.cpp
 330     settings/navigation/navigationsettingspage.cpp
 331     settings/settingspagebase.cpp)
 332
 333 set(kcm_dolphinservices_PART_SRCS
 334     settings/kcm/kcmdolphinservices.cpp
 335     settings/services/servicessettingspage.cpp
 336     settings/settingspagebase.cpp
 337     settings/serviceitemdelegate.cpp
 338     settings/servicemodel.cpp)
 339
 340 set(kcm_dolphingeneral_PART_SRCS
 341     settings/kcm/kcmdolphingeneral.cpp
 342     settings/general/behaviorsettingspage.cpp
 343     settings/general/previewssettingspage.cpp
 344     settings/general/configurepreviewplugindialog.cpp
 345     settings/general/confirmationssettingspage.cpp
 346     settings/settingspagebase.cpp
 347     settings/serviceitemdelegate.cpp
 348     settings/servicemodel.cpp)
 349
 350 kconfig_add_kcfg_files(kcm_dolphinviewmodes_PART_SRCS
 351     settings/dolphin_compactmodesettings.kcfgc
 352     settings/dolphin_directoryviewpropertysettings.kcfgc
 353     settings/dolphin_detailsmodesettings.kcfgc
 354     settings/dolphin_iconsmodesettings.kcfgc
 355     settings/dolphin_generalsettings.kcfgc
 356     settings/dolphin_versioncontrolsettings.kcfgc
 357 )
 358
 359 kconfig_add_kcfg_files(kcm_dolphinnavigation_PART_SRCS
 360     settings/dolphin_generalsettings.kcfgc)
 361
 362 kconfig_add_kcfg_files(kcm_dolphinservices_PART_SRCS
 363     settings/dolphin_generalsettings.kcfgc
 364     settings/dolphin_versioncontrolsettings.kcfgc)
 365
 366 kconfig_add_kcfg_files(kcm_dolphingeneral_PART_SRCS
 367     settings/dolphin_generalsettings.kcfgc)
 368
 369 add_library(kcm_dolphinviewmodes MODULE ${kcm_dolphinviewmodes_PART_SRCS})
 370 add_library(kcm_dolphinnavigation MODULE ${kcm_dolphinnavigation_PART_SRCS})
 371 add_library(kcm_dolphinservices MODULE ${kcm_dolphinservices_PART_SRCS})
 372 add_library(kcm_dolphingeneral MODULE ${kcm_dolphingeneral_PART_SRCS})
 373
 374 target_link_libraries(kcm_dolphinviewmodes dolphinprivate)
 375 target_link_libraries(kcm_dolphinnavigation dolphinprivate)
 376 target_link_libraries(kcm_dolphinservices dolphinprivate)
 377 target_link_libraries(kcm_dolphingeneral dolphinprivate)
 378
 379 install(TARGETS kcm_dolphinviewmodes DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 380 install(TARGETS kcm_dolphinnavigation DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 381 install(TARGETS kcm_dolphinservices DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 382 install(TARGETS kcm_dolphingeneral DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 383
 384 ########### install files ###############
 385
 386 install( PROGRAMS org.kde.dolphin.desktop DESTINATION ${KDE_INSTALL_APPDIR} )
 387 install( FILES settings/dolphin_directoryviewpropertysettings.kcfg
 388                settings/dolphin_generalsettings.kcfg
 389                settings/dolphin_compactmodesettings.kcfg
 390                settings/dolphin_iconsmodesettings.kcfg
 391                settings/dolphin_detailsmodesettings.kcfg
 392                settings/dolphin_versioncontrolsettings.kcfg
 393          DESTINATION ${KDE_INSTALL_KCFGDIR} )
 394 install( FILES org.kde.dolphin.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR} )
 395 install( FILES settings/kcm/kcmdolphinviewmodes.desktop DESTINATION
 396 ${KDE_INSTALL_KSERVICES5DIR} )
 397 install( FILES settings/kcm/kcmdolphinnavigation.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 398 install( FILES settings/kcm/kcmdolphinservices.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 399 install( FILES settings/kcm/kcmdolphingeneral.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 400 install( FILES settings/services/servicemenu.knsrc DESTINATION ${KDE_INSTALL_CONFDIR} )
 401 install( PROGRAMS settings/services/servicemenuinstallation DESTINATION ${KDE_INSTALL_BINDIR} )
 402 install( PROGRAMS settings/services/servicemenudeinstallation DESTINATION ${KDE_INSTALL_BINDIR} )
 403
 404 if(BUILD_TESTING)
 405     find_package(Qt5Test ${QT_MIN_VERSION} CONFIG REQUIRED)
 406     add_subdirectory(tests)
 407 endif()