src/CMakeLists.txt

   1 include(ECMAddAppIcon)
   2
   3 configure_file(config-baloo.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-baloo.h)
   4
   5 configure_file(config-kactivities.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-kactivities.h)
   6
   7 configure_file(config-packagekit.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-packagekit.h)
   8
   9 configure_file(config-terminal.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-terminal.h)
  10
  11 configure_file(config-kuserfeedback.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-kuserfeedback.h)
  12
  13 add_definitions(
  14     -DTRANSLATION_DOMAIN=\"dolphin\"
  15 )
  16 remove_definitions(
  17     -DQT_NO_CAST_FROM_BYTEARRAY
  18     -DQT_NO_SIGNALS_SLOTS_KEYWORDS
  19     -DQT_NO_CAST_FROM_ASCII
  20     -DQT_NO_CAST_TO_ASCII
  21     -DQT_NO_FOREACH
  22     -DQT_NO_KEYWORDS
  23 )
  24
  25 ##########################################
  26
  27 set(dolphinvcs_LIB_SRCS
  28     views/versioncontrol/kversioncontrolplugin.cpp
  29 )
  30
  31 add_library(dolphinvcs ${dolphinvcs_LIB_SRCS})
  32 generate_export_header(dolphinvcs BASE_NAME dolphinvcs)
  33
  34 target_link_libraries(
  35     dolphinvcs PUBLIC
  36     Qt5::Widgets
  37 )
  38
  39 set_target_properties(dolphinvcs PROPERTIES
  40     VERSION ${DOLPHINVCS_VERSION_STRING}
  41     SOVERSION ${DOLPHINVCS_SOVERSION}
  42     EXPORT_NAME DolphinVcs
  43 )
  44
  45 ecm_generate_headers(dolphinvcs_LIB_HEADERS
  46     HEADER_NAMES
  47     KVersionControlPlugin
  48
  49     RELATIVE "views/versioncontrol"
  50     REQUIRED_HEADERS dolphinvcs_LIB_HEADERS
  51 )
  52
  53 install(TARGETS dolphinvcs EXPORT DolphinVcsTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
  54
  55 install(FILES views/versioncontrol/fileviewversioncontrolplugin.desktop DESTINATION ${KDE_INSTALL_KSERVICETYPES5DIR})
  56 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphinvcs_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
  57 install(FILES ${dolphinvcs_LIB_HEADERS} DESTINATION "${KDE_INSTALL_INCLUDEDIR}/Dolphin" COMPONENT Devel)
  58
  59 ########### next target ###############
  60
  61 set(dolphinprivate_LIB_SRCS
  62     kitemviews/kfileitemlistview.cpp
  63     kitemviews/kfileitemlistwidget.cpp
  64     kitemviews/kfileitemmodel.cpp
  65     kitemviews/kfileitemmodelrolesupdater.cpp
  66     kitemviews/kitemlistcontainer.cpp
  67     kitemviews/kitemlistcontroller.cpp
  68     kitemviews/kitemlistgroupheader.cpp
  69     kitemviews/kitemlistheader.cpp
  70     kitemviews/kitemlistselectionmanager.cpp
  71     kitemviews/kitemliststyleoption.cpp
  72     kitemviews/kitemlistview.cpp
  73     kitemviews/kitemlistviewaccessible.cpp
  74     kitemviews/kitemlistwidget.cpp
  75     kitemviews/kitemmodelbase.cpp
  76     kitemviews/kitemset.cpp
  77     kitemviews/kstandarditem.cpp
  78     kitemviews/kstandarditemlistgroupheader.cpp
  79     kitemviews/kstandarditemlistwidget.cpp
  80     kitemviews/kstandarditemlistview.cpp
  81     kitemviews/kstandarditemmodel.cpp
  82     kitemviews/private/kdirectorycontentscounter.cpp
  83     kitemviews/private/kdirectorycontentscounterworker.cpp
  84     kitemviews/private/kfileitemclipboard.cpp
  85     kitemviews/private/kfileitemmodeldirlister.cpp
  86     kitemviews/private/kfileitemmodelfilter.cpp
  87     kitemviews/private/kitemlistheaderwidget.cpp
  88     kitemviews/private/kitemlistkeyboardsearchmanager.cpp
  89     kitemviews/private/kitemlistroleeditor.cpp
  90     kitemviews/private/kitemlistrubberband.cpp
  91     kitemviews/private/kitemlistselectiontoggle.cpp
  92     kitemviews/private/kitemlistsizehintresolver.cpp
  93     kitemviews/private/kitemlistsmoothscroller.cpp
  94     kitemviews/private/kitemlistviewanimation.cpp
  95     kitemviews/private/kitemlistviewlayouter.cpp
  96     kitemviews/private/kpixmapmodifier.cpp
  97     kitemviews/private/ktwofingerswipe.cpp
  98     kitemviews/private/ktwofingertap.cpp
  99     settings/applyviewpropsjob.cpp
 100     settings/viewmodes/viewmodesettings.cpp
 101     settings/viewpropertiesdialog.cpp
 102     settings/viewpropsprogressinfo.cpp
 103     views/dolphinfileitemlistwidget.cpp
 104     views/dolphinitemlistview.cpp
 105     views/dolphinnewfilemenuobserver.cpp
 106     views/dolphinremoteencoding.cpp
 107     views/dolphinview.cpp
 108     views/dolphinviewactionhandler.cpp
 109     views/draganddrophelper.cpp
 110     views/versioncontrol/updateitemstatesthread.cpp
 111     views/versioncontrol/versioncontrolobserver.cpp
 112     views/viewmodecontroller.cpp
 113     views/viewproperties.cpp
 114     views/zoomlevelinfo.cpp
 115     dolphinremoveaction.cpp
 116     middleclickactioneventfilter.cpp
 117     dolphinnewfilemenu.cpp
 118 )
 119
 120 ecm_qt_declare_logging_category(dolphinprivate_LIB_SRCS HEADER dolphindebug.h IDENTIFIER DolphinDebug CATEGORY_NAME org.kde.dolphin)
 121
 122 if(HAVE_BALOO)
 123     set(dolphinprivate_LIB_SRCS
 124         ${dolphinprivate_LIB_SRCS}
 125         views/tooltips/dolphinfilemetadatawidget.cpp
 126         views/tooltips/tooltipmanager.cpp
 127         kitemviews/private/kbaloorolesprovider.cpp
 128     )
 129 endif()
 130
 131 kconfig_add_kcfg_files(dolphinprivate_LIB_SRCS GENERATE_MOC
 132     settings/dolphin_compactmodesettings.kcfgc
 133     settings/dolphin_directoryviewpropertysettings.kcfgc
 134     settings/dolphin_detailsmodesettings.kcfgc
 135     settings/dolphin_iconsmodesettings.kcfgc
 136     settings/dolphin_generalsettings.kcfgc
 137     settings/dolphin_contextmenusettings.kcfgc
 138     settings/dolphin_versioncontrolsettings.kcfgc
 139 )
 140
 141 add_library(dolphinprivate ${dolphinprivate_LIB_SRCS})
 142 generate_export_header(dolphinprivate BASE_NAME dolphin)
 143
 144 target_link_libraries(
 145     dolphinprivate PUBLIC
 146     dolphinvcs
 147     Qt5::Concurrent
 148     Qt5::Gui
 149     KF5::I18n
 150     KF5::IconThemes
 151     KF5::KIOCore
 152     KF5::KIOWidgets
 153     KF5::KIOFileWidgets
 154     KF5::Completion
 155     KF5::TextWidgets
 156     KF5::ConfigCore
 157     KF5::NewStuff
 158     KF5::Parts
 159     KF5::WindowSystem
 160 )
 161
 162 if(HAVE_BALOO)
 163     target_link_libraries(
 164         dolphinprivate PUBLIC
 165         KF5::FileMetaData
 166         KF5::Baloo
 167         KF5::BalooWidgets
 168     )
 169 endif()
 170
 171 set_target_properties(dolphinprivate PROPERTIES
 172     VERSION ${DOLPHINPRIVATE_VERSION_STRING}
 173     SOVERSION ${DOLPHINPRIVATE_SOVERSION}
 174 )
 175
 176 install(TARGETS dolphinprivate ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} LIBRARY NAMELINK_SKIP)
 177 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphin_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
 178
 179 ##########################################
 180 configure_file(dolphinpart.desktop.in ${CMAKE_CURRENT_BINARY_DIR}/dolphinpart.desktop @ONLY)
 181
 182 set(dolphinpart_SRCS
 183    dolphinpart.cpp
 184    dolphinpart_ext.cpp
 185    dolphindebug.cpp
 186 )
 187
 188 qt5_add_resources(dolphinpart_SRCS dolphinpart.qrc)
 189
 190 add_library(dolphinpart MODULE ${dolphinpart_SRCS})
 191 kcoreaddons_desktop_to_json(dolphinpart ${CMAKE_CURRENT_BINARY_DIR}/dolphinpart.desktop)
 192
 193 target_link_libraries(dolphinpart
 194     dolphinprivate
 195 )
 196
 197 install(TARGETS dolphinpart DESTINATION ${KDE_INSTALL_PLUGINDIR}/kf5/parts)
 198
 199 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphinpart.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR})
 200
 201 ##########################################
 202
 203 set(dolphinstatic_SRCS
 204     dolphinbookmarkhandler.cpp
 205     dolphindockwidget.cpp
 206     dolphinmainwindow.cpp
 207     dolphinviewcontainer.cpp
 208     dolphincontextmenu.cpp
 209     dolphinnavigatorswidgetaction.cpp
 210     dolphintabbar.cpp
 211     dolphinplacesmodelsingleton.cpp
 212     dolphinrecenttabsmenu.cpp
 213     dolphintabpage.cpp
 214     dolphintabwidget.cpp
 215     dolphinurlnavigator.cpp
 216     dolphinurlnavigatorscontroller.cpp
 217     trash/dolphintrash.cpp
 218     filterbar/filterbar.cpp
 219     panels/places/placespanel.cpp
 220     panels/places/placesitem.cpp
 221     panels/places/placesitemlistgroupheader.cpp
 222     panels/places/placesitemlistwidget.cpp
 223     panels/places/placesitemmodel.cpp
 224     panels/places/placesitemsignalhandler.cpp
 225     panels/places/placesview.cpp
 226     panels/panel.cpp
 227     panels/folders/foldersitemlistwidget.cpp
 228     panels/folders/treeviewcontextmenu.cpp
 229     panels/folders/folderspanel.cpp
 230     panels/terminal/terminalpanel.cpp
 231     search/dolphinfacetswidget.cpp
 232     search/dolphinquery.cpp
 233     search/dolphinsearchbox.cpp
 234     settings/general/behaviorsettingspage.cpp
 235     settings/general/configurepreviewplugindialog.cpp
 236     settings/general/confirmationssettingspage.cpp
 237     settings/general/generalsettingspage.cpp
 238     settings/general/previewssettingspage.cpp
 239     settings/general/statusbarsettingspage.cpp
 240     settings/dolphinsettingsdialog.cpp
 241     settings/navigation/navigationsettingspage.cpp
 242     settings/contextmenu/contextmenusettingspage.cpp
 243     settings/settingspagebase.cpp
 244     settings/serviceitemdelegate.cpp
 245     settings/servicemodel.cpp
 246     settings/startup/startupsettingspage.cpp
 247     settings/trash/trashsettingspage.cpp
 248     settings/viewmodes/dolphinfontrequester.cpp
 249     settings/viewmodes/viewsettingspage.cpp
 250     settings/viewmodes/viewmodesettings.cpp
 251     settings/viewmodes/viewsettingstab.cpp
 252     statusbar/dolphinstatusbar.cpp
 253     statusbar/mountpointobserver.cpp
 254     statusbar/mountpointobservercache.cpp
 255     statusbar/spaceinfoobserver.cpp
 256     statusbar/statusbarspaceinfo.cpp
 257     views/zoomlevelinfo.cpp
 258     dolphindebug.cpp
 259     global.cpp
 260 )
 261
 262 if(HAVE_BALOO)
 263     set(dolphinstatic_SRCS
 264         ${dolphinstatic_SRCS}
 265         panels/information/informationpanel.cpp
 266         panels/information/informationpanelcontent.cpp
 267         panels/information/pixmapviewer.cpp
 268         panels/information/phononwidget.cpp
 269     )
 270 endif()
 271
 272 if(HAVE_KUSERFEEDBACK)
 273     set(dolphinstatic_SRCS
 274         ${dolphinstatic_SRCS}
 275         userfeedback/dolphinfeedbackprovider.cpp
 276         userfeedback/settingsdatasource.cpp
 277         userfeedback/placesdatasource.cpp
 278         settings/userfeedback/userfeedbacksettingspage.cpp
 279     )
 280 endif()
 281
 282 kconfig_add_kcfg_files(dolphinstatic_SRCS GENERATE_MOC
 283     panels/folders/dolphin_folderspanelsettings.kcfgc
 284     panels/information/dolphin_informationpanelsettings.kcfgc
 285     panels/places/dolphin_placespanelsettings.kcfgc
 286     settings/dolphin_compactmodesettings.kcfgc
 287     settings/dolphin_detailsmodesettings.kcfgc
 288     settings/dolphin_generalsettings.kcfgc
 289     settings/dolphin_contextmenusettings.kcfgc
 290     settings/dolphin_iconsmodesettings.kcfgc
 291     search/dolphin_searchsettings.kcfgc
 292     settings/dolphin_versioncontrolsettings.kcfgc
 293 )
 294
 295 qt5_add_resources(dolphinstatic_SRCS dolphin.qrc)
 296
 297 qt5_generate_dbus_interface(${CMAKE_CURRENT_SOURCE_DIR}/dolphinmainwindow.h org.kde.DolphinMainWindow.xml)
 298 qt5_add_dbus_adaptor(dolphinstatic_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindow.h DolphinMainWindow)
 299 qt5_add_dbus_interface(dolphinstatic_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindowinterface)
 300 qt5_add_dbus_interface(dolphinstatic_SRCS panels/terminal/org.kde.KIOFuse.VFS.xml kiofuse_interface)
 301
 302 add_library(dolphinstatic STATIC ${dolphinstatic_SRCS})
 303
 304 target_include_directories(dolphinstatic SYSTEM PRIVATE ${PHONON_INCLUDES})
 305 target_link_libraries(dolphinstatic
 306     dolphinprivate
 307     KF5::CoreAddons
 308     KF5::KCMUtils
 309     KF5::DBusAddons
 310     KF5::Notifications
 311     Phonon::phonon4qt5
 312 )
 313
 314 if (HAVE_KACTIVITIES)
 315     target_link_libraries(
 316         dolphinstatic
 317         KF5::Activities
 318     )
 319 endif()
 320
 321 if (HAVE_KUSERFEEDBACK)
 322     target_link_libraries(
 323         dolphinstatic
 324         KUserFeedbackCore
 325         KUserFeedbackWidgets
 326     )
 327 endif()
 328
 329 set(dolphin_SRCS
 330     dbusinterface.cpp
 331     main.cpp
 332 )
 333
 334 # Sets the icon on Windows and OSX
 335 file(GLOB ICONS_SRCS "${CMAKE_CURRENT_SOURCE_DIR}/icons/*system-file-manager.png")
 336 ecm_add_app_icon(dolphin_SRCS ICONS ${ICONS_SRCS})
 337
 338 kf5_add_kdeinit_executable(dolphin ${dolphin_SRCS})
 339
 340
 341 target_link_libraries(kdeinit_dolphin PUBLIC
 342     dolphinprivate
 343     PRIVATE
 344     dolphinstatic
 345     KF5::Crash
 346 )
 347
 348 include(DbusInterfaceMacros)
 349
 350 generate_and_install_dbus_interface(
 351     kdeinit_dolphin
 352     dbusinterface.h
 353     org.freedesktop.FileManager1.xml
 354     OPTIONS -a
 355 )
 356
 357 install(TARGETS kdeinit_dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 358 install(TARGETS dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 359
 360 ##########################################
 361
 362 set(kcm_dolphinviewmodes_PART_SRCS
 363     settings/kcm/kcmdolphinviewmodes.cpp
 364     settings/viewmodes/dolphinfontrequester.cpp
 365     settings/viewmodes/viewmodesettings.cpp
 366     settings/viewmodes/viewsettingstab.cpp
 367     views/zoomlevelinfo.cpp)
 368
 369 set(kcm_dolphinnavigation_PART_SRCS
 370     settings/kcm/kcmdolphinnavigation.cpp
 371     settings/navigation/navigationsettingspage.cpp
 372     settings/settingspagebase.cpp)
 373
 374 set(kcm_dolphingeneral_PART_SRCS
 375     settings/kcm/kcmdolphingeneral.cpp
 376     settings/general/behaviorsettingspage.cpp
 377     settings/general/previewssettingspage.cpp
 378     settings/general/configurepreviewplugindialog.cpp
 379     settings/general/confirmationssettingspage.cpp
 380     settings/settingspagebase.cpp
 381     settings/serviceitemdelegate.cpp
 382     settings/servicemodel.cpp)
 383
 384 kconfig_add_kcfg_files(kcm_dolphinviewmodes_PART_SRCS
 385     settings/dolphin_compactmodesettings.kcfgc
 386     settings/dolphin_directoryviewpropertysettings.kcfgc
 387     settings/dolphin_detailsmodesettings.kcfgc
 388     settings/dolphin_iconsmodesettings.kcfgc
 389     settings/dolphin_generalsettings.kcfgc
 390     settings/dolphin_versioncontrolsettings.kcfgc
 391 )
 392
 393 kconfig_add_kcfg_files(kcm_dolphinnavigation_PART_SRCS
 394     settings/dolphin_generalsettings.kcfgc)
 395
 396 kconfig_add_kcfg_files(kcm_dolphingeneral_PART_SRCS
 397     settings/dolphin_generalsettings.kcfgc)
 398
 399
 400 if(NOT WIN32)
 401     # The settings are still accessible from the hamburger menu
 402     add_library(kcm_dolphinviewmodes MODULE ${kcm_dolphinviewmodes_PART_SRCS})
 403     add_library(kcm_dolphinnavigation MODULE ${kcm_dolphinnavigation_PART_SRCS})
 404     add_library(kcm_dolphingeneral MODULE ${kcm_dolphingeneral_PART_SRCS})
 405
 406     target_link_libraries(kcm_dolphinviewmodes dolphinprivate)
 407     target_link_libraries(kcm_dolphinnavigation dolphinprivate)
 408     target_link_libraries(kcm_dolphingeneral dolphinprivate)
 409
 410     install( FILES org.kde.dolphin.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR} )
 411     install( FILES settings/kcm/kcmdolphinviewmodes.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 412     install( FILES settings/kcm/kcmdolphinnavigation.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 413     install( FILES settings/kcm/kcmdolphingeneral.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 414
 415     install(TARGETS kcm_dolphinviewmodes DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 416     install(TARGETS kcm_dolphinnavigation DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 417     install(TARGETS kcm_dolphingeneral DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 418 endif()
 419
 420 if(NOT WIN32)
 421     add_subdirectory(settings/contextmenu/servicemenuinstaller)
 422     install( FILES settings/contextmenu/servicemenu.knsrc DESTINATION ${KDE_INSTALL_KNSRCDIR} )
 423 endif()
 424
 425 ########### install files ###############
 426
 427 install( PROGRAMS org.kde.dolphin.desktop DESTINATION ${KDE_INSTALL_APPDIR} )
 428
 429 install( DIRECTORY DESTINATION "${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel" )
 430
 431 install(
 432     CODE "execute_process(COMMAND \"${CMAKE_COMMAND}\" -E create_symlink \"${KDE_INSTALL_FULL_APPDIR}/org.kde.dolphin.desktop\" \"\$ENV{DESTDIR}${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel/org.kde.dolphin.desktop\")"
 433 )
 434
 435 install( FILES settings/dolphin_directoryviewpropertysettings.kcfg
 436                settings/dolphin_generalsettings.kcfg
 437                settings/dolphin_contextmenusettings.kcfg
 438                settings/dolphin_compactmodesettings.kcfg
 439                settings/dolphin_iconsmodesettings.kcfg
 440                settings/dolphin_detailsmodesettings.kcfg
 441                settings/dolphin_versioncontrolsettings.kcfg
 442          DESTINATION ${KDE_INSTALL_KCFGDIR} )
 443
 444 if(BUILD_TESTING)
 445     find_package(Qt5Test ${QT_MIN_VERSION} CONFIG REQUIRED)
 446     add_subdirectory(tests)
 447 endif()