src/CMakeLists.txt

   1 include(ECMAddAppIcon)
   2
   3 configure_file(config-baloo.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-baloo.h)
   4
   5 configure_file(config-kactivities.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-kactivities.h)
   6
   7 configure_file(config-packagekit.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-packagekit.h)
   8
   9 configure_file(config-terminal.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-terminal.h)
  10
  11 configure_file(config-kuserfeedback.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-kuserfeedback.h)
  12
  13 add_definitions(
  14     -DTRANSLATION_DOMAIN=\"dolphin\"
  15 )
  16 remove_definitions(
  17     -DQT_NO_CAST_FROM_BYTEARRAY
  18     -DQT_NO_CAST_FROM_ASCII
  19     -DQT_NO_CAST_TO_ASCII
  20 )
  21
  22 ##########################################
  23
  24 set(dolphinvcs_LIB_SRCS
  25     views/versioncontrol/kversioncontrolplugin.cpp
  26 )
  27
  28 add_library(dolphinvcs ${dolphinvcs_LIB_SRCS})
  29 generate_export_header(dolphinvcs BASE_NAME dolphinvcs)
  30
  31 target_link_libraries(
  32     dolphinvcs PUBLIC
  33     Qt5::Widgets
  34 )
  35
  36 set_target_properties(dolphinvcs PROPERTIES
  37     VERSION ${DOLPHINVCS_VERSION_STRING}
  38     SOVERSION ${DOLPHINVCS_SOVERSION}
  39     EXPORT_NAME DolphinVcs
  40 )
  41
  42 ecm_generate_headers(dolphinvcs_LIB_HEADERS
  43     HEADER_NAMES
  44     KVersionControlPlugin
  45
  46     RELATIVE "views/versioncontrol"
  47     REQUIRED_HEADERS dolphinvcs_LIB_HEADERS
  48 )
  49
  50 install(TARGETS dolphinvcs EXPORT DolphinVcsTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
  51
  52 install(FILES views/versioncontrol/fileviewversioncontrolplugin.desktop DESTINATION ${KDE_INSTALL_KSERVICETYPES5DIR})
  53 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphinvcs_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
  54 install(FILES ${dolphinvcs_LIB_HEADERS} DESTINATION "${KDE_INSTALL_INCLUDEDIR}/Dolphin" COMPONENT Devel)
  55
  56 ########### next target ###############
  57
  58 set(dolphinprivate_LIB_SRCS
  59     kitemviews/kfileitemlistview.cpp
  60     kitemviews/kfileitemlistwidget.cpp
  61     kitemviews/kfileitemmodel.cpp
  62     kitemviews/kfileitemmodelrolesupdater.cpp
  63     kitemviews/kitemlistcontainer.cpp
  64     kitemviews/kitemlistcontroller.cpp
  65     kitemviews/kitemlistgroupheader.cpp
  66     kitemviews/kitemlistheader.cpp
  67     kitemviews/kitemlistselectionmanager.cpp
  68     kitemviews/kitemliststyleoption.cpp
  69     kitemviews/kitemlistview.cpp
  70     kitemviews/kitemlistviewaccessible.cpp
  71     kitemviews/kitemlistwidget.cpp
  72     kitemviews/kitemmodelbase.cpp
  73     kitemviews/kitemset.cpp
  74     kitemviews/kstandarditem.cpp
  75     kitemviews/kstandarditemlistgroupheader.cpp
  76     kitemviews/kstandarditemlistwidget.cpp
  77     kitemviews/kstandarditemlistview.cpp
  78     kitemviews/kstandarditemmodel.cpp
  79     kitemviews/private/kdirectorycontentscounter.cpp
  80     kitemviews/private/kdirectorycontentscounterworker.cpp
  81     kitemviews/private/kfileitemclipboard.cpp
  82     kitemviews/private/kfileitemmodeldirlister.cpp
  83     kitemviews/private/kfileitemmodelfilter.cpp
  84     kitemviews/private/kitemlistheaderwidget.cpp
  85     kitemviews/private/kitemlistkeyboardsearchmanager.cpp
  86     kitemviews/private/kitemlistroleeditor.cpp
  87     kitemviews/private/kitemlistrubberband.cpp
  88     kitemviews/private/kitemlistselectiontoggle.cpp
  89     kitemviews/private/kitemlistsizehintresolver.cpp
  90     kitemviews/private/kitemlistsmoothscroller.cpp
  91     kitemviews/private/kitemlistviewanimation.cpp
  92     kitemviews/private/kitemlistviewlayouter.cpp
  93     kitemviews/private/kpixmapmodifier.cpp
  94     kitemviews/private/ktwofingerswipe.cpp
  95     kitemviews/private/ktwofingertap.cpp
  96     settings/applyviewpropsjob.cpp
  97     settings/viewmodes/viewmodesettings.cpp
  98     settings/viewpropertiesdialog.cpp
  99     settings/viewpropsprogressinfo.cpp
 100     views/dolphinfileitemlistwidget.cpp
 101     views/dolphinitemlistview.cpp
 102     views/dolphinnewfilemenuobserver.cpp
 103     views/dolphinremoteencoding.cpp
 104     views/dolphinview.cpp
 105     views/dolphinviewactionhandler.cpp
 106     views/draganddrophelper.cpp
 107     views/versioncontrol/updateitemstatesthread.cpp
 108     views/versioncontrol/versioncontrolobserver.cpp
 109     views/viewmodecontroller.cpp
 110     views/viewproperties.cpp
 111     views/zoomlevelinfo.cpp
 112     dolphinremoveaction.cpp
 113     middleclickactioneventfilter.cpp
 114     dolphinnewfilemenu.cpp
 115 )
 116
 117 ecm_qt_declare_logging_category(dolphinprivate_LIB_SRCS HEADER dolphindebug.h IDENTIFIER DolphinDebug CATEGORY_NAME org.kde.dolphin
 118     DESCRIPTION "dolphin" EXPORT DOLPHIN)
 119
 120 if(HAVE_BALOO)
 121     set(dolphinprivate_LIB_SRCS
 122         ${dolphinprivate_LIB_SRCS}
 123         views/tooltips/dolphinfilemetadatawidget.cpp
 124         views/tooltips/tooltipmanager.cpp
 125         kitemviews/private/kbaloorolesprovider.cpp
 126     )
 127 endif()
 128
 129 kconfig_add_kcfg_files(dolphinprivate_LIB_SRCS
 130     settings/dolphin_compactmodesettings.kcfgc
 131     settings/dolphin_directoryviewpropertysettings.kcfgc
 132     settings/dolphin_detailsmodesettings.kcfgc
 133     settings/dolphin_iconsmodesettings.kcfgc
 134     settings/dolphin_generalsettings.kcfgc
 135     settings/dolphin_contextmenusettings.kcfgc
 136     settings/dolphin_versioncontrolsettings.kcfgc
 137 )
 138
 139 add_library(dolphinprivate ${dolphinprivate_LIB_SRCS})
 140 generate_export_header(dolphinprivate BASE_NAME dolphin)
 141
 142 target_link_libraries(
 143     dolphinprivate PUBLIC
 144     dolphinvcs
 145     Qt5::Concurrent
 146     Qt5::Gui
 147     KF5::I18n
 148     KF5::IconThemes
 149     KF5::KIOCore
 150     KF5::KIOWidgets
 151     KF5::KIOFileWidgets
 152     KF5::Completion
 153     KF5::TextWidgets
 154     KF5::ConfigCore
 155     KF5::NewStuff
 156     KF5::Parts
 157     KF5::WindowSystem
 158 )
 159
 160 if(HAVE_BALOO)
 161     target_link_libraries(
 162         dolphinprivate PUBLIC
 163         KF5::FileMetaData
 164         KF5::Baloo
 165         KF5::BalooWidgets
 166     )
 167 endif()
 168
 169 set_target_properties(dolphinprivate PROPERTIES
 170     VERSION ${DOLPHINPRIVATE_VERSION_STRING}
 171     SOVERSION ${DOLPHINPRIVATE_SOVERSION}
 172 )
 173
 174 install(TARGETS dolphinprivate ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} LIBRARY NAMELINK_SKIP)
 175 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphin_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
 176
 177 ##########################################
 178 configure_file(dolphinpart.desktop.in ${CMAKE_CURRENT_BINARY_DIR}/dolphinpart.desktop @ONLY)
 179
 180 set(dolphinpart_SRCS
 181    dolphinpart.cpp
 182    dolphinpart_ext.cpp
 183    dolphindebug.cpp
 184 )
 185
 186 qt5_add_resources(dolphinpart_SRCS dolphinpart.qrc)
 187
 188 add_library(dolphinpart MODULE ${dolphinpart_SRCS})
 189 kcoreaddons_desktop_to_json(dolphinpart ${CMAKE_CURRENT_BINARY_DIR}/dolphinpart.desktop)
 190
 191 target_link_libraries(dolphinpart
 192     dolphinprivate
 193 )
 194
 195 install(TARGETS dolphinpart DESTINATION ${KDE_INSTALL_PLUGINDIR}/kf5/parts)
 196
 197 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphinpart.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR})
 198
 199 ##########################################
 200
 201 set(dolphinstatic_SRCS
 202     dolphinbookmarkhandler.cpp
 203     dolphindockwidget.cpp
 204     dolphinmainwindow.cpp
 205     dolphinviewcontainer.cpp
 206     dolphincontextmenu.cpp
 207     dolphinnavigatorswidgetaction.cpp
 208     dolphintabbar.cpp
 209     dolphinplacesmodelsingleton.cpp
 210     dolphinrecenttabsmenu.cpp
 211     dolphintabpage.cpp
 212     dolphintabwidget.cpp
 213     dolphinurlnavigator.cpp
 214     dolphinurlnavigatorscontroller.cpp
 215     trash/dolphintrash.cpp
 216     filterbar/filterbar.cpp
 217     panels/places/placespanel.cpp
 218     panels/places/placesitem.cpp
 219     panels/places/placesitemlistgroupheader.cpp
 220     panels/places/placesitemlistwidget.cpp
 221     panels/places/placesitemmodel.cpp
 222     panels/places/placesitemsignalhandler.cpp
 223     panels/places/placesview.cpp
 224     panels/panel.cpp
 225     panels/folders/foldersitemlistwidget.cpp
 226     panels/folders/treeviewcontextmenu.cpp
 227     panels/folders/folderspanel.cpp
 228     panels/terminal/terminalpanel.cpp
 229     search/dolphinfacetswidget.cpp
 230     search/dolphinquery.cpp
 231     search/dolphinsearchbox.cpp
 232     settings/general/behaviorsettingspage.cpp
 233     settings/general/configurepreviewplugindialog.cpp
 234     settings/general/confirmationssettingspage.cpp
 235     settings/general/generalsettingspage.cpp
 236     settings/general/previewssettingspage.cpp
 237     settings/general/statusbarsettingspage.cpp
 238     settings/dolphinsettingsdialog.cpp
 239     settings/navigation/navigationsettingspage.cpp
 240     settings/contextmenu/contextmenusettingspage.cpp
 241     settings/settingspagebase.cpp
 242     settings/serviceitemdelegate.cpp
 243     settings/servicemodel.cpp
 244     settings/startup/startupsettingspage.cpp
 245     settings/trash/trashsettingspage.cpp
 246     settings/viewmodes/dolphinfontrequester.cpp
 247     settings/viewmodes/viewsettingspage.cpp
 248     settings/viewmodes/viewmodesettings.cpp
 249     settings/viewmodes/viewsettingstab.cpp
 250     statusbar/dolphinstatusbar.cpp
 251     statusbar/mountpointobserver.cpp
 252     statusbar/mountpointobservercache.cpp
 253     statusbar/spaceinfoobserver.cpp
 254     statusbar/statusbarspaceinfo.cpp
 255     views/zoomlevelinfo.cpp
 256     dolphindebug.cpp
 257     global.cpp
 258 )
 259
 260 if(HAVE_BALOO)
 261     set(dolphinstatic_SRCS
 262         ${dolphinstatic_SRCS}
 263         panels/information/informationpanel.cpp
 264         panels/information/informationpanelcontent.cpp
 265         panels/information/pixmapviewer.cpp
 266         panels/information/phononwidget.cpp
 267     )
 268 endif()
 269
 270 if(HAVE_KUSERFEEDBACK)
 271     set(dolphinstatic_SRCS
 272         ${dolphinstatic_SRCS}
 273         userfeedback/dolphinfeedbackprovider.cpp
 274         userfeedback/settingsdatasource.cpp
 275         userfeedback/placesdatasource.cpp
 276         settings/userfeedback/userfeedbacksettingspage.cpp
 277     )
 278 endif()
 279
 280 kconfig_add_kcfg_files(dolphinstatic_SRCS
 281     panels/folders/dolphin_folderspanelsettings.kcfgc
 282     panels/information/dolphin_informationpanelsettings.kcfgc
 283     panels/places/dolphin_placespanelsettings.kcfgc
 284     settings/dolphin_compactmodesettings.kcfgc
 285     settings/dolphin_detailsmodesettings.kcfgc
 286     settings/dolphin_contextmenusettings.kcfgc
 287     settings/dolphin_iconsmodesettings.kcfgc
 288     search/dolphin_searchsettings.kcfgc
 289     settings/dolphin_versioncontrolsettings.kcfgc
 290 )
 291 kconfig_add_kcfg_files(dolphinstatic_SRCS GENERATE_MOC
 292     settings/dolphin_generalsettings.kcfgc
 293 )
 294
 295 qt5_add_resources(dolphinstatic_SRCS dolphin.qrc)
 296
 297 qt5_generate_dbus_interface(${CMAKE_CURRENT_SOURCE_DIR}/dolphinmainwindow.h org.kde.DolphinMainWindow.xml)
 298 qt5_add_dbus_adaptor(dolphinstatic_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindow.h DolphinMainWindow)
 299 qt5_add_dbus_interface(dolphinstatic_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindowinterface)
 300 qt5_add_dbus_interface(dolphinstatic_SRCS panels/terminal/org.kde.KIOFuse.VFS.xml kiofuse_interface)
 301
 302 add_library(dolphinstatic STATIC ${dolphinstatic_SRCS})
 303
 304 target_include_directories(dolphinstatic SYSTEM PRIVATE ${PHONON_INCLUDES})
 305 target_link_libraries(dolphinstatic
 306     dolphinprivate
 307     KF5::CoreAddons
 308     KF5::KCMUtils
 309     KF5::DBusAddons
 310     KF5::Notifications
 311     Phonon::phonon4qt5
 312 )
 313
 314 if (HAVE_KACTIVITIES)
 315     target_link_libraries(
 316         dolphinstatic
 317         KF5::Activities
 318     )
 319 endif()
 320
 321 if (HAVE_KUSERFEEDBACK)
 322     target_link_libraries(
 323         dolphinstatic
 324         KUserFeedbackCore
 325         KUserFeedbackWidgets
 326     )
 327 endif()
 328
 329 set(dolphin_SRCS
 330     dbusinterface.cpp
 331     main.cpp
 332 )
 333
 334 # Sets the icon on Windows and OSX
 335 file(GLOB ICONS_SRCS "${CMAKE_CURRENT_SOURCE_DIR}/icons/*system-file-manager.png")
 336 ecm_add_app_icon(dolphin_SRCS ICONS ${ICONS_SRCS})
 337
 338 add_executable(dolphin ${dolphin_SRCS})
 339
 340 target_link_libraries(dolphin
 341     PRIVATE
 342     dolphinprivate
 343     dolphinstatic
 344     KF5::Crash
 345 )
 346
 347 include(DbusInterfaceMacros)
 348
 349 generate_and_install_dbus_interface(
 350     dolphin
 351     dbusinterface.h
 352     org.freedesktop.FileManager1.xml
 353     OPTIONS -a
 354 )
 355
 356 install(TARGETS dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 357
 358 ##########################################
 359
 360 set(kcm_dolphinviewmodes_PART_SRCS
 361     settings/kcm/kcmdolphinviewmodes.cpp
 362     settings/viewmodes/dolphinfontrequester.cpp
 363     settings/viewmodes/viewmodesettings.cpp
 364     settings/viewmodes/viewsettingstab.cpp
 365     views/zoomlevelinfo.cpp)
 366
 367 set(kcm_dolphinnavigation_PART_SRCS
 368     settings/kcm/kcmdolphinnavigation.cpp
 369     settings/navigation/navigationsettingspage.cpp
 370     settings/settingspagebase.cpp)
 371
 372 set(kcm_dolphingeneral_PART_SRCS
 373     settings/kcm/kcmdolphingeneral.cpp
 374     settings/general/behaviorsettingspage.cpp
 375     settings/general/previewssettingspage.cpp
 376     settings/general/configurepreviewplugindialog.cpp
 377     settings/general/confirmationssettingspage.cpp
 378     settings/settingspagebase.cpp
 379     settings/serviceitemdelegate.cpp
 380     settings/servicemodel.cpp)
 381
 382 kconfig_add_kcfg_files(kcm_dolphinviewmodes_PART_SRCS
 383     settings/dolphin_compactmodesettings.kcfgc
 384     settings/dolphin_directoryviewpropertysettings.kcfgc
 385     settings/dolphin_detailsmodesettings.kcfgc
 386     settings/dolphin_iconsmodesettings.kcfgc
 387     settings/dolphin_generalsettings.kcfgc
 388     settings/dolphin_versioncontrolsettings.kcfgc
 389 )
 390
 391 kconfig_add_kcfg_files(kcm_dolphinnavigation_PART_SRCS
 392     settings/dolphin_generalsettings.kcfgc)
 393
 394 kconfig_add_kcfg_files(kcm_dolphingeneral_PART_SRCS
 395     settings/dolphin_generalsettings.kcfgc)
 396
 397
 398 if(NOT WIN32)
 399     # The settings are still accessible from the hamburger menu
 400     add_library(kcm_dolphinviewmodes MODULE ${kcm_dolphinviewmodes_PART_SRCS})
 401     add_library(kcm_dolphinnavigation MODULE ${kcm_dolphinnavigation_PART_SRCS})
 402     add_library(kcm_dolphingeneral MODULE ${kcm_dolphingeneral_PART_SRCS})
 403
 404     target_link_libraries(kcm_dolphinviewmodes dolphinprivate)
 405     target_link_libraries(kcm_dolphinnavigation dolphinprivate)
 406     target_link_libraries(kcm_dolphingeneral dolphinprivate)
 407
 408     install( FILES org.kde.dolphin.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR} )
 409     install( FILES settings/kcm/kcmdolphinviewmodes.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 410     install( FILES settings/kcm/kcmdolphinnavigation.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 411     install( FILES settings/kcm/kcmdolphingeneral.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 412
 413     install(TARGETS kcm_dolphinviewmodes DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 414     install(TARGETS kcm_dolphinnavigation DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 415     install(TARGETS kcm_dolphingeneral DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 416 endif()
 417
 418 if(NOT WIN32)
 419     add_subdirectory(settings/contextmenu/servicemenuinstaller)
 420     install( FILES settings/contextmenu/servicemenu.knsrc DESTINATION ${KDE_INSTALL_KNSRCDIR} )
 421 endif()
 422
 423 ########### install files ###############
 424
 425 install( PROGRAMS org.kde.dolphin.desktop DESTINATION ${KDE_INSTALL_APPDIR} )
 426
 427 install( DIRECTORY DESTINATION "${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel" )
 428
 429 install(
 430     CODE "execute_process(COMMAND \"${CMAKE_COMMAND}\" -E create_symlink \"${KDE_INSTALL_FULL_APPDIR}/org.kde.dolphin.desktop\" \"\$ENV{DESTDIR}${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel/org.kde.dolphin.desktop\")"
 431 )
 432
 433 install( FILES settings/dolphin_directoryviewpropertysettings.kcfg
 434                settings/dolphin_generalsettings.kcfg
 435                settings/dolphin_contextmenusettings.kcfg
 436                settings/dolphin_compactmodesettings.kcfg
 437                settings/dolphin_iconsmodesettings.kcfg
 438                settings/dolphin_detailsmodesettings.kcfg
 439                settings/dolphin_versioncontrolsettings.kcfg
 440          DESTINATION ${KDE_INSTALL_KCFGDIR} )
 441
 442 if(BUILD_TESTING)
 443     find_package(Qt5Test ${QT_MIN_VERSION} CONFIG REQUIRED)
 444     add_subdirectory(tests)
 445 endif()