src/CMakeLists.txt

   1 include(ECMAddAppIcon)
   2
   3 configure_file(config-baloo.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-baloo.h)
   4
   5 configure_file(config-kactivities.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-kactivities.h)
   6
   7 configure_file(config-packagekit.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-packagekit.h)
   8
   9 configure_file(config-terminal.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-terminal.h)
  10
  11 configure_file(config-kuserfeedback.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-kuserfeedback.h)
  12
  13 add_definitions(
  14     -DTRANSLATION_DOMAIN=\"dolphin\"
  15 )
  16 remove_definitions(
  17     -DQT_NO_CAST_FROM_BYTEARRAY
  18     -DQT_NO_CAST_FROM_ASCII
  19     -DQT_NO_CAST_TO_ASCII
  20 )
  21
  22 ##########################################
  23
  24 add_library(dolphinvcs SHARED)
  25
  26 target_sources(dolphinvcs PRIVATE
  27     views/versioncontrol/kversioncontrolplugin.cpp
  28 )
  29
  30 generate_export_header(dolphinvcs BASE_NAME dolphinvcs)
  31
  32 target_link_libraries(
  33     dolphinvcs PUBLIC
  34     Qt${QT_MAJOR_VERSION}::Widgets
  35 )
  36
  37 set_target_properties(dolphinvcs PROPERTIES
  38     VERSION ${DOLPHINVCS_VERSION}
  39     SOVERSION ${DOLPHINVCS_SOVERSION}
  40     EXPORT_NAME DolphinVcs
  41 )
  42
  43 ecm_generate_headers(dolphinvcs_LIB_HEADERS
  44     HEADER_NAMES
  45     KVersionControlPlugin
  46
  47     RELATIVE "views/versioncontrol"
  48     REQUIRED_HEADERS dolphinvcs_LIB_HEADERS
  49 )
  50
  51 install(TARGETS dolphinvcs EXPORT DolphinVcsTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
  52
  53 install(FILES views/versioncontrol/fileviewversioncontrolplugin.desktop DESTINATION ${KDE_INSTALL_KSERVICETYPESDIR})
  54 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphinvcs_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
  55 install(FILES ${dolphinvcs_LIB_HEADERS} DESTINATION "${KDE_INSTALL_INCLUDEDIR}/Dolphin" COMPONENT Devel)
  56
  57 ########### next target ###############
  58
  59 add_library(dolphinprivate SHARED)
  60
  61 target_sources(dolphinprivate PRIVATE
  62     kitemviews/kfileitemlistview.cpp
  63     kitemviews/kfileitemlistwidget.cpp
  64     kitemviews/kfileitemlisttostring.cpp
  65     kitemviews/kfileitemmodel.cpp
  66     kitemviews/kfileitemmodelrolesupdater.cpp
  67     kitemviews/kitemlistcontainer.cpp
  68     kitemviews/kitemlistcontroller.cpp
  69     kitemviews/kitemlistgroupheader.cpp
  70     kitemviews/kitemlistheader.cpp
  71     kitemviews/kitemlistselectionmanager.cpp
  72     kitemviews/kitemliststyleoption.cpp
  73     kitemviews/kitemlistview.cpp
  74     kitemviews/kitemlistviewaccessible.cpp
  75     kitemviews/kitemlistwidget.cpp
  76     kitemviews/kitemmodelbase.cpp
  77     kitemviews/kitemset.cpp
  78     kitemviews/kstandarditemlistgroupheader.cpp
  79     kitemviews/kstandarditemlistwidget.cpp
  80     kitemviews/kstandarditemlistview.cpp
  81     kitemviews/private/kdirectorycontentscounter.cpp
  82     kitemviews/private/kdirectorycontentscounterworker.cpp
  83     kitemviews/private/kfileitemclipboard.cpp
  84     kitemviews/private/kfileitemmodelfilter.cpp
  85     kitemviews/private/kitemlistheaderwidget.cpp
  86     kitemviews/private/kitemlistkeyboardsearchmanager.cpp
  87     kitemviews/private/kitemlistroleeditor.cpp
  88     kitemviews/private/kitemlistrubberband.cpp
  89     kitemviews/private/kitemlistselectiontoggle.cpp
  90     kitemviews/private/kitemlistsizehintresolver.cpp
  91     kitemviews/private/kitemlistsmoothscroller.cpp
  92     kitemviews/private/kitemlistviewanimation.cpp
  93     kitemviews/private/kitemlistviewlayouter.cpp
  94     kitemviews/private/kpixmapmodifier.cpp
  95     settings/applyviewpropsjob.cpp
  96     settings/viewmodes/viewmodesettings.cpp
  97     settings/viewpropertiesdialog.cpp
  98     settings/viewpropsprogressinfo.cpp
  99     views/dolphinfileitemlistwidget.cpp
 100     views/dolphinitemlistview.cpp
 101     views/dolphinnewfilemenuobserver.cpp
 102     views/dolphinremoteencoding.cpp
 103     views/dolphinview.cpp
 104     views/dolphinviewactionhandler.cpp
 105     views/draganddrophelper.cpp
 106     views/versioncontrol/updateitemstatesthread.cpp
 107     views/versioncontrol/versioncontrolobserver.cpp
 108     views/viewmodecontroller.cpp
 109     views/viewproperties.cpp
 110     views/zoomlevelinfo.cpp
 111     dolphinremoveaction.cpp
 112     middleclickactioneventfilter.cpp
 113     dolphinnewfilemenu.cpp
 114 )
 115
 116 ecm_qt_declare_logging_category(dolphinprivate
 117     HEADER dolphindebug.h
 118     IDENTIFIER DolphinDebug
 119     CATEGORY_NAME org.kde.dolphin
 120     DESCRIPTION "dolphin"
 121     EXPORT DOLPHIN
 122 )
 123
 124 if(HAVE_BALOO)
 125     target_sources(dolphinprivate PRIVATE
 126         views/tooltips/dolphinfilemetadatawidget.cpp
 127         views/tooltips/tooltipmanager.cpp
 128         kitemviews/private/kbaloorolesprovider.cpp
 129     )
 130 endif()
 131
 132 kconfig_add_kcfg_files(dolphinprivate
 133     settings/dolphin_compactmodesettings.kcfgc
 134     settings/dolphin_directoryviewpropertysettings.kcfgc
 135     settings/dolphin_detailsmodesettings.kcfgc
 136     settings/dolphin_iconsmodesettings.kcfgc
 137     settings/dolphin_generalsettings.kcfgc
 138     settings/dolphin_contextmenusettings.kcfgc
 139     settings/dolphin_versioncontrolsettings.kcfgc
 140 )
 141
 142 generate_export_header(dolphinprivate BASE_NAME dolphin)
 143
 144 target_link_libraries(
 145     dolphinprivate PUBLIC
 146     dolphinvcs
 147     Qt${QT_MAJOR_VERSION}::Concurrent
 148     Qt${QT_MAJOR_VERSION}::Gui
 149     KF5::I18n
 150     KF5::IconThemes
 151     KF5::KIOCore
 152     KF5::KIOWidgets
 153     KF5::KIOFileWidgets
 154     KF5::Completion
 155     KF5::TextWidgets
 156     KF5::ConfigCore
 157     KF5::NewStuff
 158     KF5::Parts
 159     KF5::WindowSystem
 160     KF5::WidgetsAddons
 161 )
 162
 163 if(HAVE_BALOO)
 164     target_link_libraries(
 165         dolphinprivate PUBLIC
 166         KF5::FileMetaData
 167         KF5::Baloo
 168         KF5::BalooWidgets
 169     )
 170 endif()
 171
 172 set_target_properties(dolphinprivate PROPERTIES
 173     VERSION ${DOLPHINPRIVATE_VERSION}
 174     SOVERSION ${DOLPHINPRIVATE_SOVERSION}
 175 )
 176
 177 install(TARGETS dolphinprivate ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} LIBRARY NAMELINK_SKIP)
 178 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphin_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
 179
 180 ##########################################
 181 configure_file(dolphinpart.json.in ${CMAKE_CURRENT_BINARY_DIR}/dolphinpart.json @ONLY)
 182
 183 add_library(dolphinpart MODULE)
 184
 185 target_sources(dolphinpart PRIVATE
 186     dolphinpart.cpp
 187     dolphinpart_ext.cpp
 188     dolphindebug.cpp
 189
 190     dolphinpart.qrc
 191 )
 192
 193 target_link_libraries(dolphinpart
 194     dolphinprivate
 195 )
 196
 197 install(TARGETS dolphinpart DESTINATION ${KDE_INSTALL_PLUGINDIR}/kf5/parts)
 198
 199 ##########################################
 200
 201 add_library(dolphinstatic STATIC)
 202
 203 target_sources(dolphinstatic PRIVATE
 204     dolphinbookmarkhandler.cpp
 205     dolphindockwidget.cpp
 206     dolphinmainwindow.cpp
 207     dolphinviewcontainer.cpp
 208     dolphincontextmenu.cpp
 209     dolphinnavigatorswidgetaction.cpp
 210     dolphintabbar.cpp
 211     dolphinplacesmodelsingleton.cpp
 212     dolphinrecenttabsmenu.cpp
 213     dolphintabpage.cpp
 214     dolphintabwidget.cpp
 215     dolphinurlnavigator.cpp
 216     dolphinurlnavigatorscontroller.cpp
 217     trash/dolphintrash.cpp
 218     filterbar/filterbar.cpp
 219     panels/places/placespanel.cpp
 220     panels/panel.cpp
 221     panels/folders/foldersitemlistwidget.cpp
 222     panels/folders/treeviewcontextmenu.cpp
 223     panels/folders/folderspanel.cpp
 224     panels/terminal/terminalpanel.cpp
 225     search/dolphinfacetswidget.cpp
 226     search/dolphinquery.cpp
 227     search/dolphinsearchbox.cpp
 228     settings/general/behaviorsettingspage.cpp
 229     settings/general/configurepreviewplugindialog.cpp
 230     settings/general/confirmationssettingspage.cpp
 231     settings/general/generalsettingspage.cpp
 232     settings/general/previewssettingspage.cpp
 233     settings/general/statusbarsettingspage.cpp
 234     settings/dolphinsettingsdialog.cpp
 235     settings/navigation/navigationsettingspage.cpp
 236     settings/contextmenu/contextmenusettingspage.cpp
 237     settings/settingspagebase.cpp
 238     settings/serviceitemdelegate.cpp
 239     settings/servicemodel.cpp
 240     settings/startup/startupsettingspage.cpp
 241     settings/trash/trashsettingspage.cpp
 242     settings/viewmodes/dolphinfontrequester.cpp
 243     settings/viewmodes/viewsettingspage.cpp
 244     settings/viewmodes/viewmodesettings.cpp
 245     settings/viewmodes/viewsettingstab.cpp
 246     statusbar/dolphinstatusbar.cpp
 247     statusbar/mountpointobserver.cpp
 248     statusbar/mountpointobservercache.cpp
 249     statusbar/spaceinfoobserver.cpp
 250     statusbar/statusbarspaceinfo.cpp
 251     views/zoomlevelinfo.cpp
 252     dolphindebug.cpp
 253     global.cpp
 254     dolphin.qrc
 255 )
 256
 257 if(HAVE_BALOO)
 258     target_sources(dolphinstatic PRIVATE
 259         panels/information/informationpanel.cpp
 260         panels/information/informationpanelcontent.cpp
 261         panels/information/pixmapviewer.cpp
 262         panels/information/phononwidget.cpp
 263     )
 264 endif()
 265
 266 if(HAVE_KUSERFEEDBACK)
 267     target_sources(dolphinstatic PRIVATE
 268         userfeedback/dolphinfeedbackprovider.cpp
 269         userfeedback/settingsdatasource.cpp
 270         userfeedback/placesdatasource.cpp
 271         settings/userfeedback/userfeedbacksettingspage.cpp
 272     )
 273 endif()
 274
 275 kconfig_add_kcfg_files(dolphinstatic
 276     panels/folders/dolphin_folderspanelsettings.kcfgc
 277     panels/information/dolphin_informationpanelsettings.kcfgc
 278     panels/places/dolphin_placespanelsettings.kcfgc
 279     settings/dolphin_compactmodesettings.kcfgc
 280     settings/dolphin_detailsmodesettings.kcfgc
 281     settings/dolphin_contextmenusettings.kcfgc
 282     settings/dolphin_iconsmodesettings.kcfgc
 283     search/dolphin_searchsettings.kcfgc
 284     settings/dolphin_versioncontrolsettings.kcfgc
 285 )
 286 kconfig_add_kcfg_files(dolphinstatic GENERATE_MOC
 287     settings/dolphin_generalsettings.kcfgc
 288 )
 289
 290 qt_generate_dbus_interface(${CMAKE_CURRENT_SOURCE_DIR}/dolphinmainwindow.h org.kde.DolphinMainWindow.xml)
 291 qt_add_dbus_adaptor(dolphin_dbus_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindow.h DolphinMainWindow)
 292 qt_add_dbus_interface(dolphin_dbus_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindowinterface)
 293 qt_add_dbus_interface(dolphin_dbus_SRCS panels/terminal/org.kde.KIOFuse.VFS.xml kiofuse_interface)
 294
 295 target_sources(dolphinstatic PRIVATE
 296     ${dolphin_dbus_SRCS}
 297 )
 298
 299 target_include_directories(dolphinstatic SYSTEM PRIVATE ${PHONON_INCLUDES})
 300 target_link_libraries(dolphinstatic
 301     dolphinprivate
 302     KF5::CoreAddons
 303     KF5::KCMUtils
 304     KF5::DBusAddons
 305     KF5::Notifications
 306     Phonon::phonon4qt${QT_MAJOR_VERSION}
 307 )
 308
 309 if (HAVE_KACTIVITIES)
 310     target_link_libraries(
 311         dolphinstatic
 312         KF5::Activities
 313     )
 314 endif()
 315
 316 if (HAVE_KUSERFEEDBACK)
 317     target_link_libraries(
 318         dolphinstatic
 319         KUserFeedbackCore
 320         KUserFeedbackWidgets
 321     )
 322 endif()
 323
 324 add_executable(dolphin)
 325
 326 target_sources(dolphin PRIVATE
 327     dbusinterface.cpp
 328     main.cpp
 329 )
 330
 331 if(FLATPAK)
 332     target_compile_definitions(dolphin PRIVATE FLATPAK)
 333 endif()
 334
 335 # Sets the icon on Windows and OSX
 336 file(GLOB ICONS_SRCS "${CMAKE_CURRENT_SOURCE_DIR}/icons/*system-file-manager.png")
 337 ecm_add_app_icon(dolphin ICONS ${ICONS_SRCS})
 338
 339 target_link_libraries(dolphin
 340     PRIVATE
 341     dolphinprivate
 342     dolphinstatic
 343     KF5::Crash
 344 )
 345
 346 include(DbusInterfaceMacros)
 347
 348 generate_and_install_dbus_interface(
 349     dolphin
 350     dbusinterface.h
 351     org.freedesktop.FileManager1.xml
 352     OPTIONS -a
 353 )
 354
 355 install(TARGETS dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 356
 357 ##########################################
 358
 359 if(NOT WIN32)
 360     # The settings are still accessible from the hamburger menu
 361     add_library(kcm_dolphinviewmodes MODULE)
 362     add_library(kcm_dolphinnavigation MODULE)
 363     add_library(kcm_dolphingeneral MODULE)
 364
 365     target_sources(kcm_dolphinviewmodes PRIVATE
 366         settings/kcm/kcmdolphinviewmodes.cpp
 367         settings/viewmodes/dolphinfontrequester.cpp
 368         settings/viewmodes/viewmodesettings.cpp
 369         settings/viewmodes/viewsettingstab.cpp
 370         views/zoomlevelinfo.cpp)
 371
 372     target_sources(kcm_dolphinnavigation PRIVATE
 373         settings/kcm/kcmdolphinnavigation.cpp
 374         settings/navigation/navigationsettingspage.cpp
 375         settings/settingspagebase.cpp)
 376
 377     target_sources(kcm_dolphingeneral PRIVATE
 378         settings/kcm/kcmdolphingeneral.cpp
 379         settings/general/behaviorsettingspage.cpp
 380         settings/general/previewssettingspage.cpp
 381         settings/general/configurepreviewplugindialog.cpp
 382         settings/general/confirmationssettingspage.cpp
 383         settings/settingspagebase.cpp
 384         settings/serviceitemdelegate.cpp
 385         settings/servicemodel.cpp)
 386
 387     kconfig_add_kcfg_files(kcm_dolphinviewmodes
 388         settings/dolphin_compactmodesettings.kcfgc
 389         settings/dolphin_directoryviewpropertysettings.kcfgc
 390         settings/dolphin_detailsmodesettings.kcfgc
 391         settings/dolphin_iconsmodesettings.kcfgc
 392         settings/dolphin_generalsettings.kcfgc
 393         settings/dolphin_versioncontrolsettings.kcfgc
 394     )
 395
 396     kconfig_add_kcfg_files(kcm_dolphinnavigation
 397         settings/dolphin_generalsettings.kcfgc)
 398
 399     kconfig_add_kcfg_files(kcm_dolphingeneral
 400         settings/dolphin_generalsettings.kcfgc)
 401
 402     target_link_libraries(kcm_dolphinviewmodes dolphinprivate)
 403     target_link_libraries(kcm_dolphinnavigation dolphinprivate)
 404     target_link_libraries(kcm_dolphingeneral dolphinprivate)
 405
 406     install( FILES org.kde.dolphin.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR} )
 407
 408     install(TARGETS kcm_dolphinviewmodes DESTINATION ${KDE_INSTALL_PLUGINDIR}/dolphin/kcms )
 409     install(TARGETS kcm_dolphinnavigation DESTINATION ${KDE_INSTALL_PLUGINDIR}/dolphin/kcms )
 410     install(TARGETS kcm_dolphingeneral DESTINATION ${KDE_INSTALL_PLUGINDIR}/dolphin/kcms )
 411 endif()
 412
 413 if(NOT WIN32)
 414     add_subdirectory(settings/contextmenu/servicemenuinstaller)
 415     install( FILES settings/contextmenu/servicemenu.knsrc DESTINATION ${KDE_INSTALL_KNSRCDIR} )
 416 endif()
 417
 418 ########### install files ###############
 419
 420 install( PROGRAMS org.kde.dolphin.desktop DESTINATION ${KDE_INSTALL_APPDIR} )
 421
 422 install( DIRECTORY DESTINATION "${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel" )
 423
 424 install(
 425     CODE "execute_process(COMMAND \"${CMAKE_COMMAND}\" -E create_symlink \"${KDE_INSTALL_FULL_APPDIR}/org.kde.dolphin.desktop\" \"\$ENV{DESTDIR}${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel/org.kde.dolphin.desktop\")"
 426 )
 427
 428 install( FILES settings/dolphin_directoryviewpropertysettings.kcfg
 429                settings/dolphin_generalsettings.kcfg
 430                settings/dolphin_contextmenusettings.kcfg
 431                settings/dolphin_compactmodesettings.kcfg
 432                settings/dolphin_iconsmodesettings.kcfg
 433                settings/dolphin_detailsmodesettings.kcfg
 434                settings/dolphin_versioncontrolsettings.kcfg
 435          DESTINATION ${KDE_INSTALL_KCFGDIR} )
 436
 437 if(BUILD_TESTING)
 438     add_subdirectory(tests)
 439 endif()