src/CMakeLists.txt

   1 include(ECMAddAppIcon)
   2
   3 configure_file(config-dolphin.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-dolphin.h)
   4
   5 add_definitions(
   6     -DTRANSLATION_DOMAIN=\"dolphin\"
   7 )
   8 remove_definitions(
   9     -DQT_NO_CAST_FROM_BYTEARRAY
  10     -DQT_NO_CAST_FROM_ASCII
  11     -DQT_NO_CAST_TO_ASCII
  12 )
  13
  14 ##########################################
  15
  16 add_library(dolphinvcs SHARED)
  17
  18 target_sources(dolphinvcs PRIVATE
  19     views/versioncontrol/kversioncontrolplugin.cpp
  20 )
  21
  22 generate_export_header(dolphinvcs BASE_NAME dolphinvcs)
  23
  24 target_link_libraries(
  25     dolphinvcs PUBLIC
  26     Qt${QT_MAJOR_VERSION}::Widgets
  27 )
  28
  29 set_target_properties(dolphinvcs PROPERTIES
  30     VERSION ${DOLPHINVCS_VERSION}
  31     SOVERSION ${DOLPHINVCS_SOVERSION}
  32     EXPORT_NAME DolphinVcs
  33 )
  34
  35 ecm_generate_headers(dolphinvcs_LIB_HEADERS
  36     HEADER_NAMES
  37     KVersionControlPlugin
  38
  39     RELATIVE "views/versioncontrol"
  40     REQUIRED_HEADERS dolphinvcs_LIB_HEADERS
  41 )
  42
  43 install(TARGETS dolphinvcs EXPORT DolphinVcsTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
  44
  45 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphinvcs_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
  46 install(FILES ${dolphinvcs_LIB_HEADERS} DESTINATION "${KDE_INSTALL_INCLUDEDIR}/Dolphin" COMPONENT Devel)
  47
  48 ########### next target ###############
  49
  50 add_library(dolphinprivate SHARED)
  51
  52 target_sources(dolphinprivate PRIVATE
  53     kitemviews/kfileitemlistview.cpp
  54     kitemviews/kfileitemlistwidget.cpp
  55     kitemviews/kfileitemlisttostring.cpp
  56     kitemviews/kfileitemmodel.cpp
  57     kitemviews/kfileitemmodelrolesupdater.cpp
  58     kitemviews/kitemlistcontainer.cpp
  59     kitemviews/kitemlistcontroller.cpp
  60     kitemviews/kitemlistgroupheader.cpp
  61     kitemviews/kitemlistheader.cpp
  62     kitemviews/kitemlistselectionmanager.cpp
  63     kitemviews/kitemliststyleoption.cpp
  64     kitemviews/kitemlistview.cpp
  65     kitemviews/kitemlistviewaccessible.cpp
  66     kitemviews/kitemlistwidget.cpp
  67     kitemviews/kitemmodelbase.cpp
  68     kitemviews/kitemset.cpp
  69     kitemviews/kstandarditemlistgroupheader.cpp
  70     kitemviews/kstandarditemlistwidget.cpp
  71     kitemviews/kstandarditemlistview.cpp
  72     kitemviews/private/kdirectorycontentscounter.cpp
  73     kitemviews/private/kdirectorycontentscounterworker.cpp
  74     kitemviews/private/kfileitemclipboard.cpp
  75     kitemviews/private/kfileitemmodelfilter.cpp
  76     kitemviews/private/kitemlistheaderwidget.cpp
  77     kitemviews/private/kitemlistkeyboardsearchmanager.cpp
  78     kitemviews/private/kitemlistroleeditor.cpp
  79     kitemviews/private/kitemlistrubberband.cpp
  80     kitemviews/private/kitemlistselectiontoggle.cpp
  81     kitemviews/private/kitemlistsizehintresolver.cpp
  82     kitemviews/private/kitemlistsmoothscroller.cpp
  83     kitemviews/private/kitemlistviewanimation.cpp
  84     kitemviews/private/kitemlistviewlayouter.cpp
  85     kitemviews/private/kpixmapmodifier.cpp
  86     settings/applyviewpropsjob.cpp
  87     settings/viewmodes/viewmodesettings.cpp
  88     settings/viewpropertiesdialog.cpp
  89     settings/viewpropsprogressinfo.cpp
  90     views/dolphinfileitemlistwidget.cpp
  91     views/dolphinitemlistview.cpp
  92     views/dolphinnewfilemenuobserver.cpp
  93     views/dolphinremoteencoding.cpp
  94     views/dolphinview.cpp
  95     views/dolphinviewactionhandler.cpp
  96     views/draganddrophelper.cpp
  97     views/versioncontrol/updateitemstatesthread.cpp
  98     views/versioncontrol/versioncontrolobserver.cpp
  99     views/viewmodecontroller.cpp
 100     views/viewproperties.cpp
 101     views/zoomlevelinfo.cpp
 102     dolphinremoveaction.cpp
 103     middleclickactioneventfilter.cpp
 104     dolphinnewfilemenu.cpp
 105 )
 106
 107 ecm_qt_declare_logging_category(dolphinprivate
 108     HEADER dolphindebug.h
 109     IDENTIFIER DolphinDebug
 110     CATEGORY_NAME org.kde.dolphin
 111     DESCRIPTION "dolphin"
 112     EXPORT DOLPHIN
 113 )
 114
 115 if(HAVE_BALOO)
 116     target_sources(dolphinprivate PRIVATE
 117         views/tooltips/dolphinfilemetadatawidget.cpp
 118         views/tooltips/tooltipmanager.cpp
 119         kitemviews/private/kbaloorolesprovider.cpp
 120     )
 121 endif()
 122
 123 kconfig_add_kcfg_files(dolphinprivate
 124     settings/dolphin_compactmodesettings.kcfgc
 125     settings/dolphin_directoryviewpropertysettings.kcfgc
 126     settings/dolphin_detailsmodesettings.kcfgc
 127     settings/dolphin_iconsmodesettings.kcfgc
 128     settings/dolphin_generalsettings.kcfgc
 129     settings/dolphin_contextmenusettings.kcfgc
 130     settings/dolphin_versioncontrolsettings.kcfgc
 131 )
 132
 133 generate_export_header(dolphinprivate BASE_NAME dolphin)
 134
 135 target_link_libraries(
 136     dolphinprivate PUBLIC
 137     dolphinvcs
 138     Qt${QT_MAJOR_VERSION}::Concurrent
 139     Qt${QT_MAJOR_VERSION}::Gui
 140     KF5::I18n
 141     KF5::IconThemes
 142     KF5::KIOCore
 143     KF5::KIOWidgets
 144     KF5::KIOFileWidgets
 145     KF5::Completion
 146     KF5::TextWidgets
 147     KF5::ConfigCore
 148     KF5::NewStuff
 149     KF5::NewStuffWidgets    # KNSWidgets::Button
 150     KF5::Parts
 151     KF5::WindowSystem
 152     KF5::WidgetsAddons
 153 )
 154
 155 if(HAVE_BALOO)
 156     target_link_libraries(
 157         dolphinprivate PUBLIC
 158         KF5::FileMetaData
 159         KF5::Baloo
 160         KF5::BalooWidgets
 161     )
 162 endif()
 163
 164 set_target_properties(dolphinprivate PROPERTIES
 165     VERSION ${DOLPHINPRIVATE_VERSION}
 166     SOVERSION ${DOLPHINPRIVATE_SOVERSION}
 167 )
 168
 169 install(TARGETS dolphinprivate ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} LIBRARY NAMELINK_SKIP)
 170 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphin_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
 171
 172 ##########################################
 173 configure_file(dolphinpart.json.in ${CMAKE_CURRENT_BINARY_DIR}/dolphinpart.json @ONLY)
 174
 175 add_library(dolphinpart MODULE)
 176
 177 target_sources(dolphinpart PRIVATE
 178     dolphinpart.cpp
 179     dolphinpart_ext.cpp
 180     dolphindebug.cpp
 181
 182     dolphinpart.qrc
 183 )
 184
 185 target_link_libraries(dolphinpart
 186     dolphinprivate
 187 )
 188
 189 install(TARGETS dolphinpart DESTINATION ${KDE_INSTALL_PLUGINDIR}/kf${QT_MAJOR_VERSION}/parts)
 190
 191 ##########################################
 192
 193 add_library(dolphinstatic STATIC)
 194
 195 target_sources(dolphinstatic PRIVATE
 196     dolphinbookmarkhandler.cpp
 197     dolphindockwidget.cpp
 198     dolphinmainwindow.cpp
 199     dolphinviewcontainer.cpp
 200     dolphincontextmenu.cpp
 201     dolphinnavigatorswidgetaction.cpp
 202     dolphintabbar.cpp
 203     dolphinplacesmodelsingleton.cpp
 204     dolphinrecenttabsmenu.cpp
 205     dolphintabpage.cpp
 206     dolphintabwidget.cpp
 207     dolphinurlnavigator.cpp
 208     dolphinurlnavigatorscontroller.cpp
 209     trash/dolphintrash.cpp
 210     filterbar/filterbar.cpp
 211     panels/places/placespanel.cpp
 212     panels/panel.cpp
 213     panels/folders/foldersitemlistwidget.cpp
 214     panels/folders/treeviewcontextmenu.cpp
 215     panels/folders/folderspanel.cpp
 216     panels/terminal/terminalpanel.cpp
 217     search/dolphinfacetswidget.cpp
 218     search/dolphinquery.cpp
 219     search/dolphinsearchbox.cpp
 220     settings/general/behaviorsettingspage.cpp
 221     settings/general/configurepreviewplugindialog.cpp
 222     settings/general/confirmationssettingspage.cpp
 223     settings/general/generalsettingspage.cpp
 224     settings/general/previewssettingspage.cpp
 225     settings/general/statusbarsettingspage.cpp
 226     settings/dolphinsettingsdialog.cpp
 227     settings/navigation/navigationsettingspage.cpp
 228     settings/contextmenu/contextmenusettingspage.cpp
 229     settings/settingspagebase.cpp
 230     settings/serviceitemdelegate.cpp
 231     settings/servicemodel.cpp
 232     settings/startup/startupsettingspage.cpp
 233     settings/trash/trashsettingspage.cpp
 234     settings/viewmodes/dolphinfontrequester.cpp
 235     settings/viewmodes/viewsettingspage.cpp
 236     settings/viewmodes/viewmodesettings.cpp
 237     settings/viewmodes/viewsettingstab.cpp
 238     statusbar/dolphinstatusbar.cpp
 239     statusbar/mountpointobserver.cpp
 240     statusbar/mountpointobservercache.cpp
 241     statusbar/spaceinfoobserver.cpp
 242     statusbar/statusbarspaceinfo.cpp
 243     views/zoomlevelinfo.cpp
 244     dolphindebug.cpp
 245     global.cpp
 246     dolphin.qrc
 247 )
 248
 249 if(HAVE_BALOO)
 250     target_sources(dolphinstatic PRIVATE
 251         panels/information/informationpanel.cpp
 252         panels/information/informationpanelcontent.cpp
 253         panels/information/pixmapviewer.cpp
 254         panels/information/phononwidget.cpp
 255     )
 256 endif()
 257
 258 if(HAVE_KUSERFEEDBACK)
 259     target_sources(dolphinstatic PRIVATE
 260         userfeedback/dolphinfeedbackprovider.cpp
 261         userfeedback/settingsdatasource.cpp
 262         userfeedback/placesdatasource.cpp
 263         settings/userfeedback/userfeedbacksettingspage.cpp
 264     )
 265 endif()
 266
 267 kconfig_add_kcfg_files(dolphinstatic
 268     panels/folders/dolphin_folderspanelsettings.kcfgc
 269     panels/information/dolphin_informationpanelsettings.kcfgc
 270     panels/places/dolphin_placespanelsettings.kcfgc
 271     settings/dolphin_compactmodesettings.kcfgc
 272     settings/dolphin_detailsmodesettings.kcfgc
 273     settings/dolphin_contextmenusettings.kcfgc
 274     settings/dolphin_iconsmodesettings.kcfgc
 275     search/dolphin_searchsettings.kcfgc
 276     settings/dolphin_versioncontrolsettings.kcfgc
 277 )
 278 kconfig_add_kcfg_files(dolphinstatic GENERATE_MOC
 279     settings/dolphin_generalsettings.kcfgc
 280 )
 281
 282 qt_generate_dbus_interface(${CMAKE_CURRENT_SOURCE_DIR}/dolphinmainwindow.h org.kde.DolphinMainWindow.xml)
 283 qt_add_dbus_adaptor(dolphin_dbus_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindow.h DolphinMainWindow)
 284 qt_add_dbus_interface(dolphin_dbus_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindowinterface)
 285 qt_add_dbus_interface(dolphin_dbus_SRCS panels/terminal/org.kde.KIOFuse.VFS.xml kiofuse_interface)
 286
 287 target_sources(dolphinstatic PRIVATE
 288     ${dolphin_dbus_SRCS}
 289 )
 290
 291 target_include_directories(dolphinstatic SYSTEM PRIVATE ${PHONON_INCLUDES})
 292 target_link_libraries(dolphinstatic
 293     dolphinprivate
 294     KF5::CoreAddons
 295     KF5::KCMUtils
 296     KF5::DBusAddons
 297     KF5::Notifications
 298     Phonon::phonon4qt${QT_MAJOR_VERSION}
 299 )
 300
 301 if (HAVE_KACTIVITIES)
 302     target_link_libraries(
 303         dolphinstatic
 304         KF5::Activities
 305     )
 306 endif()
 307
 308 if (HAVE_KUSERFEEDBACK)
 309     target_link_libraries(
 310         dolphinstatic
 311         KUserFeedbackCore
 312         KUserFeedbackWidgets
 313     )
 314 endif()
 315
 316 add_executable(dolphin)
 317
 318 target_sources(dolphin PRIVATE
 319     dbusinterface.cpp
 320     main.cpp
 321 )
 322
 323 if(FLATPAK)
 324     target_compile_definitions(dolphin PRIVATE FLATPAK)
 325 endif()
 326
 327 # Sets the icon on Windows and OSX
 328 file(GLOB ICONS_SRCS "${CMAKE_CURRENT_SOURCE_DIR}/icons/*system-file-manager.png")
 329 ecm_add_app_icon(dolphin ICONS ${ICONS_SRCS})
 330
 331 target_link_libraries(dolphin
 332     PRIVATE
 333     dolphinprivate
 334     dolphinstatic
 335     KF5::Crash
 336 )
 337
 338 include(DbusInterfaceMacros)
 339
 340 generate_and_install_dbus_interface(
 341     dolphin
 342     dbusinterface.h
 343     org.freedesktop.FileManager1.xml
 344     OPTIONS -a
 345 )
 346
 347 install(TARGETS dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 348
 349 ##########################################
 350
 351 if(NOT WIN32)
 352     # The settings are still accessible from the hamburger menu
 353     add_library(kcm_dolphinviewmodes MODULE)
 354     add_library(kcm_dolphinnavigation MODULE)
 355     add_library(kcm_dolphingeneral MODULE)
 356
 357     target_sources(kcm_dolphinviewmodes PRIVATE
 358         settings/kcm/kcmdolphinviewmodes.cpp
 359         settings/viewmodes/dolphinfontrequester.cpp
 360         settings/viewmodes/viewmodesettings.cpp
 361         settings/viewmodes/viewsettingstab.cpp
 362         views/zoomlevelinfo.cpp)
 363
 364     target_sources(kcm_dolphinnavigation PRIVATE
 365         settings/kcm/kcmdolphinnavigation.cpp
 366         settings/navigation/navigationsettingspage.cpp
 367         settings/settingspagebase.cpp)
 368
 369     target_sources(kcm_dolphingeneral PRIVATE
 370         settings/kcm/kcmdolphingeneral.cpp
 371         settings/general/behaviorsettingspage.cpp
 372         settings/general/previewssettingspage.cpp
 373         settings/general/configurepreviewplugindialog.cpp
 374         settings/general/confirmationssettingspage.cpp
 375         settings/settingspagebase.cpp
 376         settings/serviceitemdelegate.cpp
 377         settings/servicemodel.cpp)
 378
 379     kconfig_add_kcfg_files(kcm_dolphinviewmodes
 380         settings/dolphin_compactmodesettings.kcfgc
 381         settings/dolphin_directoryviewpropertysettings.kcfgc
 382         settings/dolphin_detailsmodesettings.kcfgc
 383         settings/dolphin_iconsmodesettings.kcfgc
 384         settings/dolphin_generalsettings.kcfgc
 385         settings/dolphin_versioncontrolsettings.kcfgc
 386     )
 387
 388     kconfig_add_kcfg_files(kcm_dolphinnavigation
 389         settings/dolphin_generalsettings.kcfgc)
 390
 391     kconfig_add_kcfg_files(kcm_dolphingeneral
 392         settings/dolphin_generalsettings.kcfgc)
 393
 394     target_link_libraries(kcm_dolphinviewmodes dolphinprivate)
 395     target_link_libraries(kcm_dolphinnavigation dolphinprivate)
 396     target_link_libraries(kcm_dolphingeneral dolphinprivate)
 397
 398     install( FILES org.kde.dolphin.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR} )
 399
 400     install(TARGETS kcm_dolphinviewmodes DESTINATION ${KDE_INSTALL_PLUGINDIR}/dolphin/kcms )
 401     install(TARGETS kcm_dolphinnavigation DESTINATION ${KDE_INSTALL_PLUGINDIR}/dolphin/kcms )
 402     install(TARGETS kcm_dolphingeneral DESTINATION ${KDE_INSTALL_PLUGINDIR}/dolphin/kcms )
 403 endif()
 404
 405 if(NOT WIN32)
 406     add_subdirectory(settings/contextmenu/servicemenuinstaller)
 407     install( FILES settings/contextmenu/servicemenu.knsrc DESTINATION ${KDE_INSTALL_KNSRCDIR} )
 408 endif()
 409
 410 ########### install files ###############
 411
 412 install( PROGRAMS org.kde.dolphin.desktop DESTINATION ${KDE_INSTALL_APPDIR} )
 413
 414 install( DIRECTORY DESTINATION "${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel" )
 415
 416 install(
 417     CODE "execute_process(COMMAND \"${CMAKE_COMMAND}\" -E create_symlink \"${KDE_INSTALL_FULL_APPDIR}/org.kde.dolphin.desktop\" \"\$ENV{DESTDIR}${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel/org.kde.dolphin.desktop\")"
 418 )
 419
 420 install( FILES settings/dolphin_directoryviewpropertysettings.kcfg
 421                settings/dolphin_generalsettings.kcfg
 422                settings/dolphin_contextmenusettings.kcfg
 423                settings/dolphin_compactmodesettings.kcfg
 424                settings/dolphin_iconsmodesettings.kcfg
 425                settings/dolphin_detailsmodesettings.kcfg
 426                settings/dolphin_versioncontrolsettings.kcfg
 427          DESTINATION ${KDE_INSTALL_KCFGDIR} )
 428
 429 install( FILES settings/dolphin_detailsmodesettings.upd
 430          DESTINATION ${KDE_INSTALL_KCONFUPDATEDIR} )
 431
 432 if(BUILD_TESTING)
 433     add_subdirectory(tests)
 434 endif()