src/CMakeLists.txt

   1 include(ECMAddAppIcon)
   2
   3 configure_file(config-dolphin.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-dolphin.h)
   4
   5 add_definitions(
   6     -DTRANSLATION_DOMAIN=\"dolphin\"
   7 )
   8 remove_definitions(
   9     -DQT_NO_CAST_FROM_BYTEARRAY
  10     -DQT_NO_CAST_FROM_ASCII
  11     -DQT_NO_CAST_TO_ASCII
  12 )
  13
  14 ##########################################
  15
  16 add_library(dolphinvcs SHARED)
  17
  18 target_sources(dolphinvcs PRIVATE
  19     views/versioncontrol/kversioncontrolplugin.cpp
  20 )
  21
  22 generate_export_header(dolphinvcs BASE_NAME dolphinvcs)
  23
  24 target_link_libraries(
  25     dolphinvcs PUBLIC
  26     Qt${QT_MAJOR_VERSION}::Widgets
  27 )
  28
  29 set_target_properties(dolphinvcs PROPERTIES
  30     VERSION ${DOLPHINVCS_VERSION}
  31     SOVERSION ${DOLPHINVCS_SOVERSION}
  32     EXPORT_NAME DolphinVcs
  33 )
  34
  35 ecm_generate_headers(dolphinvcs_LIB_HEADERS
  36     HEADER_NAMES
  37     KVersionControlPlugin
  38
  39     RELATIVE "views/versioncontrol"
  40     REQUIRED_HEADERS dolphinvcs_LIB_HEADERS
  41 )
  42
  43 install(TARGETS dolphinvcs EXPORT DolphinVcsTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
  44
  45 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphinvcs_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
  46 install(FILES ${dolphinvcs_LIB_HEADERS} DESTINATION "${KDE_INSTALL_INCLUDEDIR}/Dolphin" COMPONENT Devel)
  47
  48 ########### next target ###############
  49
  50 add_library(dolphinprivate SHARED)
  51
  52 target_sources(dolphinprivate PRIVATE
  53     kitemviews/kfileitemlistview.cpp
  54     kitemviews/kfileitemlistwidget.cpp
  55     kitemviews/kfileitemlisttostring.cpp
  56     kitemviews/kfileitemmodel.cpp
  57     kitemviews/kfileitemmodelrolesupdater.cpp
  58     kitemviews/kitemlistcontainer.cpp
  59     kitemviews/kitemlistcontroller.cpp
  60     kitemviews/kitemlistgroupheader.cpp
  61     kitemviews/kitemlistheader.cpp
  62     kitemviews/kitemlistselectionmanager.cpp
  63     kitemviews/kitemliststyleoption.cpp
  64     kitemviews/kitemlistview.cpp
  65     kitemviews/kitemlistviewaccessible.cpp
  66     kitemviews/kitemlistwidget.cpp
  67     kitemviews/kitemmodelbase.cpp
  68     kitemviews/kitemset.cpp
  69     kitemviews/kstandarditemlistgroupheader.cpp
  70     kitemviews/kstandarditemlistwidget.cpp
  71     kitemviews/kstandarditemlistview.cpp
  72     kitemviews/private/kdirectorycontentscounter.cpp
  73     kitemviews/private/kdirectorycontentscounterworker.cpp
  74     kitemviews/private/kfileitemclipboard.cpp
  75     kitemviews/private/kfileitemmodelfilter.cpp
  76     kitemviews/private/kitemlistheaderwidget.cpp
  77     kitemviews/private/kitemlistkeyboardsearchmanager.cpp
  78     kitemviews/private/kitemlistroleeditor.cpp
  79     kitemviews/private/kitemlistrubberband.cpp
  80     kitemviews/private/kitemlistselectiontoggle.cpp
  81     kitemviews/private/kitemlistsizehintresolver.cpp
  82     kitemviews/private/kitemlistsmoothscroller.cpp
  83     kitemviews/private/kitemlistviewanimation.cpp
  84     kitemviews/private/kitemlistviewlayouter.cpp
  85     kitemviews/private/kpixmapmodifier.cpp
  86     settings/applyviewpropsjob.cpp
  87     settings/viewmodes/viewmodesettings.cpp
  88     settings/viewpropertiesdialog.cpp
  89     settings/viewpropsprogressinfo.cpp
  90     selectionmode/actiontexthelper.cpp
  91     views/dolphinfileitemlistwidget.cpp
  92     views/dolphinitemlistview.cpp
  93     views/dolphinnewfilemenuobserver.cpp
  94     views/dolphinremoteencoding.cpp
  95     views/dolphinview.cpp
  96     views/dolphinviewactionhandler.cpp
  97     views/draganddrophelper.cpp
  98     views/versioncontrol/updateitemstatesthread.cpp
  99     views/versioncontrol/versioncontrolobserver.cpp
 100     views/viewmodecontroller.cpp
 101     views/viewproperties.cpp
 102     views/zoomlevelinfo.cpp
 103     dolphinremoveaction.cpp
 104     middleclickactioneventfilter.cpp
 105     dolphinnewfilemenu.cpp
 106
 107     kitemviews/kfileitemlistview.h
 108     kitemviews/kfileitemlistwidget.h
 109     kitemviews/kfileitemlisttostring.h
 110     kitemviews/kfileitemmodel.h
 111     kitemviews/kfileitemmodelrolesupdater.h
 112     kitemviews/kitemlistcontainer.h
 113     kitemviews/kitemlistcontroller.h
 114     kitemviews/kitemlistgroupheader.h
 115     kitemviews/kitemlistheader.h
 116     kitemviews/kitemlistselectionmanager.h
 117     kitemviews/kitemliststyleoption.h
 118     kitemviews/kitemlistview.h
 119     kitemviews/kitemlistviewaccessible.h
 120     kitemviews/kitemlistwidget.h
 121     kitemviews/kitemmodelbase.h
 122     kitemviews/kitemset.h
 123     kitemviews/kstandarditemlistgroupheader.h
 124     kitemviews/kstandarditemlistwidget.h
 125     kitemviews/kstandarditemlistview.h
 126     kitemviews/private/kdirectorycontentscounter.h
 127     kitemviews/private/kdirectorycontentscounterworker.h
 128     kitemviews/private/kfileitemclipboard.h
 129     kitemviews/private/kfileitemmodelfilter.h
 130     kitemviews/private/kitemlistheaderwidget.h
 131     kitemviews/private/kitemlistkeyboardsearchmanager.h
 132     kitemviews/private/kitemlistroleeditor.h
 133     kitemviews/private/kitemlistrubberband.h
 134     kitemviews/private/kitemlistselectiontoggle.h
 135     kitemviews/private/kitemlistsizehintresolver.h
 136     kitemviews/private/kitemlistsmoothscroller.h
 137     kitemviews/private/kitemlistviewanimation.h
 138     kitemviews/private/kitemlistviewlayouter.h
 139     kitemviews/private/kpixmapmodifier.h
 140     settings/applyviewpropsjob.h
 141     settings/viewmodes/viewmodesettings.h
 142     settings/viewpropertiesdialog.h
 143     settings/viewpropsprogressinfo.h
 144     selectionmode/actiontexthelper.h
 145     views/dolphinfileitemlistwidget.h
 146     views/dolphinitemlistview.h
 147     views/dolphinnewfilemenuobserver.h
 148     views/dolphinremoteencoding.h
 149     views/dolphinview.h
 150     views/dolphinviewactionhandler.h
 151     views/draganddrophelper.h
 152     views/versioncontrol/updateitemstatesthread.h
 153     views/versioncontrol/versioncontrolobserver.h
 154     views/viewmodecontroller.h
 155     views/viewproperties.h
 156     views/zoomlevelinfo.h
 157     dolphinremoveaction.h
 158     middleclickactioneventfilter.h
 159     dolphinnewfilemenu.h
 160 )
 161
 162 ecm_qt_declare_logging_category(dolphinprivate
 163     HEADER dolphindebug.h
 164     IDENTIFIER DolphinDebug
 165     CATEGORY_NAME org.kde.dolphin
 166     DESCRIPTION "dolphin"
 167     EXPORT DOLPHIN
 168 )
 169
 170 if(HAVE_BALOO)
 171     target_sources(dolphinprivate PRIVATE
 172         views/tooltips/dolphinfilemetadatawidget.cpp
 173         views/tooltips/tooltipmanager.cpp
 174         kitemviews/private/kbaloorolesprovider.cpp
 175         views/tooltips/dolphinfilemetadatawidget.h
 176         views/tooltips/tooltipmanager.h
 177         kitemviews/private/kbaloorolesprovider.h
 178     )
 179 endif()
 180
 181 kconfig_add_kcfg_files(dolphinprivate
 182     settings/dolphin_compactmodesettings.kcfgc
 183     settings/dolphin_directoryviewpropertysettings.kcfgc
 184     settings/dolphin_detailsmodesettings.kcfgc
 185     settings/dolphin_iconsmodesettings.kcfgc
 186     settings/dolphin_contentdisplaysettings.kcfgc
 187     settings/dolphin_generalsettings.kcfgc
 188     settings/dolphin_contextmenusettings.kcfgc
 189     settings/dolphin_versioncontrolsettings.kcfgc
 190 )
 191
 192 generate_export_header(dolphinprivate BASE_NAME dolphin)
 193
 194 target_link_libraries(
 195     dolphinprivate PUBLIC
 196     dolphinvcs
 197     Qt${QT_MAJOR_VERSION}::Concurrent
 198     Qt${QT_MAJOR_VERSION}::Gui
 199     KF5::I18n
 200     KF5::IconThemes
 201     KF5::KIOCore
 202     KF5::KIOWidgets
 203     KF5::KIOFileWidgets
 204     KF5::Completion
 205     KF5::TextWidgets
 206     KF5::ConfigCore
 207     KF5::NewStuff
 208     KF5::NewStuffWidgets    # KNSWidgets::Button
 209     KF5::Parts
 210     KF5::WindowSystem
 211     KF5::WidgetsAddons
 212     KF5::Codecs
 213 )
 214
 215 if(HAVE_BALOO)
 216     target_link_libraries(
 217         dolphinprivate PUBLIC
 218         KF5::FileMetaData
 219         KF5::Baloo
 220         KF5::BalooWidgets
 221     )
 222 endif()
 223
 224 set_target_properties(dolphinprivate PROPERTIES
 225     VERSION ${DOLPHINPRIVATE_VERSION}
 226     SOVERSION ${DOLPHINPRIVATE_SOVERSION}
 227 )
 228
 229 install(TARGETS dolphinprivate ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} LIBRARY NAMELINK_SKIP)
 230 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphin_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
 231
 232 ##########################################
 233 configure_file(dolphinpart.json.in ${CMAKE_CURRENT_BINARY_DIR}/dolphinpart.json @ONLY)
 234
 235 add_library(dolphinpart MODULE)
 236
 237 target_sources(dolphinpart PRIVATE
 238     dolphinpart.cpp
 239     dolphinpart_ext.cpp
 240     dolphindebug.cpp
 241     dolphinpart.h
 242     dolphinpart_ext.h
 243     dolphindebug.h
 244
 245     dolphinpart.qrc
 246 )
 247
 248 target_link_libraries(dolphinpart
 249     dolphinprivate
 250 )
 251
 252 install(TARGETS dolphinpart DESTINATION ${KDE_INSTALL_PLUGINDIR}/kf${QT_MAJOR_VERSION}/parts)
 253 install(FILES dolphinpartactions.desktop DESTINATION "${KDE_INSTALL_DATADIR}/dolphin/")
 254
 255 ##########################################
 256
 257 add_library(dolphinstatic STATIC)
 258
 259 target_sources(dolphinstatic PRIVATE
 260     dolphinbookmarkhandler.cpp
 261     dolphindockwidget.cpp
 262     dolphinmainwindow.cpp
 263     dolphinviewcontainer.cpp
 264     dolphincontextmenu.cpp
 265     dolphinnavigatorswidgetaction.cpp
 266     dolphintabbar.cpp
 267     dolphinplacesmodelsingleton.cpp
 268     dolphinrecenttabsmenu.cpp
 269     dolphintabpage.cpp
 270     dolphintabwidget.cpp
 271     dolphinurlnavigator.cpp
 272     dolphinurlnavigatorscontroller.cpp
 273     trash/dolphintrash.cpp
 274     filterbar/filterbar.cpp
 275     kitemviews/kfileitemlisttostring.cpp
 276     panels/places/placespanel.cpp
 277     panels/panel.cpp
 278     panels/folders/foldersitemlistwidget.cpp
 279     panels/folders/treeviewcontextmenu.cpp
 280     panels/folders/folderspanel.cpp
 281     panels/terminal/terminalpanel.cpp
 282     search/dolphinfacetswidget.cpp
 283     search/dolphinquery.cpp
 284     search/dolphinsearchbox.cpp
 285     selectionmode/actiontexthelper.cpp
 286     selectionmode/actionwithwidget.cpp
 287     selectionmode/backgroundcolorhelper.cpp
 288     selectionmode/bottombar.cpp
 289     selectionmode/bottombarcontentscontainer.cpp
 290     selectionmode/topbar.cpp
 291     settings/interface/folderstabssettingspage.cpp
 292     settings/interface/statusandlocationbarssettingspage.cpp
 293     settings/interface/configurepreviewplugindialog.cpp
 294     settings/interface/confirmationssettingspage.cpp
 295     settings/interface/interfacesettingspage.cpp
 296     settings/interface/previewssettingspage.cpp
 297     settings/dolphinsettingsdialog.cpp
 298     settings/contextmenu/contextmenusettingspage.cpp
 299     settings/settingspagebase.cpp
 300     settings/serviceitemdelegate.cpp
 301     settings/servicemodel.cpp
 302     settings/trash/trashsettingspage.cpp
 303     settings/viewmodes/dolphinfontrequester.cpp
 304     settings/viewmodes/viewsettingspage.cpp
 305     settings/viewmodes/viewmodesettings.cpp
 306     settings/viewmodes/viewsettingstab.cpp
 307     settings/viewmodes/contentdisplaytab.cpp
 308     settings/viewmodes/generalviewsettingspage.cpp
 309     statusbar/dolphinstatusbar.cpp
 310     statusbar/mountpointobserver.cpp
 311     statusbar/mountpointobservercache.cpp
 312     statusbar/spaceinfoobserver.cpp
 313     statusbar/statusbarspaceinfo.cpp
 314     views/zoomlevelinfo.cpp
 315     dolphindebug.cpp
 316     global.cpp
 317     dolphin.qrc
 318
 319     dolphinbookmarkhandler.h
 320     dolphindockwidget.h
 321     dolphinmainwindow.h
 322     dolphinviewcontainer.h
 323     dolphincontextmenu.h
 324     dolphinnavigatorswidgetaction.h
 325     dolphintabbar.h
 326     dolphinplacesmodelsingleton.h
 327     dolphinrecenttabsmenu.h
 328     dolphintabpage.h
 329     dolphintabwidget.h
 330     dolphinurlnavigator.h
 331     dolphinurlnavigatorscontroller.h
 332     trash/dolphintrash.h
 333     filterbar/filterbar.h
 334     kitemviews/kfileitemlisttostring.h
 335     panels/places/placespanel.h
 336     panels/panel.h
 337     panels/folders/foldersitemlistwidget.h
 338     panels/folders/treeviewcontextmenu.h
 339     panels/folders/folderspanel.h
 340     panels/terminal/terminalpanel.h
 341     search/dolphinfacetswidget.h
 342     search/dolphinquery.h
 343     search/dolphinsearchbox.h
 344     selectionmode/actiontexthelper.h
 345     selectionmode/actionwithwidget.h
 346     selectionmode/backgroundcolorhelper.h
 347     selectionmode/bottombar.h
 348     selectionmode/bottombarcontentscontainer.h
 349     selectionmode/topbar.h
 350     settings/interface/folderstabssettingspage.h
 351     settings/interface/statusandlocationbarssettingspage.h
 352     settings/interface/configurepreviewplugindialog.h
 353     settings/interface/confirmationssettingspage.h
 354     settings/interface/interfacesettingspage.h
 355     settings/interface/previewssettingspage.h
 356     settings/dolphinsettingsdialog.h
 357     settings/contextmenu/contextmenusettingspage.h
 358     settings/settingspagebase.h
 359     settings/serviceitemdelegate.h
 360     settings/servicemodel.h
 361     settings/trash/trashsettingspage.h
 362     settings/viewmodes/dolphinfontrequester.h
 363     settings/viewmodes/viewsettingspage.h
 364     settings/viewmodes/viewmodesettings.h
 365     settings/viewmodes/viewsettingstab.h
 366     settings/viewmodes/contentdisplaytab.h
 367     settings/viewmodes/generalviewsettingspage.h
 368     statusbar/dolphinstatusbar.h
 369     statusbar/mountpointobserver.h
 370     statusbar/mountpointobservercache.h
 371     statusbar/spaceinfoobserver.h
 372     statusbar/statusbarspaceinfo.h
 373     views/zoomlevelinfo.h
 374     dolphindebug.h
 375     global.h
 376 )
 377
 378 if(HAVE_BALOO)
 379     target_sources(dolphinstatic PRIVATE
 380         panels/information/informationpanel.cpp
 381         panels/information/informationpanelcontent.cpp
 382         panels/information/pixmapviewer.cpp
 383         panels/information/phononwidget.cpp
 384         panels/information/informationpanel.h
 385         panels/information/informationpanelcontent.h
 386         panels/information/pixmapviewer.h
 387         panels/information/phononwidget.h
 388     )
 389 endif()
 390
 391 if(HAVE_KUSERFEEDBACK)
 392     target_sources(dolphinstatic PRIVATE
 393         userfeedback/dolphinfeedbackprovider.cpp
 394         userfeedback/settingsdatasource.cpp
 395         userfeedback/placesdatasource.cpp
 396         settings/userfeedback/userfeedbacksettingspage.cpp
 397         userfeedback/dolphinfeedbackprovider.h
 398         userfeedback/settingsdatasource.h
 399         userfeedback/placesdatasource.h
 400         settings/userfeedback/userfeedbacksettingspage.h
 401     )
 402 endif()
 403
 404 kconfig_add_kcfg_files(dolphinstatic
 405     panels/folders/dolphin_folderspanelsettings.kcfgc
 406     panels/information/dolphin_informationpanelsettings.kcfgc
 407     panels/places/dolphin_placespanelsettings.kcfgc
 408     settings/dolphin_compactmodesettings.kcfgc
 409     settings/dolphin_detailsmodesettings.kcfgc
 410     settings/dolphin_contextmenusettings.kcfgc
 411     settings/dolphin_iconsmodesettings.kcfgc
 412     settings/dolphin_contentdisplaysettings.kcfgc
 413     search/dolphin_searchsettings.kcfgc
 414     settings/dolphin_versioncontrolsettings.kcfgc
 415 )
 416 kconfig_add_kcfg_files(dolphinstatic GENERATE_MOC
 417     settings/dolphin_generalsettings.kcfgc
 418 )
 419
 420 qt_generate_dbus_interface(${CMAKE_CURRENT_SOURCE_DIR}/dolphinmainwindow.h org.kde.DolphinMainWindow.xml)
 421 qt_add_dbus_adaptor(dolphin_dbus_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindow.h DolphinMainWindow)
 422 qt_add_dbus_interface(dolphin_dbus_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindowinterface)
 423 qt_add_dbus_interface(dolphin_dbus_SRCS panels/terminal/org.kde.KIOFuse.VFS.xml kiofuse_interface)
 424
 425 target_sources(dolphinstatic PRIVATE
 426     ${dolphin_dbus_SRCS}
 427 )
 428
 429 target_include_directories(dolphinstatic SYSTEM PRIVATE ${PHONON_INCLUDES})
 430 target_link_libraries(dolphinstatic
 431     dolphinprivate
 432     KF5::CoreAddons
 433     KF5::KCMUtils
 434     KF5::DBusAddons
 435     KF5::Notifications
 436     Phonon::phonon4qt${QT_MAJOR_VERSION}
 437 )
 438
 439 if (HAVE_KACTIVITIES)
 440     target_link_libraries(
 441         dolphinstatic
 442         KF5::Activities
 443     )
 444 endif()
 445
 446 if (HAVE_KUSERFEEDBACK)
 447     target_link_libraries(
 448         dolphinstatic
 449         KUserFeedbackCore
 450         KUserFeedbackWidgets
 451     )
 452 endif()
 453
 454 add_executable(dolphin)
 455
 456 target_sources(dolphin PRIVATE
 457     dbusinterface.cpp
 458     dbusinterface.h
 459     main.cpp
 460 )
 461
 462 if(FLATPAK)
 463     target_compile_definitions(dolphin PRIVATE FLATPAK)
 464 endif()
 465
 466 # Sets the icon on Windows and OSX
 467 file(GLOB ICONS_SRCS "${CMAKE_CURRENT_SOURCE_DIR}/icons/*system-file-manager.png")
 468 ecm_add_app_icon(dolphin ICONS ${ICONS_SRCS})
 469
 470 target_link_libraries(dolphin
 471     PRIVATE
 472     dolphinprivate
 473     dolphinstatic
 474     KF5::Crash
 475 )
 476
 477 if (HAVE_X11)
 478     if (QT_MAJOR_VERSION STREQUAL "5")
 479         target_link_libraries(dolphin PRIVATE Qt5::X11Extras)
 480     else()
 481         target_link_libraries(dolphin PRIVATE Qt::GuiPrivate)
 482     endif()
 483 endif()
 484
 485 include(DbusInterfaceMacros)
 486
 487 generate_and_install_dbus_interface(
 488     dolphin
 489     dbusinterface.h
 490     org.freedesktop.FileManager1.xml
 491     OPTIONS -a
 492 )
 493
 494 install(TARGETS dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 495
 496 ##########################################
 497
 498 if(NOT WIN32)
 499     # The settings are still accessible from the hamburger menu
 500     add_library(kcm_dolphinviewmodes MODULE)
 501     add_library(kcm_dolphingeneral MODULE)
 502
 503     target_sources(kcm_dolphinviewmodes PRIVATE
 504         settings/kcm/kcmdolphinviewmodes.cpp
 505         settings/viewmodes/dolphinfontrequester.cpp
 506         settings/viewmodes/viewmodesettings.cpp
 507         settings/viewmodes/viewsettingstab.cpp
 508         settings/settingspagebase.cpp
 509         views/zoomlevelinfo.cpp
 510         settings/kcm/kcmdolphinviewmodes.h
 511         settings/viewmodes/dolphinfontrequester.h
 512         settings/viewmodes/viewmodesettings.h
 513         settings/viewmodes/viewsettingstab.h
 514         views/zoomlevelinfo.h)
 515
 516     target_sources(kcm_dolphingeneral PRIVATE
 517         settings/kcm/kcmdolphingeneral.cpp
 518         settings/interface/folderstabssettingspage.cpp
 519         settings/interface/statusandlocationbarssettingspage.cpp
 520         settings/interface/previewssettingspage.cpp
 521         settings/interface/configurepreviewplugindialog.cpp
 522         settings/interface/confirmationssettingspage.cpp
 523         settings/settingspagebase.cpp
 524         settings/serviceitemdelegate.cpp
 525         settings/servicemodel.cpp
 526         dolphin_generalsettings.cpp
 527         dolphindebug.cpp
 528         dolphinmainwindowinterface.cpp
 529         views/viewproperties.cpp
 530         dolphin_directoryviewpropertysettings.cpp
 531         global.cpp
 532         settings/kcm/kcmdolphingeneral.h
 533         settings/interface/folderstabssettingspage.h
 534         settings/interface/statusandlocationbarssettingspage.h
 535         settings/interface/previewssettingspage.h
 536         settings/interface/configurepreviewplugindialog.h
 537         settings/interface/confirmationssettingspage.h
 538         settings/settingspagebase.h
 539         settings/serviceitemdelegate.h
 540         settings/servicemodel.h
 541         dolphin_generalsettings.h
 542         dolphindebug.h
 543         dolphinmainwindowinterface.h
 544         views/viewproperties.h
 545         dolphin_directoryviewpropertysettings.h
 546         global.h
 547     )
 548
 549     kconfig_add_kcfg_files(kcm_dolphinviewmodes
 550         settings/dolphin_compactmodesettings.kcfgc
 551         settings/dolphin_directoryviewpropertysettings.kcfgc
 552         settings/dolphin_detailsmodesettings.kcfgc
 553         settings/dolphin_iconsmodesettings.kcfgc
 554         settings/dolphin_contentdisplaysettings.kcfgc
 555         settings/dolphin_generalsettings.kcfgc
 556         settings/dolphin_versioncontrolsettings.kcfgc
 557     )
 558
 559     kconfig_add_kcfg_files(kcm_dolphingeneral
 560         settings/dolphin_generalsettings.kcfgc)
 561
 562     target_link_libraries(kcm_dolphinviewmodes dolphinprivate)
 563     target_link_libraries(kcm_dolphingeneral dolphinprivate)
 564
 565     install( FILES org.kde.dolphin.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR} )
 566
 567     install(TARGETS kcm_dolphinviewmodes DESTINATION ${KDE_INSTALL_PLUGINDIR}/dolphin/kcms )
 568     install(TARGETS kcm_dolphingeneral DESTINATION ${KDE_INSTALL_PLUGINDIR}/dolphin/kcms )
 569 endif()
 570
 571 if(NOT WIN32)
 572     add_subdirectory(settings/contextmenu/servicemenuinstaller)
 573     install( FILES settings/contextmenu/servicemenu.knsrc DESTINATION ${KDE_INSTALL_KNSRCDIR} )
 574 endif()
 575
 576 ########### install files ###############
 577
 578 install( PROGRAMS org.kde.dolphin.desktop DESTINATION ${KDE_INSTALL_APPDIR} )
 579
 580 install( DIRECTORY DESTINATION "${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel" )
 581
 582 install(
 583     CODE "execute_process(COMMAND \"${CMAKE_COMMAND}\" -E create_symlink \"${KDE_INSTALL_FULL_APPDIR}/org.kde.dolphin.desktop\" \"\$ENV{DESTDIR}${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel/org.kde.dolphin.desktop\")"
 584 )
 585
 586 install( FILES settings/dolphin_directoryviewpropertysettings.kcfg
 587                settings/dolphin_generalsettings.kcfg
 588                settings/dolphin_contextmenusettings.kcfg
 589                settings/dolphin_compactmodesettings.kcfg
 590                settings/dolphin_iconsmodesettings.kcfg
 591                settings/dolphin_detailsmodesettings.kcfg
 592                settings/dolphin_contentdisplaysettings.kcfg
 593                settings/dolphin_versioncontrolsettings.kcfg
 594          DESTINATION ${KDE_INSTALL_KCFGDIR} )
 595
 596 install( FILES settings/dolphin_detailsmodesettings.upd
 597          DESTINATION ${KDE_INSTALL_KCONFUPDATEDIR} )
 598
 599 if(BUILD_TESTING)
 600     add_subdirectory(tests)
 601 endif()