src/CMakeLists.txt

   1 include(ECMAddAppIcon)
   2
   3 configure_file(config-dolphin.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-dolphin.h)
   4
   5 add_definitions(
   6     -DTRANSLATION_DOMAIN=\"dolphin\"
   7 )
   8 remove_definitions(
   9     -DQT_NO_CAST_FROM_BYTEARRAY
  10     -DQT_NO_CAST_FROM_ASCII
  11     -DQT_NO_CAST_TO_ASCII
  12 )
  13
  14 ##########################################
  15
  16 add_library(dolphinvcs SHARED)
  17
  18 target_sources(dolphinvcs PRIVATE
  19     views/versioncontrol/kversioncontrolplugin.cpp
  20 )
  21
  22 generate_export_header(dolphinvcs BASE_NAME dolphinvcs)
  23
  24 target_link_libraries(
  25     dolphinvcs PUBLIC
  26     Qt6::Widgets
  27 )
  28
  29 set_target_properties(dolphinvcs PROPERTIES
  30     VERSION ${DOLPHINVCS_VERSION}
  31     SOVERSION ${DOLPHINVCS_SOVERSION}
  32     EXPORT_NAME DolphinVcs
  33 )
  34
  35 ecm_generate_headers(dolphinvcs_LIB_HEADERS
  36     HEADER_NAMES
  37     KVersionControlPlugin
  38
  39     RELATIVE "views/versioncontrol"
  40     REQUIRED_HEADERS dolphinvcs_LIB_HEADERS
  41 )
  42 target_include_directories(dolphinvcs INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR}>")
  43
  44 install(TARGETS dolphinvcs EXPORT DolphinVcsTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
  45
  46 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphinvcs_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
  47 install(FILES ${dolphinvcs_LIB_HEADERS} DESTINATION "${KDE_INSTALL_INCLUDEDIR}/Dolphin" COMPONENT Devel)
  48
  49 ########### next target ###############
  50
  51 add_library(dolphinprivate SHARED)
  52
  53 target_sources(dolphinprivate PRIVATE
  54     kitemviews/kfileitemlistview.cpp
  55     kitemviews/kfileitemlistwidget.cpp
  56     kitemviews/kfileitemlisttostring.cpp
  57     kitemviews/kfileitemmodel.cpp
  58     kitemviews/kfileitemmodelrolesupdater.cpp
  59     kitemviews/kitemlistcontainer.cpp
  60     kitemviews/kitemlistcontroller.cpp
  61     kitemviews/kitemlistgroupheader.cpp
  62     kitemviews/kitemlistheader.cpp
  63     kitemviews/kitemlistselectionmanager.cpp
  64     kitemviews/kitemliststyleoption.cpp
  65     kitemviews/kitemlistview.cpp
  66     kitemviews/kitemlistviewaccessible.cpp
  67     kitemviews/kitemlistwidget.cpp
  68     kitemviews/kitemmodelbase.cpp
  69     kitemviews/kitemset.cpp
  70     kitemviews/kstandarditemlistgroupheader.cpp
  71     kitemviews/kstandarditemlistwidget.cpp
  72     kitemviews/kstandarditemlistview.cpp
  73     kitemviews/private/kdirectorycontentscounter.cpp
  74     kitemviews/private/kdirectorycontentscounterworker.cpp
  75     kitemviews/private/kfileitemclipboard.cpp
  76     kitemviews/private/kfileitemmodelfilter.cpp
  77     kitemviews/private/kitemlistheaderwidget.cpp
  78     kitemviews/private/kitemlistkeyboardsearchmanager.cpp
  79     kitemviews/private/kitemlistroleeditor.cpp
  80     kitemviews/private/kitemlistrubberband.cpp
  81     kitemviews/private/kitemlistselectiontoggle.cpp
  82     kitemviews/private/kitemlistsizehintresolver.cpp
  83     kitemviews/private/kitemlistsmoothscroller.cpp
  84     kitemviews/private/kitemlistviewanimation.cpp
  85     kitemviews/private/kitemlistviewlayouter.cpp
  86     kitemviews/private/kitemviewsutils.cpp
  87     kitemviews/private/kpixmapmodifier.cpp
  88     settings/applyviewpropsjob.cpp
  89     settings/viewmodes/viewmodesettings.cpp
  90     settings/viewpropertiesdialog.cpp
  91     settings/viewpropsprogressinfo.cpp
  92     selectionmode/actiontexthelper.cpp
  93     views/dolphinfileitemlistwidget.cpp
  94     views/dolphinitemlistview.cpp
  95     views/dolphinnewfilemenuobserver.cpp
  96     views/dolphinremoteencoding.cpp
  97     views/dolphinview.cpp
  98     views/dolphinviewactionhandler.cpp
  99     views/draganddrophelper.cpp
 100     views/versioncontrol/updateitemstatesthread.cpp
 101     views/versioncontrol/versioncontrolobserver.cpp
 102     views/viewmodecontroller.cpp
 103     views/viewproperties.cpp
 104     views/zoomlevelinfo.cpp
 105     dolphinremoveaction.cpp
 106     middleclickactioneventfilter.cpp
 107     dolphinnewfilemenu.cpp
 108
 109     kitemviews/kfileitemlistview.h
 110     kitemviews/kfileitemlistwidget.h
 111     kitemviews/kfileitemlisttostring.h
 112     kitemviews/kfileitemmodel.h
 113     kitemviews/kfileitemmodelrolesupdater.h
 114     kitemviews/kitemlistcontainer.h
 115     kitemviews/kitemlistcontroller.h
 116     kitemviews/kitemlistgroupheader.h
 117     kitemviews/kitemlistheader.h
 118     kitemviews/kitemlistselectionmanager.h
 119     kitemviews/kitemliststyleoption.h
 120     kitemviews/kitemlistview.h
 121     kitemviews/kitemlistviewaccessible.h
 122     kitemviews/kitemlistwidget.h
 123     kitemviews/kitemmodelbase.h
 124     kitemviews/kitemset.h
 125     kitemviews/kstandarditemlistgroupheader.h
 126     kitemviews/kstandarditemlistwidget.h
 127     kitemviews/kstandarditemlistview.h
 128     kitemviews/private/kdirectorycontentscounter.h
 129     kitemviews/private/kdirectorycontentscounterworker.h
 130     kitemviews/private/kfileitemclipboard.h
 131     kitemviews/private/kfileitemmodelfilter.h
 132     kitemviews/private/kitemlistheaderwidget.h
 133     kitemviews/private/kitemlistkeyboardsearchmanager.h
 134     kitemviews/private/kitemlistroleeditor.h
 135     kitemviews/private/kitemlistrubberband.h
 136     kitemviews/private/kitemlistselectiontoggle.h
 137     kitemviews/private/kitemlistsizehintresolver.h
 138     kitemviews/private/kitemlistsmoothscroller.h
 139     kitemviews/private/kitemlistviewanimation.h
 140     kitemviews/private/kitemlistviewlayouter.h
 141     kitemviews/private/kpixmapmodifier.h
 142     settings/applyviewpropsjob.h
 143     settings/viewmodes/viewmodesettings.h
 144     settings/viewpropertiesdialog.h
 145     settings/viewpropsprogressinfo.h
 146     selectionmode/actiontexthelper.h
 147     views/dolphinfileitemlistwidget.h
 148     views/dolphinitemlistview.h
 149     views/dolphinnewfilemenuobserver.h
 150     views/dolphinremoteencoding.h
 151     views/dolphinview.h
 152     views/dolphinviewactionhandler.h
 153     views/draganddrophelper.h
 154     views/versioncontrol/updateitemstatesthread.h
 155     views/versioncontrol/versioncontrolobserver.h
 156     views/viewmodecontroller.h
 157     views/viewproperties.h
 158     views/zoomlevelinfo.h
 159     dolphinremoveaction.h
 160     middleclickactioneventfilter.h
 161     dolphinnewfilemenu.h
 162 )
 163
 164 ecm_qt_declare_logging_category(dolphinprivate
 165     HEADER dolphindebug.h
 166     IDENTIFIER DolphinDebug
 167     CATEGORY_NAME org.kde.dolphin
 168     DESCRIPTION "dolphin"
 169     EXPORT DOLPHIN
 170 )
 171
 172 if(HAVE_BALOO)
 173     target_sources(dolphinprivate PRIVATE
 174         views/tooltips/dolphinfilemetadatawidget.cpp
 175         views/tooltips/tooltipmanager.cpp
 176         kitemviews/private/kbaloorolesprovider.cpp
 177         views/tooltips/dolphinfilemetadatawidget.h
 178         views/tooltips/tooltipmanager.h
 179         kitemviews/private/kbaloorolesprovider.h
 180     )
 181 endif()
 182
 183 kconfig_add_kcfg_files(dolphinprivate
 184     settings/dolphin_compactmodesettings.kcfgc
 185     settings/dolphin_directoryviewpropertysettings.kcfgc
 186     settings/dolphin_detailsmodesettings.kcfgc
 187     settings/dolphin_iconsmodesettings.kcfgc
 188     settings/dolphin_contentdisplaysettings.kcfgc
 189     settings/dolphin_generalsettings.kcfgc
 190     settings/dolphin_contextmenusettings.kcfgc
 191     settings/dolphin_versioncontrolsettings.kcfgc
 192     GENERATE_MOC
 193 )
 194
 195 generate_export_header(dolphinprivate BASE_NAME dolphin)
 196
 197 target_link_libraries(
 198     dolphinprivate PUBLIC
 199     dolphinvcs
 200     Qt6::Concurrent
 201     Qt6::DBus
 202     Qt6::Gui
 203     KF6::I18n
 204     KF6::IconThemes
 205     KF6::KIOCore
 206     KF6::KIOWidgets
 207     KF6::KIOFileWidgets
 208     KF6::Completion
 209     KF6::TextWidgets
 210     KF6::ConfigCore
 211     KF6::NewStuffWidgets    # KNSWidgets::Button
 212     KF6::Parts
 213     KF6::WindowSystem
 214     KF6::WidgetsAddons
 215     KF6::Codecs
 216     KF6::KCMUtils
 217
 218     ${FTS_LIB}
 219 )
 220
 221 if(HAVE_BALOO)
 222     target_link_libraries(
 223         dolphinprivate PUBLIC
 224         KF6::FileMetaData
 225         KF6::Baloo
 226         KF6::BalooWidgets
 227     )
 228 endif()
 229
 230 set_target_properties(dolphinprivate PROPERTIES
 231     VERSION ${DOLPHINPRIVATE_VERSION}
 232     SOVERSION ${DOLPHINPRIVATE_SOVERSION}
 233 )
 234
 235 install(TARGETS dolphinprivate ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} LIBRARY NAMELINK_SKIP)
 236 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphin_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
 237
 238 ##########################################
 239 configure_file(dolphinpart.json.in ${CMAKE_CURRENT_BINARY_DIR}/dolphinpart.json @ONLY)
 240
 241 add_library(dolphinpart MODULE)
 242
 243 target_sources(dolphinpart PRIVATE
 244     dolphinpart.cpp
 245     dolphinpart_ext.cpp
 246     dolphindebug.cpp
 247     dolphinpart.h
 248     dolphinpart_ext.h
 249     dolphindebug.h
 250
 251     dolphinpart.qrc
 252 )
 253
 254 target_link_libraries(dolphinpart
 255     dolphinprivate
 256 )
 257
 258 install(TARGETS dolphinpart DESTINATION ${KDE_INSTALL_PLUGINDIR}/kf6/parts)
 259 install(FILES dolphinpartactions.desktop DESTINATION "${KDE_INSTALL_DATADIR}/dolphin/")
 260
 261 ##########################################
 262
 263 add_library(dolphinstatic STATIC)
 264
 265 target_sources(dolphinstatic PRIVATE
 266     admin/bar.cpp
 267     admin/workerintegration.cpp
 268     animatedheightwidget.cpp
 269     disabledactionnotifier.cpp
 270     dolphinbookmarkhandler.cpp
 271     dolphindockwidget.cpp
 272     dolphinmainwindow.cpp
 273     dolphinviewcontainer.cpp
 274     dolphincontextmenu.cpp
 275     dolphinnavigatorswidgetaction.cpp
 276     dolphintabbar.cpp
 277     dolphinplacesmodelsingleton.cpp
 278     dolphinrecenttabsmenu.cpp
 279     dolphintabpage.cpp
 280     dolphintabwidget.cpp
 281     dolphinurlnavigator.cpp
 282     dolphinurlnavigatorscontroller.cpp
 283     trash/dolphintrash.cpp
 284     filterbar/filterbar.cpp
 285     kitemviews/kfileitemlisttostring.cpp
 286     panels/places/placespanel.cpp
 287     panels/panel.cpp
 288     panels/folders/foldersitemlistwidget.cpp
 289     panels/folders/treeviewcontextmenu.cpp
 290     panels/folders/folderspanel.cpp
 291     panels/terminal/terminalpanel.cpp
 292     search/dolphinfacetswidget.cpp
 293     search/dolphinquery.cpp
 294     search/dolphinsearchbox.cpp
 295     selectionmode/actiontexthelper.cpp
 296     selectionmode/actionwithwidget.cpp
 297     selectionmode/backgroundcolorhelper.cpp
 298     selectionmode/bottombar.cpp
 299     selectionmode/bottombarcontentscontainer.cpp
 300     selectionmode/topbar.cpp
 301     settings/interface/folderstabssettingspage.cpp
 302     settings/interface/statusandlocationbarssettingspage.cpp
 303     settings/interface/confirmationssettingspage.cpp
 304     settings/interface/interfacesettingspage.cpp
 305     settings/interface/previewssettingspage.cpp
 306     settings/dolphinsettingsdialog.cpp
 307     settings/contextmenu/contextmenusettingspage.cpp
 308     settings/settingspagebase.cpp
 309     settings/servicemodel.cpp
 310     settings/trash/trashsettingspage.cpp
 311     settings/viewmodes/dolphinfontrequester.cpp
 312     settings/viewmodes/viewsettingspage.cpp
 313     settings/viewmodes/viewmodesettings.cpp
 314     settings/viewmodes/viewsettingstab.cpp
 315     settings/viewmodes/contentdisplaytab.cpp
 316     settings/viewmodes/generalviewsettingspage.cpp
 317     statusbar/dolphinstatusbar.cpp
 318     statusbar/mountpointobserver.cpp
 319     statusbar/mountpointobservercache.cpp
 320     statusbar/spaceinfoobserver.cpp
 321     statusbar/statusbarspaceinfo.cpp
 322     views/zoomlevelinfo.cpp
 323     dolphindebug.cpp
 324     global.cpp
 325     dolphin.qrc
 326
 327     admin/bar.h
 328     admin/workerintegration.h
 329     animatedheightwidget.h
 330     dolphinbookmarkhandler.h
 331     dolphindockwidget.h
 332     dolphinmainwindow.h
 333     dolphinviewcontainer.h
 334     dolphincontextmenu.h
 335     dolphinnavigatorswidgetaction.h
 336     dolphintabbar.h
 337     dolphinplacesmodelsingleton.h
 338     dolphinrecenttabsmenu.h
 339     dolphintabpage.h
 340     dolphintabwidget.h
 341     dolphinurlnavigator.h
 342     dolphinurlnavigatorscontroller.h
 343     trash/dolphintrash.h
 344     filterbar/filterbar.h
 345     kitemviews/kfileitemlisttostring.h
 346     panels/places/placespanel.h
 347     panels/panel.h
 348     panels/folders/foldersitemlistwidget.h
 349     panels/folders/treeviewcontextmenu.h
 350     panels/folders/folderspanel.h
 351     panels/terminal/terminalpanel.h
 352     search/dolphinfacetswidget.h
 353     search/dolphinquery.h
 354     search/dolphinsearchbox.h
 355     selectionmode/actiontexthelper.h
 356     selectionmode/actionwithwidget.h
 357     selectionmode/backgroundcolorhelper.h
 358     selectionmode/bottombar.h
 359     selectionmode/bottombarcontentscontainer.h
 360     selectionmode/topbar.h
 361     settings/interface/folderstabssettingspage.h
 362     settings/interface/statusandlocationbarssettingspage.h
 363     settings/interface/confirmationssettingspage.h
 364     settings/interface/interfacesettingspage.h
 365     settings/interface/previewssettingspage.h
 366     settings/dolphinsettingsdialog.h
 367     settings/contextmenu/contextmenusettingspage.h
 368     settings/settingspagebase.h
 369     settings/servicemodel.h
 370     settings/trash/trashsettingspage.h
 371     settings/viewmodes/dolphinfontrequester.h
 372     settings/viewmodes/viewsettingspage.h
 373     settings/viewmodes/viewmodesettings.h
 374     settings/viewmodes/viewsettingstab.h
 375     settings/viewmodes/contentdisplaytab.h
 376     settings/viewmodes/generalviewsettingspage.h
 377     statusbar/dolphinstatusbar.h
 378     statusbar/mountpointobserver.h
 379     statusbar/mountpointobservercache.h
 380     statusbar/spaceinfoobserver.h
 381     statusbar/statusbarspaceinfo.h
 382     views/zoomlevelinfo.h
 383     dolphindebug.h
 384     global.h
 385 )
 386
 387 if(HAVE_BALOO)
 388     target_sources(dolphinstatic PRIVATE
 389         panels/information/informationpanel.cpp
 390         panels/information/informationpanelcontent.cpp
 391         panels/information/pixmapviewer.cpp
 392         panels/information/phononwidget.cpp
 393         settings/interface/panelsettingspage.cpp
 394         panels/information/informationpanel.h
 395         panels/information/informationpanelcontent.h
 396         panels/information/pixmapviewer.h
 397         panels/information/phononwidget.h
 398         settings/interface/panelsettingspage.h
 399     )
 400
 401     kconfig_add_kcfg_files(dolphinstatic
 402         panels/information/dolphin_informationpanelsettings.kcfgc
 403     )
 404
 405 endif()
 406
 407 if(HAVE_KUSERFEEDBACK)
 408     target_sources(dolphinstatic PRIVATE
 409         userfeedback/dolphinfeedbackprovider.cpp
 410         userfeedback/settingsdatasource.cpp
 411         userfeedback/placesdatasource.cpp
 412         settings/userfeedback/userfeedbacksettingspage.cpp
 413         userfeedback/dolphinfeedbackprovider.h
 414         userfeedback/settingsdatasource.h
 415         userfeedback/placesdatasource.h
 416         settings/userfeedback/userfeedbacksettingspage.h
 417     )
 418 endif()
 419
 420 kconfig_add_kcfg_files(dolphinstatic
 421     panels/folders/dolphin_folderspanelsettings.kcfgc
 422     panels/places/dolphin_placespanelsettings.kcfgc
 423     settings/dolphin_compactmodesettings.kcfgc
 424     settings/dolphin_detailsmodesettings.kcfgc
 425     settings/dolphin_contextmenusettings.kcfgc
 426     settings/dolphin_iconsmodesettings.kcfgc
 427     settings/dolphin_contentdisplaysettings.kcfgc
 428     search/dolphin_searchsettings.kcfgc
 429     settings/dolphin_versioncontrolsettings.kcfgc
 430 )
 431 kconfig_add_kcfg_files(dolphinstatic GENERATE_MOC
 432     settings/dolphin_generalsettings.kcfgc
 433 )
 434
 435 qt_generate_dbus_interface(${CMAKE_CURRENT_SOURCE_DIR}/dolphinmainwindow.h org.kde.DolphinMainWindow.xml)
 436 qt_add_dbus_adaptor(dolphin_dbus_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindow.h DolphinMainWindow)
 437 qt_add_dbus_interface(dolphin_dbus_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindowinterface)
 438 qt_add_dbus_interface(dolphin_dbus_SRCS panels/terminal/org.kde.KIOFuse.VFS.xml kiofuse_interface)
 439
 440 target_sources(dolphinstatic PRIVATE
 441     ${dolphin_dbus_SRCS}
 442 )
 443
 444 target_include_directories(dolphinstatic SYSTEM PRIVATE ${PHONON_INCLUDES})
 445 target_link_libraries(dolphinstatic
 446     dolphinprivate
 447     KF6::CoreAddons
 448     KF6::KCMUtils
 449     KF6::DBusAddons
 450     KF6::Notifications
 451     KF6::BookmarksWidgets
 452     Phonon::phonon4qt6
 453 )
 454
 455 if (HAVE_PLASMA_ACTIVITIES)
 456     target_link_libraries(
 457         dolphinstatic
 458         Plasma::Activities
 459     )
 460 endif()
 461
 462 if (HAVE_KUSERFEEDBACK)
 463     target_link_libraries(
 464         dolphinstatic
 465         KF6::UserFeedbackCore
 466         KF6::UserFeedbackWidgets
 467     )
 468 endif()
 469
 470 add_executable(dolphin)
 471
 472 target_sources(dolphin PRIVATE
 473     dbusinterface.cpp
 474     dbusinterface.h
 475     main.cpp
 476 )
 477
 478 if(FLATPAK)
 479     target_compile_definitions(dolphin PRIVATE FLATPAK)
 480 endif()
 481
 482 # Install the icons on macOS and Windows
 483 ecm_add_app_icon(dolphin
 484     ICONS
 485         icons/128-apps-org.kde.dolphin.png
 486         icons/16-apps-org.kde.dolphin.png
 487         icons/22-apps-org.kde.dolphin.png
 488         icons/32-apps-org.kde.dolphin.png
 489         icons/48-apps-org.kde.dolphin.png
 490         icons/64-apps-org.kde.dolphin.png
 491 )
 492
 493 install(FILES icons/org.kde.dolphin.svg DESTINATION ${KDE_INSTALL_ICONDIR}/hicolor/scalable/apps)
 494
 495 target_link_libraries(dolphin
 496     PRIVATE
 497     dolphinprivate
 498     dolphinstatic
 499     KF6::Crash
 500 )
 501
 502 if (HAVE_X11)
 503     target_link_libraries(dolphin PRIVATE Qt::GuiPrivate)
 504 endif()
 505
 506 include(DbusInterfaceMacros)
 507
 508 generate_and_install_dbus_interface(
 509     dolphin
 510     dbusinterface.h
 511     org.freedesktop.FileManager1.xml
 512     OPTIONS -a
 513 )
 514
 515 install(TARGETS dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 516
 517 ##########################################
 518
 519 if(NOT WIN32)
 520     # The settings are still accessible from the hamburger menu
 521     add_library(kcm_dolphinviewmodes MODULE)
 522     add_library(kcm_dolphingeneral MODULE)
 523
 524     target_sources(kcm_dolphinviewmodes PRIVATE
 525         settings/kcm/kcmdolphinviewmodes.cpp
 526         settings/viewmodes/dolphinfontrequester.cpp
 527         settings/viewmodes/viewmodesettings.cpp
 528         settings/viewmodes/viewsettingstab.cpp
 529         settings/settingspagebase.cpp
 530         views/zoomlevelinfo.cpp
 531         settings/kcm/kcmdolphinviewmodes.h
 532         settings/viewmodes/dolphinfontrequester.h
 533         settings/viewmodes/viewmodesettings.h
 534         settings/viewmodes/viewsettingstab.h
 535         views/zoomlevelinfo.h)
 536
 537     target_sources(kcm_dolphingeneral PRIVATE
 538         settings/kcm/kcmdolphingeneral.cpp
 539         settings/interface/folderstabssettingspage.cpp
 540         settings/interface/statusandlocationbarssettingspage.cpp
 541         settings/interface/previewssettingspage.cpp
 542         settings/interface/confirmationssettingspage.cpp
 543         settings/settingspagebase.cpp
 544         settings/servicemodel.cpp
 545         dolphin_generalsettings.cpp
 546         dolphindebug.cpp
 547         dolphinmainwindowinterface.cpp
 548         views/viewproperties.cpp
 549         dolphin_directoryviewpropertysettings.cpp
 550         global.cpp
 551         settings/kcm/kcmdolphingeneral.h
 552         settings/interface/folderstabssettingspage.h
 553         settings/interface/statusandlocationbarssettingspage.h
 554         settings/interface/previewssettingspage.h
 555         settings/interface/confirmationssettingspage.h
 556         settings/settingspagebase.h
 557         settings/servicemodel.h
 558         dolphin_generalsettings.h
 559         dolphindebug.h
 560         dolphinmainwindowinterface.h
 561         views/viewproperties.h
 562         dolphin_directoryviewpropertysettings.h
 563         global.h
 564     )
 565
 566     kconfig_add_kcfg_files(kcm_dolphinviewmodes
 567         settings/dolphin_compactmodesettings.kcfgc
 568         settings/dolphin_directoryviewpropertysettings.kcfgc
 569         settings/dolphin_detailsmodesettings.kcfgc
 570         settings/dolphin_iconsmodesettings.kcfgc
 571         settings/dolphin_contentdisplaysettings.kcfgc
 572         settings/dolphin_generalsettings.kcfgc
 573         settings/dolphin_versioncontrolsettings.kcfgc
 574         GENERATE_MOC
 575     )
 576
 577     kconfig_add_kcfg_files(kcm_dolphingeneral
 578         settings/dolphin_generalsettings.kcfgc
 579         GENERATE_MOC
 580     )
 581
 582     target_link_libraries(kcm_dolphinviewmodes dolphinprivate)
 583     target_link_libraries(kcm_dolphingeneral dolphinprivate)
 584
 585     install( FILES org.kde.dolphin.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR} )
 586
 587     install(TARGETS kcm_dolphinviewmodes DESTINATION ${KDE_INSTALL_PLUGINDIR}/dolphin/kcms )
 588     install(TARGETS kcm_dolphingeneral DESTINATION ${KDE_INSTALL_PLUGINDIR}/dolphin/kcms )
 589 endif()
 590
 591 if(NOT WIN32)
 592     add_subdirectory(settings/contextmenu/servicemenuinstaller)
 593     install( FILES settings/contextmenu/servicemenu.knsrc DESTINATION ${KDE_INSTALL_KNSRCDIR} )
 594 endif()
 595
 596 ########### install files ###############
 597
 598 install( PROGRAMS org.kde.dolphin.desktop DESTINATION ${KDE_INSTALL_APPDIR} )
 599
 600 install( DIRECTORY DESTINATION "${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel" )
 601
 602 install(
 603     CODE "execute_process(COMMAND \"${CMAKE_COMMAND}\" -E create_symlink \"${KDE_INSTALL_FULL_APPDIR}/org.kde.dolphin.desktop\" \"\$ENV{DESTDIR}${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel/org.kde.dolphin.desktop\")"
 604 )
 605
 606 install( FILES settings/dolphin_directoryviewpropertysettings.kcfg
 607                settings/dolphin_generalsettings.kcfg
 608                settings/dolphin_contextmenusettings.kcfg
 609                settings/dolphin_compactmodesettings.kcfg
 610                settings/dolphin_iconsmodesettings.kcfg
 611                settings/dolphin_detailsmodesettings.kcfg
 612                settings/dolphin_contentdisplaysettings.kcfg
 613                settings/dolphin_versioncontrolsettings.kcfg
 614          DESTINATION ${KDE_INSTALL_KCFGDIR} )
 615
 616 install( FILES settings/dolphin_detailsmodesettings.upd
 617                settings/dolphin_directorysizemode.upd
 618                settings/dolphin_directorysizemode.py
 619          DESTINATION ${KDE_INSTALL_KCONFUPDATEDIR} )
 620
 621 if(BUILD_TESTING)
 622     add_subdirectory(tests)
 623 endif()
 624
 625 # movetonewfolderitemaction plugin
 626
 627 kcoreaddons_add_plugin(movetonewfolderitemaction
 628     SOURCES itemactions/movetonewfolderitemaction.cpp itemactions/movetonewfolderitemaction.h
 629     INSTALL_NAMESPACE "kf6/kfileitemaction")
 630
 631 target_link_libraries(movetonewfolderitemaction
 632     KF6::I18n
 633     KF6::KIOCore
 634     KF6::KIOWidgets
 635     KF6::KIOFileWidgets)