src/CMakeLists.txt

   1 macro_optional_find_package(NepomukCore)
   2 set_package_properties(NepomukCore PROPERTIES DESCRIPTION "Nepomuk Core libraries"
   3                        URL "http://www.kde.org"
   4                        TYPE OPTIONAL
   5                        PURPOSE "For adding desktop-wide tagging support to dolphin"
   6                       )
   7
   8 macro_optional_find_package(NepomukWidgets)
   9 set_package_properties(NepomukWidgets PROPERTIES DESCRIPTION "Nepomuk Widgets"
  10                        URL "http://www.kde.org"
  11                        TYPE OPTIONAL
  12                        PURPOSE "For adding desktop-wide tagging support to dolphin"
  13                       )
  14
  15 if(NepomukCore_FOUND AND NepomukWidgets_FOUND)
  16     set(HAVE_NEPOMUK TRUE)
  17 endif()
  18
  19 configure_file(config-nepomuk.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-nepomuk.h )
  20
  21 macro_bool_to_01(X11_Xrender_FOUND HAVE_XRENDER)
  22 configure_file(config-X11.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-X11.h )
  23
  24 include_directories( ${KACTIVITIES_INCLUDE_DIRS} )
  25
  26 if(HAVE_NEPOMUK)
  27   find_package(Soprano 2.7.56)
  28   set_package_properties(Soprano PROPERTIES DESCRIPTION "Qt-based RDF storage and parsing solution"
  29                          URL "http://soprano.sourceforge.net"
  30                          TYPE REQUIRED
  31                          PURPOSE "Required for everything (storage and general data management)"
  32                         )
  33
  34   include_directories( ${SOPRANO_INCLUDE_DIR} ${NEPOMUK_CORE_INCLUDE_DIR} ${NEPOMUK_WIDGETS_INCLUDE_DIR} )
  35 endif()
  36
  37 add_subdirectory(tests)
  38
  39 ########### next target ###############
  40
  41 set(dolphinprivate_LIB_SRCS
  42     kitemviews/kfileitemlistview.cpp
  43     kitemviews/kfileitemlistwidget.cpp
  44     kitemviews/kfileitemmodel.cpp
  45     kitemviews/kfileitemmodelrolesupdater.cpp
  46     kitemviews/kitemlistcontainer.cpp
  47     kitemviews/kitemlistcontroller.cpp
  48     kitemviews/kitemlistgroupheader.cpp
  49     kitemviews/kitemlistheader.cpp
  50     kitemviews/kitemlistselectionmanager.cpp
  51     kitemviews/kitemliststyleoption.cpp
  52     kitemviews/kitemlistview.cpp
  53     kitemviews/kitemlistviewaccessible.cpp
  54     kitemviews/kitemlistwidget.cpp
  55     kitemviews/kitemmodelbase.cpp
  56     kitemviews/kstandarditem.cpp
  57     kitemviews/kstandarditemlistgroupheader.cpp
  58     kitemviews/kstandarditemlistwidget.cpp
  59     kitemviews/kstandarditemlistview.cpp
  60     kitemviews/kstandarditemmodel.cpp
  61     kitemviews/private/kfileitemclipboard.cpp
  62     kitemviews/private/kfileitemmodeldirlister.cpp
  63     kitemviews/private/kfileitemmodelfilter.cpp
  64     kitemviews/private/kitemlistheaderwidget.cpp
  65     kitemviews/private/kitemlistkeyboardsearchmanager.cpp
  66     kitemviews/private/kitemlistroleeditor.cpp
  67     kitemviews/private/kitemlistrubberband.cpp
  68     kitemviews/private/kitemlistselectiontoggle.cpp
  69     kitemviews/private/kitemlistsizehintresolver.cpp
  70     kitemviews/private/kitemlistsmoothscroller.cpp
  71     kitemviews/private/kitemlistviewanimation.cpp
  72     kitemviews/private/kitemlistviewlayouter.cpp
  73     kitemviews/private/kpixmapmodifier.cpp
  74     settings/additionalinfodialog.cpp
  75     settings/applyviewpropsjob.cpp
  76     settings/viewmodes/viewmodesettings.cpp
  77     settings/viewpropertiesdialog.cpp
  78     settings/viewpropsprogressinfo.cpp
  79     views/dolphinfileitemlistwidget.cpp
  80     views/dolphinitemlistview.cpp
  81     views/dolphinnewfilemenuobserver.cpp
  82     views/dolphinremoteencoding.cpp
  83     views/dolphinview.cpp
  84     views/dolphinviewactionhandler.cpp
  85     views/draganddrophelper.cpp
  86     views/renamedialog.cpp
  87     views/tooltips/filemetadatatooltip.cpp
  88     views/tooltips/tooltipmanager.cpp
  89     views/versioncontrol/updateitemstatesthread.cpp
  90     views/versioncontrol/versioncontrolobserver.cpp
  91     views/viewmodecontroller.cpp
  92     views/viewproperties.cpp
  93     views/zoomlevelinfo.cpp
  94     dolphinremoveaction.cpp
  95 )
  96
  97 if(HAVE_NEPOMUK)
  98     set(dolphinprivate_LIB_SRCS
  99         ${dolphinprivate_LIB_SRCS}
 100         kitemviews/private/knepomukrolesprovider.cpp
 101     )
 102 endif()
 103
 104 kde4_add_kcfg_files(dolphinprivate_LIB_SRCS
 105     settings/dolphin_compactmodesettings.kcfgc
 106     settings/dolphin_directoryviewpropertysettings.kcfgc
 107     settings/dolphin_detailsmodesettings.kcfgc
 108     settings/dolphin_iconsmodesettings.kcfgc
 109     settings/dolphin_generalsettings.kcfgc
 110     settings/dolphin_versioncontrolsettings.kcfgc
 111 )
 112
 113 kde4_add_library(dolphinprivate SHARED ${dolphinprivate_LIB_SRCS})
 114
 115 target_link_libraries(
 116     dolphinprivate
 117     ${KDE4_KFILE_LIBS}
 118     konq
 119     ${KDE4_KNEWSTUFF3_LIBS}
 120 )
 121
 122 if(HAVE_NEPOMUK)
 123     target_link_libraries(
 124         dolphinprivate
 125         ${NEPOMUK_CORE_LIBRARY}
 126         ${NEPOMUK_WIDGETS_LIBRARY}
 127         ${SOPRANO_LIBRARIES}
 128     )
 129 endif()
 130
 131 if(X11_Xrender_FOUND)
 132     target_link_libraries(dolphinprivate ${X11_Xrender_LIB})
 133 endif(X11_Xrender_FOUND)
 134
 135 target_link_libraries(dolphinprivate ${KDE4_PLASMA_LIBS})
 136
 137 set_target_properties(dolphinprivate PROPERTIES VERSION ${GENERIC_LIB_VERSION} SOVERSION ${GENERIC_LIB_SOVERSION} )
 138 install(TARGETS dolphinprivate  ${INSTALL_TARGETS_DEFAULT_ARGS})
 139
 140 ##########################################
 141
 142 set(dolphinpart_SRCS
 143    dolphinpart.cpp
 144 )
 145
 146 # Add dolphinpart_ext.cpp conditionally, only with KDE > 4.9.1.
 147 if (${KDE_VERSION} VERSION_GREATER "4.9.1")
 148 set(dolphinpart_SRCS
 149     ${dolphinpart_SRCS}
 150     dolphinpart_ext.cpp)
 151 endif (${KDE_VERSION} VERSION_GREATER "4.9.1")
 152
 153 kde4_add_plugin(dolphinpart ${dolphinpart_SRCS})
 154
 155 target_link_libraries(dolphinpart dolphinprivate konq ${KDE4_KPARTS_LIBS} ${KDE4_KFILE_LIBS})
 156
 157 install(TARGETS dolphinpart DESTINATION ${PLUGIN_INSTALL_DIR})
 158
 159 install(FILES dolphinpart.rc DESTINATION ${DATA_INSTALL_DIR}/dolphinpart)
 160 install(FILES dolphinpart.desktop DESTINATION ${SERVICES_INSTALL_DIR} )
 161 install(FILES views/versioncontrol/fileviewversioncontrolplugin.desktop DESTINATION ${SERVICETYPES_INSTALL_DIR})
 162
 163 ##########################################
 164
 165 set(dolphin_SRCS
 166     dolphinapplication.cpp
 167     dolphindockwidget.cpp
 168     dolphinmainwindow.cpp
 169     dolphinnewfilemenu.cpp
 170     dolphinviewcontainer.cpp
 171     dolphincontextmenu.cpp
 172     filterbar/filterbar.cpp
 173     main.cpp
 174     panels/information/filemetadataconfigurationdialog.cpp
 175     panels/information/informationpanel.cpp
 176     panels/information/informationpanelcontent.cpp
 177     panels/information/pixmapviewer.cpp
 178     panels/information/phononwidget.cpp
 179     panels/places/placespanel.cpp
 180     panels/places/placesitem.cpp
 181     panels/places/placesitemeditdialog.cpp
 182     panels/places/placesitemlistgroupheader.cpp
 183     panels/places/placesitemlistwidget.cpp
 184     panels/places/placesitemmodel.cpp
 185     panels/places/placesitemsignalhandler.cpp
 186     panels/places/placesview.cpp
 187     panels/panel.cpp
 188     panels/folders/foldersitemlistwidget.cpp
 189     panels/folders/treeviewcontextmenu.cpp
 190     panels/folders/folderspanel.cpp
 191     search/dolphinfacetswidget.cpp
 192     search/dolphinsearchbox.cpp
 193     search/dolphinsearchinformation.cpp
 194     settings/general/behaviorsettingspage.cpp
 195     settings/general/configurepreviewplugindialog.cpp
 196     settings/general/confirmationssettingspage.cpp
 197     settings/general/generalsettingspage.cpp
 198     settings/general/previewssettingspage.cpp
 199     settings/general/statusbarsettingspage.cpp
 200     settings/dolphinsettingsdialog.cpp
 201     settings/navigation/navigationsettingspage.cpp
 202     settings/services/servicessettingspage.cpp
 203     settings/settingspagebase.cpp
 204     settings/serviceitemdelegate.cpp
 205     settings/servicemodel.cpp
 206     settings/startup/startupsettingspage.cpp
 207     settings/trash/trashsettingspage.cpp
 208     settings/viewmodes/dolphinfontrequester.cpp
 209     settings/viewmodes/viewsettingspage.cpp
 210     settings/viewmodes/viewmodesettings.cpp
 211     settings/viewmodes/viewsettingstab.cpp
 212     statusbar/dolphinstatusbar.cpp
 213     statusbar/statusbarspaceinfo.cpp
 214     views/zoomlevelinfo.cpp
 215 )
 216
 217 kde4_add_kcfg_files(dolphin_SRCS
 218     panels/folders/dolphin_folderspanelsettings.kcfgc
 219     panels/information/dolphin_informationpanelsettings.kcfgc
 220     panels/places/dolphin_placespanelsettings.kcfgc
 221     settings/dolphin_compactmodesettings.kcfgc
 222     settings/dolphin_detailsmodesettings.kcfgc
 223     settings/dolphin_generalsettings.kcfgc
 224     settings/dolphin_iconsmodesettings.kcfgc
 225     search/dolphin_searchsettings.kcfgc
 226     settings/dolphin_versioncontrolsettings.kcfgc
 227 )
 228
 229 if(NOT WIN32)
 230    set(dolphin_SRCS ${dolphin_SRCS} panels/terminal/terminalpanel.cpp)
 231 endif(NOT WIN32)
 232
 233 kde4_add_app_icon(dolphin_SRCS "${KDE4_ICON_INSTALL_DIR}/oxygen/*/apps/system-file-manager.png")
 234
 235 kde4_add_kdeinit_executable(dolphin ${dolphin_SRCS})
 236
 237 target_link_libraries(kdeinit_dolphin
 238     ${KDE4_KDEPRINT_LIBS}
 239     ${KDE4_KFILE_LIBS}
 240     ${KDE4_KPARTS_LIBS}
 241     ${KDE4_KCMUTILS_LIBRARY}
 242     konq
 243     dolphinprivate
 244     knewstuff3
 245     ${KDE4_SOLID_LIBS}
 246     ${KDE4_PHONON_LIBS}
 247 )
 248
 249 if(HAVE_NEPOMUK)
 250     target_link_libraries(kdeinit_dolphin
 251         ${NEPOMUK_CORE_LIBRARY}
 252         ${NEPOMUK_WIDGETS_LIBRARY}
 253         ${SOPRANO_LIBRARIES}
 254     )
 255 endif()
 256
 257 if (KActivities_FOUND)
 258     target_link_libraries(
 259         kdeinit_dolphin
 260         ${KACTIVITIES_LIBRARY}
 261     )
 262 endif (KActivities_FOUND)
 263
 264 install(TARGETS kdeinit_dolphin ${INSTALL_TARGETS_DEFAULT_ARGS})
 265 install(TARGETS dolphin ${INSTALL_TARGETS_DEFAULT_ARGS})
 266
 267 ##########################################
 268
 269 set(kcm_dolphinviewmodes_PART_SRCS
 270     settings/kcm/kcmdolphinviewmodes.cpp
 271     settings/viewmodes/dolphinfontrequester.cpp
 272     settings/viewmodes/viewmodesettings.cpp
 273     settings/viewmodes/viewsettingstab.cpp
 274     views/zoomlevelinfo.cpp)
 275
 276 set(kcm_dolphinnavigation_PART_SRCS
 277     settings/kcm/kcmdolphinnavigation.cpp
 278     settings/navigation/navigationsettingspage.cpp
 279     settings/settingspagebase.cpp)
 280
 281 set(kcm_dolphinservices_PART_SRCS
 282     settings/kcm/kcmdolphinservices.cpp
 283     settings/services/servicessettingspage.cpp
 284     settings/settingspagebase.cpp
 285     settings/serviceitemdelegate.cpp
 286     settings/servicemodel.cpp)
 287
 288 set(kcm_dolphingeneral_PART_SRCS
 289     settings/kcm/kcmdolphingeneral.cpp
 290     settings/general/behaviorsettingspage.cpp
 291     settings/general/previewssettingspage.cpp
 292     settings/general/configurepreviewplugindialog.cpp
 293     settings/general/confirmationssettingspage.cpp
 294     settings/settingspagebase.cpp
 295     settings/serviceitemdelegate.cpp
 296     settings/servicemodel.cpp)
 297
 298 kde4_add_kcfg_files(kcm_dolphinviewmodes_PART_SRCS
 299     settings/dolphin_compactmodesettings.kcfgc
 300     settings/dolphin_directoryviewpropertysettings.kcfgc
 301     settings/dolphin_detailsmodesettings.kcfgc
 302     settings/dolphin_iconsmodesettings.kcfgc
 303     settings/dolphin_generalsettings.kcfgc
 304     settings/dolphin_versioncontrolsettings.kcfgc
 305 )
 306
 307 kde4_add_kcfg_files(kcm_dolphinnavigation_PART_SRCS
 308     settings/dolphin_generalsettings.kcfgc)
 309
 310 kde4_add_kcfg_files(kcm_dolphinservices_PART_SRCS
 311     settings/dolphin_generalsettings.kcfgc
 312     settings/dolphin_versioncontrolsettings.kcfgc)
 313
 314 kde4_add_kcfg_files(kcm_dolphingeneral_PART_SRCS
 315     settings/dolphin_generalsettings.kcfgc)
 316
 317 kde4_add_plugin(kcm_dolphinviewmodes ${kcm_dolphinviewmodes_PART_SRCS})
 318 kde4_add_plugin(kcm_dolphinnavigation ${kcm_dolphinnavigation_PART_SRCS})
 319 kde4_add_plugin(kcm_dolphinservices ${kcm_dolphinservices_PART_SRCS})
 320 kde4_add_plugin(kcm_dolphingeneral ${kcm_dolphingeneral_PART_SRCS})
 321
 322 target_link_libraries(kcm_dolphinviewmodes  ${KDE4_KDEUI_LIBS} ${KDE4_KFILE_LIBS} dolphinprivate)
 323 target_link_libraries(kcm_dolphinnavigation  ${KDE4_KDEUI_LIBS} ${KDE4_KFILE_LIBS} dolphinprivate)
 324 target_link_libraries(kcm_dolphinservices  ${KDE4_KDEUI_LIBS} ${KDE4_KFILE_LIBS} ${KDE4_KIO_LIBS} ${KDE4_KNEWSTUFF3_LIBRARY} dolphinprivate)
 325 target_link_libraries(kcm_dolphingeneral ${KDE4_KDEUI_LIBS} ${KDE4_KFILE_LIBS} ${KDE4_KIO_LIBS} dolphinprivate)
 326 if(HAVE_NEPOMUK)
 327   target_link_libraries(kcm_dolphinviewmodes ${NEPOMUK_CORE_LIBRARY} ${NEPOMUK_WIDGETS_LIBRARY})
 328   target_link_libraries(kcm_dolphinnavigation ${NEPOMUK_CORE_LIBRARY} ${NEPOMUK_WIDGETS_LIBRARY})
 329   target_link_libraries(kcm_dolphinservices ${NEPOMUK_CORE_LIBRARY} ${NEPOMUK_WIDGETS_LIBRARY})
 330   target_link_libraries(kcm_dolphingeneral ${NEPOMUK_CORE_LIBRARY} ${NEPOMUK_WIDGETS_LIBRARY})
 331 endif()
 332
 333 install(TARGETS kcm_dolphinviewmodes DESTINATION ${PLUGIN_INSTALL_DIR} )
 334 install(TARGETS kcm_dolphinnavigation DESTINATION ${PLUGIN_INSTALL_DIR} )
 335 install(TARGETS kcm_dolphinservices DESTINATION ${PLUGIN_INSTALL_DIR} )
 336 install(TARGETS kcm_dolphingeneral DESTINATION ${PLUGIN_INSTALL_DIR} )
 337
 338 #########################################
 339
 340 set(kio_search_PART_SRCS
 341     search/filenamesearchprotocol.cpp)
 342 kde4_add_plugin(kio_filenamesearch ${kio_search_PART_SRCS})
 343 target_link_libraries(kio_filenamesearch ${KDE4_KIO_LIBS})
 344 install(TARGETS kio_filenamesearch DESTINATION ${PLUGIN_INSTALL_DIR})
 345
 346 ########### install files ###############
 347
 348 install( PROGRAMS dolphin.desktop DESTINATION ${XDG_APPS_INSTALL_DIR} )
 349 install( FILES settings/dolphin_directoryviewpropertysettings.kcfg
 350                settings/dolphin_generalsettings.kcfg
 351                settings/dolphin_compactmodesettings.kcfg
 352                settings/dolphin_iconsmodesettings.kcfg
 353                settings/dolphin_detailsmodesettings.kcfg
 354                settings/dolphin_versioncontrolsettings.kcfg
 355          DESTINATION ${KCFG_INSTALL_DIR} )
 356 install( FILES dolphinui.rc DESTINATION ${DATA_INSTALL_DIR}/dolphin )
 357 install( FILES search/filenamesearch.protocol DESTINATION ${SERVICES_INSTALL_DIR} )
 358 install( FILES settings/kcm/kcmdolphinviewmodes.desktop DESTINATION
 359 ${SERVICES_INSTALL_DIR} )
 360 install( FILES settings/kcm/kcmdolphinnavigation.desktop DESTINATION ${SERVICES_INSTALL_DIR} )
 361 install( FILES settings/kcm/kcmdolphinservices.desktop DESTINATION ${SERVICES_INSTALL_DIR} )
 362 install( FILES settings/kcm/kcmdolphingeneral.desktop DESTINATION ${SERVICES_INSTALL_DIR} )
 363 install( FILES settings/services/servicemenu.knsrc DESTINATION ${CONFIG_INSTALL_DIR} )
 364 install( PROGRAMS settings/services/servicemenuinstallation DESTINATION ${BIN_INSTALL_DIR} )
 365 install( PROGRAMS settings/services/servicemenudeinstallation DESTINATION ${BIN_INSTALL_DIR} )
 366