src/CMakeLists.txt

   1 include(ECMAddAppIcon)
   2
   3 configure_file(config-dolphin.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-dolphin.h)
   4
   5 add_definitions(
   6     -DTRANSLATION_DOMAIN=\"dolphin\"
   7 )
   8 remove_definitions(
   9     -DQT_NO_CAST_FROM_BYTEARRAY
  10     -DQT_NO_CAST_FROM_ASCII
  11     -DQT_NO_CAST_TO_ASCII
  12 )
  13
  14 ##########################################
  15
  16 add_library(dolphinvcs SHARED)
  17
  18 target_sources(dolphinvcs PRIVATE
  19     views/versioncontrol/kversioncontrolplugin.cpp
  20 )
  21
  22 generate_export_header(dolphinvcs BASE_NAME dolphinvcs)
  23
  24 target_link_libraries(
  25     dolphinvcs PUBLIC
  26     Qt${QT_MAJOR_VERSION}::Widgets
  27 )
  28
  29 set_target_properties(dolphinvcs PROPERTIES
  30     VERSION ${DOLPHINVCS_VERSION}
  31     SOVERSION ${DOLPHINVCS_SOVERSION}
  32     EXPORT_NAME DolphinVcs
  33 )
  34
  35 ecm_generate_headers(dolphinvcs_LIB_HEADERS
  36     HEADER_NAMES
  37     KVersionControlPlugin
  38
  39     RELATIVE "views/versioncontrol"
  40     REQUIRED_HEADERS dolphinvcs_LIB_HEADERS
  41 )
  42
  43 install(TARGETS dolphinvcs EXPORT DolphinVcsTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
  44
  45 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphinvcs_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
  46 install(FILES ${dolphinvcs_LIB_HEADERS} DESTINATION "${KDE_INSTALL_INCLUDEDIR}/Dolphin" COMPONENT Devel)
  47
  48 ########### next target ###############
  49
  50 add_library(dolphinprivate SHARED)
  51
  52 target_sources(dolphinprivate PRIVATE
  53     kitemviews/kfileitemlistview.cpp
  54     kitemviews/kfileitemlistwidget.cpp
  55     kitemviews/kfileitemlisttostring.cpp
  56     kitemviews/kfileitemmodel.cpp
  57     kitemviews/kfileitemmodelrolesupdater.cpp
  58     kitemviews/kitemlistcontainer.cpp
  59     kitemviews/kitemlistcontroller.cpp
  60     kitemviews/kitemlistgroupheader.cpp
  61     kitemviews/kitemlistheader.cpp
  62     kitemviews/kitemlistselectionmanager.cpp
  63     kitemviews/kitemliststyleoption.cpp
  64     kitemviews/kitemlistview.cpp
  65     kitemviews/kitemlistviewaccessible.cpp
  66     kitemviews/kitemlistwidget.cpp
  67     kitemviews/kitemmodelbase.cpp
  68     kitemviews/kitemset.cpp
  69     kitemviews/kstandarditemlistgroupheader.cpp
  70     kitemviews/kstandarditemlistwidget.cpp
  71     kitemviews/kstandarditemlistview.cpp
  72     kitemviews/private/kdirectorycontentscounter.cpp
  73     kitemviews/private/kdirectorycontentscounterworker.cpp
  74     kitemviews/private/kfileitemclipboard.cpp
  75     kitemviews/private/kfileitemmodelfilter.cpp
  76     kitemviews/private/kitemlistheaderwidget.cpp
  77     kitemviews/private/kitemlistkeyboardsearchmanager.cpp
  78     kitemviews/private/kitemlistroleeditor.cpp
  79     kitemviews/private/kitemlistrubberband.cpp
  80     kitemviews/private/kitemlistselectiontoggle.cpp
  81     kitemviews/private/kitemlistsizehintresolver.cpp
  82     kitemviews/private/kitemlistsmoothscroller.cpp
  83     kitemviews/private/kitemlistviewanimation.cpp
  84     kitemviews/private/kitemlistviewlayouter.cpp
  85     kitemviews/private/kpixmapmodifier.cpp
  86     settings/applyviewpropsjob.cpp
  87     settings/viewmodes/viewmodesettings.cpp
  88     settings/viewpropertiesdialog.cpp
  89     settings/viewpropsprogressinfo.cpp
  90     selectionmode/actiontexthelper.cpp
  91     views/dolphinfileitemlistwidget.cpp
  92     views/dolphinitemlistview.cpp
  93     views/dolphinnewfilemenuobserver.cpp
  94     views/dolphinremoteencoding.cpp
  95     views/dolphinview.cpp
  96     views/dolphinviewactionhandler.cpp
  97     views/draganddrophelper.cpp
  98     views/versioncontrol/updateitemstatesthread.cpp
  99     views/versioncontrol/versioncontrolobserver.cpp
 100     views/viewmodecontroller.cpp
 101     views/viewproperties.cpp
 102     views/zoomlevelinfo.cpp
 103     dolphinremoveaction.cpp
 104     middleclickactioneventfilter.cpp
 105     dolphinnewfilemenu.cpp
 106
 107     kitemviews/kfileitemlistview.h
 108     kitemviews/kfileitemlistwidget.h
 109     kitemviews/kfileitemlisttostring.h
 110     kitemviews/kfileitemmodel.h
 111     kitemviews/kfileitemmodelrolesupdater.h
 112     kitemviews/kitemlistcontainer.h
 113     kitemviews/kitemlistcontroller.h
 114     kitemviews/kitemlistgroupheader.h
 115     kitemviews/kitemlistheader.h
 116     kitemviews/kitemlistselectionmanager.h
 117     kitemviews/kitemliststyleoption.h
 118     kitemviews/kitemlistview.h
 119     kitemviews/kitemlistviewaccessible.h
 120     kitemviews/kitemlistwidget.h
 121     kitemviews/kitemmodelbase.h
 122     kitemviews/kitemset.h
 123     kitemviews/kstandarditemlistgroupheader.h
 124     kitemviews/kstandarditemlistwidget.h
 125     kitemviews/kstandarditemlistview.h
 126     kitemviews/private/kdirectorycontentscounter.h
 127     kitemviews/private/kdirectorycontentscounterworker.h
 128     kitemviews/private/kfileitemclipboard.h
 129     kitemviews/private/kfileitemmodelfilter.h
 130     kitemviews/private/kitemlistheaderwidget.h
 131     kitemviews/private/kitemlistkeyboardsearchmanager.h
 132     kitemviews/private/kitemlistroleeditor.h
 133     kitemviews/private/kitemlistrubberband.h
 134     kitemviews/private/kitemlistselectiontoggle.h
 135     kitemviews/private/kitemlistsizehintresolver.h
 136     kitemviews/private/kitemlistsmoothscroller.h
 137     kitemviews/private/kitemlistviewanimation.h
 138     kitemviews/private/kitemlistviewlayouter.h
 139     kitemviews/private/kpixmapmodifier.h
 140     settings/applyviewpropsjob.h
 141     settings/viewmodes/viewmodesettings.h
 142     settings/viewpropertiesdialog.h
 143     settings/viewpropsprogressinfo.h
 144     selectionmode/actiontexthelper.h
 145     views/dolphinfileitemlistwidget.h
 146     views/dolphinitemlistview.h
 147     views/dolphinnewfilemenuobserver.h
 148     views/dolphinremoteencoding.h
 149     views/dolphinview.h
 150     views/dolphinviewactionhandler.h
 151     views/draganddrophelper.h
 152     views/versioncontrol/updateitemstatesthread.h
 153     views/versioncontrol/versioncontrolobserver.h
 154     views/viewmodecontroller.h
 155     views/viewproperties.h
 156     views/zoomlevelinfo.h
 157     dolphinremoveaction.h
 158     middleclickactioneventfilter.h
 159     dolphinnewfilemenu.h
 160 )
 161
 162 ecm_qt_declare_logging_category(dolphinprivate
 163     HEADER dolphindebug.h
 164     IDENTIFIER DolphinDebug
 165     CATEGORY_NAME org.kde.dolphin
 166     DESCRIPTION "dolphin"
 167     EXPORT DOLPHIN
 168 )
 169
 170 if(HAVE_BALOO)
 171     target_sources(dolphinprivate PRIVATE
 172         views/tooltips/dolphinfilemetadatawidget.cpp
 173         views/tooltips/tooltipmanager.cpp
 174         kitemviews/private/kbaloorolesprovider.cpp
 175         views/tooltips/dolphinfilemetadatawidget.h
 176         views/tooltips/tooltipmanager.h
 177         kitemviews/private/kbaloorolesprovider.h
 178     )
 179 endif()
 180
 181 kconfig_add_kcfg_files(dolphinprivate
 182     settings/dolphin_compactmodesettings.kcfgc
 183     settings/dolphin_directoryviewpropertysettings.kcfgc
 184     settings/dolphin_detailsmodesettings.kcfgc
 185     settings/dolphin_iconsmodesettings.kcfgc
 186     settings/dolphin_generalsettings.kcfgc
 187     settings/dolphin_contextmenusettings.kcfgc
 188     settings/dolphin_versioncontrolsettings.kcfgc
 189 )
 190
 191 generate_export_header(dolphinprivate BASE_NAME dolphin)
 192
 193 target_link_libraries(
 194     dolphinprivate PUBLIC
 195     dolphinvcs
 196     Qt${QT_MAJOR_VERSION}::Concurrent
 197     Qt${QT_MAJOR_VERSION}::Gui
 198     KF6::I18n
 199     KF6::IconThemes
 200     KF6::KIOCore
 201     KF6::KIOWidgets
 202     KF6::KIOFileWidgets
 203     KF6::Completion
 204     KF6::TextWidgets
 205     KF6::ConfigCore
 206     KF6::NewStuff
 207     KF6::NewStuffWidgets    # KNSWidgets::Button
 208     KF6::Parts
 209     KF6::WindowSystem
 210     KF6::WidgetsAddons
 211     KF6::Codecs
 212 )
 213
 214 if(HAVE_BALOO)
 215     target_link_libraries(
 216         dolphinprivate PUBLIC
 217         KF6::FileMetaData
 218         KF6::Baloo
 219         KF6::BalooWidgets
 220     )
 221 endif()
 222
 223 set_target_properties(dolphinprivate PROPERTIES
 224     VERSION ${DOLPHINPRIVATE_VERSION}
 225     SOVERSION ${DOLPHINPRIVATE_SOVERSION}
 226 )
 227
 228 install(TARGETS dolphinprivate ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} LIBRARY NAMELINK_SKIP)
 229 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphin_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
 230
 231 ##########################################
 232 configure_file(dolphinpart.json.in ${CMAKE_CURRENT_BINARY_DIR}/dolphinpart.json @ONLY)
 233
 234 add_library(dolphinpart MODULE)
 235
 236 target_sources(dolphinpart PRIVATE
 237     dolphinpart.cpp
 238     dolphinpart_ext.cpp
 239     dolphindebug.cpp
 240     dolphinpart.h
 241     dolphinpart_ext.h
 242     dolphindebug.h
 243
 244     dolphinpart.qrc
 245 )
 246
 247 target_link_libraries(dolphinpart
 248     dolphinprivate
 249 )
 250
 251 install(TARGETS dolphinpart DESTINATION ${KDE_INSTALL_PLUGINDIR}/kf${QT_MAJOR_VERSION}/parts)
 252 install(FILES dolphinpartactions.desktop DESTINATION "${KDE_INSTALL_DATADIR}/dolphin/")
 253
 254 ##########################################
 255
 256 add_library(dolphinstatic STATIC)
 257
 258 target_sources(dolphinstatic PRIVATE
 259     dolphinbookmarkhandler.cpp
 260     dolphindockwidget.cpp
 261     dolphinmainwindow.cpp
 262     dolphinviewcontainer.cpp
 263     dolphincontextmenu.cpp
 264     dolphinnavigatorswidgetaction.cpp
 265     dolphintabbar.cpp
 266     dolphinplacesmodelsingleton.cpp
 267     dolphinrecenttabsmenu.cpp
 268     dolphintabpage.cpp
 269     dolphintabwidget.cpp
 270     dolphinurlnavigator.cpp
 271     dolphinurlnavigatorscontroller.cpp
 272     trash/dolphintrash.cpp
 273     filterbar/filterbar.cpp
 274     kitemviews/kfileitemlisttostring.cpp
 275     panels/places/placespanel.cpp
 276     panels/panel.cpp
 277     panels/folders/foldersitemlistwidget.cpp
 278     panels/folders/treeviewcontextmenu.cpp
 279     panels/folders/folderspanel.cpp
 280     panels/terminal/terminalpanel.cpp
 281     search/dolphinfacetswidget.cpp
 282     search/dolphinquery.cpp
 283     search/dolphinsearchbox.cpp
 284     selectionmode/actiontexthelper.cpp
 285     selectionmode/actionwithwidget.cpp
 286     selectionmode/backgroundcolorhelper.cpp
 287     selectionmode/bottombar.cpp
 288     selectionmode/bottombarcontentscontainer.cpp
 289     selectionmode/topbar.cpp
 290     settings/general/behaviorsettingspage.cpp
 291     settings/general/confirmationssettingspage.cpp
 292     settings/general/generalsettingspage.cpp
 293     settings/general/previewssettingspage.cpp
 294     settings/general/statusbarsettingspage.cpp
 295     settings/dolphinsettingsdialog.cpp
 296     settings/navigation/navigationsettingspage.cpp
 297     settings/contextmenu/contextmenusettingspage.cpp
 298     settings/settingspagebase.cpp
 299     settings/serviceitemdelegate.cpp
 300     settings/servicemodel.cpp
 301     settings/startup/startupsettingspage.cpp
 302     settings/trash/trashsettingspage.cpp
 303     settings/viewmodes/dolphinfontrequester.cpp
 304     settings/viewmodes/viewsettingspage.cpp
 305     settings/viewmodes/viewmodesettings.cpp
 306     settings/viewmodes/viewsettingstab.cpp
 307     statusbar/dolphinstatusbar.cpp
 308     statusbar/mountpointobserver.cpp
 309     statusbar/mountpointobservercache.cpp
 310     statusbar/spaceinfoobserver.cpp
 311     statusbar/statusbarspaceinfo.cpp
 312     views/zoomlevelinfo.cpp
 313     dolphindebug.cpp
 314     global.cpp
 315     dolphin.qrc
 316
 317     dolphinbookmarkhandler.h
 318     dolphindockwidget.h
 319     dolphinmainwindow.h
 320     dolphinviewcontainer.h
 321     dolphincontextmenu.h
 322     dolphinnavigatorswidgetaction.h
 323     dolphintabbar.h
 324     dolphinplacesmodelsingleton.h
 325     dolphinrecenttabsmenu.h
 326     dolphintabpage.h
 327     dolphintabwidget.h
 328     dolphinurlnavigator.h
 329     dolphinurlnavigatorscontroller.h
 330     trash/dolphintrash.h
 331     filterbar/filterbar.h
 332     kitemviews/kfileitemlisttostring.h
 333     panels/places/placespanel.h
 334     panels/panel.h
 335     panels/folders/foldersitemlistwidget.h
 336     panels/folders/treeviewcontextmenu.h
 337     panels/folders/folderspanel.h
 338     panels/terminal/terminalpanel.h
 339     search/dolphinfacetswidget.h
 340     search/dolphinquery.h
 341     search/dolphinsearchbox.h
 342     selectionmode/actiontexthelper.h
 343     selectionmode/actionwithwidget.h
 344     selectionmode/backgroundcolorhelper.h
 345     selectionmode/bottombar.h
 346     selectionmode/bottombarcontentscontainer.h
 347     selectionmode/topbar.h
 348     settings/general/behaviorsettingspage.h
 349     settings/general/confirmationssettingspage.h
 350     settings/general/generalsettingspage.h
 351     settings/general/previewssettingspage.h
 352     settings/general/statusbarsettingspage.h
 353     settings/dolphinsettingsdialog.h
 354     settings/navigation/navigationsettingspage.h
 355     settings/contextmenu/contextmenusettingspage.h
 356     settings/settingspagebase.h
 357     settings/serviceitemdelegate.h
 358     settings/servicemodel.h
 359     settings/startup/startupsettingspage.h
 360     settings/trash/trashsettingspage.h
 361     settings/viewmodes/dolphinfontrequester.h
 362     settings/viewmodes/viewsettingspage.h
 363     settings/viewmodes/viewmodesettings.h
 364     settings/viewmodes/viewsettingstab.h
 365     statusbar/dolphinstatusbar.h
 366     statusbar/mountpointobserver.h
 367     statusbar/mountpointobservercache.h
 368     statusbar/spaceinfoobserver.h
 369     statusbar/statusbarspaceinfo.h
 370     views/zoomlevelinfo.h
 371     dolphindebug.h
 372     global.h
 373 )
 374
 375 if(HAVE_BALOO)
 376     target_sources(dolphinstatic PRIVATE
 377         panels/information/informationpanel.cpp
 378         panels/information/informationpanelcontent.cpp
 379         panels/information/pixmapviewer.cpp
 380         panels/information/phononwidget.cpp
 381         panels/information/informationpanel.h
 382         panels/information/informationpanelcontent.h
 383         panels/information/pixmapviewer.h
 384         panels/information/phononwidget.h
 385     )
 386 endif()
 387
 388 if(HAVE_KUSERFEEDBACK)
 389     target_sources(dolphinstatic PRIVATE
 390         userfeedback/dolphinfeedbackprovider.cpp
 391         userfeedback/settingsdatasource.cpp
 392         userfeedback/placesdatasource.cpp
 393         settings/userfeedback/userfeedbacksettingspage.cpp
 394         userfeedback/dolphinfeedbackprovider.h
 395         userfeedback/settingsdatasource.h
 396         userfeedback/placesdatasource.h
 397         settings/userfeedback/userfeedbacksettingspage.h
 398     )
 399 endif()
 400
 401 kconfig_add_kcfg_files(dolphinstatic
 402     panels/folders/dolphin_folderspanelsettings.kcfgc
 403     panels/information/dolphin_informationpanelsettings.kcfgc
 404     panels/places/dolphin_placespanelsettings.kcfgc
 405     settings/dolphin_compactmodesettings.kcfgc
 406     settings/dolphin_detailsmodesettings.kcfgc
 407     settings/dolphin_contextmenusettings.kcfgc
 408     settings/dolphin_iconsmodesettings.kcfgc
 409     search/dolphin_searchsettings.kcfgc
 410     settings/dolphin_versioncontrolsettings.kcfgc
 411 )
 412 kconfig_add_kcfg_files(dolphinstatic GENERATE_MOC
 413     settings/dolphin_generalsettings.kcfgc
 414 )
 415
 416 qt_generate_dbus_interface(${CMAKE_CURRENT_SOURCE_DIR}/dolphinmainwindow.h org.kde.DolphinMainWindow.xml)
 417 qt_add_dbus_adaptor(dolphin_dbus_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindow.h DolphinMainWindow)
 418 qt_add_dbus_interface(dolphin_dbus_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindowinterface)
 419 qt_add_dbus_interface(dolphin_dbus_SRCS panels/terminal/org.kde.KIOFuse.VFS.xml kiofuse_interface)
 420
 421 target_sources(dolphinstatic PRIVATE
 422     ${dolphin_dbus_SRCS}
 423 )
 424
 425 target_include_directories(dolphinstatic SYSTEM PRIVATE ${PHONON_INCLUDES})
 426 target_link_libraries(dolphinstatic
 427     dolphinprivate
 428     KF6::CoreAddons
 429     KF6::KCMUtils
 430     KF6::DBusAddons
 431     KF6::Notifications
 432     Phonon::phonon4qt${QT_MAJOR_VERSION}
 433 )
 434
 435 if (HAVE_KACTIVITIES)
 436     target_link_libraries(
 437         dolphinstatic
 438         KF6::Activities
 439     )
 440 endif()
 441
 442 if (HAVE_KUSERFEEDBACK)
 443     target_link_libraries(
 444         dolphinstatic
 445         KUserFeedbackCore
 446         KUserFeedbackWidgets
 447     )
 448 endif()
 449
 450 add_executable(dolphin)
 451
 452 target_sources(dolphin PRIVATE
 453     dbusinterface.cpp
 454     dbusinterface.h
 455     main.cpp
 456 )
 457
 458 if(FLATPAK)
 459     target_compile_definitions(dolphin PRIVATE FLATPAK)
 460 endif()
 461
 462 # Sets the icon on Windows and OSX
 463 file(GLOB ICONS_SRCS "${CMAKE_CURRENT_SOURCE_DIR}/icons/*system-file-manager.png")
 464 ecm_add_app_icon(dolphin ICONS ${ICONS_SRCS})
 465
 466 target_link_libraries(dolphin
 467     PRIVATE
 468     dolphinprivate
 469     dolphinstatic
 470     KF6::Crash
 471 )
 472
 473 if (HAVE_X11)
 474     if (QT_MAJOR_VERSION STREQUAL "5")
 475         target_link_libraries(dolphin PRIVATE Qt5::X11Extras)
 476     else()
 477         target_link_libraries(dolphin PRIVATE Qt::GuiPrivate)
 478     endif()
 479 endif()
 480
 481 include(DbusInterfaceMacros)
 482
 483 generate_and_install_dbus_interface(
 484     dolphin
 485     dbusinterface.h
 486     org.freedesktop.FileManager1.xml
 487     OPTIONS -a
 488 )
 489
 490 install(TARGETS dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 491
 492 ##########################################
 493
 494 if(NOT WIN32)
 495     # The settings are still accessible from the hamburger menu
 496     add_library(kcm_dolphinviewmodes MODULE)
 497     add_library(kcm_dolphinnavigation MODULE)
 498     add_library(kcm_dolphingeneral MODULE)
 499
 500     target_sources(kcm_dolphinviewmodes PRIVATE
 501         settings/kcm/kcmdolphinviewmodes.cpp
 502         settings/viewmodes/dolphinfontrequester.cpp
 503         settings/viewmodes/viewmodesettings.cpp
 504         settings/viewmodes/viewsettingstab.cpp
 505         views/zoomlevelinfo.cpp
 506         settings/kcm/kcmdolphinviewmodes.h
 507         settings/viewmodes/dolphinfontrequester.h
 508         settings/viewmodes/viewmodesettings.h
 509         settings/viewmodes/viewsettingstab.h
 510         views/zoomlevelinfo.h)
 511
 512     target_sources(kcm_dolphinnavigation PRIVATE
 513         settings/kcm/kcmdolphinnavigation.cpp
 514         settings/navigation/navigationsettingspage.cpp
 515         settings/settingspagebase.cpp
 516         settings/kcm/kcmdolphinnavigation.h
 517         settings/navigation/navigationsettingspage.h
 518         settings/settingspagebase.h
 519     )
 520
 521     target_sources(kcm_dolphingeneral PRIVATE
 522         settings/kcm/kcmdolphingeneral.cpp
 523         settings/general/behaviorsettingspage.cpp
 524         settings/general/previewssettingspage.cpp
 525         settings/general/confirmationssettingspage.cpp
 526         settings/settingspagebase.cpp
 527         settings/serviceitemdelegate.cpp
 528         settings/servicemodel.cpp
 529         settings/kcm/kcmdolphingeneral.h
 530         settings/general/behaviorsettingspage.h
 531         settings/general/previewssettingspage.h
 532         settings/general/confirmationssettingspage.h
 533         settings/settingspagebase.h
 534         settings/serviceitemdelegate.h
 535         settings/servicemodel.h
 536     )
 537
 538     kconfig_add_kcfg_files(kcm_dolphinviewmodes
 539         settings/dolphin_compactmodesettings.kcfgc
 540         settings/dolphin_directoryviewpropertysettings.kcfgc
 541         settings/dolphin_detailsmodesettings.kcfgc
 542         settings/dolphin_iconsmodesettings.kcfgc
 543         settings/dolphin_generalsettings.kcfgc
 544         settings/dolphin_versioncontrolsettings.kcfgc
 545     )
 546
 547     kconfig_add_kcfg_files(kcm_dolphinnavigation
 548         settings/dolphin_generalsettings.kcfgc)
 549
 550     kconfig_add_kcfg_files(kcm_dolphingeneral
 551         settings/dolphin_generalsettings.kcfgc)
 552
 553     target_link_libraries(kcm_dolphinviewmodes dolphinprivate)
 554     target_link_libraries(kcm_dolphinnavigation dolphinprivate)
 555     target_link_libraries(kcm_dolphingeneral dolphinprivate)
 556
 557     install( FILES org.kde.dolphin.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR} )
 558
 559     install(TARGETS kcm_dolphinviewmodes DESTINATION ${KDE_INSTALL_PLUGINDIR}/dolphin/kcms )
 560     install(TARGETS kcm_dolphinnavigation DESTINATION ${KDE_INSTALL_PLUGINDIR}/dolphin/kcms )
 561     install(TARGETS kcm_dolphingeneral DESTINATION ${KDE_INSTALL_PLUGINDIR}/dolphin/kcms )
 562 endif()
 563
 564 if(NOT WIN32)
 565     add_subdirectory(settings/contextmenu/servicemenuinstaller)
 566     install( FILES settings/contextmenu/servicemenu.knsrc DESTINATION ${KDE_INSTALL_KNSRCDIR} )
 567 endif()
 568
 569 ########### install files ###############
 570
 571 install( PROGRAMS org.kde.dolphin.desktop DESTINATION ${KDE_INSTALL_APPDIR} )
 572
 573 install( DIRECTORY DESTINATION "${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel" )
 574
 575 install(
 576     CODE "execute_process(COMMAND \"${CMAKE_COMMAND}\" -E create_symlink \"${KDE_INSTALL_FULL_APPDIR}/org.kde.dolphin.desktop\" \"\$ENV{DESTDIR}${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel/org.kde.dolphin.desktop\")"
 577 )
 578
 579 install( FILES settings/dolphin_directoryviewpropertysettings.kcfg
 580                settings/dolphin_generalsettings.kcfg
 581                settings/dolphin_contextmenusettings.kcfg
 582                settings/dolphin_compactmodesettings.kcfg
 583                settings/dolphin_iconsmodesettings.kcfg
 584                settings/dolphin_detailsmodesettings.kcfg
 585                settings/dolphin_versioncontrolsettings.kcfg
 586          DESTINATION ${KDE_INSTALL_KCFGDIR} )
 587
 588 install( FILES settings/dolphin_detailsmodesettings.upd
 589          DESTINATION ${KDE_INSTALL_KCONFUPDATEDIR} )
 590
 591 if(BUILD_TESTING)
 592     add_subdirectory(tests)
 593 endif()