src/CMakeLists.txt

   1 include(ECMAddAppIcon)
   2
   3 configure_file(config-baloo.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-baloo.h)
   4
   5 configure_file(config-kactivities.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-kactivities.h)
   6
   7 configure_file(config-packagekit.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-packagekit.h)
   8
   9 configure_file(config-terminal.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-terminal.h)
  10
  11 configure_file(config-kuserfeedback.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-kuserfeedback.h)
  12
  13 add_definitions(
  14     -DTRANSLATION_DOMAIN=\"dolphin\"
  15 )
  16 remove_definitions(
  17     -DQT_NO_CAST_FROM_BYTEARRAY
  18     -DQT_NO_CAST_FROM_ASCII
  19     -DQT_NO_CAST_TO_ASCII
  20 )
  21
  22 ##########################################
  23
  24 add_library(dolphinvcs SHARED)
  25
  26 target_sources(dolphinvcs PRIVATE
  27     views/versioncontrol/kversioncontrolplugin.cpp
  28 )
  29
  30 generate_export_header(dolphinvcs BASE_NAME dolphinvcs)
  31
  32 target_link_libraries(
  33     dolphinvcs PUBLIC
  34     Qt5::Widgets
  35 )
  36
  37 set_target_properties(dolphinvcs PROPERTIES
  38     VERSION ${DOLPHINVCS_VERSION}
  39     SOVERSION ${DOLPHINVCS_SOVERSION}
  40     EXPORT_NAME DolphinVcs
  41 )
  42
  43 ecm_generate_headers(dolphinvcs_LIB_HEADERS
  44     HEADER_NAMES
  45     KVersionControlPlugin
  46
  47     RELATIVE "views/versioncontrol"
  48     REQUIRED_HEADERS dolphinvcs_LIB_HEADERS
  49 )
  50
  51 install(TARGETS dolphinvcs EXPORT DolphinVcsTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
  52
  53 install(FILES views/versioncontrol/fileviewversioncontrolplugin.desktop DESTINATION ${KDE_INSTALL_KSERVICETYPES5DIR})
  54 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphinvcs_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
  55 install(FILES ${dolphinvcs_LIB_HEADERS} DESTINATION "${KDE_INSTALL_INCLUDEDIR}/Dolphin" COMPONENT Devel)
  56
  57 ########### next target ###############
  58
  59 add_library(dolphinprivate SHARED)
  60
  61 target_sources(dolphinprivate PRIVATE
  62     kitemviews/kfileitemlistview.cpp
  63     kitemviews/kfileitemlistwidget.cpp
  64     kitemviews/kfileitemmodel.cpp
  65     kitemviews/kfileitemmodelrolesupdater.cpp
  66     kitemviews/kitemlistcontainer.cpp
  67     kitemviews/kitemlistcontroller.cpp
  68     kitemviews/kitemlistgroupheader.cpp
  69     kitemviews/kitemlistheader.cpp
  70     kitemviews/kitemlistselectionmanager.cpp
  71     kitemviews/kitemliststyleoption.cpp
  72     kitemviews/kitemlistview.cpp
  73     kitemviews/kitemlistviewaccessible.cpp
  74     kitemviews/kitemlistwidget.cpp
  75     kitemviews/kitemmodelbase.cpp
  76     kitemviews/kitemset.cpp
  77     kitemviews/kstandarditem.cpp
  78     kitemviews/kstandarditemlistgroupheader.cpp
  79     kitemviews/kstandarditemlistwidget.cpp
  80     kitemviews/kstandarditemlistview.cpp
  81     kitemviews/kstandarditemmodel.cpp
  82     kitemviews/private/kdirectorycontentscounter.cpp
  83     kitemviews/private/kdirectorycontentscounterworker.cpp
  84     kitemviews/private/kfileitemclipboard.cpp
  85     kitemviews/private/kfileitemmodeldirlister.cpp
  86     kitemviews/private/kfileitemmodelfilter.cpp
  87     kitemviews/private/kitemlistheaderwidget.cpp
  88     kitemviews/private/kitemlistkeyboardsearchmanager.cpp
  89     kitemviews/private/kitemlistroleeditor.cpp
  90     kitemviews/private/kitemlistrubberband.cpp
  91     kitemviews/private/kitemlistselectiontoggle.cpp
  92     kitemviews/private/kitemlistsizehintresolver.cpp
  93     kitemviews/private/kitemlistsmoothscroller.cpp
  94     kitemviews/private/kitemlistviewanimation.cpp
  95     kitemviews/private/kitemlistviewlayouter.cpp
  96     kitemviews/private/kpixmapmodifier.cpp
  97     kitemviews/private/ktwofingerswipe.cpp
  98     kitemviews/private/ktwofingertap.cpp
  99     settings/applyviewpropsjob.cpp
 100     settings/viewmodes/viewmodesettings.cpp
 101     settings/viewpropertiesdialog.cpp
 102     settings/viewpropsprogressinfo.cpp
 103     views/dolphinfileitemlistwidget.cpp
 104     views/dolphinitemlistview.cpp
 105     views/dolphinnewfilemenuobserver.cpp
 106     views/dolphinremoteencoding.cpp
 107     views/dolphinview.cpp
 108     views/dolphinviewactionhandler.cpp
 109     views/draganddrophelper.cpp
 110     views/versioncontrol/updateitemstatesthread.cpp
 111     views/versioncontrol/versioncontrolobserver.cpp
 112     views/viewmodecontroller.cpp
 113     views/viewproperties.cpp
 114     views/zoomlevelinfo.cpp
 115     dolphinremoveaction.cpp
 116     middleclickactioneventfilter.cpp
 117     dolphinnewfilemenu.cpp
 118 )
 119
 120 ecm_qt_declare_logging_category(dolphinprivate
 121     HEADER dolphindebug.h
 122     IDENTIFIER DolphinDebug
 123     CATEGORY_NAME org.kde.dolphin
 124     DESCRIPTION "dolphin"
 125     EXPORT DOLPHIN
 126 )
 127
 128 if(HAVE_BALOO)
 129     target_sources(dolphinprivate PRIVATE
 130         views/tooltips/dolphinfilemetadatawidget.cpp
 131         views/tooltips/tooltipmanager.cpp
 132         kitemviews/private/kbaloorolesprovider.cpp
 133     )
 134 endif()
 135
 136 kconfig_add_kcfg_files(dolphinprivate
 137     settings/dolphin_compactmodesettings.kcfgc
 138     settings/dolphin_directoryviewpropertysettings.kcfgc
 139     settings/dolphin_detailsmodesettings.kcfgc
 140     settings/dolphin_iconsmodesettings.kcfgc
 141     settings/dolphin_generalsettings.kcfgc
 142     settings/dolphin_contextmenusettings.kcfgc
 143     settings/dolphin_versioncontrolsettings.kcfgc
 144 )
 145
 146 generate_export_header(dolphinprivate BASE_NAME dolphin)
 147
 148 target_link_libraries(
 149     dolphinprivate PUBLIC
 150     dolphinvcs
 151     Qt5::Concurrent
 152     Qt5::Gui
 153     KF5::I18n
 154     KF5::IconThemes
 155     KF5::KIOCore
 156     KF5::KIOWidgets
 157     KF5::KIOFileWidgets
 158     KF5::Completion
 159     KF5::TextWidgets
 160     KF5::ConfigCore
 161     KF5::NewStuff
 162     KF5::Parts
 163     KF5::WindowSystem
 164 )
 165
 166 if(HAVE_BALOO)
 167     target_link_libraries(
 168         dolphinprivate PUBLIC
 169         KF5::FileMetaData
 170         KF5::Baloo
 171         KF5::BalooWidgets
 172     )
 173 endif()
 174
 175 set_target_properties(dolphinprivate PROPERTIES
 176     VERSION ${DOLPHINPRIVATE_VERSION}
 177     SOVERSION ${DOLPHINPRIVATE_SOVERSION}
 178 )
 179
 180 install(TARGETS dolphinprivate ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} LIBRARY NAMELINK_SKIP)
 181 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphin_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
 182
 183 ##########################################
 184 configure_file(dolphinpart.desktop.in ${CMAKE_CURRENT_BINARY_DIR}/dolphinpart.desktop @ONLY)
 185
 186 add_library(dolphinpart MODULE)
 187
 188 target_sources(dolphinpart PRIVATE
 189     dolphinpart.cpp
 190     dolphinpart_ext.cpp
 191     dolphindebug.cpp
 192
 193     dolphinpart.qrc
 194 )
 195
 196 kcoreaddons_desktop_to_json(dolphinpart ${CMAKE_CURRENT_BINARY_DIR}/dolphinpart.desktop)
 197
 198 target_link_libraries(dolphinpart
 199     dolphinprivate
 200 )
 201
 202 install(TARGETS dolphinpart DESTINATION ${KDE_INSTALL_PLUGINDIR}/kf5/parts)
 203
 204 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphinpart.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR})
 205
 206 ##########################################
 207
 208 add_library(dolphinstatic STATIC)
 209
 210 target_sources(dolphinstatic PRIVATE
 211     dolphinbookmarkhandler.cpp
 212     dolphindockwidget.cpp
 213     dolphinmainwindow.cpp
 214     dolphinviewcontainer.cpp
 215     dolphincontextmenu.cpp
 216     dolphinnavigatorswidgetaction.cpp
 217     dolphintabbar.cpp
 218     dolphinplacesmodelsingleton.cpp
 219     dolphinrecenttabsmenu.cpp
 220     dolphintabpage.cpp
 221     dolphintabwidget.cpp
 222     dolphinurlnavigator.cpp
 223     dolphinurlnavigatorscontroller.cpp
 224     trash/dolphintrash.cpp
 225     filterbar/filterbar.cpp
 226     panels/places/placespanel.cpp
 227     panels/places/placesitem.cpp
 228     panels/places/placesitemlistgroupheader.cpp
 229     panels/places/placesitemlistwidget.cpp
 230     panels/places/placesitemmodel.cpp
 231     panels/places/placesitemsignalhandler.cpp
 232     panels/places/placesview.cpp
 233     panels/panel.cpp
 234     panels/folders/foldersitemlistwidget.cpp
 235     panels/folders/treeviewcontextmenu.cpp
 236     panels/folders/folderspanel.cpp
 237     panels/terminal/terminalpanel.cpp
 238     search/dolphinfacetswidget.cpp
 239     search/dolphinquery.cpp
 240     search/dolphinsearchbox.cpp
 241     settings/general/behaviorsettingspage.cpp
 242     settings/general/configurepreviewplugindialog.cpp
 243     settings/general/confirmationssettingspage.cpp
 244     settings/general/generalsettingspage.cpp
 245     settings/general/previewssettingspage.cpp
 246     settings/general/statusbarsettingspage.cpp
 247     settings/dolphinsettingsdialog.cpp
 248     settings/navigation/navigationsettingspage.cpp
 249     settings/contextmenu/contextmenusettingspage.cpp
 250     settings/settingspagebase.cpp
 251     settings/serviceitemdelegate.cpp
 252     settings/servicemodel.cpp
 253     settings/startup/startupsettingspage.cpp
 254     settings/trash/trashsettingspage.cpp
 255     settings/viewmodes/dolphinfontrequester.cpp
 256     settings/viewmodes/viewsettingspage.cpp
 257     settings/viewmodes/viewmodesettings.cpp
 258     settings/viewmodes/viewsettingstab.cpp
 259     statusbar/dolphinstatusbar.cpp
 260     statusbar/mountpointobserver.cpp
 261     statusbar/mountpointobservercache.cpp
 262     statusbar/spaceinfoobserver.cpp
 263     statusbar/statusbarspaceinfo.cpp
 264     views/zoomlevelinfo.cpp
 265     dolphindebug.cpp
 266     global.cpp
 267     dolphin.qrc
 268 )
 269
 270 if(HAVE_BALOO)
 271     target_sources(dolphinstatic PRIVATE
 272         panels/information/informationpanel.cpp
 273         panels/information/informationpanelcontent.cpp
 274         panels/information/pixmapviewer.cpp
 275         panels/information/phononwidget.cpp
 276     )
 277 endif()
 278
 279 if(HAVE_KUSERFEEDBACK)
 280     target_sources(dolphinstatic PRIVATE
 281         userfeedback/dolphinfeedbackprovider.cpp
 282         userfeedback/settingsdatasource.cpp
 283         userfeedback/placesdatasource.cpp
 284         settings/userfeedback/userfeedbacksettingspage.cpp
 285     )
 286 endif()
 287
 288 kconfig_add_kcfg_files(dolphinstatic
 289     panels/folders/dolphin_folderspanelsettings.kcfgc
 290     panels/information/dolphin_informationpanelsettings.kcfgc
 291     panels/places/dolphin_placespanelsettings.kcfgc
 292     settings/dolphin_compactmodesettings.kcfgc
 293     settings/dolphin_detailsmodesettings.kcfgc
 294     settings/dolphin_contextmenusettings.kcfgc
 295     settings/dolphin_iconsmodesettings.kcfgc
 296     search/dolphin_searchsettings.kcfgc
 297     settings/dolphin_versioncontrolsettings.kcfgc
 298 )
 299 kconfig_add_kcfg_files(dolphinstatic GENERATE_MOC
 300     settings/dolphin_generalsettings.kcfgc
 301 )
 302
 303 qt5_generate_dbus_interface(${CMAKE_CURRENT_SOURCE_DIR}/dolphinmainwindow.h org.kde.DolphinMainWindow.xml)
 304 qt5_add_dbus_adaptor(dolphin_dbus_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindow.h DolphinMainWindow)
 305 qt5_add_dbus_interface(dolphin_dbus_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindowinterface)
 306 qt5_add_dbus_interface(dolphin_dbus_SRCS panels/terminal/org.kde.KIOFuse.VFS.xml kiofuse_interface)
 307
 308 target_sources(dolphinstatic PRIVATE
 309     ${dolphin_dbus_SRCS}
 310 )
 311
 312 target_include_directories(dolphinstatic SYSTEM PRIVATE ${PHONON_INCLUDES})
 313 target_link_libraries(dolphinstatic
 314     dolphinprivate
 315     KF5::CoreAddons
 316     KF5::KCMUtils
 317     KF5::DBusAddons
 318     KF5::Notifications
 319     Phonon::phonon4qt5
 320 )
 321
 322 if (HAVE_KACTIVITIES)
 323     target_link_libraries(
 324         dolphinstatic
 325         KF5::Activities
 326     )
 327 endif()
 328
 329 if (HAVE_KUSERFEEDBACK)
 330     target_link_libraries(
 331         dolphinstatic
 332         KUserFeedbackCore
 333         KUserFeedbackWidgets
 334     )
 335 endif()
 336
 337 add_executable(dolphin)
 338
 339 target_sources(dolphin PRIVATE
 340     dbusinterface.cpp
 341     main.cpp
 342 )
 343
 344 # Sets the icon on Windows and OSX
 345 file(GLOB ICONS_SRCS "${CMAKE_CURRENT_SOURCE_DIR}/icons/*system-file-manager.png")
 346 ecm_add_app_icon(dolphin_APPICON_SRCS ICONS ${ICONS_SRCS})
 347 # ecm_add_app_icon 5.83 will take target as arg, use that once it is min req.
 348 target_sources(dolphin PRIVATE
 349     ${dolphin_APPICON_SRCS}
 350 )
 351
 352 target_link_libraries(dolphin
 353     PRIVATE
 354     dolphinprivate
 355     dolphinstatic
 356     KF5::Crash
 357 )
 358
 359 include(DbusInterfaceMacros)
 360
 361 generate_and_install_dbus_interface(
 362     dolphin
 363     dbusinterface.h
 364     org.freedesktop.FileManager1.xml
 365     OPTIONS -a
 366 )
 367
 368 install(TARGETS dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 369
 370 ##########################################
 371
 372 if(NOT WIN32)
 373     # The settings are still accessible from the hamburger menu
 374     add_library(kcm_dolphinviewmodes MODULE)
 375     add_library(kcm_dolphinnavigation MODULE)
 376     add_library(kcm_dolphingeneral MODULE)
 377
 378     target_sources(kcm_dolphinviewmodes PRIVATE
 379         settings/kcm/kcmdolphinviewmodes.cpp
 380         settings/viewmodes/dolphinfontrequester.cpp
 381         settings/viewmodes/viewmodesettings.cpp
 382         settings/viewmodes/viewsettingstab.cpp
 383         views/zoomlevelinfo.cpp)
 384
 385     target_sources(kcm_dolphinnavigation PRIVATE
 386         settings/kcm/kcmdolphinnavigation.cpp
 387         settings/navigation/navigationsettingspage.cpp
 388         settings/settingspagebase.cpp)
 389
 390     target_sources(kcm_dolphingeneral PRIVATE
 391         settings/kcm/kcmdolphingeneral.cpp
 392         settings/general/behaviorsettingspage.cpp
 393         settings/general/previewssettingspage.cpp
 394         settings/general/configurepreviewplugindialog.cpp
 395         settings/general/confirmationssettingspage.cpp
 396         settings/settingspagebase.cpp
 397         settings/serviceitemdelegate.cpp
 398         settings/servicemodel.cpp)
 399
 400     kconfig_add_kcfg_files(kcm_dolphinviewmodes
 401         settings/dolphin_compactmodesettings.kcfgc
 402         settings/dolphin_directoryviewpropertysettings.kcfgc
 403         settings/dolphin_detailsmodesettings.kcfgc
 404         settings/dolphin_iconsmodesettings.kcfgc
 405         settings/dolphin_generalsettings.kcfgc
 406         settings/dolphin_versioncontrolsettings.kcfgc
 407     )
 408
 409     kconfig_add_kcfg_files(kcm_dolphinnavigation
 410         settings/dolphin_generalsettings.kcfgc)
 411
 412     kconfig_add_kcfg_files(kcm_dolphingeneral
 413         settings/dolphin_generalsettings.kcfgc)
 414
 415     target_link_libraries(kcm_dolphinviewmodes dolphinprivate)
 416     target_link_libraries(kcm_dolphinnavigation dolphinprivate)
 417     target_link_libraries(kcm_dolphingeneral dolphinprivate)
 418
 419     install( FILES org.kde.dolphin.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR} )
 420     install( FILES settings/kcm/kcmdolphinviewmodes.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 421     install( FILES settings/kcm/kcmdolphinnavigation.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 422     install( FILES settings/kcm/kcmdolphingeneral.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 423
 424     install(TARGETS kcm_dolphinviewmodes DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 425     install(TARGETS kcm_dolphinnavigation DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 426     install(TARGETS kcm_dolphingeneral DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 427 endif()
 428
 429 if(NOT WIN32)
 430     add_subdirectory(settings/contextmenu/servicemenuinstaller)
 431     install( FILES settings/contextmenu/servicemenu.knsrc DESTINATION ${KDE_INSTALL_KNSRCDIR} )
 432 endif()
 433
 434 ########### install files ###############
 435
 436 install( PROGRAMS org.kde.dolphin.desktop DESTINATION ${KDE_INSTALL_APPDIR} )
 437
 438 install( DIRECTORY DESTINATION "${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel" )
 439
 440 install(
 441     CODE "execute_process(COMMAND \"${CMAKE_COMMAND}\" -E create_symlink \"${KDE_INSTALL_FULL_APPDIR}/org.kde.dolphin.desktop\" \"\$ENV{DESTDIR}${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel/org.kde.dolphin.desktop\")"
 442 )
 443
 444 install( FILES settings/dolphin_directoryviewpropertysettings.kcfg
 445                settings/dolphin_generalsettings.kcfg
 446                settings/dolphin_contextmenusettings.kcfg
 447                settings/dolphin_compactmodesettings.kcfg
 448                settings/dolphin_iconsmodesettings.kcfg
 449                settings/dolphin_detailsmodesettings.kcfg
 450                settings/dolphin_versioncontrolsettings.kcfg
 451          DESTINATION ${KDE_INSTALL_KCFGDIR} )
 452
 453 if(BUILD_TESTING)
 454     find_package(Qt5Test ${QT_MIN_VERSION} CONFIG REQUIRED)
 455     add_subdirectory(tests)
 456 endif()