src/CMakeLists.txt

   1 include(ECMAddAppIcon)
   2
   3 configure_file(config-baloo.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-baloo.h)
   4
   5 configure_file(config-kactivities.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-kactivities.h)
   6
   7 configure_file(config-packagekit.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-packagekit.h)
   8
   9 configure_file(config-terminal.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-terminal.h)
  10
  11 configure_file(config-kuserfeedback.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-kuserfeedback.h)
  12
  13 add_definitions(
  14     -DTRANSLATION_DOMAIN=\"dolphin\"
  15 )
  16 remove_definitions(
  17     -DQT_NO_CAST_FROM_BYTEARRAY
  18     -DQT_NO_CAST_FROM_ASCII
  19     -DQT_NO_CAST_TO_ASCII
  20 )
  21
  22 ##########################################
  23
  24 add_library(dolphinvcs SHARED)
  25
  26 target_sources(dolphinvcs PRIVATE
  27     views/versioncontrol/kversioncontrolplugin.cpp
  28 )
  29
  30 generate_export_header(dolphinvcs BASE_NAME dolphinvcs)
  31
  32 target_link_libraries(
  33     dolphinvcs PUBLIC
  34     Qt5::Widgets
  35 )
  36
  37 set_target_properties(dolphinvcs PROPERTIES
  38     VERSION ${DOLPHINVCS_VERSION}
  39     SOVERSION ${DOLPHINVCS_SOVERSION}
  40     EXPORT_NAME DolphinVcs
  41 )
  42
  43 ecm_generate_headers(dolphinvcs_LIB_HEADERS
  44     HEADER_NAMES
  45     KVersionControlPlugin
  46
  47     RELATIVE "views/versioncontrol"
  48     REQUIRED_HEADERS dolphinvcs_LIB_HEADERS
  49 )
  50
  51 install(TARGETS dolphinvcs EXPORT DolphinVcsTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
  52
  53 install(FILES views/versioncontrol/fileviewversioncontrolplugin.desktop DESTINATION ${KDE_INSTALL_KSERVICETYPES5DIR})
  54 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphinvcs_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
  55 install(FILES ${dolphinvcs_LIB_HEADERS} DESTINATION "${KDE_INSTALL_INCLUDEDIR}/Dolphin" COMPONENT Devel)
  56
  57 ########### next target ###############
  58
  59 add_library(dolphinprivate SHARED)
  60
  61 target_sources(dolphinprivate PRIVATE
  62     kitemviews/kfileitemlistview.cpp
  63     kitemviews/kfileitemlistwidget.cpp
  64     kitemviews/kfileitemmodel.cpp
  65     kitemviews/kfileitemmodelrolesupdater.cpp
  66     kitemviews/kitemlistcontainer.cpp
  67     kitemviews/kitemlistcontroller.cpp
  68     kitemviews/kitemlistgroupheader.cpp
  69     kitemviews/kitemlistheader.cpp
  70     kitemviews/kitemlistselectionmanager.cpp
  71     kitemviews/kitemliststyleoption.cpp
  72     kitemviews/kitemlistview.cpp
  73     kitemviews/kitemlistviewaccessible.cpp
  74     kitemviews/kitemlistwidget.cpp
  75     kitemviews/kitemmodelbase.cpp
  76     kitemviews/kitemset.cpp
  77     kitemviews/kstandarditem.cpp
  78     kitemviews/kstandarditemlistgroupheader.cpp
  79     kitemviews/kstandarditemlistwidget.cpp
  80     kitemviews/kstandarditemlistview.cpp
  81     kitemviews/kstandarditemmodel.cpp
  82     kitemviews/private/kdirectorycontentscounter.cpp
  83     kitemviews/private/kdirectorycontentscounterworker.cpp
  84     kitemviews/private/kfileitemclipboard.cpp
  85     kitemviews/private/kfileitemmodelfilter.cpp
  86     kitemviews/private/kitemlistheaderwidget.cpp
  87     kitemviews/private/kitemlistkeyboardsearchmanager.cpp
  88     kitemviews/private/kitemlistroleeditor.cpp
  89     kitemviews/private/kitemlistrubberband.cpp
  90     kitemviews/private/kitemlistselectiontoggle.cpp
  91     kitemviews/private/kitemlistsizehintresolver.cpp
  92     kitemviews/private/kitemlistsmoothscroller.cpp
  93     kitemviews/private/kitemlistviewanimation.cpp
  94     kitemviews/private/kitemlistviewlayouter.cpp
  95     kitemviews/private/kpixmapmodifier.cpp
  96     kitemviews/private/ktwofingerswipe.cpp
  97     kitemviews/private/ktwofingertap.cpp
  98     settings/applyviewpropsjob.cpp
  99     settings/viewmodes/viewmodesettings.cpp
 100     settings/viewpropertiesdialog.cpp
 101     settings/viewpropsprogressinfo.cpp
 102     views/dolphinfileitemlistwidget.cpp
 103     views/dolphinitemlistview.cpp
 104     views/dolphinnewfilemenuobserver.cpp
 105     views/dolphinremoteencoding.cpp
 106     views/dolphinview.cpp
 107     views/dolphinviewactionhandler.cpp
 108     views/draganddrophelper.cpp
 109     views/versioncontrol/updateitemstatesthread.cpp
 110     views/versioncontrol/versioncontrolobserver.cpp
 111     views/viewmodecontroller.cpp
 112     views/viewproperties.cpp
 113     views/zoomlevelinfo.cpp
 114     dolphinremoveaction.cpp
 115     middleclickactioneventfilter.cpp
 116     dolphinnewfilemenu.cpp
 117 )
 118
 119 ecm_qt_declare_logging_category(dolphinprivate
 120     HEADER dolphindebug.h
 121     IDENTIFIER DolphinDebug
 122     CATEGORY_NAME org.kde.dolphin
 123     DESCRIPTION "dolphin"
 124     EXPORT DOLPHIN
 125 )
 126
 127 if(HAVE_BALOO)
 128     target_sources(dolphinprivate PRIVATE
 129         views/tooltips/dolphinfilemetadatawidget.cpp
 130         views/tooltips/tooltipmanager.cpp
 131         kitemviews/private/kbaloorolesprovider.cpp
 132     )
 133 endif()
 134
 135 kconfig_add_kcfg_files(dolphinprivate
 136     settings/dolphin_compactmodesettings.kcfgc
 137     settings/dolphin_directoryviewpropertysettings.kcfgc
 138     settings/dolphin_detailsmodesettings.kcfgc
 139     settings/dolphin_iconsmodesettings.kcfgc
 140     settings/dolphin_generalsettings.kcfgc
 141     settings/dolphin_contextmenusettings.kcfgc
 142     settings/dolphin_versioncontrolsettings.kcfgc
 143 )
 144
 145 generate_export_header(dolphinprivate BASE_NAME dolphin)
 146
 147 target_link_libraries(
 148     dolphinprivate PUBLIC
 149     dolphinvcs
 150     Qt5::Concurrent
 151     Qt5::Gui
 152     KF5::I18n
 153     KF5::IconThemes
 154     KF5::KIOCore
 155     KF5::KIOWidgets
 156     KF5::KIOFileWidgets
 157     KF5::Completion
 158     KF5::TextWidgets
 159     KF5::ConfigCore
 160     KF5::NewStuff
 161     KF5::Parts
 162     KF5::WindowSystem
 163 )
 164
 165 if(HAVE_BALOO)
 166     target_link_libraries(
 167         dolphinprivate PUBLIC
 168         KF5::FileMetaData
 169         KF5::Baloo
 170         KF5::BalooWidgets
 171     )
 172 endif()
 173
 174 set_target_properties(dolphinprivate PROPERTIES
 175     VERSION ${DOLPHINPRIVATE_VERSION}
 176     SOVERSION ${DOLPHINPRIVATE_SOVERSION}
 177 )
 178
 179 install(TARGETS dolphinprivate ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} LIBRARY NAMELINK_SKIP)
 180 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphin_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
 181
 182 ##########################################
 183 configure_file(dolphinpart.desktop.in ${CMAKE_CURRENT_BINARY_DIR}/dolphinpart.desktop @ONLY)
 184
 185 add_library(dolphinpart MODULE)
 186
 187 target_sources(dolphinpart PRIVATE
 188     dolphinpart.cpp
 189     dolphinpart_ext.cpp
 190     dolphindebug.cpp
 191
 192     dolphinpart.qrc
 193 )
 194
 195 kcoreaddons_desktop_to_json(dolphinpart ${CMAKE_CURRENT_BINARY_DIR}/dolphinpart.desktop)
 196
 197 target_link_libraries(dolphinpart
 198     dolphinprivate
 199 )
 200
 201 install(TARGETS dolphinpart DESTINATION ${KDE_INSTALL_PLUGINDIR}/kf5/parts)
 202
 203 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphinpart.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR})
 204
 205 ##########################################
 206
 207 add_library(dolphinstatic STATIC)
 208
 209 target_sources(dolphinstatic PRIVATE
 210     dolphinbookmarkhandler.cpp
 211     dolphindockwidget.cpp
 212     dolphinmainwindow.cpp
 213     dolphinviewcontainer.cpp
 214     dolphincontextmenu.cpp
 215     dolphinnavigatorswidgetaction.cpp
 216     dolphintabbar.cpp
 217     dolphinplacesmodelsingleton.cpp
 218     dolphinrecenttabsmenu.cpp
 219     dolphintabpage.cpp
 220     dolphintabwidget.cpp
 221     dolphinurlnavigator.cpp
 222     dolphinurlnavigatorscontroller.cpp
 223     trash/dolphintrash.cpp
 224     filterbar/filterbar.cpp
 225     panels/places/placespanel.cpp
 226     panels/places/placesitem.cpp
 227     panels/places/placesitemlistgroupheader.cpp
 228     panels/places/placesitemlistwidget.cpp
 229     panels/places/placesitemmodel.cpp
 230     panels/places/placesitemsignalhandler.cpp
 231     panels/places/placesview.cpp
 232     panels/panel.cpp
 233     panels/folders/foldersitemlistwidget.cpp
 234     panels/folders/treeviewcontextmenu.cpp
 235     panels/folders/folderspanel.cpp
 236     panels/terminal/terminalpanel.cpp
 237     search/dolphinfacetswidget.cpp
 238     search/dolphinquery.cpp
 239     search/dolphinsearchbox.cpp
 240     settings/general/behaviorsettingspage.cpp
 241     settings/general/configurepreviewplugindialog.cpp
 242     settings/general/confirmationssettingspage.cpp
 243     settings/general/generalsettingspage.cpp
 244     settings/general/previewssettingspage.cpp
 245     settings/general/statusbarsettingspage.cpp
 246     settings/dolphinsettingsdialog.cpp
 247     settings/navigation/navigationsettingspage.cpp
 248     settings/contextmenu/contextmenusettingspage.cpp
 249     settings/settingspagebase.cpp
 250     settings/serviceitemdelegate.cpp
 251     settings/servicemodel.cpp
 252     settings/startup/startupsettingspage.cpp
 253     settings/trash/trashsettingspage.cpp
 254     settings/viewmodes/dolphinfontrequester.cpp
 255     settings/viewmodes/viewsettingspage.cpp
 256     settings/viewmodes/viewmodesettings.cpp
 257     settings/viewmodes/viewsettingstab.cpp
 258     statusbar/dolphinstatusbar.cpp
 259     statusbar/mountpointobserver.cpp
 260     statusbar/mountpointobservercache.cpp
 261     statusbar/spaceinfoobserver.cpp
 262     statusbar/statusbarspaceinfo.cpp
 263     views/zoomlevelinfo.cpp
 264     dolphindebug.cpp
 265     global.cpp
 266     dolphin.qrc
 267 )
 268
 269 if(HAVE_BALOO)
 270     target_sources(dolphinstatic PRIVATE
 271         panels/information/informationpanel.cpp
 272         panels/information/informationpanelcontent.cpp
 273         panels/information/pixmapviewer.cpp
 274         panels/information/phononwidget.cpp
 275     )
 276 endif()
 277
 278 if(HAVE_KUSERFEEDBACK)
 279     target_sources(dolphinstatic PRIVATE
 280         userfeedback/dolphinfeedbackprovider.cpp
 281         userfeedback/settingsdatasource.cpp
 282         userfeedback/placesdatasource.cpp
 283         settings/userfeedback/userfeedbacksettingspage.cpp
 284     )
 285 endif()
 286
 287 kconfig_add_kcfg_files(dolphinstatic
 288     panels/folders/dolphin_folderspanelsettings.kcfgc
 289     panels/information/dolphin_informationpanelsettings.kcfgc
 290     panels/places/dolphin_placespanelsettings.kcfgc
 291     settings/dolphin_compactmodesettings.kcfgc
 292     settings/dolphin_detailsmodesettings.kcfgc
 293     settings/dolphin_contextmenusettings.kcfgc
 294     settings/dolphin_iconsmodesettings.kcfgc
 295     search/dolphin_searchsettings.kcfgc
 296     settings/dolphin_versioncontrolsettings.kcfgc
 297 )
 298 kconfig_add_kcfg_files(dolphinstatic GENERATE_MOC
 299     settings/dolphin_generalsettings.kcfgc
 300 )
 301
 302 qt5_generate_dbus_interface(${CMAKE_CURRENT_SOURCE_DIR}/dolphinmainwindow.h org.kde.DolphinMainWindow.xml)
 303 qt5_add_dbus_adaptor(dolphin_dbus_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindow.h DolphinMainWindow)
 304 qt5_add_dbus_interface(dolphin_dbus_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindowinterface)
 305 qt5_add_dbus_interface(dolphin_dbus_SRCS panels/terminal/org.kde.KIOFuse.VFS.xml kiofuse_interface)
 306
 307 target_sources(dolphinstatic PRIVATE
 308     ${dolphin_dbus_SRCS}
 309 )
 310
 311 target_include_directories(dolphinstatic SYSTEM PRIVATE ${PHONON_INCLUDES})
 312 target_link_libraries(dolphinstatic
 313     dolphinprivate
 314     KF5::CoreAddons
 315     KF5::KCMUtils
 316     KF5::DBusAddons
 317     KF5::Notifications
 318     Phonon::phonon4qt5
 319 )
 320
 321 if (HAVE_KACTIVITIES)
 322     target_link_libraries(
 323         dolphinstatic
 324         KF5::Activities
 325     )
 326 endif()
 327
 328 if (HAVE_KUSERFEEDBACK)
 329     target_link_libraries(
 330         dolphinstatic
 331         KUserFeedbackCore
 332         KUserFeedbackWidgets
 333     )
 334 endif()
 335
 336 add_executable(dolphin)
 337
 338 target_sources(dolphin PRIVATE
 339     dbusinterface.cpp
 340     main.cpp
 341 )
 342
 343 # Sets the icon on Windows and OSX
 344 file(GLOB ICONS_SRCS "${CMAKE_CURRENT_SOURCE_DIR}/icons/*system-file-manager.png")
 345 ecm_add_app_icon(dolphin_APPICON_SRCS ICONS ${ICONS_SRCS})
 346 # ecm_add_app_icon 5.83 will take target as arg, use that once it is min req.
 347 target_sources(dolphin PRIVATE
 348     ${dolphin_APPICON_SRCS}
 349 )
 350
 351 target_link_libraries(dolphin
 352     PRIVATE
 353     dolphinprivate
 354     dolphinstatic
 355     KF5::Crash
 356 )
 357
 358 include(DbusInterfaceMacros)
 359
 360 generate_and_install_dbus_interface(
 361     dolphin
 362     dbusinterface.h
 363     org.freedesktop.FileManager1.xml
 364     OPTIONS -a
 365 )
 366
 367 install(TARGETS dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 368
 369 ##########################################
 370
 371 if(NOT WIN32)
 372     # The settings are still accessible from the hamburger menu
 373     add_library(kcm_dolphinviewmodes MODULE)
 374     add_library(kcm_dolphinnavigation MODULE)
 375     add_library(kcm_dolphingeneral MODULE)
 376
 377     target_sources(kcm_dolphinviewmodes PRIVATE
 378         settings/kcm/kcmdolphinviewmodes.cpp
 379         settings/viewmodes/dolphinfontrequester.cpp
 380         settings/viewmodes/viewmodesettings.cpp
 381         settings/viewmodes/viewsettingstab.cpp
 382         views/zoomlevelinfo.cpp)
 383
 384     target_sources(kcm_dolphinnavigation PRIVATE
 385         settings/kcm/kcmdolphinnavigation.cpp
 386         settings/navigation/navigationsettingspage.cpp
 387         settings/settingspagebase.cpp)
 388
 389     target_sources(kcm_dolphingeneral PRIVATE
 390         settings/kcm/kcmdolphingeneral.cpp
 391         settings/general/behaviorsettingspage.cpp
 392         settings/general/previewssettingspage.cpp
 393         settings/general/configurepreviewplugindialog.cpp
 394         settings/general/confirmationssettingspage.cpp
 395         settings/settingspagebase.cpp
 396         settings/serviceitemdelegate.cpp
 397         settings/servicemodel.cpp)
 398
 399     kconfig_add_kcfg_files(kcm_dolphinviewmodes
 400         settings/dolphin_compactmodesettings.kcfgc
 401         settings/dolphin_directoryviewpropertysettings.kcfgc
 402         settings/dolphin_detailsmodesettings.kcfgc
 403         settings/dolphin_iconsmodesettings.kcfgc
 404         settings/dolphin_generalsettings.kcfgc
 405         settings/dolphin_versioncontrolsettings.kcfgc
 406     )
 407
 408     kconfig_add_kcfg_files(kcm_dolphinnavigation
 409         settings/dolphin_generalsettings.kcfgc)
 410
 411     kconfig_add_kcfg_files(kcm_dolphingeneral
 412         settings/dolphin_generalsettings.kcfgc)
 413
 414     target_link_libraries(kcm_dolphinviewmodes dolphinprivate)
 415     target_link_libraries(kcm_dolphinnavigation dolphinprivate)
 416     target_link_libraries(kcm_dolphingeneral dolphinprivate)
 417
 418     install( FILES org.kde.dolphin.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR} )
 419     install( FILES settings/kcm/kcmdolphinviewmodes.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 420     install( FILES settings/kcm/kcmdolphinnavigation.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 421     install( FILES settings/kcm/kcmdolphingeneral.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 422
 423     install(TARGETS kcm_dolphinviewmodes DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 424     install(TARGETS kcm_dolphinnavigation DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 425     install(TARGETS kcm_dolphingeneral DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 426 endif()
 427
 428 if(NOT WIN32)
 429     add_subdirectory(settings/contextmenu/servicemenuinstaller)
 430     install( FILES settings/contextmenu/servicemenu.knsrc DESTINATION ${KDE_INSTALL_KNSRCDIR} )
 431 endif()
 432
 433 ########### install files ###############
 434
 435 install( PROGRAMS org.kde.dolphin.desktop DESTINATION ${KDE_INSTALL_APPDIR} )
 436
 437 install( DIRECTORY DESTINATION "${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel" )
 438
 439 install(
 440     CODE "execute_process(COMMAND \"${CMAKE_COMMAND}\" -E create_symlink \"${KDE_INSTALL_FULL_APPDIR}/org.kde.dolphin.desktop\" \"\$ENV{DESTDIR}${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel/org.kde.dolphin.desktop\")"
 441 )
 442
 443 install( FILES settings/dolphin_directoryviewpropertysettings.kcfg
 444                settings/dolphin_generalsettings.kcfg
 445                settings/dolphin_contextmenusettings.kcfg
 446                settings/dolphin_compactmodesettings.kcfg
 447                settings/dolphin_iconsmodesettings.kcfg
 448                settings/dolphin_detailsmodesettings.kcfg
 449                settings/dolphin_versioncontrolsettings.kcfg
 450          DESTINATION ${KDE_INSTALL_KCFGDIR} )
 451
 452 if(BUILD_TESTING)
 453     find_package(Qt5Test ${QT_MIN_VERSION} CONFIG REQUIRED)
 454     add_subdirectory(tests)
 455 endif()