src/CMakeLists.txt

   1 include(ECMAddAppIcon)
   2
   3 set(ADMIN_WORKER_PACKAGE_NAME "kio-admin")
   4 set(FILELIGHT_PACKAGE_NAME "filelight")
   5 set(KFIND_PACKAGE_NAME "kfind")
   6
   7 configure_file(config-dolphin.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-dolphin.h)
   8
   9 add_definitions(
  10     -DTRANSLATION_DOMAIN=\"dolphin\"
  11 )
  12 remove_definitions(
  13     -DQT_NO_CAST_FROM_BYTEARRAY
  14     -DQT_NO_CAST_FROM_ASCII
  15     -DQT_NO_CAST_TO_ASCII
  16 )
  17
  18 ##########################################
  19
  20 add_library(dolphinvcs SHARED)
  21
  22 target_sources(dolphinvcs PRIVATE
  23     views/versioncontrol/kversioncontrolplugin.cpp
  24 )
  25
  26 generate_export_header(dolphinvcs BASE_NAME dolphinvcs)
  27
  28 target_link_libraries(
  29     dolphinvcs PUBLIC
  30     Qt6::Widgets
  31 )
  32
  33 set_target_properties(dolphinvcs PROPERTIES
  34     VERSION ${DOLPHINVCS_VERSION}
  35     SOVERSION ${DOLPHINVCS_SOVERSION}
  36     EXPORT_NAME DolphinVcs
  37 )
  38
  39 ecm_generate_headers(dolphinvcs_LIB_HEADERS
  40     HEADER_NAMES
  41     KVersionControlPlugin
  42
  43     RELATIVE "views/versioncontrol"
  44     REQUIRED_HEADERS dolphinvcs_LIB_HEADERS
  45 )
  46 target_include_directories(dolphinvcs INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR}>")
  47
  48 install(TARGETS dolphinvcs EXPORT DolphinVcsTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
  49
  50 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphinvcs_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
  51 install(FILES ${dolphinvcs_LIB_HEADERS} DESTINATION "${KDE_INSTALL_INCLUDEDIR}/Dolphin" COMPONENT Devel)
  52
  53 ########### next target ###############
  54
  55 add_library(dolphinprivate SHARED)
  56
  57 if(NOT QT_NO_ACCESSIBILITY)
  58     target_sources(dolphinprivate PRIVATE
  59         kitemviews/accessibility/kitemlistcontaineraccessible.cpp
  60         kitemviews/accessibility/kitemlistdelegateaccessible.cpp
  61         kitemviews/accessibility/kitemlistviewaccessible.cpp
  62
  63         kitemviews/accessibility/kitemlistcontaineraccessible.h
  64         kitemviews/accessibility/kitemlistdelegateaccessible.h
  65         kitemviews/accessibility/kitemlistviewaccessible.h
  66     )
  67 endif()
  68
  69 target_sources(dolphinprivate PRIVATE
  70     kitemviews/kfileitemlistview.cpp
  71     kitemviews/kfileitemlistwidget.cpp
  72     kitemviews/kfileitemlisttostring.cpp
  73     kitemviews/kfileitemmodel.cpp
  74     kitemviews/kfileitemmodelrolesupdater.cpp
  75     kitemviews/kitemlistcontainer.cpp
  76     kitemviews/kitemlistcontroller.cpp
  77     kitemviews/kitemlistgroupheader.cpp
  78     kitemviews/kitemlistheader.cpp
  79     kitemviews/kitemlistselectionmanager.cpp
  80     kitemviews/kitemliststyleoption.cpp
  81     kitemviews/kitemlistview.cpp
  82     kitemviews/kitemlistwidget.cpp
  83     kitemviews/kitemmodelbase.cpp
  84     kitemviews/kitemset.cpp
  85     kitemviews/kstandarditemlistgroupheader.cpp
  86     kitemviews/kstandarditemlistwidget.cpp
  87     kitemviews/kstandarditemlistview.cpp
  88     kitemviews/private/kdirectorycontentscounter.cpp
  89     kitemviews/private/kdirectorycontentscounterworker.cpp
  90     kitemviews/private/kfileitemclipboard.cpp
  91     kitemviews/private/kfileitemmodelfilter.cpp
  92     kitemviews/private/kitemlistheaderwidget.cpp
  93     kitemviews/private/kitemlistkeyboardsearchmanager.cpp
  94     kitemviews/private/kitemlistroleeditor.cpp
  95     kitemviews/private/kitemlistrubberband.cpp
  96     kitemviews/private/kitemlistselectiontoggle.cpp
  97     kitemviews/private/kitemlistsizehintresolver.cpp
  98     kitemviews/private/kitemlistsmoothscroller.cpp
  99     kitemviews/private/kitemlistviewanimation.cpp
 100     kitemviews/private/kitemlistviewlayouter.cpp
 101     kitemviews/private/kitemviewsutils.cpp
 102     kitemviews/private/kpixmapmodifier.cpp
 103     settings/applyviewpropsjob.cpp
 104     settings/viewmodes/viewmodesettings.cpp
 105     settings/viewpropertiesdialog.cpp
 106     settings/viewpropsprogressinfo.cpp
 107     selectionmode/actiontexthelper.cpp
 108     views/dolphinfileitemlistwidget.cpp
 109     views/dolphinitemlistview.cpp
 110     views/dolphinnewfilemenuobserver.cpp
 111     views/dolphinremoteencoding.cpp
 112     views/dolphinview.cpp
 113     views/dolphinviewactionhandler.cpp
 114     views/draganddrophelper.cpp
 115     views/versioncontrol/updateitemstatesthread.cpp
 116     views/versioncontrol/versioncontrolobserver.cpp
 117     views/viewmodecontroller.cpp
 118     views/viewproperties.cpp
 119     views/zoomlevelinfo.cpp
 120     dolphinremoveaction.cpp
 121     middleclickactioneventfilter.cpp
 122     dolphinnewfilemenu.cpp
 123
 124     kitemviews/kfileitemlistview.h
 125     kitemviews/kfileitemlistwidget.h
 126     kitemviews/kfileitemlisttostring.h
 127     kitemviews/kfileitemmodel.h
 128     kitemviews/kfileitemmodelrolesupdater.h
 129     kitemviews/kitemlistcontainer.h
 130     kitemviews/kitemlistcontroller.h
 131     kitemviews/kitemlistgroupheader.h
 132     kitemviews/kitemlistheader.h
 133     kitemviews/kitemlistselectionmanager.h
 134     kitemviews/kitemliststyleoption.h
 135     kitemviews/kitemlistview.h
 136     kitemviews/kitemlistwidget.h
 137     kitemviews/kitemmodelbase.h
 138     kitemviews/kitemset.h
 139     kitemviews/kstandarditemlistgroupheader.h
 140     kitemviews/kstandarditemlistwidget.h
 141     kitemviews/kstandarditemlistview.h
 142     kitemviews/private/kdirectorycontentscounter.h
 143     kitemviews/private/kdirectorycontentscounterworker.h
 144     kitemviews/private/kfileitemclipboard.h
 145     kitemviews/private/kfileitemmodelfilter.h
 146     kitemviews/private/kitemlistheaderwidget.h
 147     kitemviews/private/kitemlistkeyboardsearchmanager.h
 148     kitemviews/private/kitemlistroleeditor.h
 149     kitemviews/private/kitemlistrubberband.h
 150     kitemviews/private/kitemlistselectiontoggle.h
 151     kitemviews/private/kitemlistsizehintresolver.h
 152     kitemviews/private/kitemlistsmoothscroller.h
 153     kitemviews/private/kitemlistviewanimation.h
 154     kitemviews/private/kitemlistviewlayouter.h
 155     kitemviews/private/kpixmapmodifier.h
 156     settings/applyviewpropsjob.h
 157     settings/viewmodes/viewmodesettings.h
 158     settings/viewpropertiesdialog.h
 159     settings/viewpropsprogressinfo.h
 160     selectionmode/actiontexthelper.h
 161     views/dolphinfileitemlistwidget.h
 162     views/dolphinitemlistview.h
 163     views/dolphinnewfilemenuobserver.h
 164     views/dolphinremoteencoding.h
 165     views/dolphinview.h
 166     views/dolphinviewactionhandler.h
 167     views/draganddrophelper.h
 168     views/versioncontrol/updateitemstatesthread.h
 169     views/versioncontrol/versioncontrolobserver.h
 170     views/viewmodecontroller.h
 171     views/viewproperties.h
 172     views/zoomlevelinfo.h
 173     dolphinremoveaction.h
 174     middleclickactioneventfilter.h
 175     dolphinnewfilemenu.h
 176 )
 177
 178 ecm_qt_declare_logging_category(dolphinprivate
 179     HEADER dolphindebug.h
 180     IDENTIFIER DolphinDebug
 181     CATEGORY_NAME org.kde.dolphin
 182     DESCRIPTION "dolphin"
 183     EXPORT DOLPHIN
 184 )
 185
 186 if(HAVE_BALOO)
 187     target_sources(dolphinprivate PRIVATE
 188         views/tooltips/dolphinfilemetadatawidget.cpp
 189         views/tooltips/tooltipmanager.cpp
 190         kitemviews/private/kbaloorolesprovider.cpp
 191         views/tooltips/dolphinfilemetadatawidget.h
 192         views/tooltips/tooltipmanager.h
 193         kitemviews/private/kbaloorolesprovider.h
 194     )
 195 endif()
 196
 197 kconfig_add_kcfg_files(dolphinprivate
 198     settings/dolphin_compactmodesettings.kcfgc
 199     settings/dolphin_directoryviewpropertysettings.kcfgc
 200     settings/dolphin_detailsmodesettings.kcfgc
 201     settings/dolphin_iconsmodesettings.kcfgc
 202     settings/dolphin_contentdisplaysettings.kcfgc
 203     settings/dolphin_generalsettings.kcfgc
 204     settings/dolphin_contextmenusettings.kcfgc
 205     settings/dolphin_versioncontrolsettings.kcfgc
 206     GENERATE_MOC
 207 )
 208
 209 generate_export_header(dolphinprivate BASE_NAME dolphin)
 210
 211 target_link_libraries(
 212     dolphinprivate PUBLIC
 213     dolphinvcs
 214     Qt6::Concurrent
 215     Qt6::DBus
 216     Qt6::Gui
 217     KF6::I18n
 218     KF6::GuiAddons
 219     KF6::IconThemes
 220     KF6::KIOCore
 221     KF6::KIOWidgets
 222     KF6::KIOFileWidgets
 223     KF6::Completion
 224     KF6::TextWidgets
 225     KF6::ConfigCore
 226     KF6::NewStuffWidgets    # KNSWidgets::Button
 227     KF6::Parts
 228     KF6::WindowSystem
 229     KF6::WidgetsAddons
 230     KF6::Codecs
 231     KF6::KCMUtils
 232     KF6::FileMetaData
 233
 234     ${FTS_LIB}
 235 )
 236
 237 if(HAVE_BALOO)
 238     target_link_libraries(
 239         dolphinprivate PUBLIC
 240         KF6::Baloo
 241         KF6::BalooWidgets
 242     )
 243 endif()
 244
 245 set_target_properties(dolphinprivate PROPERTIES
 246     VERSION ${DOLPHINPRIVATE_VERSION}
 247     SOVERSION ${DOLPHINPRIVATE_SOVERSION}
 248 )
 249
 250 install(TARGETS dolphinprivate ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} LIBRARY NAMELINK_SKIP)
 251 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphin_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
 252
 253 ##########################################
 254 configure_file(dolphinpart.json.in ${CMAKE_CURRENT_BINARY_DIR}/dolphinpart.json @ONLY)
 255
 256 add_library(dolphinpart MODULE)
 257
 258 target_sources(dolphinpart PRIVATE
 259     dolphinpart.cpp
 260     dolphinpart_ext.cpp
 261     dolphindebug.cpp
 262     dolphinpart.h
 263     dolphinpart_ext.h
 264     dolphindebug.h
 265
 266     dolphinpart.qrc
 267 )
 268
 269 target_link_libraries(dolphinpart
 270     dolphinprivate
 271 )
 272
 273 install(TARGETS dolphinpart DESTINATION ${KDE_INSTALL_PLUGINDIR}/kf6/parts)
 274 install(FILES dolphinpartactions.desktop DESTINATION "${KDE_INSTALL_DATADIR}/dolphin/")
 275
 276 ##########################################
 277
 278 add_library(dolphinstatic STATIC)
 279
 280 target_sources(dolphinstatic PRIVATE
 281     admin/bar.cpp
 282     admin/workerintegration.cpp
 283     animatedheightwidget.cpp
 284     disabledactionnotifier.cpp
 285     dolphinbookmarkhandler.cpp
 286     dolphindockwidget.cpp
 287     dolphinmainwindow.cpp
 288     dolphinviewcontainer.cpp
 289     dolphincontextmenu.cpp
 290     dolphinnavigatorswidgetaction.cpp
 291     dolphintabbar.cpp
 292     dolphinpackageinstaller.cpp
 293     dolphinplacesmodelsingleton.cpp
 294     dolphinrecenttabsmenu.cpp
 295     dolphintabpage.cpp
 296     dolphintabwidget.cpp
 297     dolphinurlnavigator.cpp
 298     dolphinurlnavigatorscontroller.cpp
 299     trash/dolphintrash.cpp
 300     filterbar/filterbar.cpp
 301     kitemviews/kfileitemlisttostring.cpp
 302     panels/places/placespanel.cpp
 303     panels/panel.cpp
 304     panels/folders/foldersitemlistwidget.cpp
 305     panels/folders/treeviewcontextmenu.cpp
 306     panels/folders/folderspanel.cpp
 307     panels/terminal/terminalpanel.cpp
 308     search/bar.cpp
 309     search/barsecondrowflowlayout.cpp
 310     search/chip.cpp
 311     search/dolphinquery.cpp
 312     search/popup.cpp
 313     search/selectors/dateselector.cpp
 314     search/selectors/filetypeselector.cpp
 315     search/selectors/minimumratingselector.cpp
 316     search/selectors/tagsselector.cpp
 317     search/widgetmenu.cpp
 318     selectionmode/actiontexthelper.cpp
 319     selectionmode/actionwithwidget.cpp
 320     selectionmode/backgroundcolorhelper.cpp
 321     selectionmode/bottombar.cpp
 322     selectionmode/bottombarcontentscontainer.cpp
 323     selectionmode/topbar.cpp
 324     settings/interface/folderstabssettingspage.cpp
 325     settings/interface/statusandlocationbarssettingspage.cpp
 326     settings/interface/confirmationssettingspage.cpp
 327     settings/interface/interfacesettingspage.cpp
 328     settings/interface/previewssettingspage.cpp
 329     settings/dolphinsettingsdialog.cpp
 330     settings/contextmenu/contextmenusettingspage.cpp
 331     settings/settingspagebase.cpp
 332     settings/servicemodel.cpp
 333     settings/trash/trashsettingspage.cpp
 334     settings/viewmodes/dolphinfontrequester.cpp
 335     settings/viewmodes/viewsettingspage.cpp
 336     settings/viewmodes/viewmodesettings.cpp
 337     settings/viewmodes/viewsettingstab.cpp
 338     settings/viewmodes/contentdisplaytab.cpp
 339     settings/viewmodes/generalviewsettingspage.cpp
 340     statusbar/dolphinstatusbar.cpp
 341     statusbar/mountpointobserver.cpp
 342     statusbar/mountpointobservercache.cpp
 343     statusbar/spaceinfoobserver.cpp
 344     statusbar/statusbarspaceinfo.cpp
 345     views/zoomlevelinfo.cpp
 346     dolphindebug.cpp
 347     global.cpp
 348     dolphin.qrc
 349
 350     admin/bar.h
 351     admin/workerintegration.h
 352     animatedheightwidget.h
 353     dolphinbookmarkhandler.h
 354     dolphindockwidget.h
 355     dolphinmainwindow.h
 356     dolphinviewcontainer.h
 357     dolphincontextmenu.h
 358     dolphinnavigatorswidgetaction.h
 359     dolphintabbar.h
 360     dolphinpackageinstaller.h
 361     dolphinplacesmodelsingleton.h
 362     dolphinrecenttabsmenu.h
 363     dolphintabpage.h
 364     dolphintabwidget.h
 365     dolphinurlnavigator.h
 366     dolphinurlnavigatorscontroller.h
 367     trash/dolphintrash.h
 368     filterbar/filterbar.h
 369     kitemviews/kfileitemlisttostring.h
 370     panels/places/placespanel.h
 371     panels/panel.h
 372     panels/folders/foldersitemlistwidget.h
 373     panels/folders/treeviewcontextmenu.h
 374     panels/folders/folderspanel.h
 375     panels/terminal/terminalpanel.h
 376     search/bar.h
 377     search/barsecondrowflowlayout.h
 378     search/chip.h
 379     search/dolphinquery.h
 380     search/popup.h
 381     search/selectors/dateselector.h
 382     search/selectors/filetypeselector.h
 383     search/selectors/minimumratingselector.h
 384     search/selectors/tagsselector.h
 385     search/widgetmenu.h
 386     selectionmode/actiontexthelper.h
 387     selectionmode/actionwithwidget.h
 388     selectionmode/backgroundcolorhelper.h
 389     selectionmode/bottombar.h
 390     selectionmode/bottombarcontentscontainer.h
 391     selectionmode/topbar.h
 392     settings/interface/folderstabssettingspage.h
 393     settings/interface/statusandlocationbarssettingspage.h
 394     settings/interface/confirmationssettingspage.h
 395     settings/interface/interfacesettingspage.h
 396     settings/interface/previewssettingspage.h
 397     settings/dolphinsettingsdialog.h
 398     settings/contextmenu/contextmenusettingspage.h
 399     settings/settingspagebase.h
 400     settings/servicemodel.h
 401     settings/trash/trashsettingspage.h
 402     settings/viewmodes/dolphinfontrequester.h
 403     settings/viewmodes/viewsettingspage.h
 404     settings/viewmodes/viewmodesettings.h
 405     settings/viewmodes/viewsettingstab.h
 406     settings/viewmodes/contentdisplaytab.h
 407     settings/viewmodes/generalviewsettingspage.h
 408     statusbar/dolphinstatusbar.h
 409     statusbar/mountpointobserver.h
 410     statusbar/mountpointobservercache.h
 411     statusbar/spaceinfoobserver.h
 412     statusbar/statusbarspaceinfo.h
 413     views/zoomlevelinfo.h
 414     dolphindebug.h
 415     global.h
 416 )
 417
 418 if(HAVE_BALOO)
 419     target_sources(dolphinstatic PRIVATE
 420         panels/information/informationpanel.cpp
 421         panels/information/informationpanelcontent.cpp
 422         panels/information/pixmapviewer.cpp
 423         panels/information/phononwidget.cpp
 424         settings/interface/panelsettingspage.cpp
 425         panels/information/informationpanel.h
 426         panels/information/informationpanelcontent.h
 427         panels/information/pixmapviewer.h
 428         panels/information/phononwidget.h
 429         settings/interface/panelsettingspage.h
 430     )
 431
 432     kconfig_add_kcfg_files(dolphinstatic
 433         panels/information/dolphin_informationpanelsettings.kcfgc
 434     )
 435
 436 endif()
 437
 438 if(HAVE_KUSERFEEDBACK)
 439     target_sources(dolphinstatic PRIVATE
 440         userfeedback/dolphinfeedbackprovider.cpp
 441         userfeedback/settingsdatasource.cpp
 442         userfeedback/placesdatasource.cpp
 443         settings/userfeedback/userfeedbacksettingspage.cpp
 444         userfeedback/dolphinfeedbackprovider.h
 445         userfeedback/settingsdatasource.h
 446         userfeedback/placesdatasource.h
 447         settings/userfeedback/userfeedbacksettingspage.h
 448     )
 449 endif()
 450
 451 kconfig_add_kcfg_files(dolphinstatic
 452     panels/folders/dolphin_folderspanelsettings.kcfgc
 453     panels/places/dolphin_placespanelsettings.kcfgc
 454     settings/dolphin_compactmodesettings.kcfgc
 455     settings/dolphin_detailsmodesettings.kcfgc
 456     settings/dolphin_contextmenusettings.kcfgc
 457     settings/dolphin_iconsmodesettings.kcfgc
 458     settings/dolphin_contentdisplaysettings.kcfgc
 459     search/dolphin_searchsettings.kcfgc
 460     settings/dolphin_versioncontrolsettings.kcfgc
 461 )
 462 kconfig_add_kcfg_files(dolphinstatic GENERATE_MOC
 463     settings/dolphin_generalsettings.kcfgc
 464 )
 465
 466 qt_generate_dbus_interface(${CMAKE_CURRENT_SOURCE_DIR}/dolphinmainwindow.h org.kde.DolphinMainWindow.xml)
 467 qt_add_dbus_adaptor(dolphin_dbus_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindow.h DolphinMainWindow)
 468 qt_add_dbus_interface(dolphin_dbus_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindowinterface)
 469 qt_add_dbus_interface(dolphin_dbus_SRCS panels/terminal/org.kde.KIOFuse.VFS.xml kiofuse_interface)
 470
 471 target_sources(dolphinstatic PRIVATE
 472     ${dolphin_dbus_SRCS}
 473 )
 474
 475 target_include_directories(dolphinstatic SYSTEM PRIVATE ${PHONON_INCLUDES})
 476 target_link_libraries(dolphinstatic
 477     dolphinprivate
 478     KF6::CoreAddons
 479     KF6::GuiAddons
 480     KF6::KCMUtils
 481     KF6::DBusAddons
 482     KF6::Notifications
 483     KF6::BookmarksWidgets
 484     Phonon::phonon4qt6
 485 )
 486
 487 if(HAVE_PACKAGEKIT)
 488     target_link_libraries(
 489         dolphinstatic
 490         PK::packagekitqt6
 491     )
 492 endif()
 493
 494 if (HAVE_KUSERFEEDBACK)
 495     target_link_libraries(
 496         dolphinstatic
 497         KF6::UserFeedbackCore
 498         KF6::UserFeedbackWidgets
 499     )
 500 endif()
 501
 502 add_executable(dolphin)
 503
 504 target_sources(dolphin PRIVATE
 505     dbusinterface.cpp
 506     dbusinterface.h
 507     main.cpp
 508 )
 509
 510 if(FLATPAK)
 511     target_compile_definitions(dolphin PRIVATE FLATPAK)
 512 endif()
 513
 514 # Install the icons on macOS and Windows
 515 ecm_add_app_icon(dolphin
 516     ICONS
 517         icons/128-apps-org.kde.dolphin.png
 518         icons/16-apps-org.kde.dolphin.png
 519         icons/22-apps-org.kde.dolphin.png
 520         icons/32-apps-org.kde.dolphin.png
 521         icons/48-apps-org.kde.dolphin.png
 522         icons/64-apps-org.kde.dolphin.png
 523 )
 524
 525 install(FILES icons/org.kde.dolphin.svg DESTINATION ${KDE_INSTALL_ICONDIR}/hicolor/scalable/apps)
 526
 527 target_link_libraries(dolphin
 528     PRIVATE
 529     dolphinprivate
 530     dolphinstatic
 531     KF6::Crash
 532 )
 533
 534 if (HAVE_X11)
 535     target_link_libraries(dolphin PRIVATE Qt::GuiPrivate)
 536 endif()
 537
 538 include(DbusInterfaceMacros)
 539
 540 generate_and_install_dbus_interface(
 541     dolphin
 542     dbusinterface.h
 543     org.freedesktop.FileManager1.xml
 544     OPTIONS -a
 545 )
 546
 547 install(TARGETS dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
 548
 549 ##########################################
 550
 551 if(NOT WIN32)
 552     # The settings are still accessible from the hamburger menu
 553     add_library(kcm_dolphinviewmodes MODULE)
 554     add_library(kcm_dolphingeneral MODULE)
 555     target_compile_definitions(kcm_dolphingeneral PUBLIC IS_KCM)
 556
 557     target_sources(kcm_dolphinviewmodes PRIVATE
 558         settings/kcm/kcmdolphinviewmodes.cpp
 559         settings/viewmodes/dolphinfontrequester.cpp
 560         settings/viewmodes/viewmodesettings.cpp
 561         settings/viewmodes/viewsettingstab.cpp
 562         settings/settingspagebase.cpp
 563         views/zoomlevelinfo.cpp
 564         settings/kcm/kcmdolphinviewmodes.h
 565         settings/viewmodes/dolphinfontrequester.h
 566         settings/viewmodes/viewmodesettings.h
 567         settings/viewmodes/viewsettingstab.h
 568         views/zoomlevelinfo.h)
 569
 570     target_sources(kcm_dolphingeneral PRIVATE
 571         settings/kcm/kcmdolphingeneral.cpp
 572         settings/interface/folderstabssettingspage.cpp
 573         settings/interface/statusandlocationbarssettingspage.cpp
 574         settings/interface/previewssettingspage.cpp
 575         settings/interface/confirmationssettingspage.cpp
 576         settings/settingspagebase.cpp
 577         settings/servicemodel.cpp
 578         dolphin_generalsettings.cpp
 579         dolphindebug.cpp
 580         dolphinmainwindowinterface.cpp
 581         views/viewproperties.cpp
 582         dolphin_directoryviewpropertysettings.cpp
 583         global.cpp
 584         settings/kcm/kcmdolphingeneral.h
 585         settings/interface/folderstabssettingspage.h
 586         settings/interface/statusandlocationbarssettingspage.h
 587         settings/interface/previewssettingspage.h
 588         settings/interface/confirmationssettingspage.h
 589         settings/settingspagebase.h
 590         settings/servicemodel.h
 591         dolphin_generalsettings.h
 592         dolphindebug.h
 593         dolphinmainwindowinterface.h
 594         views/viewproperties.h
 595         dolphin_directoryviewpropertysettings.h
 596         global.h
 597     )
 598
 599     kconfig_add_kcfg_files(kcm_dolphinviewmodes
 600         settings/dolphin_compactmodesettings.kcfgc
 601         settings/dolphin_directoryviewpropertysettings.kcfgc
 602         settings/dolphin_detailsmodesettings.kcfgc
 603         settings/dolphin_iconsmodesettings.kcfgc
 604         settings/dolphin_contentdisplaysettings.kcfgc
 605         settings/dolphin_generalsettings.kcfgc
 606         settings/dolphin_versioncontrolsettings.kcfgc
 607         GENERATE_MOC
 608     )
 609
 610     kconfig_add_kcfg_files(kcm_dolphingeneral
 611         settings/dolphin_generalsettings.kcfgc
 612         GENERATE_MOC
 613     )
 614
 615     target_link_libraries(kcm_dolphinviewmodes dolphinprivate)
 616     target_link_libraries(kcm_dolphingeneral dolphinprivate)
 617
 618     install( FILES org.kde.dolphin.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR} )
 619
 620     install(TARGETS kcm_dolphinviewmodes DESTINATION ${KDE_INSTALL_PLUGINDIR}/dolphin/kcms )
 621     install(TARGETS kcm_dolphingeneral DESTINATION ${KDE_INSTALL_PLUGINDIR}/dolphin/kcms )
 622 endif()
 623
 624 if(NOT WIN32)
 625     add_subdirectory(settings/contextmenu/servicemenuinstaller)
 626     install( FILES settings/contextmenu/servicemenu.knsrc DESTINATION ${KDE_INSTALL_KNSRCDIR} )
 627 endif()
 628
 629 ########### install files ###############
 630
 631 install( PROGRAMS org.kde.dolphin.desktop DESTINATION ${KDE_INSTALL_APPDIR} )
 632
 633 install( DIRECTORY DESTINATION "${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel" )
 634
 635 install(
 636     CODE "execute_process(COMMAND \"${CMAKE_COMMAND}\" -E create_symlink \"${KDE_INSTALL_FULL_APPDIR}/org.kde.dolphin.desktop\" \"\$ENV{DESTDIR}${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel/org.kde.dolphin.desktop\")"
 637 )
 638
 639 install( FILES settings/dolphin_directoryviewpropertysettings.kcfg
 640                settings/dolphin_generalsettings.kcfg
 641                settings/dolphin_contextmenusettings.kcfg
 642                settings/dolphin_compactmodesettings.kcfg
 643                settings/dolphin_iconsmodesettings.kcfg
 644                settings/dolphin_detailsmodesettings.kcfg
 645                settings/dolphin_contentdisplaysettings.kcfg
 646                settings/dolphin_versioncontrolsettings.kcfg
 647          DESTINATION ${KDE_INSTALL_KCFGDIR} )
 648
 649 install( FILES settings/dolphin_detailsmodesettings.upd
 650                settings/dolphin_directorysizemode.upd
 651                settings/dolphin_directorysizemode.py
 652                settings/dolphin_statusandlocationbarssettings.upd
 653                settings/dolphin_replace_view_mode_with_view_settings_in_toolbar.upd
 654                settings/dolphin_replace_view_mode_with_view_settings_in_toolbar.py
 655          DESTINATION ${KDE_INSTALL_KCONFUPDATEDIR} )
 656
 657 # install KF6 kconfig updater C++ scripts to kconf_update_bin
 658 add_executable(dolphin_25.04_update_statusandlocationbarssettings "settings/dolphin_25.04_update_statusandlocationbarssettings.cpp")
 659 target_link_libraries(dolphin_25.04_update_statusandlocationbarssettings
 660     KF6::ConfigCore
 661     KF6::XmlGui
 662 )
 663
 664 install(
 665     TARGETS
 666         dolphin_25.04_update_statusandlocationbarssettings
 667     DESTINATION ${KDE_INSTALL_LIBDIR}/kconf_update_bin
 668 )
 669
 670 if(BUILD_TESTING)
 671     add_subdirectory(tests)
 672 endif()
 673
 674 # movetonewfolderitemaction plugin
 675
 676 kcoreaddons_add_plugin(movetonewfolderitemaction
 677     SOURCES itemactions/movetonewfolderitemaction.cpp itemactions/movetonewfolderitemaction.h
 678     INSTALL_NAMESPACE "kf6/kfileitemaction")
 679
 680 target_link_libraries(movetonewfolderitemaction
 681     KF6::I18n
 682     KF6::KIOCore
 683     KF6::KIOWidgets
 684     KF6::KIOFileWidgets)