src/CMakeLists.txt

   1 include(ECMAddAppIcon)
   2
   3 configure_file(config-baloo.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-baloo.h)
   4
   5 configure_file(config-kactivities.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-kactivities.h)
   6
   7 configure_file(config-terminal.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-terminal.h)
   8
   9 add_definitions(
  10     -DTRANSLATION_DOMAIN=\"dolphin\"
  11 )
  12 remove_definitions(
  13     -DQT_NO_CAST_FROM_BYTEARRAY
  14     -DQT_NO_SIGNALS_SLOTS_KEYWORDS
  15     -DQT_NO_CAST_FROM_ASCII
  16     -DQT_NO_CAST_TO_ASCII
  17 )
  18
  19 ##########################################
  20
  21 set(dolphinvcs_LIB_SRCS
  22     views/versioncontrol/kversioncontrolplugin.cpp
  23 )
  24
  25 add_library(dolphinvcs ${dolphinvcs_LIB_SRCS})
  26 generate_export_header(dolphinvcs BASE_NAME dolphinvcs)
  27
  28 target_link_libraries(
  29     dolphinvcs PUBLIC
  30     Qt5::Widgets
  31 )
  32
  33 set_target_properties(dolphinvcs PROPERTIES
  34     VERSION ${DOLPHINVCS_VERSION_STRING}
  35     SOVERSION ${DOLPHINVCS_SOVERSION}
  36     EXPORT_NAME DolphinVcs
  37 )
  38
  39 ecm_generate_headers(dolphinvcs_LIB_HEADERS
  40     HEADER_NAMES
  41     KVersionControlPlugin
  42
  43     RELATIVE "views/versioncontrol"
  44     REQUIRED_HEADERS dolphinvcs_LIB_HEADERS
  45 )
  46
  47 install(TARGETS dolphinvcs EXPORT DolphinVcsTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
  48
  49 install(FILES views/versioncontrol/fileviewversioncontrolplugin.desktop DESTINATION ${KDE_INSTALL_KSERVICETYPES5DIR})
  50 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphinvcs_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
  51 install(FILES ${dolphinvcs_LIB_HEADERS} DESTINATION "${KDE_INSTALL_INCLUDEDIR}/Dolphin" COMPONENT Devel)
  52
  53 ########### next target ###############
  54
  55 set(dolphinprivate_LIB_SRCS
  56     kitemviews/kfileitemlistview.cpp
  57     kitemviews/kfileitemlistwidget.cpp
  58     kitemviews/kfileitemmodel.cpp
  59     kitemviews/kfileitemmodelrolesupdater.cpp
  60     kitemviews/kitemlistcontainer.cpp
  61     kitemviews/kitemlistcontroller.cpp
  62     kitemviews/kitemlistgroupheader.cpp
  63     kitemviews/kitemlistheader.cpp
  64     kitemviews/kitemlistselectionmanager.cpp
  65     kitemviews/kitemliststyleoption.cpp
  66     kitemviews/kitemlistview.cpp
  67     kitemviews/kitemlistviewaccessible.cpp
  68     kitemviews/kitemlistwidget.cpp
  69     kitemviews/kitemmodelbase.cpp
  70     kitemviews/kitemset.cpp
  71     kitemviews/kstandarditem.cpp
  72     kitemviews/kstandarditemlistgroupheader.cpp
  73     kitemviews/kstandarditemlistwidget.cpp
  74     kitemviews/kstandarditemlistview.cpp
  75     kitemviews/kstandarditemmodel.cpp
  76     kitemviews/private/kdirectorycontentscounter.cpp
  77     kitemviews/private/kdirectorycontentscounterworker.cpp
  78     kitemviews/private/kfileitemclipboard.cpp
  79     kitemviews/private/kfileitemmodeldirlister.cpp
  80     kitemviews/private/kfileitemmodelfilter.cpp
  81     kitemviews/private/kitemlistheaderwidget.cpp
  82     kitemviews/private/kitemlistkeyboardsearchmanager.cpp
  83     kitemviews/private/kitemlistroleeditor.cpp
  84     kitemviews/private/kitemlistrubberband.cpp
  85     kitemviews/private/kitemlistselectiontoggle.cpp
  86     kitemviews/private/kitemlistsizehintresolver.cpp
  87     kitemviews/private/kitemlistsmoothscroller.cpp
  88     kitemviews/private/kitemlistviewanimation.cpp
  89     kitemviews/private/kitemlistviewlayouter.cpp
  90     kitemviews/private/kpixmapmodifier.cpp
  91     settings/applyviewpropsjob.cpp
  92     settings/viewmodes/viewmodesettings.cpp
  93     settings/viewpropertiesdialog.cpp
  94     settings/viewpropsprogressinfo.cpp
  95     views/dolphinfileitemlistwidget.cpp
  96     views/dolphinitemlistview.cpp
  97     views/dolphinnewfilemenuobserver.cpp
  98     views/dolphinremoteencoding.cpp
  99     views/dolphinview.cpp
 100     views/dolphinviewactionhandler.cpp
 101     views/draganddrophelper.cpp
 102     views/versioncontrol/updateitemstatesthread.cpp
 103     views/versioncontrol/versioncontrolobserver.cpp
 104     views/viewmodecontroller.cpp
 105     views/viewproperties.cpp
 106     views/zoomlevelinfo.cpp
 107     dolphinremoveaction.cpp
 108     middleclickactioneventfilter.cpp
 109     dolphinnewfilemenu.cpp
 110 )
 111
 112 ecm_qt_declare_logging_category(dolphinprivate_LIB_SRCS HEADER dolphindebug.h IDENTIFIER DolphinDebug CATEGORY_NAME org.kde.dolphin)
 113
 114 if(HAVE_BALOO)
 115     set(dolphinprivate_LIB_SRCS
 116         ${dolphinprivate_LIB_SRCS}
 117         views/tooltips/dolphinfilemetadatawidget.cpp
 118         views/tooltips/tooltipmanager.cpp
 119         kitemviews/private/kbaloorolesprovider.cpp
 120     )
 121 endif()
 122
 123 kconfig_add_kcfg_files(dolphinprivate_LIB_SRCS GENERATE_MOC
 124     settings/dolphin_compactmodesettings.kcfgc
 125     settings/dolphin_directoryviewpropertysettings.kcfgc
 126     settings/dolphin_detailsmodesettings.kcfgc
 127     settings/dolphin_iconsmodesettings.kcfgc
 128     settings/dolphin_generalsettings.kcfgc
 129     settings/dolphin_versioncontrolsettings.kcfgc
 130 )
 131
 132 add_library(dolphinprivate ${dolphinprivate_LIB_SRCS})
 133 generate_export_header(dolphinprivate BASE_NAME dolphin)
 134
 135 target_link_libraries(
 136     dolphinprivate PUBLIC
 137     dolphinvcs
 138     Qt5::Concurrent
 139     Qt5::Gui
 140     KF5::I18n
 141     KF5::IconThemes
 142     KF5::KIOCore
 143     KF5::KIOWidgets
 144     KF5::KIOFileWidgets
 145     KF5::Completion
 146     KF5::TextWidgets
 147     KF5::ConfigCore
 148     KF5::NewStuff
 149     KF5::Parts
 150     KF5::WindowSystem
 151 )
 152
 153 if(HAVE_BALOO)
 154     target_link_libraries(
 155         dolphinprivate PUBLIC
 156         KF5::FileMetaData
 157         KF5::Baloo
 158         KF5::BalooWidgets
 159     )
 160 endif()
 161
 162 set_target_properties(dolphinprivate PROPERTIES
 163     VERSION ${DOLPHINPRIVATE_VERSION_STRING}
 164     SOVERSION ${DOLPHINPRIVATE_SOVERSION}
 165 )
 166
 167 install(TARGETS dolphinprivate ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} LIBRARY NAMELINK_SKIP)
 168 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphin_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
 169
 170 ##########################################
 171
 172 set(dolphinpart_SRCS
 173    dolphinpart.cpp
 174    dolphinpart_ext.cpp
 175    dolphindebug.cpp
 176 )
 177
 178 qt5_add_resources(dolphinpart_SRCS dolphinpart.qrc)
 179
 180 add_library(dolphinpart MODULE ${dolphinpart_SRCS})
 181
 182 target_link_libraries(dolphinpart
 183     dolphinprivate
 184 )
 185
 186 install(TARGETS dolphinpart DESTINATION ${KDE_INSTALL_PLUGINDIR})
 187
 188 install(FILES dolphinpart.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR})
 189
 190 ##########################################
 191
 192 set(dolphinstatic_SRCS
 193     dolphinbookmarkhandler.cpp
 194     dolphindockwidget.cpp
 195     dolphinmainwindow.cpp
 196     dolphinviewcontainer.cpp
 197     dolphincontextmenu.cpp
 198     dolphintabbar.cpp
 199     dolphinplacesmodelsingleton.cpp
 200     dolphinrecenttabsmenu.cpp
 201     dolphintabpage.cpp
 202     dolphintabwidget.cpp
 203     trash/dolphintrash.cpp
 204     filterbar/filterbar.cpp
 205     panels/places/placespanel.cpp
 206     panels/places/placesitem.cpp
 207     panels/places/placesitemlistgroupheader.cpp
 208     panels/places/placesitemlistwidget.cpp
 209     panels/places/placesitemmodel.cpp
 210     panels/places/placesitemsignalhandler.cpp
 211     panels/places/placesview.cpp
 212     panels/panel.cpp
 213     panels/folders/foldersitemlistwidget.cpp
 214     panels/folders/treeviewcontextmenu.cpp
 215     panels/folders/folderspanel.cpp
 216     panels/terminal/terminalpanel.cpp
 217     search/dolphinfacetswidget.cpp
 218     search/dolphinquery.cpp
 219     search/dolphinsearchbox.cpp
 220     settings/general/behaviorsettingspage.cpp
 221     settings/general/configurepreviewplugindialog.cpp
 222     settings/general/confirmationssettingspage.cpp
 223     settings/general/generalsettingspage.cpp
 224     settings/general/previewssettingspage.cpp
 225     settings/general/statusbarsettingspage.cpp
 226     settings/dolphinsettingsdialog.cpp
 227     settings/navigation/navigationsettingspage.cpp
 228     settings/services/servicessettingspage.cpp
 229     settings/settingspagebase.cpp
 230     settings/serviceitemdelegate.cpp
 231     settings/servicemodel.cpp
 232     settings/startup/startupsettingspage.cpp
 233     settings/trash/trashsettingspage.cpp
 234     settings/viewmodes/dolphinfontrequester.cpp
 235     settings/viewmodes/viewsettingspage.cpp
 236     settings/viewmodes/viewmodesettings.cpp
 237     settings/viewmodes/viewsettingstab.cpp
 238     statusbar/dolphinstatusbar.cpp
 239     statusbar/mountpointobserver.cpp
 240     statusbar/mountpointobservercache.cpp
 241     statusbar/spaceinfoobserver.cpp
 242     statusbar/statusbarspaceinfo.cpp
 243     views/zoomlevelinfo.cpp
 244     dolphindebug.cpp
 245     global.cpp
 246 )
 247
 248 if(HAVE_BALOO)
 249     set(dolphinstatic_SRCS
 250         ${dolphinstatic_SRCS}
 251         panels/information/informationpanel.cpp
 252         panels/information/informationpanelcontent.cpp
 253         panels/information/pixmapviewer.cpp
 254         panels/information/phononwidget.cpp
 255     )
 256 endif()
 257
 258 kconfig_add_kcfg_files(dolphinstatic_SRCS GENERATE_MOC
 259     panels/folders/dolphin_folderspanelsettings.kcfgc
 260     panels/information/dolphin_informationpanelsettings.kcfgc
 261     panels/places/dolphin_placespanelsettings.kcfgc
 262     settings/dolphin_compactmodesettings.kcfgc
 263     settings/dolphin_detailsmodesettings.kcfgc
 264     settings/dolphin_generalsettings.kcfgc
 265     settings/dolphin_iconsmodesettings.kcfgc
 266     search/dolphin_searchsettings.kcfgc
 267     settings/dolphin_versioncontrolsettings.kcfgc
 268 )
 269
 270 qt5_add_resources(dolphinstatic_SRCS dolphin.qrc)
 271
 272 qt5_generate_dbus_interface(${CMAKE_CURRENT_SOURCE_DIR}/dolphinmainwindow.h org.kde.DolphinMainWindow.xml)
 273 qt5_add_dbus_adaptor(dolphinstatic_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindow.h DolphinMainWindow)
 274 qt5_add_dbus_interface(dolphinstatic_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindowinterface)
 275 qt5_add_dbus_interface(dolphinstatic_SRCS panels/terminal/org.kde.KIOFuse.VFS.xml kiofuse_interface)
 276
 277 add_library(dolphinstatic STATIC ${dolphinstatic_SRCS})
 278
 279 target_include_directories(dolphinstatic SYSTEM PRIVATE ${PHONON_INCLUDES})
 280 target_link_libraries(dolphinstatic
 281     dolphinprivate
 282     KF5::CoreAddons
 283     KF5::KCMUtils
 284     KF5::DBusAddons
 285     KF5::Notifications
 286     Phonon::phonon4qt5
 287 )
 288
 289 if (HAVE_KACTIVITIES)
 290     target_link_libraries(
 291         dolphinstatic
 292         KF5::Activities
 293     )
 294 endif()
 295
 296 set(dolphin_SRCS
 297     dbusinterface.cpp
 298     main.cpp
 299 )
 300
 301 # Sets the icon on Windows and OSX
 302 file(GLOB ICONS_SRCS "${CMAKE_CURRENT_SOURCE_DIR}/icons/*system-file-manager.png")
 303 ecm_add_app_icon(dolphin_SRCS ICONS ${ICONS_SRCS})
 304
 305 kf5_add_kdeinit_executable(dolphin ${dolphin_SRCS})
 306
 307
 308 target_link_libraries(kdeinit_dolphin PUBLIC
 309     dolphinprivate
 310     PRIVATE
 311     dolphinstatic
 312     KF5::Crash
 313 )
 314
 315 include(DbusInterfaceMacros)
 316
 317 generate_and_install_dbus_interface(
 318     kdeinit_dolphin
 319     dbusinterface.h
 320     org.freedesktop.FileManager1.xml
 321     OPTIONS -a
 322 )
 323
 324 install(TARGETS kdeinit_dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 325 install(TARGETS dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 326
 327 ##########################################
 328
 329 set(kcm_dolphinviewmodes_PART_SRCS
 330     settings/kcm/kcmdolphinviewmodes.cpp
 331     settings/viewmodes/dolphinfontrequester.cpp
 332     settings/viewmodes/viewmodesettings.cpp
 333     settings/viewmodes/viewsettingstab.cpp
 334     views/zoomlevelinfo.cpp)
 335
 336 set(kcm_dolphinnavigation_PART_SRCS
 337     settings/kcm/kcmdolphinnavigation.cpp
 338     settings/navigation/navigationsettingspage.cpp
 339     settings/settingspagebase.cpp)
 340
 341 set(kcm_dolphinservices_PART_SRCS
 342     settings/kcm/kcmdolphinservices.cpp
 343     settings/services/servicessettingspage.cpp
 344     settings/settingspagebase.cpp
 345     settings/serviceitemdelegate.cpp
 346     settings/servicemodel.cpp)
 347
 348 set(kcm_dolphingeneral_PART_SRCS
 349     settings/kcm/kcmdolphingeneral.cpp
 350     settings/general/behaviorsettingspage.cpp
 351     settings/general/previewssettingspage.cpp
 352     settings/general/configurepreviewplugindialog.cpp
 353     settings/general/confirmationssettingspage.cpp
 354     settings/settingspagebase.cpp
 355     settings/serviceitemdelegate.cpp
 356     settings/servicemodel.cpp)
 357
 358 kconfig_add_kcfg_files(kcm_dolphinviewmodes_PART_SRCS
 359     settings/dolphin_compactmodesettings.kcfgc
 360     settings/dolphin_directoryviewpropertysettings.kcfgc
 361     settings/dolphin_detailsmodesettings.kcfgc
 362     settings/dolphin_iconsmodesettings.kcfgc
 363     settings/dolphin_generalsettings.kcfgc
 364     settings/dolphin_versioncontrolsettings.kcfgc
 365 )
 366
 367 kconfig_add_kcfg_files(kcm_dolphinnavigation_PART_SRCS
 368     settings/dolphin_generalsettings.kcfgc)
 369
 370 kconfig_add_kcfg_files(kcm_dolphinservices_PART_SRCS
 371     settings/dolphin_generalsettings.kcfgc
 372     settings/dolphin_versioncontrolsettings.kcfgc)
 373
 374 kconfig_add_kcfg_files(kcm_dolphingeneral_PART_SRCS
 375     settings/dolphin_generalsettings.kcfgc)
 376
 377 add_library(kcm_dolphinviewmodes MODULE ${kcm_dolphinviewmodes_PART_SRCS})
 378 add_library(kcm_dolphinnavigation MODULE ${kcm_dolphinnavigation_PART_SRCS})
 379 add_library(kcm_dolphinservices MODULE ${kcm_dolphinservices_PART_SRCS})
 380 add_library(kcm_dolphingeneral MODULE ${kcm_dolphingeneral_PART_SRCS})
 381
 382 target_link_libraries(kcm_dolphinviewmodes dolphinprivate)
 383 target_link_libraries(kcm_dolphinnavigation dolphinprivate)
 384 target_link_libraries(kcm_dolphinservices dolphinprivate)
 385 target_link_libraries(kcm_dolphingeneral dolphinprivate)
 386
 387 install(TARGETS kcm_dolphinviewmodes DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 388 install(TARGETS kcm_dolphinnavigation DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 389 install(TARGETS kcm_dolphinservices DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 390 install(TARGETS kcm_dolphingeneral DESTINATION ${KDE_INSTALL_PLUGINDIR} )
 391
 392 add_subdirectory(settings/services/servicemenuinstaller)
 393
 394 ########### install files ###############
 395
 396 install( PROGRAMS org.kde.dolphin.desktop DESTINATION ${KDE_INSTALL_APPDIR} )
 397
 398 install( DIRECTORY DESTINATION "${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel" )
 399
 400 install(
 401     CODE "execute_process(COMMAND \"${CMAKE_COMMAND}\" -E create_symlink \"${KDE_INSTALL_FULL_APPDIR}/org.kde.dolphin.desktop\" \"\$ENV{DESTDIR}${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel/org.kde.dolphin.desktop\")"
 402 )
 403
 404 install( FILES settings/dolphin_directoryviewpropertysettings.kcfg
 405                settings/dolphin_generalsettings.kcfg
 406                settings/dolphin_compactmodesettings.kcfg
 407                settings/dolphin_iconsmodesettings.kcfg
 408                settings/dolphin_detailsmodesettings.kcfg
 409                settings/dolphin_versioncontrolsettings.kcfg
 410          DESTINATION ${KDE_INSTALL_KCFGDIR} )
 411 install( FILES org.kde.dolphin.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR} )
 412 install( FILES settings/kcm/kcmdolphinviewmodes.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 413 install( FILES settings/kcm/kcmdolphinnavigation.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 414 install( FILES settings/kcm/kcmdolphinservices.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 415 install( FILES settings/kcm/kcmdolphingeneral.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} )
 416 install( FILES settings/services/servicemenu.knsrc DESTINATION ${KDE_INSTALL_CONFDIR} )
 417
 418 if(BUILD_TESTING)
 419     find_package(Qt5Test ${QT_MIN_VERSION} CONFIG REQUIRED)
 420     add_subdirectory(tests)
 421 endif()